WOLFRAM

Wolfram 语言与系统参考资料中心

EigenvectorCentrality[g]

给出图 g 中的顶点的特征向量中心度列表.

EigenvectorCentrality[g,"In"]

给出有向图 g 的内中心度列表.

EigenvectorCentrality[g,"Out"]

给出有向图 g 的外中心度列表.

EigenvectorCentrality[{vw,…},…]

用规则 vw 指定图 g.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
WorkingPrecision  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

EigenvectorCentrality

EigenvectorCentrality[g]

给出图 g 中的顶点的特征向量中心度列表.

EigenvectorCentrality[g,"In"]

给出有向图 g 的内中心度列表.

EigenvectorCentrality[g,"Out"]

给出有向图 g 的外中心度列表.

EigenvectorCentrality[{vw,…},…]

用规则 vw 指定图 g.

更多信息和选项

  • EigenvectorCentrality 对于与许多其他连接度很好的顶点相连接的顶点，给出高中心度.
  • EigenvectorCentrality 给出中心度 组成的列表，这些中心度可以表示为邻节点的中心度的加权和.
  • 当 是图 g 中邻接矩阵 的最大特征值时，我们有：
  • EigenvectorCentrality[g]c=TemplateBox[{{{1, /, {lambda, _, 1}}, a}}, Transpose].c
    EigenvectorCentrality[g,"In"]c=TemplateBox[{{{1, /, {lambda, _, 1}}, a}}, Transpose].c， 左特征向量
    EigenvectorCentrality[g,"Out"]， 右特征向量
  • 特征向量中心度是经过规范化处理的.
  • 对于有向图 g，EigenvectorCentrality[g] 等价于 EigenvectorCentrality[g,"In"].
  • 选项 WorkingPrecision->p 可用于控制在内部计算中所用的精度.
  • EigenvectorCentrality 作用于无向图、有向图、多重图和混合图.

范例

打开所有单元 关闭所有单元

基本范例  (2)

计算特征向量中心度：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: EigenvectorCentrality[g]

突出显示：

Wolfram Language code: HighlightGraph[g, VertexList[g], VertexSize -> Thread[VertexList[g] -> Rescale[%]]]

对顶点排序. 与许多连接度很好的顶点相连接的顶点排在最前面.

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: Part[VertexList[g], Ordering[EigenvectorCentrality[g], All, Greater]]

范围  (7)

EigenvectorCentrality 可用于无向图：

Wolfram Language code: EigenvectorCentrality[[image]]

有向图：

Wolfram Language code: EigenvectorCentrality[[image]]

多重图：

Wolfram Language code: EigenvectorCentrality[[image]]

混合图：

Wolfram Language code: EigenvectorCentrality[[image]]

用规则指定图：

Wolfram Language code: EigenvectorCentrality[{1 -> 3, 2 -> 1, 3 -> 6, 4 -> 6, 1 -> 5, 5 -> 4, 6 -> 1}]

计算入度中心度和出度中心度：

Wolfram Language code: EigenvectorCentrality[[image], "In"]
Wolfram Language code: EigenvectorCentrality[[image], "Out"]

EigenvectorCentrality 作用于大规模图：

Wolfram Language code: g = RandomGraph[{10000, 10005}];
Wolfram Language code: EigenvectorCentrality[g]//Short//Timing

选项  (3)

WorkingPrecision  (3)

默认情况下，EigenvectorCentrality 利用机器精度计算求中心度：

Wolfram Language code: EigenvectorCentrality[[image]]

指定较高的工作精度：

Wolfram Language code: EigenvectorCentrality[[image], WorkingPrecision -> 50]

无穷大的工作精度对应于精确计算：

Wolfram Language code: EigenvectorCentrality[[image], WorkingPrecision -> ∞]

应用  (9)

根据与其他连接度很好的顶点的连接度，对顶点排序：

Wolfram Language code: g = [image];

按照从最高到最低中心度，对顶点排序：

Wolfram Language code: SortBy[{VertexList[g], EigenvectorCentrality[g]}, Last]//Reverse

突出显示 CycleGraph 的特征向量中心度：

Wolfram Language code: HighlightCentrality[g_, cc_] := HighlightGraph[g, Table[Style[VertexList[g][[i]], ColorData["TemperatureMap"][cc[[i]] / Max[cc]]], {i, VertexCount[g]}]];
Wolfram Language code: g = CycleGraph[8, VertexSize -> Large];
Wolfram Language code: cc = EigenvectorCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

GridGraph:

Wolfram Language code: g = GridGraph[{10, 10}, VertexSize -> Large];
Wolfram Language code: cc = EigenvectorCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

CompleteKaryTree:

Wolfram Language code: g = CompleteKaryTree[3, 3, VertexSize -> Large];
Wolfram Language code: cc = EigenvectorCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

PathGraph:

Wolfram Language code: g = PathGraph[Range[20], VertexSize -> Large];
Wolfram Language code: cc = EigenvectorCentrality[g];
Wolfram Language code: HighlightCentrality[g, cc]

求一个社交网络中连接度良好的人员：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "ZacharyKarateClub"}];
Wolfram Language code: Part[VertexList[g], Ordering[EigenvectorCentrality[g], -10]]

突出显示该网络：

Wolfram Language code: HighlightGraph[g, %]

如果 A 学生咨询 B 学生的意见，求从 A 学生到 B 学生具有链接的学生会网络中最有影响力的成员：

Wolfram Language code: g = [image];
Wolfram Language code: Part[VertexList[g], Ordering[EigenvectorCentrality[g], -10]]

存档的高能物理现象部门的引用文献网络. 求排名前10的重要文献：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "HighEnergyPhysicsPhenomenology"}];
Wolfram Language code: c = EigenvectorCentrality[g, "In"];
Wolfram Language code: Part[VertexList[g], Ordering[c, -10]]

在自治系统水平，求网络的核心节点：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Internet"}];
Wolfram Language code: SortBy[VertexList[g], VertexDegree[g, #]&]//Reverse//Shallow

核心节点是连通度良好的顶点，并且具有最高特征向量中心度：

Wolfram Language code: c = EigenvectorCentrality[g]; Table[VertexList[g][[i]], {i, Ordering[c, -4]}]

求一个蛋白质，删除蛋白质后将导致酵母的蛋白质交互网络中出现致命性：

Wolfram Language code: UndirectedGraph[ExampleData[{"NetworkGraph", "ProteinInteraction"}]];
Wolfram Language code: network = Subgraph[%, First[ConnectedComponents[%]]];

具有最大特征向量中心度的蛋白质：

Wolfram Language code: Short[c = EigenvectorCentrality[network]]
Wolfram Language code: Pick[VertexList[network], c, Max[c]]

删除蛋白质增加了网络的半径：

Wolfram Language code: {GraphDiameter[network], GraphDiameter[VertexDelete[network, %]]}

Saccharomyces cerevisiae 蛋白质交互网络. 特征向量中心度的频率服从幂律分布：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "WholeNetworkSaccharomycesCerevisiae"}];
Wolfram Language code: c = EigenvectorCentrality[g];
Wolfram Language code: hist = Histogram[c, {"Log", 10}, {"Log", "PDF"}, Ticks -> None]

假定采用齐夫分布，获得最大似然参数估计：

Wolfram Language code: 𝒟 = EstimatedDistribution[Cases[c, x_ /; x > 0], ParetoDistribution[k, α]]

概率密度函数：

Wolfram Language code: PDF[𝒟, k]
Wolfram Language code: Show[{hist, LogLogPlot[PDF[𝒟, x], {x, 10^-14, 0.01}]}]

某组织的人机系统处理网络订单，并且通过邮件发送货物. 求应该给予最多资源的部门：

Wolfram Language code: g = [image];
Wolfram Language code: With[{c = EigenvectorCentrality[g]}, Part[VertexList[g], Ordering[c, -2]]]

大部分服务依赖于系统管理部门，以及注册订单部门：

Wolfram Language code: HighlightGraph[g, NeighborhoodGraph[g, %]]

属性和关系  (6)

对于无向图，中心度向量 满足方程 ：

Wolfram Language code: g = [image];
Wolfram Language code: c = EigenvectorCentrality[g]; a = N[AdjacencyMatrix[g]]; Subscript[λ, 1] = First[Eigenvalues[a, 1]];
Wolfram Language code: c == (1 / Subscript[λ, 1]) a.c

对于有向图，入度向量 满足方程 :

Wolfram Language code: g = [image];
Wolfram Language code: c = EigenvectorCentrality[g, "In"]; a = N[AdjacencyMatrix[g]]; Subscript[λ, 1] = First[Eigenvalues[a, 1]];
Wolfram Language code: c == (1 / Subscript[λ, 1]) a.c

出度中心度向量 满足方程 ：

Wolfram Language code: c = EigenvectorCentrality[g, "Out"]; Subscript[λ, 1] = First[Eigenvalues[a, 1]];
Wolfram Language code: c == (1 / Subscript[λ, 1]) a.c

特征向量中心度被规范化处理：

Wolfram Language code: EigenvectorCentrality[[image]]
Wolfram Language code: Total[%]

对于非连通图，中心度关于连通分量进行规范化处理：

Wolfram Language code: g = [image];
Wolfram Language code: c = Last[ConnectedComponents[g]]
Wolfram Language code: Part[EigenvectorCentrality[g], c]

由连接分量生成的子图的中心度：

Wolfram Language code: h = Subgraph[g, c];
Wolfram Language code: EigenvectorCentrality[h] * (VertexCount[h] - 1) / (VertexCount[g] - Length[ConnectedComponents[g]])

EigenvectorCentrality 是 KatzCentrality 的一个特例：

Wolfram Language code: g = [image];
Wolfram Language code: EigenvectorCentrality[g]

将 和 作为 KatzCentrality 的参数使用：

Wolfram Language code: α = 1 / First@Eigenvalues[N@AdjacencyMatrix[g], 1]
Wolfram Language code: KatzCentrality[g, α, 0] // Normalize[#, Total]&

使用 VertexIndex 获取特定顶点的中心度：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "Friendship"}];
Wolfram Language code: EigenvectorCentrality[g][[VertexIndex[g, "Anna"]]]
Wolfram Research (2010)，EigenvectorCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EigenvectorCentrality.html （更新于 2015 年）.

文本

Wolfram Research (2010)，EigenvectorCentrality，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EigenvectorCentrality.html （更新于 2015 年）.

CMS

Wolfram 语言. 2010. "EigenvectorCentrality." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/EigenvectorCentrality.html.

APA

Wolfram 语言. (2010). EigenvectorCentrality. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EigenvectorCentrality.html 年

BibTeX

@misc{reference.wolfram_2026_eigenvectorcentrality, author="Wolfram Research", title="{EigenvectorCentrality}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/EigenvectorCentrality.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_eigenvectorcentrality, organization={Wolfram Research}, title={EigenvectorCentrality}, year={2015}, url={https://reference.wolfram.com/language/ref/EigenvectorCentrality.html}, note=[Accessed: 15-September-2026]}