WOLFRAM

Wolfram 语言与系统参考资料中心

EccentricityCentrality[g]

给出图 g 中顶点的偏心率中心性列表.

EccentricityCentrality[{vw,…}]

用规则 vw 指定图 g.

更多信息
Details and Options Details and Options
背景
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

EccentricityCentrality

EccentricityCentrality[g]

给出图 g 中顶点的偏心率中心性列表.

EccentricityCentrality[{vw,…}]

用规则 vw 指定图 g.

更多信息

  • EccentricityCentrality 给出与每个其它可达到的顶点具有最短最大距离的顶点的高中心性.
  • 图 g 的 EccentricityCentrality 由 给出，其中 是从顶点 到所有与 相连的顶点的最大距离.
  • 孤立顶点的偏心率中心性为零.
  • EccentricityCentrality 可用于无向图、有向图、加权图、多重图和混合图.

背景

  • EccentricityCentrality 返回一个由非负机器精度数值构成的列表（“偏心率中心度”）作为图顶点的某种特定的中心性度量的近似值. 偏心率中心度是对网络中一个结点的中心性的度量，这个值基于从一个顶点 到所有其它可达结点的最短距离中的最大值（即图偏心率）. 这一度量在社交网络、交通、生物学和社会科学中都有应用.
  • 若 是从顶点 到所有其它与之相连的顶点的最大距离，那么偏心率中心度就是 . 孤立顶点的偏心率中心度为零. 偏心率中心度介于 0 和 1 之间（包括两端）.
  • 一个顶点的偏心率中心度是其 VertexEccentricity 的倒数. 图的全距离矩阵可以用 GraphDistanceMatrix 计算.

范例

打开所有单元 关闭所有单元

基本范例  (2)

计算偏心率中心性：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: EccentricityCentrality[g]

突出显示：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

对顶点排序. 排序在前面的顶点位于其它每个可达到顶点的短距离内：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: Part[VertexList[g], Ordering[EccentricityCentrality[g], All, Greater]]

范围  (7)

EccentricityCentrality 可用于无向图：

Wolfram Language code: EccentricityCentrality[[image]]

有向图：

Wolfram Language code: EccentricityCentrality[[image]]

加权图：

Wolfram Language code: EccentricityCentrality[[image]]

多重图：

Wolfram Language code: EccentricityCentrality[[image]]

混合图：

Wolfram Language code: EccentricityCentrality[[image]]

用规则指定图：

Wolfram Language code: EccentricityCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

EccentricityCentrality 可用于大规模图：

Wolfram Language code: g = RandomGraph[{10000, 10005}];
Wolfram Language code: EccentricityCentrality[g]//Short//Timing

应用  (5)

按偏心率对顶点排序：

Wolfram Language code: g = [image];
Wolfram Language code: SortBy[{VertexList[g], EccentricityCentrality[g]}, Last]//Reverse

突出显示 CycleGraph 的偏心率中心性：

Wolfram Language code: HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];
Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];
Wolfram Language code: cc = EccentricityCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

GridGraph:

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];
Wolfram Language code: cc = EccentricityCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree:

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];
Wolfram Language code: cc = EccentricityCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

PathGraph:

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];
Wolfram Language code: cc = EccentricityCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

在 Micronesia 东部的 Marshall 群岛的基建网络基础上，找到一个经过策略布局的岛屿：

Wolfram Language code: g = [image];
Wolfram Language code: With[{c = EccentricityCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

它与图的中位数不同：

Wolfram Language code: With[{d = Total[GraphDistanceMatrix[g]]}, Pick[VertexList[g], d, Min[d]]]

连接芝加哥郊区的公路网络. 求医院和消防部门的最佳位置，以最小化紧急车辆行驶的距离：

Wolfram Language code: g = [image];
Wolfram Language code: With[{c = EccentricityCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

对于具有 个距离的图，最中心的顶点和所有其他顶点之间的偏心率差异的最大和是 的倒数：

Wolfram Language code: n = 10; g = StarGraph[n]; c = EccentricityCentrality[g];
Wolfram Language code: {Total[Max[c] - c], (n - 1) / 2.}

测量最中心的顶点关于其他顶点的中心度：

Wolfram Language code: eccentricity[g_] := With[{c = EccentricityCentrality[g], n = VertexCount[g]}, N[Total[Max[c] - c] / ((n - 1) / 2)]]

将社会网络中心化处理：

Wolfram Language code: eccentricity[ExampleData[{"NetworkGraph", "ZacharyKarateClub"}]]
Wolfram Language code: eccentricity[ExampleData[{"NetworkGraph", "DolphinSocialNetwork"}]]

属性和关系  (6)

EccentricityCentrality 是与其他可达到顶点的最大距离的逆：

Wolfram Language code: g = [image];
Wolfram Language code: EccentricityCentrality[g]

与其他可达到顶点的最大距离的逆：

Wolfram Language code: d = GraphDistanceMatrix[g];
Wolfram Language code: 1. / Map[Max, DeleteCases[d, 0 | ∞, {2}]]

顶点的偏心率中心性是 VertexEccentricity 的倒数：

Wolfram Language code: g = RandomGraph[{6, 9}]
Wolfram Language code: Table[1. / VertexEccentricity[g, i], {i, VertexList[g]}]
Wolfram Language code: EccentricityCentrality[g]

偏心率中心性位于0和1之间：

Wolfram Language code: Through[{Min, Max}[EccentricityCentrality [RandomGraph[{100, 200}]]]]

无向图的偏心率中心性等于每个分量的中心性：

Wolfram Language code: g = [image];
Wolfram Language code: EccentricityCentrality[g]

计算每个分量的中心性给出相同结果：

Wolfram Language code: {g1, g2} = Subgraph[g, #]& /@ ConnectedComponents[g]
Wolfram Language code: {EccentricityCentrality[g1], EccentricityCentrality[g2]}
Wolfram Language code: Join@@%

使用 GraphCenter 求具有最高偏心率中心性的顶点：

Wolfram Language code: g = [image];
Wolfram Language code: GraphCenter[g]
Wolfram Language code: With [{c = EccentricityCentrality[g]}, Pick[VertexList[g], c, Max[c]]]

使用 VertexIndex 获取特定顶点的中心性：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: EccentricityCentrality[g][[VertexIndex[g, "Anna"]]]
Wolfram Research (2012)，EccentricityCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EccentricityCentrality.html （更新于 2015 年）.

文本

Wolfram Research (2012)，EccentricityCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EccentricityCentrality.html （更新于 2015 年）.

CMS

Wolfram 语言. 2012. "EccentricityCentrality." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/EccentricityCentrality.html.

APA

Wolfram 语言. (2012). EccentricityCentrality. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EccentricityCentrality.html 年

BibTeX

@misc{reference.wolfram_2026_eccentricitycentrality, author="Wolfram Research", title="{EccentricityCentrality}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/EccentricityCentrality.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_eccentricitycentrality, organization={Wolfram Research}, title={EccentricityCentrality}, year={2015}, url={https://reference.wolfram.com/language/ref/EccentricityCentrality.html}, note=[Accessed: 13-September-2026]}