WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FactorList[poly]

多項式の因子をこれらの指数とともにリスト形式にして返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
高度な用法  
オプション  
Extension  
GaussianIntegers  
Modulus  
Trig  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

FactorList

FactorList[poly]

多項式の因子をこれらの指数とともにリスト形式にして返す．

詳細とオプション

  • このリストの第1要素は常に式全体にかかる因子となる．また，式全体にかかる因子が存在しない場合，{1,1}となる．
  • FactorListは，次のオプションを取る．
  • Extension None使用する係数体
    GaussianIntegers Falseガウス整数係数を許容するかどうか
    Modulus 0整数に仮定する法
    Trig False代数変換だけでなく三角変換も行うかどうか
  • FactorList[poly,Modulus->p]の p は素数でなければならない．
  • FactorList[poly,Extension->{a1,a2,…}]は，ai の任意の有理的組合せからなる係数を認める．

例題

すべて開く すべて閉じる

例  (2)

多項式の既約因子をリストにする：

Wolfram Language code: FactorList[x ^ 2 - 1]
Wolfram Language code: FactorList[2x ^ 3 + 2x ^ 2 - 2x - 2]

多変量多項式の既約因子をリストにする：

Wolfram Language code: FactorList[x ^ 3 + 2x ^ 2y + x y ^ 2 + x ^ 2z - y ^ 2z - x z ^ 2 - 2y z ^ 2 - z ^ 3]

スコープ  (11)

基本的な用法  (4)

一変数多項式：

Wolfram Language code: FactorList[x ^ 3 - 6x ^ 2 + 11x - 6]

多変数多項式：

Wolfram Language code: FactorList[2x ^ 3 y - 2a ^ 2x y - 3a ^ 2x ^ 2 + 3a ^ 4]

重複因子を持つ多項式：

Wolfram Language code: FactorList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

有理関数：

Wolfram Language code: FactorList[(x ^ 3 + 2x ^ 2) / (x ^ 2 - 4y ^ 2) - (x + 2) / (x ^ 2 - 4y ^ 2)]

高度な用法  (7)

ガウスの整数上の既約因子：

Wolfram Language code: FactorList[x ^ 2 + 1, GaussianIntegers -> True]

代数拡大上の既約因子：

Wolfram Language code: FactorList[x ^ 4 - 2, Extension -> Sqrt[2]]

2を法とした整数上の既約因子：

Wolfram Language code: FactorList[x ^ 4 + 1, Modulus -> 2]

有限体上で既約の因子：

Wolfram Language code: ℱ = FiniteField[17, 3];
Wolfram Language code: FactorList[ℱ[3]x ^ 2 + ℱ[1771]]
Wolfram Language code: FactorList[x ^ 3 + 5x + 19, Extension -> ℱ]

有限体の拡大上で既約の因子：

Wolfram Language code: ℱ = FiniteField[29, 3]; 𝒢 = FiniteField[29, 6]; ℰ = FiniteFieldEmbedding[ℱ, 𝒢];

上で既約の多項式は， をより大きい体 に埋め込んだ後で因数分解できる：

Wolfram Language code: FactorList[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56]]
Wolfram Language code: FactorList[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56], Extension -> ℰ]

非多項式の因子をリストにする：

Wolfram Language code: FactorList[E ^ (2 x) - 2E ^ x + 1]
Wolfram Language code: FactorList[x ^ 2 - Sqrt[x]]

次数の多項式の因子を列挙する：

Wolfram Language code: rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n] SeedRandom[1234]; p = rpoly[1000]; q = rpoly[1000]; r = Expand[p q];
Wolfram Language code: (facs = FactorList[r]);//AbsoluteTiming
Wolfram Language code: {Exponent[#[[1]], x], #[[2]]}& /@ facs

オプション  (7)

Extension  (4)

代数的数体上で因子分解する：

Wolfram Language code: FactorList[1 + x ^ 4, Extension -> Sqrt[2]]
Wolfram Language code: FactorList[1 + x ^ 4, Extension -> {Sqrt[2], I}]

Extension->Automaticは自動的に係数をカバーする体に拡大する：

Wolfram Language code: FactorList[2 + 2Sqrt[2]x + x ^ 2]
Wolfram Language code: FactorList[2 + 2Sqrt[2]x + x ^ 2, Extension -> Automatic]

整数係数を持つ多項式を有限体上で因数分解する：

Wolfram Language code: ℱ = FiniteField[73, 3];
Wolfram Language code: FactorList[x ^ 3 + 21x + 3, Extension -> ℱ]

係数を持つ多項式を有限体上で因数分解する：

Wolfram Language code: ℱ = FiniteField[7, 2];
Wolfram Language code: FactorList[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567]]

をより大きい体 に埋め込むとさらに因数分解できる：

Wolfram Language code: 𝒢 = FiniteField[7, 4]; ℰ = FiniteFieldEmbedding[ℱ, 𝒢];
Wolfram Language code: FactorList[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567], Extension -> ℰ]

GaussianIntegers  (1)

ガウスの整数上で因子分解する：

Wolfram Language code: FactorList[1 + x ^ 2, GaussianIntegers -> True]
Wolfram Language code: FactorList[1 + x ^ 2, Extension -> I]

Modulus  (1)

有限体上で因子分解する：

Wolfram Language code: FactorList[5 + x ^ 12]
Wolfram Language code: FactorList[5 + x ^ 12, Modulus -> 7]

Trig  (1)

三角関数の式を因子分解する：

Wolfram Language code: FactorList[Sin[x] + Sin[y], Trig -> True]

アプリケーション  (2)

FactorListは関数の動作を決定する上で役に立つ：

Wolfram Language code: f = x ^ 3 - x ^ 2 - 16x - 20;
Wolfram Language code: FactorList[f]

はとに根を持ち，では 軸と交差しないがで 軸と交差する：

Wolfram Language code: Plot[-20 - 16 x - x^2 + x^3, {x, -4, 6}]

ある多項式が完全平方であることを示す：

Wolfram Language code: f = 62500 - 112500 x + 15625 x^2 + 47500 x^3 - 3500 x^4 - 9380 x^5 - 1106 x^6 + 628 x^7 + 208 x^8 + 24 x^9 + x^10;

因子を計算し定数因子が正であることに注目する：

Wolfram Language code: fac = FactorList[f]

非定数因子の指数を抽出する：

Wolfram Language code: exp = Transpose[Rest[fac]][[2]]

どの因子も偶数の指数を持ち，したがって が平方であることを確かめる：

Wolfram Language code: AllTrue[exp, EvenQ]

特性と関係  (3)

FactorListは既約因子のリストを返す：

Wolfram Language code: FactorList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

これは，因子を掛け合せる：

Wolfram Language code: Times@@Power@@@%

Factorは因子の積を返す：

Wolfram Language code: Factor[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

Expandはすべての因子を繋ぐ：

Wolfram Language code: Expand[%]

FactorSquareFreeListは無平方因子のリストを返す：

Wolfram Language code: FactorSquareFreeList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

FactorIntegerは整数の素因子のリストを返す：

Wolfram Language code: FactorInteger[1234567]
Wolfram Language code: Times@@Power@@@%
Wolfram Research (1988), FactorList, Wolfram言語関数， https://reference.wolfram.com/language/ref/FactorList.html （2023年に更新）.

テキスト

Wolfram Research (1988), FactorList, Wolfram言語関数， https://reference.wolfram.com/language/ref/FactorList.html （2023年に更新）.

CMS

Wolfram Language. 1988. "FactorList." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/FactorList.html.

APA

Wolfram Language. (1988). FactorList. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FactorList.html

BibTeX

@misc{reference.wolfram_2026_factorlist, author="Wolfram Research", title="{FactorList}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/FactorList.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_factorlist, organization={Wolfram Research}, title={FactorList}, year={2023}, url={https://reference.wolfram.com/language/ref/FactorList.html}, note=[Accessed: 10-September-2026]}