Exp

Exp[z]

z の指数関数を返す．

詳細

記号操作・数値操作の両方に適した数学関数である．
特別な引数の場合，Expは自動的に厳密値を計算する．
Expは任意の数値精度で評価できる．
Expは自動的にリストに縫い込まれる．
Exp[z]は，E^z に変換される．
ExpはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (6)

数値的に評価する：

Wolfram Language code: Exp[3.4]

任意制度で数値的に評価する：

Wolfram Language code: Exp[I Pi / 5]

Wolfram Language code: N[%, 30]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Exp[x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Exp[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[Exp[x], {x, 0, 10}]

指数関数はee xとして入力することができる：

Wolfram Language code: E^x

スコープ (55)

数値評価 (6)

数値的に評価する：

Wolfram Language code: Exp[1.5]

高精度で評価する：

Wolfram Language code: N[Exp[16 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: Exp[1.60000000000000000000000]

Expは複素数を入力として取ることができる：

Wolfram Language code: Exp[2.5 + I]

Expを高精度で効率よく評価する：

Wolfram Language code: Exp[1.6`500]//Timing

Wolfram Language code: Exp[1.6`100000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Exp[Interval[{-1, Log[2]}]]

Wolfram Language code: Exp[CenteredInterval[2, 1 / 100]]

Wolfram Language code: Exp[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Exp[ Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: Exp[{{1, I π / 2}, {0, 1}}]

MatrixFunctionを使って行列のExp関数を計算することもできる：

Wolfram Language code: MatrixFunction[Exp, {{1, I π / 2}, {0, 1}}]

特定の値 (6)

0における値：

Wolfram Language code: Exp[0]

固定点におけるExpの値：

Wolfram Language code: Table[Exp[I n (π/2)], {n, 0, 4}]

無限大における値：

Wolfram Language code: Exp[Infinity]

Wolfram Language code: Exp[-Infinity]

簡単な厳密値は自動的に生成される：

Wolfram Language code: Exp[9 / 2 I Pi]

より複雑な値はExpToTrigを使って展開できる：

Wolfram Language code: ExpToTrig[Exp[I Pi / 5]]

虚軸に沿ったExpの極値：

Wolfram Language code: Assuming[n∈Integers, Refine@Exp[2π I n]]

Wolfram Language code: Assuming[n∈Integers, Refine@Exp[2 π I(n + (1/2))]]

Solveを使ってとなるの値を求める：

Wolfram Language code: f[x_] := Exp[x] - 1.7

Wolfram Language code: Solve[f[x] == 0, x, Reals]//Quiet

結果を代入する：

Wolfram Language code: xval = x /. First[%]

結果を可視化する：

Wolfram Language code: Plot[f[x], {x, -2, 2}, Epilog -> Style[Point[{xval, f[xval]}], PointSize[Large], Red]]

可視化 (4)

Exp関数をプロットする：

Wolfram Language code: Plot[Exp[x], {x, -2, 2}]

Exp[I x]の実部と虚部をプロットする：

Wolfram Language code: ReImPlot[Exp[I x], {x, -2π, 2π}, PlotLegends -> Automatic]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Exp[z]], {z, -2 - 4 I, 2 + 4 I}, Contours -> 20]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Exp[z]], {z, -2 - 4 I, 2 + 4 I}, Contours -> 20]

の極プロット：

Wolfram Language code: PolarPlot[Exp[ϕ], {ϕ, 0, 2π}, Frame -> True]

関数の特性 (12)

Expはすべての実数値と虚数値について定義される：

Wolfram Language code: FunctionDomain[Exp[x], x]

Wolfram Language code: FunctionDomain[Exp[z], z, Complexes]

Expはすべての正の実数値に達する：

Wolfram Language code: FunctionRange[Exp[x], x, y]

複素数値の範囲は0を除く平面全体である：

Wolfram Language code: FunctionRange[Exp[z], z, y, Complexes]

Expは，周期がの周期関数である：

Wolfram Language code: FullSimplify[Exp[z + 2π I n] == Exp[z], n∈Integers]

Expは鏡特性を有する：

Wolfram Language code: FullSimplify[Exp[Conjugate[z]] == Conjugate[Exp[z]]]

Expは x の解析関数である：

Wolfram Language code: FunctionAnalytic[Exp[x], x]

Expは非減少である：

Wolfram Language code: FunctionMonotonicity[Exp[x], x]

Expは単射である：

Wolfram Language code: FunctionInjective[Exp[x], x]

Wolfram Language code: Plot[{Exp[x], 2}, {x, -3, 3}]

Expは全射ではない：

Wolfram Language code: FunctionSurjective[Exp[x], x]

Wolfram Language code: Plot[{Exp[x], -1}, {x, -2π, 2π}]

Expは非負である：

Wolfram Language code: FunctionSign[Exp[x], x]

特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[Exp[x], x]

Wolfram Language code: FunctionDiscontinuities[Exp[x], x]

Exp は凸である：

Wolfram Language code: FunctionConvexity[Exp[x], x]

TraditionalFormによる表示：

Wolfram Language code: Exp[x]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[Exp[x], x]

次導関数の式：

Wolfram Language code: D[Exp[x], {x, n}]

ネストした指数関数の導関数：

Wolfram Language code: D[Exp[Exp[x]], x]

積分 (5)

Expの不定積分：

Wolfram Language code: Integrate[Exp[x], x]

Expの定積分：

Wolfram Language code: Integrate[Exp[x], {x, -Infinity, 0}]

ガウス積分：

Wolfram Language code: Integrate[Exp[-x^2], {x, -Infinity, Infinity}]

Wolfram Language code: Plot[Exp[-x^2], {x, -3, 3}, Axes -> False, Frame -> True, Filling -> Bottom]

ガンマ関数の定義：

Wolfram Language code: Integrate[t^z - 1Exp[-t], {t, 0, Infinity}, Assumptions -> Re[z] > 0]

その他の積分例：

Wolfram Language code: Integrate[z^αExp[z^β], z]

Wolfram Language code: Integrate[t^k / (Exp[t] + 1), {t, 0, Infinity}, Assumptions -> k > -1]

Wolfram Language code: Integrate[Exp[-a t^2 - (b/t^2)], {t, 0, Infinity}, Assumptions -> a > 0 && b > 0]

Wolfram Language code: Integrate[Exp[Exp[I t]], {t, 0, 2Pi}]

級数展開 (5)

Expのテイラー(Taylor)展開：

Wolfram Language code: Series[Exp[x], {x, 0, 7}]

の周りのExpの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[Exp[x], {x, 0, m}], {m, 1, 3}];
Plot[{Exp[x], terms}, {x, -2, 3}]

Expの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Exp[x], {x, 0, n}]

無限大における指数関数の級数展開：

Wolfram Language code: Series[Exp[1 / x], {x, Infinity, 3}]

一次フーリエ(Fourier)級数：

Wolfram Language code: FourierSeries[Exp[z], z, 1]//FullSimplify

Expはベキ級数に適用できる：

Wolfram Language code: Exp[x - (x^2/2) + (x^3/9) + O[x]^4]

積分変換 (3)

FourierTransformを使ってフーリエ変換を計算する：

Wolfram Language code: FourierTransform[Exp[-Abs[t]], t, ω]

Wolfram Language code: FourierTransform[Exp[-t ^ 2], t, ω]

LaplaceTransform：

Wolfram Language code: LaplaceTransform[Exp[t], t, s ]

MellinTransform：

Wolfram Language code: MellinTransform[Exp[-x], x, s ]

関数の恒等式と簡約 (6)

主定義：

Wolfram Language code: Exp[z] == Power[E, z]

オイラーの公式：

Wolfram Language code: ExpToTrig[Exp[I x]]

指数関数から双曲線関数に変換する：

Wolfram Language code: ExpToTrig[Exp[x]]

三角関数と双曲線関数を指数関数に変換する：

Wolfram Language code: TrigToExp[{Sin[z], Cosh[z]}]

積は自動的に組み合される：

Wolfram Language code: Exp[x]Exp[y]Exp[1 / z]

実変数 x および y を仮定して展開する：

Wolfram Language code: ComplexExpand[Exp[x + I y]]

関数表現 (5)

Expは極限におけるベキ関数から生じる：

Wolfram Language code: Limit[(1 + (x/n))^n, n -> Infinity]

級数表現：

Wolfram Language code: Sum[(z^k/k!), {k, 0, Infinity}]

ベッセル関数による表現：

Wolfram Language code: Sqrt[(π I z/2)] BesselJ[-(1/2), I z] + I Sqrt[-(π I z/2)] BesselJ[(1/2), -I z]//FullSimplify

Wolfram Language code: Sqrt[(z π/2)] (BesselI[(1/2), z] + BesselI[-(1/2), z])//FullSimplify

ExpはMeijerGによって表現できる：

Wolfram Language code: MeijerGReduce[Exp[x], x]

Wolfram Language code: Activate[%]

ExpはDifferentialRootとして表現できる：

Wolfram Language code: DifferentialRootReduce[Exp[x], x]

アプリケーション (15)

微分方程式 (7)

指数的な減少：

Wolfram Language code: DSolve[{n'[t] == -λ n[t], n[0] == n0}, n[t], t]

減衰調和振動子：

Wolfram Language code: DSolve[{x''[t] + 3x'[t] + 5 / 4x[t] == 0, x[0] == 1, x'[0] == 0}, x[t], t] //ExpandAll

Wolfram Language code: Plot[Evaluate[x[t] /. %], {t, 0, 10}]

Expを使った境界層問題の解：

Wolfram Language code: DSolve[{ϵ y''[x] + (1 + ϵ)y'[x] + y[x] == 0, y[0] == 0, y[1] == 1}, y[x], x]//Simplify

さまざまな解をプロットする：

Wolfram Language code: Plot[Evaluate[Table[y[x] /. % /. ϵ -> 10 ^ k, {k, -2, 2, 4 / 15}]], {x, 0, 1}]

平面波のアプローチを使って電信方程式の分散関係を計算する：

Wolfram Language code:

Subscript[∂, x, x]V[x, t] - L C Subscript[∂, t, t]V[x, t] - R C Subscript[∂, t]V[x, t] == 0 /. V -> Function[{x, t}, E^I (k x - ω t)]

Wolfram Language code: Solve[%, ω]

指数的なLiouvilleポテンシャルについてのシュレディンガー(Schrödinger)方程式を解く：

Wolfram Language code: DSolve[-ψ''[x] + Exp[x]ψ[x] == ε ψ[x], ψ[x], x]

ステップポテンシャルについてのシュレディンガー方程式の伝達係数と反射係数：

Wolfram Language code:

ψL[ℰ_, x_] := Exp[I Sqrt[ℰ]x] + ℛ[ℰ]Exp[-ISqrt[ℰ]x]
ψR[ℰ_, x_] := 𝒯[ℰ]Exp[I Sqrt[ℰ - Subscript[𝒱, 0]]x]

Wolfram Language code: Solve[{ψL[ℰ, 0] == ψR[ℰ, 0], D[ψL[ℰ, x], x] == D[ψR[ℰ, x], x] /. x -> 0}, {ℛ[ℰ], 𝒯[ℰ]}]

自由粒子のシュレディンガー方程式の伝搬子：

Wolfram Language code: 𝒢[x_, t_] := Sqrt[(m/2 π t I ℏ)]Exp[(I m x^2/2 t ℏ)]

ガウス波束の広がりを計算する：

Wolfram Language code: ψ[x_, t_] = Integrate[𝒢[x - y, t]Exp[-y^2]Exp[I k y], {y, -∞, ∞}, Assumptions -> m > 0 && ℏ > 0 && t > 0]

広がりを可視化する：

Wolfram Language code: ContourPlot[Evaluate[Abs[ψ[x, t] /. {ℏ -> 1, m -> 1, k -> 1}] ^ 2], {x, -4, 4}, {t, 0, 4}, PlotRange -> All]

確率，統計，統計力学 (4)

正規分布：

Wolfram Language code: PDF[NormalDistribution[μ, σ]][x]

Wolfram Language code: Plot[% /. {μ -> 0, σ -> 1}, {x, -3, 3}]

モーメントを計算する：

Wolfram Language code:

Assuming[μ∈Reals∧σ > 0, 
	Table[Integrate[x^kPDF[NormalDistribution[μ, σ]][x], {x, -∞, ∞}], {k, 0, 4}]]

ネストした指数関数を使ってガンベル(Gumbel)分布のCDFを定義する：

Wolfram Language code: GumbelG[x_, {a_, b_}] := Exp[-Exp[-(x - b) / a]]

Wolfram Language code: Plot[GumbelG[x, {2, 2}], {x, -4, 12}]

PDFをプロットする：

Wolfram Language code: Plot[Evaluate[D[GumbelG[x, {2, 2}], x]], {x, -4, 12}]

最初のモーメントを記号的に計算する：

Wolfram Language code: Integrate[x D[GumbelG[x, {1, 0}], x], {x, -∞, ∞}]

Fermi–Dirac分布関数，Bose–Einstein分布関数，Maxwell–Boltzmann分布関数を定義する：

Wolfram Language code: fd[ℰ_, μ_, kBT_] := (1/E^(ℰ - μ/kBT) + 1)

Wolfram Language code: be[ℰ_, μ_, kBT_] := UnitStep[ℰ - μ](1/E^(ℰ - μ/kBT) - 1)

Wolfram Language code: mb[ℰ_, μ_, kBT_] := E^-(ℰ - μ/kBT)

これらの分布をプロットする：

Wolfram Language code: Plot[{fd[ℰ, 1, 1 / 10], be[ℰ, 1, 1 / 10], mb[ℰ, 1, 1 / 10]}, {ℰ, 0, 3}]

指数型母関数から二項分布のモーメントを計算する：

Wolfram Language code: egf[n_, p_][t_] := (p Exp[t] + (1 - p)) ^ n

Wolfram Language code: Table[Derivative[k][egf[n, p]][0], {k, 0, 4}]//Factor

ガウス関数 (2)

多変量ガウス積分：

Wolfram Language code:

Assuming[λ > 0 && {a, b}∈Reals, Subsuperscript[∫, -∞, ∞]Subsuperscript[∫, -∞, ∞]Subsuperscript[∫, -∞, ∞]E^-λ((Subscript[x, 1] - a)^2 + (Subscript[x, 2] - Subscript[x, 1])^2 + (b - Subscript[x, 3])^2)ⅆSubscript[x, 1]ⅆSubscript[x, 2]ⅆSubscript[x, 3]]

Wolfram Language code:

Subsuperscript[∫, -∞, ∞]Subsuperscript[∫, -∞, ∞]E^ I(Subsuperscript[x, 1, 2] + Subsuperscript[x, 2, 2])ⅆSubscript[x, 1]ⅆSubscript[x, 2]

フーリエ変換をプロットする：

Wolfram Language code:

f1 = Exp[-x^2 + 1]UnitStep[x];
f2 = Exp[-x^2 + 1](UnitStep[x + 2] - UnitStep[x - 3]);
ft1 = FourierTransform[f1, x, k];
ft2 = FourierTransform[f2, x, k];

Wolfram Language code: AbsArgPlot[{ft1, ft2}, {k, -20, 20}, PlotRange -> All, ScalingFunctions -> "Log", PlotLabels -> {ℱ[f1], ℱ[f2]}]

極限と展開 (2)

この多変量関数を取る：

Wolfram Language code:

f = Sin[x + y + u + v] - u x + v y;
g = Exp[x - u] + Exp[y - v] - 2 Cos[x - v] + y - u;

次の方程式系について3次までの級数解を求める：

Wolfram Language code: AsymptoticSolve[f == 0 && g == 0, {{x, y}, {0, 0}}, {{u, v}, {0, 0}, 3}]

結果は方程式を満足する：

Wolfram Language code: Series[{f, g} /. %[[1]] /. {u -> t u, v -> t v}, {t, 0, 3}]

Expを使って急速に大きくなる関数を構築し，その極限を計算する：

Wolfram Language code:

Assuming[a∈Reals, # == Activate@#&[Inactive[Limit][Exp[Exp[Exp[a Exp - Exp[Exp[x]] - Exp[x]] + x] - Exp[Exp[Exp[x]]]], x -> ∞]]]

特性と関係 (19)

ExpからPowerに変換する：

Wolfram Language code: Together[Exp[I Pi / 5]]

指数関数から三角・双曲線関数に変換する：

Wolfram Language code: ExpToTrig[Exp[x]]

Wolfram Language code: ExpToTrig[Exp[I x]]

Wolfram Language code: ExpToTrig[Exp[I Pi / 5]]

三角関数と双曲線関数を指数関数に変換する：

Wolfram Language code: TrigToExp[{Sin[z], Cosh[z]}]

特別な値を無理式として計算する：

Wolfram Language code: Exp[I Pi / 32]

Wolfram Language code: FunctionExpand[ExpToTrig[%]]

分子と分母を抽出する：

Wolfram Language code: Numerator[{E^x, E^-x, E^x - 1 / y}]

Wolfram Language code: Denominator[{E^x, E^-x, E^x - 1 / y}]

指数関数の逆数を評価すると指数関数になる：

Wolfram Language code: 1 / Exp[x]

Expは極限においてベキ関数から現れる：

Wolfram Language code: Limit[(1 + (x/n))^n, n -> Infinity]

逆関数と組み合せる：

Wolfram Language code: {Exp[Log[z]], Log[Exp[z]]}

PowerExpandはLogの多価性を無視する：

Wolfram Language code: PowerExpand[%]

すべての複素値について正しい形式を得る：

Wolfram Language code: PowerExpand[%%, Assumptions -> {}]

三角関数と双曲線関数の逆関数で構成する：

Wolfram Language code: {Exp[I ArcSin[x]], Exp[I ArcTanh[x]]}//TrigToExp//Together

Expを含む超越関数を解く：

Wolfram Language code: Reduce[Exp[x] + x == 0, x]

Wolfram Language code: FindRoot[Exp[x] + x == 0, {x, 0}]

Wolfram Language code: FindRoot[Exp[x] - x == 0, {x, 2I}]

指数方程式を還元する：

Wolfram Language code: Reduce[Exp[α x + β] == 1, x]

積分：

Wolfram Language code: ∫z^αExp[z^β]ⅆz

Wolfram Language code: Subsuperscript[∫, 0, ∞](t^k/E^t + 1)ⅆt

Wolfram Language code: Subsuperscript[∫, 0, ∞]E^-a t^2 - (b/t^2)ⅆt

Wolfram Language code: Subsuperscript[∫, 0, 2 π]E^E^I tⅆt

積分変換：

Wolfram Language code: InverseFourierCosTransform[Exp[-μ Abs[k] ^ 3 t], k, x, Assumptions -> μ > 0]

総和：

Wolfram Language code: Underoverscript[∑, k = 1, ∞](E^k z/k)

Wolfram Language code: Underoverscript[∑, k = 1, ∞]((-1)^k - 1 E^k w/k^2)

ネストした指数関数の級数の係数はベル(Bell)数の倍数である：

Wolfram Language code: CoefficientList[Series[Exp[Exp[t] - 1], {t, 0, 12}], t]

Wolfram Language code: Table[BellB[n] / n!, {n, 0, 12}]

Expは数値関数である：

Wolfram Language code: Attributes[Exp]

Wolfram Language code: NumericQ[Exp[2 + GoldenRatio]]

Expの母関数：

Wolfram Language code: GeneratingFunction[Exp[n], n, x]

Wolfram Language code: Series[%, {x, 0, 10}]

FindSequenceFunctionはExp数列を認識する：

Wolfram Language code: Table[Exp[n], {n, 10}]

Wolfram Language code: FindSequenceFunction[%, n]

Expの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[Exp[n], n, x]

考えられる問題 (7)

指数関数は非常に大きくなることがある：

Wolfram Language code: N[Exp[10 ^ 6]]

コンピュータで表示するには大きくなり過ぎることもある：

Wolfram Language code: Exp[%]

指数関数を評価すると底がEの級数になるので，文字通りのマッチングは失敗することがある：

Wolfram Language code: MatchQ[Exp[x + y], HoldPattern[Exp[_ + _]]]

Wolfram Language code: Exp[x]//FullForm

UnevaluatedまたはHoldを使って評価を避ける：

Wolfram Language code: Hold[Exp[x]]//FullForm

Wolfram Language code: MatchQ[Unevaluated[Exp[x + y]], HoldPattern[Exp[_ + _]]]

指数中の対数は常に自動的に分解される訳ではない：

Wolfram Language code: {Exp[-Pi Log[2]], Exp[1 - Pi Log[2]]}

Togetherを使って指数中の対数を除去する：

Wolfram Language code: Together[%]

機械精度の入力は正しい答を得るためには不十分である：

Wolfram Language code: Exp[20 + 10. ^ 30 I]

厳密な入力をすると正しい答が得られる：

Wolfram Language code: N[Exp[20 + 10 ^ 30 I], 20]

無限大では，基本的にExpが特異点を持ち，ベキ級数は存在しない：

Wolfram Language code: Series[Exp[x], {x, Infinity, 2}]

Expは行列に対して要素単位で適用される．MatrixExpは指数関数を求める：

Wolfram Language code: Exp[{{0, 1}, {1, 0}}]

Wolfram Language code: MatrixExp[{{0, 1}, {1, 0}}]

TraditionalFormの入力では引数の前後にカッコが必要である：

Wolfram Language code: exp x

Wolfram Language code: exp(x)

おもしろい例題 (5)

古典的な極限の修正項を求める：

Wolfram Language code: Series[(1 + (z/n))^n, {n, ∞, 2}]

Expのベキ級数の部分和の閉形式：

Wolfram Language code: Sum[z ^ k / k!, {k, 0, n}]

大きいについてのExp[z]の差分の主要な修正：

Wolfram Language code: Simplify[Normal[Series[Exp[z] - %, {n, ∞, 2}]]]

複素平面上のネストした指数関数：

Wolfram Language code: DensityPlot[Arg[Nest[Exp, x + I y, 3]], {x, 0, 3}, {y, -2, 2}]

Expを反復させることによるフラクタル：

Wolfram Language code:

DensityPlot[Length @FixedPointList[If[TrueQ[Abs[#] > 10. ^ 5], Indeterminate, Exp[# / (x + I y)]]&, x + I y, 10], {x, -1 / 2, 3}, {y, -1, 1}, MaxRecursion -> 4]

ほとんどどこにも微分可能なところがないリーマン・ワイエルシュトラス(Riemann–Weierstrass)関数：

Wolfram Language code: ParametricPlot[{Re[#], Im[#]}&@Underoverscript[∑, j = 1, 200](E^I j^3 φ/j^2), {φ, 0, 2π}]