WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Encrypt["password",expr]

指定されたパスワードを使って expr を暗号化し，暗号化オブジェクトを与える．

Encrypt[keyspec,expr]

暗号鍵の指定 keyspec を使って expr を暗号化する．

Encrypt[expr]

expr を暗号化するためのパスワードをインタラクティブにリクエストする．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Method  
アプリケーション  
特性と関係  
考えられる問題  
タイミング  
暗号化されたデータサイズ  
互換ではない鍵  
互換ではない埋込みモード  
互換ではないブロックモード  
関連項目
関連するガイド
履歴
引用書式

Encrypt

Encrypt["password",expr]

指定されたパスワードを使って expr を暗号化し，暗号化オブジェクトを与える．

Encrypt[keyspec,expr]

暗号鍵の指定 keyspec を使って expr を暗号化する．

Encrypt[expr]

expr を暗号化するためのパスワードをインタラクティブにリクエストする．

詳細とオプション

  • Encryptは，Decryptを使った復号化に適したEncryptedObject[…]を与える．
  • Encrypt[key,"string"]は，UTF-8で符号化された文字列の暗号化されたバージョンを含むEncryptedObjectを与える．
  • Encrypt[key,ByteArray[…]]は，ByteArrayオブジェクト中の生のバイトの暗号化されたバージョンを含むEncryptedObjectを与える．
  • Encrypt[key,expr]は，一般的な式についてはCompress[expr]を暗号化したものを含むEncryptedObjectを与える．
  • 暗号化の方法は key の暗号とパラメータに基づいている．詳細についてはGenerateSymmetricKeyおよびGenerateAsymmetricKeyPairを参照のこと．
  • Encrypt[expr]は，ノートブックインターフェースではダイアログボックスを，テキスト型のインターフェースではテキストプロンプトを生成する．
  • Encryptは次のオプションを取る．
  • Method Automatic暗号化法の詳細
  • Methodassoc の設定のとき，連想 assoc は使用する暗号化法の詳細を与える．
  • 連想 assoc には次の要素を与えることができる．
  • "Padding"Automatic充填モード
    "InitializationVector"Automaticブロック暗号のための初期化ベクトル
    "BlockMode""CBC"ブロック暗号モード ("ECB","CBC", "OFB", "CFB", "CTR")
  • 連想中 assoc の"Padding"要素は，不完全な入力を充填する方法を指定する．
  • 対称キーによる暗号化はAutomaticとNoneの充填法をサポートする．
  • 公開鍵による暗号化と秘密鍵による復号化は，"PKCS1"，"OAEP"，Noneの充填法をサポートする．
  • 秘密鍵による暗号化と公開鍵による復号化は，"PKCS1"とNoneの充填法をサポートする．
  • 非対称暗号化にはデフォルトでは"PKCS1"充填法が使われる．
  • RC4とRSAを除く暗号化はどれも，ブロックモードの"ECB"，"CBC"，"CFB"，"OFB"を使うことができる．"RC4"にはNoneしか使えない．
  • 次は，"InitializationVector"の可能な設定である．
  • Automatic適切な初期化ベクトルを生成する
    ByteArray[…]明示的に指定された初期化ベクトルを使用する
  • "InitializationVector"->Automaticのとき， Encryptは実行されるたびに新たな初期化ベクトルを生成する．ベクトルは，作成されたEncryptedObjectから後に入手できる．
  • 次は，サポートされる暗号とそのデフォルトの初期化ベクトルのサイズである．
  • "Blowfish"64ビット
    "CAST5"64ビット
    "DES"64ビット
    "IDEA"64ビット
    "AES128"128ビット
    "AES192"128ビット
    "AES256"128ビット
  • RSA暗号については，暗号化可能な最長データは を法としたバイト数と埋込みモードで，以下に従って決定される．
  • "PKCS1"<
    "OAEP"<
    None

例題

すべて開く すべて閉じる

例  (3)

メッセージをパスワードを付けて暗号化する：

Wolfram Language code: Encrypt["my password", "Now is the time..."]

生の暗号化データと使われた暗号化アルゴリズムの詳細を示す：

Wolfram Language code: InputForm[%]

パスワードで復号化し，メッセージを取り出す：

Wolfram Language code: Decrypt["my password", %]

秘密鍵を生成する：

Wolfram Language code: key = GenerateSymmetricKey[]

鍵を使って暗号化する：

Wolfram Language code: Encrypt[key, "Now is the time..."]
Wolfram Language code: Decrypt[key, %]

公開鍵と秘密鍵を生成する：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]

公開鍵を使って暗号化する：

Wolfram Language code: Encrypt[keys["PublicKey"], "Now is the time..."]

秘密鍵を使って復号化する：

Wolfram Language code: Decrypt[keys["PrivateKey"], %]

秘密鍵を使って暗号化することもできる：

Wolfram Language code: Encrypt[keys["PrivateKey"], "Now is the time..."]

公開鍵を使って復号化する：

Wolfram Language code: Decrypt[keys["PublicKey"], %]

スコープ  (2)

式を暗号化する：

Wolfram Language code: Encrypt["my password", Graphics[Disk[]]]
Wolfram Language code: Decrypt["my password", %]

バイト配列は，文字通り暗号化されるので，外部プログラムでより使いやすい：

Wolfram Language code: Encrypt["my password", ByteArray[{1, 2, 3, 4, 5}]]
Wolfram Language code: Decrypt["my password", %]

オプション  (5)

Method  (5)

特定の初期化ベクトルを使って暗号化する：

Wolfram Language code: key = GenerateSymmetricKey[]; Encrypt[key, "Specified IV example", Method -> <|"InitializationVector" -> ByteArray[{1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16}]|>]

初期化ベクトルをAutomaticに設定すると，Encryptが呼ばれるたびにランダムな初期化ベクトルが生成される：

Wolfram Language code: key = GenerateSymmetricKey[];Encrypt[key, "Automatic IV example", Method -> <|"InitializationVector" -> Automatic|>]
Wolfram Language code: %["InitializationVector"]

CTRブロックモードで暗号化する：

Wolfram Language code: key = GenerateSymmetricKey[];Encrypt[key, "CTR block mode example", Method -> <|"BlockMode" -> "CTR"|>]

RSA暗号化に使用する充填スキームを指定する：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]; Encrypt[keys["PublicKey"], "Now is the time...", Method -> <|"Padding" -> "OAEP"|>]

"Padding"をNoneに設定して厳密に1ブロックのデータを暗号化する：

Wolfram Language code: key = GenerateSymmetricKey[];Encrypt[key, ByteArray["3072ICGBQhJED8uxEt7OLg=="], Method -> <|"Padding" -> None|>]

アプリケーション  (2)

メッセージを暗号化し，ファイルに暗号文を保存する：

Wolfram Language code: enc = Encrypt["my password", "Now is the time..."]
Wolfram Language code: file = FileNameJoin[{$TemporaryDirectory, "test"}];
Wolfram Language code: BinaryWrite[file, Normal[enc["Data"]]];Close[file];

ファイルのコンテンツをバイトとして読み出す：

Wolfram Language code: BinaryReadList[file]

もとの暗号文と比較する：

Wolfram Language code: Normal[enc["Data"]]

一時ファイルを削除する：

Wolfram Language code: DeleteFile[file]

簡単な暗号署名と検証の関数を書く：

Wolfram Language code: sign[key_PrivateKey, expr_] := Encrypt[key, Hash[expr, "SHA256"]]
Wolfram Language code: verify[key_PublicKey, expr_, signature_EncryptedObject] := Decrypt[key, signature] === Hash[expr, "SHA256"]

公開鍵と秘密鍵のペアを生成する：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]

署名に対する式を定義する：

Wolfram Language code: expr = Graphics[Disk[]]

署名を生成する：

Wolfram Language code: sig = sign[keys["PrivateKey"], expr]

署名が信頼できることを検証する：

Wolfram Language code: verify[keys["PublicKey"], expr, sig]

他の式での検証は失敗する：

Wolfram Language code: verify[keys["PublicKey"], "another expression", sig]

特性と関係  (2)

返された暗号化オブジェクトは，暗号化のすべての局面を保存する：

Wolfram Language code: enc = Encrypt["my password", ByteArray[{1, 2, 3, 4, 5}]]

暗号文のバイトを抽出する：

Wolfram Language code: enc["Data"]//Normal

暗号化に使った初期化ベクトルのバイトを抽出する：

Wolfram Language code: enc["InitializationVector"]//Normal

あるブロックモードは他のブロックモードよりも安全である：

Wolfram Language code: key = GenerateSymmetricKey[];

ECBを使って均一なデータを暗号化すると明らかな繰返しパターンが現れる：

Wolfram Language code: ecb = Encrypt[key, ByteArray[ConstantArray[1, 100]], Method -> <|"BlockMode" -> "ECB"|>];
Wolfram Language code: ListLinePlot[Normal[ecb["Data"]]]

CBCを使うとそのようなことはない：

Wolfram Language code: cbc = Encrypt[key, ByteArray[ConstantArray[1, 100]], Method -> <|"BlockMode" -> "CBC"|>];
Wolfram Language code: ListLinePlot[Normal[cbc["Data"]]]

考えられる問題  (5)

タイミング  (1)

パスワードを使った暗号化には鍵の派生が必要である．これは，故意に遅くしてある：

Wolfram Language code: AbsoluteTiming[Encrypt["password", "test"]]

事前に鍵を生成しておくことで，これを避けることができる：

Wolfram Language code: key = GenerateSymmetricKey["password"]
Wolfram Language code: AbsoluteTiming[Encrypt[key, "test"]]

暗号化されたデータサイズ  (1)

暗号文は入力とは長さが異なることがある：

Wolfram Language code: Encrypt["my password", ByteArray[{1, 2, 3, 4, 5}]]
Wolfram Language code: Length[%["Data"]]

互換ではない鍵  (1)

楕円曲線に基づいた鍵を使った暗号化は，現在はサポートされていない：

Wolfram Language code: keys = GenerateAsymmetricKeyPair["EllipticCurve"]
Wolfram Language code: Encrypt[keys["PrivateKey"], "Now is the time..."]

互換ではない埋込みモード  (1)

秘密鍵で暗号化することが不可能な埋込みモードもある：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]
Wolfram Language code: Encrypt[keys["PrivateKey"], "Now is the time...", Method -> <|"Padding" -> "OAEP"|>]

互換ではないブロックモード  (1)

RSAはブロックモード操作をサポートしない非対称の暗号なので，Encryptは"BlockMode"の設定を無視して進む：

Wolfram Language code: keys = GenerateAsymmetricKeyPair[]; Encrypt[keys["PublicKey"], "RSA is an asymmetric cipher", Method -> <|"BlockMode" -> "CBC"|>]

RC4はブロックモード操作をサポートしないストリームなので，Encryptは"BlockMode"の設定を無視して進む：

Wolfram Language code: key = GenerateSymmetricKey[Method -> "RC4"]; Encrypt[key, "RC4 is a stream cipher", Method -> <|"BlockMode" -> "CFB"|>]
Wolfram Research (2015), Encrypt, Wolfram言語関数， https://reference.wolfram.com/language/ref/Encrypt.html （2023年に更新）.

テキスト

Wolfram Research (2015), Encrypt, Wolfram言語関数， https://reference.wolfram.com/language/ref/Encrypt.html （2023年に更新）.

CMS

Wolfram Language. 2015. "Encrypt." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/Encrypt.html.

APA

Wolfram Language. (2015). Encrypt. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Encrypt.html

BibTeX

@misc{reference.wolfram_2026_encrypt, author="Wolfram Research", title="{Encrypt}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/Encrypt.html}", note=[Accessed: 12-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_encrypt, organization={Wolfram Research}, title={Encrypt}, year={2023}, url={https://reference.wolfram.com/language/ref/Encrypt.html}, note=[Accessed: 12-October-2026]}