Wolfram言語＆システムドキュメントセンター

Factor

Factor[poly]

整数について多項式を因数分解する．

Factor[poly,Modulusp]

素数 p を法として多項式を因数分解する．

Factor[poly,Extension{a₁,a₂,…}]

代数的数 a_iの有理的組合せからなる係数を使い，多項式を因数分解する．

詳細とオプション

Factorは，式の最上の代数的レベルに限って適用される．他のレベルに到達するためにはMapを使用したり，Factorを再適用したりする必要があることがある．
Factor[poly,GaussianIntegers->True]は，ガウスの整数を係数と認識し因数分解する．
poly の係数が複素数である場合，ガウスの整数を係数と認め因数分解が実行される．
変数の指数が正の整数である必要はなく，Factorは，指数が記号式の線形結合のものを取り扱うことができる．
有理式が与えられる場合，Factorは，まずTogetherを呼び出し，それから分子と分母を因数分解する．
Factorは以下のオプションを取る．

Extension	None	使用する係数体
GaussianIntegers	False	ガウス整数上で因数分解するかどうか
Modulus	0	整数に仮定する法
Trig	False	代数変換だけでなく三角変換も行うかどうか

デフォルト設定のExtension->Noneでは，Factor[poly]は多項式 poly において代数的数である係数を独立変数と同様のやり方で取り扱う．
Factor[poly,Extension->Automatic]は，多項式 poly にある任意の代数的数を含めるように，係数の取り扱える領域を拡張する． »
Factorは自動的に，リスト，方程式，不等式，論理関数に縫い込まれる．

例題

すべて開くすべて閉じる

例 (3)

一変数多項式の因数分解：

Wolfram Language code: Factor[1 + 2x + x ^ 2]

Wolfram Language code: Factor[x ^ 10 - 1]

多変数多項式の因数分解：

Wolfram Language code: Factor[x ^ 10 - y ^ 10]

2を法とした整数上で多項式を因数分解する：

Wolfram Language code: Factor[x ^ 10 - 1, Modulus -> 2]

スコープ (13)

基本的な用法 (6)

一変数の多項式：

Wolfram Language code: Factor[x ^ 3 - 6x ^ 2 + 11x - 6]

多変数の多項式：

Wolfram Language code: Factor[2x ^ 3 y - 2a ^ 2x y - 3a ^ 2x ^ 2 + 3a ^ 4]

有理関数：

Wolfram Language code: Factor[(x ^ 3 + 2x ^ 2) / (x ^ 2 - 4y ^ 2) - (x + 2) / (x ^ 2 - 4y ^ 2)]

多項式ではない式：

Wolfram Language code: Factor[2 ^ (3x) - 1]

Factorはリストに縫い込まれる：

Wolfram Language code: Factor[{x ^ 2 - 1, x ^ 4 - 1, x ^ 8 - 1}]

Factorは等式と不等式に縫い込まれる：

Wolfram Language code: Factor[1 < 1 + 2 x + x ^ 2 + 1 / (1 + x) < 2]

高度な用法 (7)

ガウス整数上で多項式を因数分解する：

Wolfram Language code: Factor[x ^ 2 + 1, GaussianIntegers -> True]

代数拡大上で多項式を因数分解する：

Wolfram Language code: Factor[x ^ 4 - 2, Extension -> Sqrt[2]]

3を法とする整数上で多項式を因数分解する：

Wolfram Language code: Factor[x ^ 3 + 1, Modulus -> 3]

有限体上で多項式を因数分解する：

Wolfram Language code: ℱ = FiniteField[17, 3];

Wolfram Language code: Factor[ℱ[3]x ^ 2 + ℱ[1771]]

Wolfram Language code: Factor[x ^ 3 + 5x + 19, Extension -> ℱ]

有限体の拡大上で多項式を因数分解する：

Wolfram Language code:

ℱ = FiniteField[29, 3];
𝒢 = FiniteField[29, 6];
ℰ = FiniteFieldEmbedding[ℱ, 𝒢];

上で既約の有限体は，をより大きい体に埋め込んだ後で因数分解される：

Wolfram Language code: Factor[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56]]

Wolfram Language code: Factor[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56], Extension -> ℰ]

多項式ではない式にも因数分解できるものがある：

Wolfram Language code: Factor[x ^ (2s) + 2x ^ s + 1]

Wolfram Language code: Factor[x ^ (2 / 3s) + 2x ^ s + 1]

Wolfram Language code: Factor[Exp[2s] + 2Exp[s] + 1]

次数の多項式を因数分解する：

Wolfram Language code:

rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n]
SeedRandom[1234];
p = rpoly[1000]; q = rpoly[1000];
r = Expand[p q];

Wolfram Language code: Factor[r]//Short//AbsoluteTiming

オプション (7)

Extension (4)

代数的数体上で因数分解する：

Wolfram Language code: Factor[1 + x ^ 4, Extension -> Sqrt[2]]

Wolfram Language code: Factor[1 + x ^ 4, Extension -> {Sqrt[2], I}]

Extension->Automaticとすると，自動的に係数をカバーする体まで拡大する：

Wolfram Language code: Factor[2 + 2Sqrt[2]x + x ^ 2]

Wolfram Language code: Factor[2 + 2Sqrt[2]x + x ^ 2, Extension -> Automatic]

整数定数を持つ多項式を有限体上で因数分解する：

Wolfram Language code: ℱ = FiniteField[73, 4];

Wolfram Language code: Factor[x ^ 4 + 21x + 3, Extension -> ℱ]

係数を持つ多項式を有限体上で因数分解する：

Wolfram Language code: ℱ = FiniteField[7, 2];

Wolfram Language code: Factor[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567]]

をより大きい体に埋め込むとさらに因数分解できるようになる：

Wolfram Language code:

𝒢 = FiniteField[7, 4];
ℰ = FiniteFieldEmbedding[ℱ, 𝒢];

Wolfram Language code: Factor[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567], Extension -> ℰ]

GaussianIntegers (1)

ガウス整数上で因数分解する：

Wolfram Language code: Factor[1 + x ^ 2, GaussianIntegers -> True]

Wolfram Language code: Factor[1 + x ^ 2, Extension -> I]

Modulus (1)

有限体上で因数分解する：

Wolfram Language code: Factor[5 + x ^ 12]

Wolfram Language code: Factor[5 + x ^ 12, Modulus -> 7]

Trig (1)

三角法の式を因数分解する：

Wolfram Language code: Factor[Sin[x] + Sin[y], Trig -> True]

アプリケーション (3)

多項式で動作をモデル化する場合，多項式を評価すると0になるタイミングを決定することが重要である．例えば，ビデオゲームシステムを作成するためのコストが次の式でモデル化されるとする：

Wolfram Language code: cost[x_] := -.03x ^ 3 + 4x ^ 2 - x + 500

Wolfram Language code: Plot[cost[x], {x, 0, 100}]

また，収益が以下の方程式でモデル化されるとする：

Wolfram Language code: revenue[x_] := .03x ^ 2 - 4x + 200

Wolfram Language code: Plot[revenue[x], {x, 0, 100}]

収益をあげるまでに何単位売らなければならないかが知りたければ，差を計算する：

Wolfram Language code: profit[x_] := revenue[x] - cost[x]

Wolfram Language code: Plot[profit[x], {x, 0, 100}]

次に，Factorを使って収益関数が0になる点を求めることで問題を解く：

Wolfram Language code: Factor[profit[x]]

以下で，で収益が0になることが分かる：

Wolfram Language code: Plot[profit[x], {x, 130, 140}]

それ自身の平方と等しい数を求める：

Wolfram Language code: x ^ 2 == x

方程式の両辺からを引く：

Wolfram Language code: SubtractSides[%, x]

Factorを使って多項式が0になる点を求める：

Wolfram Language code: Factor[%]

それ自身の平方と等しい唯一の数は，したがって，とである：

Wolfram Language code: 0 ^ 2

Wolfram Language code: 1 ^ 2

2つの多項式の最大公約数を計算する：

Wolfram Language code: Factor[-x ^ 2 + x]

Wolfram Language code: Factor[x ^ 4 - 1]

両者が因子を共有していることがわかる．PolynomialGCDを使ってこの結果を確かめる：

Wolfram Language code: PolynomialGCD[-x ^ 2 + x, x ^ 4 - 1]

特性と関係 (3)

Expandは実質的にFactorの逆である：

Wolfram Language code: Factor[x ^ 50 - 1]

Wolfram Language code: Expand[Factor[x ^ 50 - 1]]

FactorListは因数のリストを返す：

Wolfram Language code: FactorList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

FactorSquareFreeは，無平方因子のみを取り出す：

Wolfram Language code: f = x ^ 9 + 9x ^ 8 + 21x ^ 7 - 27x ^ 6 - 153x ^ 5 - 81x ^ 4 + 239x ^ 3 + 207x ^ 2 - 108x - 108;

Wolfram Language code: Factor[f]

Wolfram Language code: FactorSquareFree[f]

おもしろい例題 (2)

2が係数として現れるの最初の因数分解：

Wolfram Language code: Factor[x ^ 105 - 1]

の因子の個数を可視化する：

Wolfram Language code: ListLinePlot[Table[Length[Factor[x ^ n - 1]], {n, 200}]]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Factor

詳細とオプション

例題

例 (3)

スコープ (13)

基本的な用法 (6)

高度な用法 (7)

オプション (7)

Extension (4)

GaussianIntegers (1)

Modulus (1)

Trig (1)

アプリケーション (3)

特性と関係 (3)

おもしろい例題 (2)

テキスト

CMS

APA

BibTeX

BibLaTeX

Factor

詳細とオプション

例題

例 (3)

スコープ (13)

基本的な用法 (6)

高度な用法 (7)

オプション (7)

Extension (4)

GaussianIntegers (1)

Modulus (1)

Trig (1)

アプリケーション (3)

特性と関係 (3)

おもしろい例題 (2)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX