WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Element[x,dom]

または x∈dom は，x が領域 dom の要素であることを宣言する．

Element[x,reg]

または x∈reg は，x が領域 reg の要素であることを宣言する．

Element[x1|x2|…,dom]

すべての xiが dom の要素であることを宣言する．

Element[patt,dom]

パターン patt にマッチする任意の式が dom の要素であることを宣言する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Element

Element[x,dom]

または x∈dom は，x が領域 dom の要素であることを宣言する．

Element[x,reg]

または x∈reg は，x が領域 reg の要素であることを宣言する．

Element[x1|x2|…,dom]

すべての xiが dom の要素であることを宣言する．

Element[patt,dom]

パターン patt にマッチする任意の式が dom の要素であることを宣言する．

詳細

  • x∈dom は，x el dom または x \[Element] dom として入力できる．
  • Elementは，Simplifyおよび関連する関数の仮定を設定するのに使用される．
  • dom は，数値領域あるいはにおける領域である．
  • 可能な領域 dom
  • Algebraics代数的数
    BooleansTrueまたはFalse
    Complexes複素数
    Integers整数
    Primes素数
    Rationals有理数
    Reals実数
  • 可能な領域 reg はRegionQによって定義される．
  • x が数値の場合，x∈dom は，可能なら直ちに評価される．
  • 領域 dom については，{x1,x2,…}∈domは(x1|x2|…)∈dom と同等である．
  • 領域 reg については，{x1,x2,…}∈reg は座標x1,x2,…の点は reg に属すると宣言する．
  • {x1,x2,…}∈dom は，真偽が直ちに決定できない場合，(x1|x2|…)∈dom に評価される．

例題

すべて開く すべて閉じる

例  (5)

が実数の要素かどうかの検定を行う：

Wolfram Language code: Pi ∈ Reals

点が単位円板に属するかどうかの検定を行う：

Wolfram Language code: {1 / 2, 1 / 3}∈Disk[]

式の領域構成を表す：

Wolfram Language code: Element[x + y, Reals]

点 が単位球体に属すると宣言する：

Wolfram Language code: Element[{x, y, z}, Ball[]]

要素の宣言を使って領域上で積分する：

Wolfram Language code: Integrate[1, {x, y, z}∈Ball[]]

あるいは，領域上で最適化する：

Wolfram Language code: MinValue[x + y, {x, y, z}∈Ball[]]

elemを使って入力する：

Wolfram Language code: x∈Reals

スコープ  (9)

領域構成の検定を行う：

Wolfram Language code: Element[Sqrt[2], #]& /@ {Complexes, Algebraics, Reals, Rationals, Integers, Primes}

領域の帰属判定：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{1, 1}]; Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}]; Subscript[ℛ, 3] = ImplicitRegion[x ^ 2 ≤ y ^ 3 + 1, {x, y}]; Subscript[ℛ, 4] = RegionUnion[Disk[{-1, 0}], Line[{{0, 0}, {2, 2}}]];
Wolfram Language code: Element[{3 / 2, 3 / 2}, #]& /@ {Subscript[ℛ, 1], Subscript[ℛ, 2], Subscript[ℛ, 3], Subscript[ℛ, 4]}

これをプロットする：

Wolfram Language code: Show[{DiscretizeRegion[Subscript[ℛ, 3]], Graphics[{{Opacity[0.5], {Orange, Subscript[ℛ, 1]}, {Yellow, Subscript[ℛ, 2]}, {Green, Disk[{-1, 0}], Line[{{0, 0}, {2, 2}}]}}, {Red, PointSize[Large], Point[{3 / 2, 3 / 2}]}}]}]

領域構成の仮定をする：

Wolfram Language code: Refine[Sin[Pi x], Element[x, Integers]]
Wolfram Language code: Integrate[Abs[1 - Abs[x + 2]], x, Assumptions -> Element[x, Reals]]

領域の帰属関係を表す：

Wolfram Language code: Refine[Sqrt[(x + y - 2) ^ 2], Element[{x, y}, Disk[]]]
Wolfram Language code: Solve[x + y == 1 / 2 && Element[{x, y}, Circle[]], {x, y}]
Wolfram Language code: Integrate[1, Element[{x, y}, Circle[]]]

仮定を使って領域構成の検定を行う：

Wolfram Language code: Refine[Element[x ^ y + Log[x + y], Reals], x > 0 && y > 0]

仮定を使って領域の帰属判定を行う：

Wolfram Language code: Refine[Element[{x, y}, Rectangle[{-1, -1}, {1, 1}]], x ^ 2 + y ^ 2 ≤ 1]

変数の領域を指定する：

Wolfram Language code: Reduce[E ^ x - 2x == 3 && Element[x, Reals], x]
Wolfram Language code: FindInstance[x ^ 2 - 2y ^ 2 == 1 && x > 10 ^ 10 && Element[x | y, Integers], {x, y}]
Wolfram Language code: Minimize[{x - y, x ^ 2 + y ^ 2 ≤ 100 && Element[x | y, Integers]}, {x, y}]

パターンにマッチするオブジェクトの仮定を指定する：

Wolfram Language code: Simplify[Sin[2Pi x[1] + 4x[2]x[3] ^ 2Pi + a Pi], Element[x[_], Integers]]

TraditionalFormによる表示：

Wolfram Language code: Element[x, Reals]//TraditionalForm

特性と関係  (2)

単一の変数の場合，Elementの否定は自動的にNotElementに変換される：

Wolfram Language code: !Element[a, Reals]

変数が複数の場合，Elementの否定は自動的には簡約されない：

Wolfram Language code: !Element[a | b | c, Reals]

LogicalExpandを使ってNotElementについての表現を求める：

Wolfram Language code: LogicalExpand[%]

Elementは，領域の帰属関係を宣言する：

Wolfram Language code: Element[{x, y}, Disk[]]

RegionMemberは明示的な領域の帰属条件を与える：

Wolfram Language code: RegionMember[Disk[], {x, y}]

考えられる問題  (1)

領域構成が不明の場合，Element文は評価されずに残る：

Wolfram Language code: Element[I ^ Pi, Algebraics]
Wolfram Research (1999), Element, Wolfram言語関数， https://reference.wolfram.com/language/ref/Element.html （2014年に更新）.

テキスト

Wolfram Research (1999), Element, Wolfram言語関数， https://reference.wolfram.com/language/ref/Element.html （2014年に更新）.

CMS

Wolfram Language. 1999. "Element." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Element.html.

APA

Wolfram Language. (1999). Element. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Element.html

BibTeX

@misc{reference.wolfram_2026_element, author="Wolfram Research", title="{Element}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Element.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_element, organization={Wolfram Research}, title={Element}, year={2014}, url={https://reference.wolfram.com/language/ref/Element.html}, note=[Accessed: 17-August-2026]}