WOLFRAM

Wolfram 语言与系统参考资料中心

FactorList[poly]

给出一个多项式的因子及它们的指数组成的列表.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
高级用法  
选项  
Extension  
GaussianIntegers  
Modulus  
Trig  
应用  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

FactorList

FactorList[poly]

给出一个多项式的因子及它们的指数组成的列表.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

列出多项式的不可约因子：

Wolfram Language code: FactorList[x ^ 2 - 1]
Wolfram Language code: FactorList[2x ^ 3 + 2x ^ 2 - 2x - 2]

列出多变量多项式的不可约因子：

Wolfram Language code: FactorList[x ^ 3 + 2x ^ 2y + x y ^ 2 + x ^ 2z - y ^ 2z - x z ^ 2 - 2y z ^ 2 - z ^ 3]

范围  (11)

基本用法  (4)

一元多项式：

Wolfram Language code: FactorList[x ^ 3 - 6x ^ 2 + 11x - 6]

多元多项式：

Wolfram Language code: FactorList[2x ^ 3 y - 2a ^ 2x y - 3a ^ 2x ^ 2 + 3a ^ 4]

多重因子多项式：

Wolfram Language code: FactorList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

有理函数：

Wolfram Language code: FactorList[(x ^ 3 + 2x ^ 2) / (x ^ 2 - 4y ^ 2) - (x + 2) / (x ^ 2 - 4y ^ 2)]

高级用法  (7)

高斯整数上的不可约因子：

Wolfram Language code: FactorList[x ^ 2 + 1, GaussianIntegers -> True]

代数扩展域上的不可约因子：

Wolfram Language code: FactorList[x ^ 4 - 2, Extension -> Sqrt[2]]

整数模数 2 上的不可约因子：

Wolfram Language code: FactorList[x ^ 4 + 1, Modulus -> 2]

有限域上的不可约因子：

Wolfram Language code: ℱ = FiniteField[17, 3];
Wolfram Language code: FactorList[ℱ[3]x ^ 2 + ℱ[1771]]
Wolfram Language code: FactorList[x ^ 3 + 5x + 19, Extension -> ℱ]

有限域的扩张上的不可约因子：

Wolfram Language code: ℱ = FiniteField[29, 3]; 𝒢 = FiniteField[29, 6]; ℰ = FiniteFieldEmbedding[ℱ, 𝒢];

在把 嵌入更大的领域 后，一个在 上本不可约的多项式可以进一步因式分解：

Wolfram Language code: FactorList[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56]]
Wolfram Language code: FactorList[ℱ[12]x ^ 2 + ℱ[34]x + ℱ[56], Extension -> ℰ]

列出非多项式表达式的因子：

Wolfram Language code: FactorList[E ^ (2 x) - 2E ^ x + 1]
Wolfram Language code: FactorList[x ^ 2 - Sqrt[x]]

对一个阶为 的多项式进行因式分解：

Wolfram Language code: rpoly[n_] := RandomInteger[{-2 ^ 10, 2 ^ 10}, {n + 1}].x ^ Range[0, n] SeedRandom[1234]; p = rpoly[1000]; q = rpoly[1000]; r = Expand[p q];
Wolfram Language code: (facs = FactorList[r]);//AbsoluteTiming
Wolfram Language code: {Exponent[#[[1]], x], #[[2]]}& /@ facs

选项  (7)

Extension  (4)

代数数域上的因式分解：

Wolfram Language code: FactorList[1 + x ^ 4, Extension -> Sqrt[2]]
Wolfram Language code: FactorList[1 + x ^ 4, Extension -> {Sqrt[2], I}]

Extension->Automatic 自动扩展到覆盖系数的域：

Wolfram Language code: FactorList[2 + 2Sqrt[2]x + x ^ 2]
Wolfram Language code: FactorList[2 + 2Sqrt[2]x + x ^ 2, Extension -> Automatic]

对有限域上有整数系数的多项式进行分解：

Wolfram Language code: ℱ = FiniteField[73, 3];
Wolfram Language code: FactorList[x ^ 3 + 21x + 3, Extension -> ℱ]

对一个系数在有限域中的多项式进行因式分解：

Wolfram Language code: ℱ = FiniteField[7, 2];
Wolfram Language code: FactorList[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567]]

将 嵌入到更大的域 ，可以进一步进行因式分解：

Wolfram Language code: 𝒢 = FiniteField[7, 4]; ℰ = FiniteFieldEmbedding[ℱ, 𝒢];
Wolfram Language code: FactorList[ℱ[1]x ^ 4 + ℱ[234]x + ℱ[567], Extension -> ℰ]

GaussianIntegers  (1)

高斯整数上的因式分解：

Wolfram Language code: FactorList[1 + x ^ 2, GaussianIntegers -> True]
Wolfram Language code: FactorList[1 + x ^ 2, Extension -> I]

Modulus  (1)

有限域上的因式分解：

Wolfram Language code: FactorList[5 + x ^ 12]
Wolfram Language code: FactorList[5 + x ^ 12, Modulus -> 7]

Trig  (1)

三角表达式的因式分解：

Wolfram Language code: FactorList[Sin[x] + Sin[y], Trig -> True]

应用  (2)

在确定函数的行为时，FactorList 很有用：

Wolfram Language code: f = x ^ 3 - x ^ 2 - 16x - 20;
Wolfram Language code: FactorList[f]

的根为 和 ，在 处它没有穿过 轴，在 处穿过 轴：

Wolfram Language code: Plot[-20 - 16 x - x^2 + x^3, {x, -4, 6}]

证明多项式是一个完美平方式：

Wolfram Language code: f = 62500 - 112500 x + 15625 x^2 + 47500 x^3 - 3500 x^4 - 9380 x^5 - 1106 x^6 + 628 x^7 + 208 x^8 + 24 x^9 + x^10;

计算因子，注意，常数因子为正：

Wolfram Language code: fac = FactorList[f]

提取非常数因子的指数：

Wolfram Language code: exp = Transpose[Rest[fac]][[2]]

确认每一个因子的指数为偶数，因此 是平方式：

Wolfram Language code: AllTrue[exp, EvenQ]

属性和关系  (3)

FactorList 给出不可约的因子列表：

Wolfram Language code: FactorList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

因子相乘：

Wolfram Language code: Times@@Power@@@%

Factor 给出因子的一个乘积：

Wolfram Language code: Factor[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

Expand 展开所有的因子：

Wolfram Language code: Expand[%]

FactorSquareFreeList 给出无平方因子列表：

Wolfram Language code: FactorSquareFreeList[x ^ 8 + 11x ^ 7 + 43x ^ 6 + 59x ^ 5 - 35x ^ 4 - 151x ^ 3 - 63x ^ 2 + 81x + 54]

FactorInteger 给出整数的素数因子列表：

Wolfram Language code: FactorInteger[1234567]
Wolfram Language code: Times@@Power@@@%
Wolfram Research (1988)，FactorList，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FactorList.html （更新于 2023 年）.

文本

Wolfram Research (1988)，FactorList，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FactorList.html （更新于 2023 年）.

CMS

Wolfram 语言. 1988. "FactorList." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/FactorList.html.

APA

Wolfram 语言. (1988). FactorList. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FactorList.html 年

BibTeX

@misc{reference.wolfram_2026_factorlist, author="Wolfram Research", title="{FactorList}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/FactorList.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_factorlist, organization={Wolfram Research}, title={FactorList}, year={2023}, url={https://reference.wolfram.com/language/ref/FactorList.html}, note=[Accessed: 15-September-2026]}