WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EigenvectorCentrality[g]

グラフ g 中の頂点の固有ベクトル中心性のリストを与える．

EigenvectorCentrality[g,"In"]

有向グラフ g の入中心性のリストを与える．

EigenvectorCentrality[g,"Out"]

有向グラフ g の出中心性のリストを与える．

EigenvectorCentrality[{vw,…},…]

規則 vw を使ってグラフ g を指定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
WorkingPrecision  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

EigenvectorCentrality

EigenvectorCentrality[g]

グラフ g 中の頂点の固有ベクトル中心性のリストを与える．

EigenvectorCentrality[g,"In"]

有向グラフ g の入中心性のリストを与える．

EigenvectorCentrality[g,"Out"]

有向グラフ g の出中心性のリストを与える．

EigenvectorCentrality[{vw,…},…]

規則 vw を使ってグラフ g を指定する．

詳細とオプション

  • EigenvectorCentralityは数多くの頂点と連結している頂点と多数連結している頂点に高い中心性を与える．
  • EigenvectorCentralityは近傍の中心性の重み付き総和として表すことができる中心性 のリストを与える．
  • がグラフ g の隣接行列 の最大固有値のときは次のようになる．
  • EigenvectorCentrality[g]c=TemplateBox[{{{1, /, {lambda, _, 1}}, a}}, Transpose].c
    EigenvectorCentrality[g,"In"]c=TemplateBox[{{{1, /, {lambda, _, 1}}, a}}, Transpose].c, 左固有ベクトル
    EigenvectorCentrality[g,"Out"], 右固有ベクトル
  • 固有ベクトルの中心性は正規化される．
  • 有向グラフ g については，EigenvectorCentrality[g]はEigenvectorCentrality[g,"In"]と等価である．
  • オプションWorkingPrecision->p を使って内部計算で使われる精度が制御できる．
  • EigenvectorCentralityは，無向グラフ，有向グラフ，多重グラフ，混合グラフに使うことができる．

例題

すべて開く すべて閉じる

例  (2)

固有ベクトル中心性を計算する：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: EigenvectorCentrality[g]

ハイライトする：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

頂点に順位を付ける．順位が最も高い頂点はたくさんの連結を持つ多くの頂点に連結されている：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: Part[VertexList[g], Ordering[EigenvectorCentrality[g], All, Greater]]

スコープ  (7)

EigenvectorCentralityは無向グラフに使うことができる：

Wolfram Language code: EigenvectorCentrality[[image]]

有向グラフに使う：

Wolfram Language code: EigenvectorCentrality[[image]]

多重グラフ：

Wolfram Language code: EigenvectorCentrality[[image]]

混合グラフ：

Wolfram Language code: EigenvectorCentrality[[image]]

規則を使ってグラフを指定する：

Wolfram Language code: EigenvectorCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

入中心性と出中心性を計算する：

Wolfram Language code: EigenvectorCentrality[[image], "In"]
Wolfram Language code: EigenvectorCentrality[[image], "Out"]

EigenvectorCentralityは大きいグラフに使うことができる：

Wolfram Language code: g = RandomGraph[{10000, 10005}];
Wolfram Language code: EigenvectorCentrality[g]//Short//Timing

オプション  (3)

WorkingPrecision  (3)

デフォルトで，EigenvectorCentralityは機械精度計算で中心性を求める：

Wolfram Language code: EigenvectorCentrality[[image]]

より高い作業精度を指定する：

Wolfram Language code: EigenvectorCentrality[[image], WorkingPrecision -> 50]

無限作業精度は厳密計算に相当する：

Wolfram Language code: EigenvectorCentrality[[image], WorkingPrecision -> ∞]

アプリケーション  (9)

他のたくさんの接続がある頂点との接続性で頂点をランク付けする：

Wolfram Language code: g = [image];

頂点を中心性の高いものから低いものへと並べる：

Wolfram Language code: SortBy[{VertexList[g], EigenvectorCentrality[g]}, Last]//Reverse

CycleGraphの固有ベクトル中心性をハイライトする：

Wolfram Language code: HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];
Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];
Wolfram Language code: cc = EigenvectorCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

GridGraph：

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];
Wolfram Language code: cc = EigenvectorCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree：

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];
Wolfram Language code: cc = EigenvectorCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

PathGraph：

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];
Wolfram Language code: cc = EigenvectorCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

ソーシャルネットワークでうまく繋がっている人々を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "ZacharyKarateClub"}];
Wolfram Language code: Part[VertexList[g], Ordering[EigenvectorCentrality[g], -10]]

ネットワークをハイライトする：

Wolfram Language code: HighlightGraph[g, %]

学生Aが学生Bに意見を求める場合の学生Aから学生Bへの接続から，学生自治会ネットワークで最も影響力の強いメンバーを求める：

Wolfram Language code: g = [image];
Wolfram Language code: Part[VertexList[g], Ordering[EigenvectorCentrality[g], -10]]

arXiv e-Printアーカイブのgh Energy Physics Phenomenologyセクションからの引用ネットワーク．最も引用されている上位10本の論文を求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "HighEnergyPhysicsPhenomenology"}];
Wolfram Language code: c = EigenvectorCentrality[g, "In"];
Wolfram Language code: Part[VertexList[g], Ordering[c, -10]]

自立システムのレベルでのインターネットのハブを求める：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Internet"}];
Wolfram Language code: SortBy[VertexList[g], VertexDegree[g, #]&]//Reverse//Shallow

ハブはたくさんの連結点を持つ頂点で固有ベクトル中心性が最も高いものである：

Wolfram Language code: c = EigenvectorCentrality[g]; Table[VertexList[g][[i]], {i, Ordering[c, -4]}]

削除するとイーストのタンパク質相互作用ネットワークに致命的な影響を与えるタンパク質を求める：

Wolfram Language code: UndirectedGraph[ExampleData[{"NetworkGraph", "ProteinInteraction"}]];
Wolfram Language code: network = Subgraph[%, First[ConnectedComponents[%]]];

固有ベクトル中心性が最大のタンパク質：

Wolfram Language code: Short[c = EigenvectorCentrality[network]]
Wolfram Language code: Pick[VertexList[network], c, Max[c]]

このタンパク質を削除するとネットワークの直径が増大する：

Wolfram Language code: {GraphDiameter[network], GraphDiameter[VertexDelete[network, %]]}

「出芽酵母」タンパク質相互作用ネットワーク．固有ベクトル中心性の頻度はベキ法則分布に従う：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "WholeNetworkSaccharomycesCerevisiae"}];
Wolfram Language code: c = EigenvectorCentrality[g];
Wolfram Language code: hist = Histogram[c, {"Log", 10}, {"Log", "PDF"}, Ticks -> None]

パレート(Pareto)分布を仮定して最大尤度母数推定を求める：

Wolfram Language code: 𝒟 = EstimatedDistribution[Cases[c, x_ /; x > 0], ParetoDistribution[k, α]]

確率密度関数：

Wolfram Language code: PDF[𝒟, k]
Wolfram Language code: Show[{hist, LogLogPlot[PDF[𝒟, x], {x, 10^-14, 0.01}]}]

インターネットで注文を受けて商品を郵送する機関の人間とコンピュータのシステム．最も多くの人員を配備すべき部署を求める：

Wolfram Language code: g = [image];
Wolfram Language code: With[{c = EigenvectorCentrality[g]}, Part[VertexList[g], Ordering[c, -2]]]

ほとんどのサービスがシステム管理部と注文管理部に依存している：

Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, %]]

特性と関係  (6)

無向グラフの場合，中心性ベクトル は方程式 を満たす：

Wolfram Language code: g = [image];
Wolfram Language code: c = EigenvectorCentrality[g]; a = N[AdjacencyMatrix[g]]; Subscript[λ, 1] = First[Eigenvalues[a, 1]];
Wolfram Language code: c == (1 / Subscript[λ, 1]) a.c

有向グラフの場合，入中心性ベクトル は方程式 を満たす：

Wolfram Language code: g = [image];
Wolfram Language code: c = EigenvectorCentrality[g, "In"]; a = N[AdjacencyMatrix[g]]; Subscript[λ, 1] = First[Eigenvalues[a, 1]];
Wolfram Language code: c == (1 / Subscript[λ, 1]) a.c

出中心性ベクトル は方程式 を満たす：

Wolfram Language code: c = EigenvectorCentrality[g, "Out"]; Subscript[λ, 1] = First[Eigenvalues[a, 1]];
Wolfram Language code: c == (1 / Subscript[λ, 1]) a.c

固有ベクトル中心性は正規化される：

Wolfram Language code: EigenvectorCentrality[[image]]
Wolfram Language code: Total[%]

不連続グラフの場合，中心性は連結成分について正規化される：

Wolfram Language code: g = [image];
Wolfram Language code: c = Last[ConnectedComponents[g]]
Wolfram Language code: Part[EigenvectorCentrality[g], c]

連結成分によって生成された部分グラフの中心性：

Wolfram Language code: h = Subgraph[g, c];
Wolfram Language code: EigenvectorCentrality[h] * (VertexCount[h] - 1) / (VertexCount[g] - Length[ConnectedComponents[g]])

EigenvectorCentralityはKatzCentralityの特殊ケースである：

Wolfram Language code: g = [image];
Wolfram Language code: EigenvectorCentrality[g]

と をKatzCentralityのパラメータとして使う：

Wolfram Language code: α = 1 / First@Eigenvalues[N@AdjacencyMatrix[g], 1]
Wolfram Language code: KatzCentrality[g, α, 0] // Normalize[#, Total]&

VertexIndexを使って特定の頂点の中心性を得る：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: EigenvectorCentrality[g][[VertexIndex[g, "Anna"]]]
Wolfram Research (2010), EigenvectorCentrality, Wolfram言語関数， https://reference.wolfram.com/language/ref/EigenvectorCentrality.html （2015年に更新）.

テキスト

Wolfram Research (2010), EigenvectorCentrality, Wolfram言語関数， https://reference.wolfram.com/language/ref/EigenvectorCentrality.html （2015年に更新）.

CMS

Wolfram Language. 2010. "EigenvectorCentrality." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2015. https://reference.wolfram.com/language/ref/EigenvectorCentrality.html.

APA

Wolfram Language. (2010). EigenvectorCentrality. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EigenvectorCentrality.html

BibTeX

@misc{reference.wolfram_2026_eigenvectorcentrality, author="Wolfram Research", title="{EigenvectorCentrality}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/EigenvectorCentrality.html}", note=[Accessed: 14-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_eigenvectorcentrality, organization={Wolfram Research}, title={EigenvectorCentrality}, year={2015}, url={https://reference.wolfram.com/language/ref/EigenvectorCentrality.html}, note=[Accessed: 14-October-2026]}