WOLFRAM

Wolfram 语言与系统参考资料中心

EllipticE[m]

给出完全椭圆积分 TemplateBox[{m}, EllipticE].

EllipticE[ϕ,m]

给出第二类椭圆积分 TemplateBox[{phi, m}, EllipticE2].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开式  
积分变换  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

EllipticE

EllipticE[m]

给出完全椭圆积分 TemplateBox[{m}, EllipticE].

EllipticE[ϕ,m]

给出第二类椭圆积分 TemplateBox[{phi, m}, EllipticE2].

更多信息

  • 数学函数，可用于符号和数值运算.
  • 对于 和 ，TemplateBox[{phi, m}, EllipticE2]=int_0^phi(1-m sin^2(theta))^(1/2)dtheta.
  • TemplateBox[{m}, EllipticE]=TemplateBox[{{pi, /, 2}, m}, EllipticE2].
  • EllipticE[m] 在复平面 m 上从 到 有一条不连续分支切割.
  • EllipticE[ϕ,m] 在 和 处有分支切割断点.
  • 对于某些特殊的变量值，EllipticE 自动计算精确数值.
  • EllipticE 可计算到任意数值精度.
  • EllipticE 自动逐项作用于列表的各个元素.
  • EllipticE 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值运算：

Wolfram Language code: EllipticE[0.4]

在实数的子集上绘图：

Wolfram Language code: Plot[EllipticE[m], {m, 0, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[EllipticE[z], {z, -7 - 7I, 7 + 7I}, PlotLegends -> Automatic, Exclusions -> All, PlotTheme -> "Web"]

原点处的级数展开式：

Wolfram Language code: Series[EllipticE[m], {m, 0, 6}]

Infinity 处的级数展开式：

Wolfram Language code: Series[EllipticE[x], {x, ∞, 2}]//Normal

范围  (41)

数值计算  (5)

对复自变量进行数值计算：

Wolfram Language code: EllipticE[3 + 2.5 I]
Wolfram Language code: EllipticE[3 + 2.5 I, 2.3 - 1.5 I]

高精度计算：

Wolfram Language code: N[EllipticE[1 / 3], 50]
Wolfram Language code: N[EllipticE[2 / 3, 2], 50]

输出的精度与输入的精度一致：

Wolfram Language code: EllipticE[0.1234567890000000000]
Wolfram Language code: EllipticE[0.1234567890000000000000000000000]
Wolfram Language code: EllipticE[2, 0.1234567890000000000000000000000]
Wolfram Language code: EllipticE[2, 0.123456789000000000000000000000000000000]

在高精度条件下高效计算 EllipticE：

Wolfram Language code: EllipticE[0.4`500]//Timing
Wolfram Language code: EllipticE[0.4`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: EllipticE[1 / 10, Interval[{1.2, 1.3}]]
Wolfram Language code: EllipticE[CenteredInterval[-4, 1 / 100]]
Wolfram Language code: EllipticE[1 / 3, CenteredInterval[-4, 1 / 5]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: EllipticE[ Around[2, 0.01], 1 / 2]

计算数组中每个元素的值：

Wolfram Language code: EllipticE[{{1, 0}, {0, 1}}]

或用 MatrixFunction 计算矩阵形式的 EllipticE 函数：

Wolfram Language code: MatrixFunction[EllipticE, {{1, 0}, {0, 1}}]

特殊值  (4)

自动生成简单精确值：

Wolfram Language code: {EllipticE[0], EllipticE[1]}
Wolfram Language code: {EllipticE[0, m], EllipticE[ϕ, 0], EllipticE[Pi / 2, m]}

在完整椭圆积分的分支切割处求极限：

Wolfram Language code: {Limit[EllipticE[2 + ε I], ε -> 0, Direction -> 1], Limit[EllipticE[2 + ε I], ε -> 0, Direction -> -1]}

在第二类椭圆积分的分支切割处求极值：

Wolfram Language code: {Limit[EllipticE[Pi / 2 + ε I, 2], ε -> 0, Direction -> -1], Limit[EllipticE[Pi / 2 + ε I, 2], ε -> 0, Direction -> +1]}

无穷处的值：

Wolfram Language code: {EllipticE[Infinity], EllipticE[ComplexInfinity]}
Wolfram Language code: EllipticE[Infinity, Infinity]

求方程 TemplateBox[{m}, EllipticE]=2 的根：

Wolfram Language code: f[m_] := EllipticE[m] - 2; xzero = N@Solve[f[m] == 0 && -2 < m < -1, m][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[f[m], {m, -2, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制完整椭圆积分：

Wolfram Language code: Plot[EllipticE[m], {m, -10, 1}]

绘制第二类椭圆积分：

Wolfram Language code: Plot[{EllipticE[-2, m], EllipticE[-1, m], EllipticE[1, m], EllipticE[2, m]}, {m, -10, 2}]

绘制 TemplateBox[{z}, EllipticE] 的实部：

Wolfram Language code: ComplexContourPlot[Re[EllipticE[z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{z}, EllipticE] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[EllipticE[z]], {z, -5 - 5I, 5 + 5I}, IconizedObject[«PlotOptions»]]

函数的属性  (10)

TemplateBox[{m}, EllipticE] 是针对所有小于或等于 1 的实数定义的：

Wolfram Language code: FunctionDomain[EllipticE[m], m]

TemplateBox[{m}, EllipticE] 的值域为所有大于或等于 1 的实数：

Wolfram Language code: FunctionRange[EllipticE[m], m, y]//Quiet

对于第一个参数来说，EllipticE 是一个奇函数：

Wolfram Language code: EllipticE[-ϕ, m]

EllipticE 不是解析函数：

Wolfram Language code: FunctionAnalytic[EllipticE[x], x]

当 时，函数有奇点和断点：

Wolfram Language code: FunctionSingularities[EllipticE[x], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[EllipticE[x], x]//Quiet

EllipticE 不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[EllipticE[m], m]

TemplateBox[{m}, EllipticE] 在定义域上非递增：

Wolfram Language code: FunctionMonotonicity[{EllipticE[x], x < 1}, x]

TemplateBox[{m}, EllipticE] 是单射函数：

Wolfram Language code: FunctionInjective[EllipticE[x], x]
Wolfram Language code: Plot[{EllipticE[x], 2}, {x, -5, 1}]

TemplateBox[{m}, EllipticE] 不是满射函数：

Wolfram Language code: FunctionSurjective[EllipticE[x], x]
Wolfram Language code: Plot[{EllipticE[x], -1}, {x, -5, 2}]

TemplateBox[{m}, EllipticE] 在定义域上非负：

Wolfram Language code: FunctionSign[{EllipticE[x], x < 1}, x]

TemplateBox[{m}, EllipticE] 在定义域上是凹函数：

Wolfram Language code: FunctionConvexity[{EllipticE[x], x < 1}, x]

微分  (4)

一阶导数：

Wolfram Language code: D[EllipticE[m], m]

高阶导数：

Wolfram Language code: Table[D[EllipticE[m], {m, n}], {n, 1, 3}]//FullSimplify
Wolfram Language code: Plot[Evaluate[%], {m, -10, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

n^(th) 阶导数的公式：

Wolfram Language code: D[EllipticE[m], {m, n}]

相对于第二类椭圆积分的第一个参数求导：

Wolfram Language code: D[EllipticE[ϕ, m], ϕ]

积分  (3)

EllipticE 的不定积分：

Wolfram Language code: Integrate[EllipticE[m], m]//FullSimplify

奇函数在以原点为中心的区间上的定积分为 0：

Wolfram Language code: Integrate[EllipticE[ϕ, m], {ϕ, -1 / 2, 1 / 2}]

更多积分：

Wolfram Language code: Integrate[m^αEllipticE[m], m]
Wolfram Language code: Integrate[Sin[ϕ]EllipticE[ϕ, m], ϕ]
Wolfram Language code: Integrate[( Sin[2 ϕ]EllipticE[ϕ, m]/(1 - m Sin[ϕ]^2)^3 / 2), ϕ]

级数展开式  (4)

EllipticE 的泰勒展开式：

Wolfram Language code: Series[EllipticE[m], {m, 0, 3}]

绘制 EllipticE 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[EllipticE[m], {m, 0, n}], {n, 1, 3}]; Plot[{EllipticE[m], terms}, {m, -3, 1}]

求分支点处的级数展开式：

Wolfram Language code: Series[EllipticE[m], {m, 1, 1}]

第二类椭圆积分的级数展开式：

Wolfram Language code: Series[EllipticE[ϕ, m], {ϕ, 0, 10}]

关于模的级数展开：

Wolfram Language code: Series[EllipticE[ϕ, m], {m, 0, 2}]

EllipticE 可被应用于幂级数：

Wolfram Language code: EllipticE[m + (m^2/2) + (m^3/3) + O[m]^4]
Wolfram Language code: EllipticE[x + (x^2/2) + (x^3/3) + O[x]^4, m]

积分变换  (2)

用 LaplaceTransform 计算拉普拉斯变换：

Wolfram Language code: LaplaceTransform[EllipticE[-t], t, s]

HankelTransform:

Wolfram Language code: HankelTransform[EllipticE[-r], r, s]

函数表示  (6)

第二类椭圆积分的定义：

Wolfram Language code: Integrate[Sqrt[1 - m Sin[θ] ^ 2], {θ, 0, ϕ}, Assumptions -> ϕ ≥ 0]

完全椭圆积分是第二类椭圆积分的部分特例：

Wolfram Language code: EllipticE[(π/2), m]

与其他椭圆积分的关系：

Wolfram Language code: (1 - m)EllipticPi[m, m]//FullSimplify

通过 MeijerGReduce 用 MeijerG 来表示：

Wolfram Language code: MeijerGReduce[EllipticE[m], m]
Wolfram Language code: Activate[%]

EllipticE 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[EllipticE[m], m]

TraditionalForm 格式：

Wolfram Language code: EllipticE[m]//TraditionalForm EllipticE[ϕ, m]//TraditionalForm

应用  (10)

计算椭圆积分：

Wolfram Language code: ∫Sqrt[ x^4 - 1]ⅆ x
Wolfram Language code: ∫Sqrt[x^3 - x^2 + 2 / 9 x]ⅆ x

在复平面上绘制不完全椭圆积分：

Wolfram Language code: Plot3D[Im[EllipticE[x + I y, 1 / 2]], {x, -2Pi, 2Pi}, {y, -3, 3}]

椭圆的周长：

Wolfram Language code: x[t_] := a Cos[t]; y[t_] := b Sin[t];
Wolfram Language code: 4Integrate[Sqrt[Derivative[1][x][t]^2 + Derivative[1][y][t]^2], {t, 0, (Pi/2)}, Assumptions -> a > 0∧b > 0]

用 ArcLength 获取周长：

Wolfram Language code: ArcLength[Circle[{0, 0}, {a, b}]]

轴长几乎相等时的级数展开：

Wolfram Language code: Series[%, {b, a, 6}]

与通过 Ramanujan 得到的近似值比较：

Wolfram Language code: Series[Pi (3a + 3b - Sqrt[(a + 3b)(b + 3a)]), {b, a, 6}]//Simplify[#, Assumptions -> a > 0]&

作为双曲线上点的角度的函数的双曲线弧长：

Wolfram Language code: x[t_] := a Cosh[t] y[t_] := b Sinh[t]
Wolfram Language code: Integrate[Sqrt[x'[t] ^ 2 + y'[t] ^ 2], {t, 0, ArcTanh[(a /b)Tan[ϕ]]}, Assumptions -> a > 0 && b > 0 && b ^ 2 > a ^ 2Tan[ϕ] ^ 2]

绘制弧长作为角度的函数的图形：

Wolfram Language code: Plot[% /. {a -> 2, b -> 2}, {ϕ, -1, 1}]

柱面坐标中环电流的矢势：

Wolfram Language code: A = 2Integrate[(Cos[φ]/Sqrt[z^2 + r^2 + R^2 - 2 r R Cos[φ]]), {φ, 0, Pi}, Assumptions -> r > 0∧R > 0∧z > 0]

磁场的垂直与径向分量：

Wolfram Language code: Bz = (1/r)D[r A, r]//Simplify
Wolfram Language code: Br = -D[A, z]//Simplify

绘制磁场大小的图形：

Wolfram Language code: Plot3D[Evaluate[Sqrt[Br^2 + Bz^2] /. R -> 1], {r, -(3/2), (3/2)}, {z, -1, 1}]

半径为 r、长度为 a，单位长度匝数固定的电导螺线管的磁感应系数：

Wolfram Language code: 2r^2 a Integrate[Sinc[(x/2)]^2 BesselI[1, (x r/a)] BesselK[1, (x r/a)], {x, 0, Infinity}, Assumptions -> r > 0 && a > 0]

无限长电导螺线每单位长度的磁感应系数：

Wolfram Language code: Limit[% / a, a -> Infinity]

计算三轴椭球体的表面积：

Wolfram Language code: area[{a_, b_, c_}] := With[{m = (a^2(b^2 - c^2)/b^2(a^2 - c^2)), θ = ArcSin[Sqrt[1 - (c^2/a^2)]]}, 2 π(c^2 + b Sqrt[a^2 - c^2] EllipticE[θ, m] + (b c^2 /Sqrt[a^2 - c^2])EllipticF[θ, m])] /; a > b > c;

半轴为 3, 2, 1 的椭球体的表面积：

Wolfram Language code: area[{3, 2, 1}]//N

通过对表面微分面元积分计算表面积：

Wolfram Language code: NIntegrate[Evaluate[Sin[θ]Sqrt[b^2c^2Cos[ϕ]^2Sin[θ]^2 + a^2c^2Sin[ϕ]^2Sin[θ]^2 + a^2b^2Cos[θ]^2] /. {a -> 3, b -> 2, c -> 1}], {ϕ, 0, 2Pi}, {θ, 0, Pi}]

将聚脂气球参数化（两块塑料布在圆周缝在一起然后再充气）：

Wolfram Language code: x[u_, v_] := (Cos[v]/Sqrt[Cosh[2u]]) y[u_, v_] := (Sin[v]/Sqrt[Cosh[2u]]) z[u_, v_] := With[{f = ArcSin[(Sqrt[2]Sinh[u]/Sqrt[Cosh[2u]])]}, Sqrt[2](EllipticE[f, (1/2)] - (1/2)EllipticF[f, (1/2)])]

绘制这个气球：

Wolfram Language code: ParametricPlot3D[{x[u, v], y[u, v], z[u, v]}, {v, 0, 2Pi}, {u, -8, 8}, PlotRange -> All]

计算主曲率的比率：

Wolfram Language code: Module[{h, g}, h[u_] = x[u, v] / Cos[v];g[u_] = z[u, v]; (((g''[u]h'[u] - g'[u]h''[u]/(g'[u]^2 + h'[u]^2)^3 / 2))/((g'[u]/h[u]Sqrt[g'[u]^2 + h'[u]^2])))//Simplify]

将原来塑料布的半径用膨胀气球体的半径表示：

Wolfram Language code: Module[{h, g}, h[u_] = x[u, v] / Cos[v];g[u_] = z[u, v];Integrate[Sqrt[h'[u]^2 + g'[u]^2]//Simplify, {u, 0, ∞}]]
Wolfram Language code: N[%, $MachinePrecision]

使用 EllipticE 对椭圆进行参数化处理：

Wolfram Language code: ellipse[ϕ_, {a_, b_}] := With[{u = a EllipticE[ϕ, 1 - (b^2/a^2)]}, {a JacobiSN[u, Sqrt[1 - (b^2/a^2)]], b JacobiCN[u, Sqrt[1 - (b^2/a^2)]]}]

绘制椭圆和圆形的参数图：

Wolfram Language code: With[{b = 1 / 2, a = 2}, ParametricPlot[Evaluate[{{a Cos[ϕ], b Sin[ϕ]}, ellipse[ϕ, {a, b}]}], {ϕ, -Pi, Pi}]]

用椭圆函数定义 Halphen 常数 [MathWorld]：

Wolfram Language code: SetAttributes[HalphenConstant, Constant]; HalphenConstant/:N[HalphenConstant, wp_] := N[EllipticNomeQ[Root[{EllipticK[#] - 2EllipticE[#]&, 0.82611476598497033617737323860075640603409051645331}]], wp]

求得展开的精度值：

Wolfram Language code: x = N[HalphenConstant, 50]

验证其为函数 的零点：

Wolfram Language code: Sum[(2k + 1)^2(-x)^k(k + 1) / 2, {k, 0, 50}]

属性和关系  (6)

对于受以下条件限制的实参数，EllipticE[ϕ,m] 的值为实数：

Wolfram Language code: FunctionDomain[EllipticE[ϕ, m], {ϕ, m}, Reals]

对于实参数，如果 phi=TemplateBox[{u, m}, JacobiAmplitude]，则对于 ，TemplateBox[{u, m}, JacobiEpsilon]=TemplateBox[{phi, m}, EllipticE2]：

Wolfram Language code: With[{m = 1 / 3}, {ParametricPlot[{ϕ, EllipticE[ϕ, m]}, {ϕ, -2Pi, 2Pi}, PlotStyle -> Thick], ParametricPlot[{JacobiAmplitude[u, m], JacobiEpsilon[u, m]}, {u, -4 EllipticK[m], 4EllipticK[m]}, PlotStyle -> Directive[Dashed, Orange]]}]
Wolfram Language code: Show[%, ImageSize -> Tiny]

对于 ，则只有 时才成立：

Wolfram Language code: With[{m = 4}, {ParametricPlot[{ϕ, EllipticE[ϕ, m]}, {ϕ, -ArcSin[m^-1 / 2], ArcSin[m^-1 / 2]}, PlotStyle -> Thick], ParametricPlot[{JacobiAmplitude[u, m], JacobiEpsilon[u, m]}, {u, -(1/Sqrt[m])EllipticK[1 / m], (1/Sqrt[m])EllipticK[1 / m]}, PlotStyle -> Directive[Dashed, Orange]]}]
Wolfram Language code: Show[%, ImageSize -> Tiny]

展开特定实例：

Wolfram Language code: EllipticE[ArcCsc[Sqrt[m]], m]//FunctionExpand

在限定自变量范围下展开特定实例：

Wolfram Language code: EllipticE[z, 1]//FunctionExpand
Wolfram Language code: FunctionExpand[%, 0 < z < Pi / 2]

求超越方程的数值根：

Wolfram Language code: FindRoot[EllipticE[z, 2]^3 + EllipticE[z, 2] + z == 2, {z, I}]

在分支切割上的极限：

Wolfram Language code: Limit[EllipticE[Pi / 2 + ε I, 2], ε -> 0, Direction -> -1]
Wolfram Language code: Limit[EllipticE[Pi / 2 + ε I, 2], ε -> 0, Direction -> +1]

对某些特定函数，自动返回 EllipticE 的特定形式：

Wolfram Language code: {HypergeometricPFQ[{-(1/2), (1/2)}, {1}, z], MeijerG[{{(1/2), (3/2)}, {}}, {{0}, {0}}, -z], MeijerG[{{0, 1}, {}}, {{-(1/2), (1/2)}, {}}, z], EllipticPi[z, (π/2), z], EllipticE[(π/2), z]}

可能存在的问题  (1)

对于第二自变量存在不同惯例：

Wolfram Language code: Integrate[Sqrt[1 - k ^ 2 Sin[t] ^ 2], {t, 0, z}, GenerateConditions -> False]
Wolfram Language code: Integrate[Sqrt[(1 - m t ^ 2) / (1 - t ^ 2)], {t, 0, z}, GenerateConditions -> False]//Simplify[#, 0 < m < 1 && 0 < z < 1]&

巧妙范例  (4)

嵌套的导数和积分：

Wolfram Language code: NestList[D[#, x]&, EllipticE[x, m], 4]//TraditionalForm
Wolfram Language code: NestList[Integrate[#, x]&, EllipticE[x], 6]//FunctionExpand//TraditionalForm

在整数点绘制 EllipticE：

Wolfram Language code: ArrayPlot[Table[Mod[Round[Abs[EllipticE[x y, 0.3]]], 2], {x, -50, 50}, {y, -50, 50}]]

通过连续的泰勒级数计算 EllipticE：

Wolfram Language code: ℱ[n_, z_] = (π/2) Underoverscript[∑, k = 0, n](Pochhammer[-(1/2), k] Pochhammer[(1/2), k] z^k/k!^2)
Wolfram Language code: EllipticE[0.6 - 0.2I]
Wolfram Language code: Plot[{Re@ℱ[n, 0.6 - 0.2I], Im@ℱ[n, 0.6 - 0.2I]}, {n, 0, 5}]

TemplateBox[{m}, EllipticE] 的黎曼面：

Wolfram Language code: Show[Plot3D[Evaluate[Table[Im[EllipticE[x + I y] + j 2 I (EllipticK[1 - (x + I y)] - EllipticE[1 - (x + I y)])], {j, -2, 2}]], {x, -9, 9}, {y, ##}, ClippingStyle -> None, PlotStyle -> Opacity[0.6], Mesh -> False, BoxRatios -> {1, 1, 1}, MaxRecursion -> 5, PlotRange -> {All, All, {-9, 9}}]&@@@{{-9, -10 ^ -6}, {10 ^ -6, 9}}]
Wolfram Research (1988)，EllipticE，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticE.html （更新于 2022 年）.

文本

Wolfram Research (1988)，EllipticE，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticE.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "EllipticE." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/EllipticE.html.

APA

Wolfram 语言. (1988). EllipticE. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EllipticE.html 年

BibTeX

@misc{reference.wolfram_2026_elliptice, author="Wolfram Research", title="{EllipticE}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticE.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_elliptice, organization={Wolfram Research}, title={EllipticE}, year={2022}, url={https://reference.wolfram.com/language/ref/EllipticE.html}, note=[Accessed: 14-September-2026]}