WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FactorialMomentGeneratingFunction[dist,t]

分布 dist の階乗モーメント母関数を変数 t の関数として与える．

FactorialMomentGeneratingFunction[dist,{t1,t2,…}]

多変量分布 dist の階乗モーメント母関数を変数 t1, t2, … の関数として与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

FactorialMomentGeneratingFunction

FactorialMomentGeneratingFunction[dist,t]

分布 dist の階乗モーメント母関数を変数 t の関数として与える．

FactorialMomentGeneratingFunction[dist,{t1,t2,…}]

多変量分布 dist の階乗モーメント母関数を変数 t1, t2, … の関数として与える．

詳細

例題

すべて開く すべて閉じる

例  (3)

一変量離散分布の階乗モーメント母関数：

Wolfram Language code: FactorialMomentGeneratingFunction[PoissonDistribution[μ], t]

一変量連続分布の階乗モーメント母関数を計算する：

Wolfram Language code: FactorialMomentGeneratingFunction[NormalDistribution[μ, σ], t]

多変量分布の階乗モーメント母関数：

Wolfram Language code: FactorialMomentGeneratingFunction[MultinomialDistribution[n, {p1, p2, p3}], {t1, t2, t3}]

スコープ  (5)

離散式分布の階乗モーメント母関数を求める：

Wolfram Language code: FactorialMomentGeneratingFunction[ProbabilityDistribution[(18^-k/Sqrt[6]) Binomial[4k, 2k], {k, 0, Infinity, 1}], t]

データ分布の階乗モーメント母関数を計算する：

Wolfram Language code: FactorialMomentGeneratingFunction[EmpiricalDistribution[{1, 2, 3, 3, 4, 5, 5}], t]

打切り分布の階乗モーメント母関数を求める：

Wolfram Language code: FactorialMomentGeneratingFunction[CensoredDistribution[{0, 10}, PoissonDistribution[2]], t]

母数混合分布の階乗モーメント母関数を求める：

Wolfram Language code: FactorialMomentGeneratingFunction[ParameterMixtureDistribution[PoissonDistribution[λ], λExponentialDistribution[μ]], t]

ランダム過程のスライス分布についての階乗モーメント母関数を求める：

Wolfram Language code: FactorialMomentGeneratingFunction[PoissonProcess[μ][s], t]

アプリケーション  (6)

個の独立同分布に従う幾何変量の総和の階乗モーメント母関数を求める：

Wolfram Language code: FactorialMomentGeneratingFunction[GeometricDistribution[p], t] ^ n

NegativeBinomialDistributionの階乗モーメント母関数と比較する：

Wolfram Language code: FactorialMomentGeneratingFunction[NegativeBinomialDistribution[n, p], t]
Wolfram Language code: % - %%

がPoissonDistributionに従うと仮定して， 個の独立同分布に従う確率変数の乱数の総和のか以上モーメント母関数を求める：

Wolfram Language code: Expectation[FactorialMomentGeneratingFunction[GeometricDistribution[p], t] ^ n, nPoissonDistribution[μ]]

PolyaAeppliDistributionの階乗モーメント母関数と比較する：

Wolfram Language code: FactorialMomentGeneratingFunction[PolyaAeppliDistribution[μ(1 - p), 1 - p], t]
Wolfram Language code: Simplify[% / %%]

非負整数の確率変数のPDFをその階乗モーメント母関数から求める：

Wolfram Language code: fmgf[t_] = ((2 - t)^3/(4 - 3 t)^5);

確率母関数の解釈を使う：

Wolfram Language code: pdf = SeriesCoefficient[fmgf[z], {z, 0, k}, Assumptions -> k ≥ 0]

確率質量関数を示す：

Wolfram Language code: DiscretePlot[pdf, {k, 0, 25}, FillingStyle -> Gray]

正規化を確かめる：

Wolfram Language code: Sum[pdf, {k, 0, Infinity}]

BernoulliDistributionの確率母関数を構築する：

Wolfram Language code: bpgf[z_] = FactorialMomentGeneratingFunction[BernoulliDistribution[p], z]

そのラグランジュ(Lagrange)変換を行い，これを新たな確率母関数として使う：

Wolfram Language code: {pgf[z_]} = u /. Solve[u == z bpgf[u], u] //Simplify

これをシフトされたGeometricDistributionの確率母関数と比較する：

Wolfram Language code: FactorialMomentGeneratingFunction[TransformedDistribution[x + 1, xGeometricDistribution[1 - p]], z]

ラグランジュ変換をGeometricDistributionの確率母関数に適用する：

Wolfram Language code: gpgf[z_] = FactorialMomentGeneratingFunction[GeometricDistribution[p], z]
Wolfram Language code: u /. Solve[u == z gpgf[u] && 0 < p < 1 && 0 < u < 1 && 0 < z < 1, u, Reals]
Wolfram Language code: {hpgf[z_]} = Refine[%, 0 < p < 1 && 0 < z < 1]

PDFを再構築する：

Wolfram Language code: pdf = SeriesCoefficient[hpgf[z], {z, 0, k}, Assumptions -> 0 < p < 1]//FullSimplify

結果の分布はHaight分布として知られるものである．これはについてのみ1に正規化される：

Wolfram Language code: Sum[pdf, {k, 1, Infinity}, Assumptions -> 0 < p < 1]

確率質量関数を示す：

Wolfram Language code: DiscretePlot[pdf /. p -> 5 / 9, {k, 0, 10}]

不正なコインで表が連続2回出るまでにはこのコインを何回トスしたらよいか，その回数の分布を求める．表が出る確率を とする．事象空間には，裏(T)，表の次に裏(HT)，表が2回連続(HH)の3つのタイプの以下の確率の事象が含まれる：

Wolfram Language code: pr["T"] = (1 - p); pr["HT"] = p(1 - p); pr["HH"] = p ^ 2;

確率変数の階乗モーメント母関数を，それが事象Tの合計に事象HTの2倍に2を加えたものと解釈して求める：

Wolfram Language code: fmgf = t ^ 2FactorialMomentGeneratingFunction[NegativeMultinomialDistribution[1, {pr["T"], pr["HT"]}], {t, t^2}]

PDFを再構築する：

Wolfram Language code: pdf = SeriesCoefficient[fmgf, {t, 0, k}, Assumptions -> k ≥ 0]

平均を計算する：

Wolfram Language code: mean = Limit[D[fmgf, t], t -> 1]//Simplify

関係を使って分散を求める：

Wolfram Language code: MomentConvert[CentralMoment[2], FactorialMoment]
Wolfram Language code: variance = Factor[Limit[D[fmgf, {t, 2}], t -> 1] + mean(1 - mean)]

特性と関係  (3)

FactorialMomentGeneratingFunctionは のExpectationに等しい：

Wolfram Language code: Expectation[t ^ n, nGeometricDistribution[p]]
Wolfram Language code: FactorialMomentGeneratingFunction[GeometricDistribution[p], t]
Wolfram Language code: Simplify[% - %%]

非負の離散変量については，階乗モーメント母関数は確率母関数と一致する：

Wolfram Language code: FactorialMomentGeneratingFunction[GeometricDistribution[p], z]
Wolfram Language code: Sum[PDF[GeometricDistribution[p], k]z^k, {k, 0, Infinity}]
Wolfram Language code: Simplify[% == %%]

階乗モーメント母関数から階乗モーメントを抽出することができる：

Wolfram Language code: 𝒟 = HypergeometricDistribution[n, m, nt];
Wolfram Language code: D[FactorialMomentGeneratingFunction[𝒟, t], {t, 3}] /. t -> 1
Wolfram Language code: FactorialMoment[𝒟, 3]//Refine[#, nt ≥ 3]&
Wolfram Language code: %% - %//Simplify

あるいは，SeriesCoefficientを使う：

Wolfram Language code: SeriesCoefficient[3!FactorialMomentGeneratingFunction[𝒟, t], {t, 1, 3}]
Wolfram Language code: FactorialMoment[𝒟, 3]//Refine[#, nt ≥ 3]&
Wolfram Language code: %% - %//Simplify

考えられる問題  (2)

裾部の長い分布の中には低次数のいくつかの階乗モーメントしか定義できないものがある：

Wolfram Language code: FactorialMoment[BetaNegativeBinomialDistribution[7, 11, 13], r]

それに応じて，階乗モーメント母関数も定義されない：

Wolfram Language code: FactorialMomentGeneratingFunction[BetaNegativeBinomialDistribution[7, 11, 13], t]

FactorialMomentGeneratingFunctionは常に閉形式で既知である訳ではない：

Wolfram Language code: FactorialMomentGeneratingFunction[WalleniusHypergeometricDistribution[n, m, nt, w], t]

おもしろい例題  (1)

一変数分布について，階乗モーメント母関数を複素平面上で可視化する：

Wolfram Language code: dists = {NegativeBinomialDistribution[10, 2 / 3], PoissonDistribution[3], BorelTannerDistribution[5 / 6, 10], ExponentialDistribution[1], BirnbaumSaundersDistribution[1, 3], HyperbolicDistribution[2, 1, 1, 2]};
Wolfram Language code: Table[Plot3D[Re[FactorialMomentGeneratingFunction[𝒟, x + I y]]//Evaluate, {x, -2, 2}, {y, -4, 4}, Mesh -> None, ImageSize -> 200, PlotLabel -> 𝒟], {𝒟, dists}]
Wolfram Research (2010), FactorialMomentGeneratingFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/FactorialMomentGeneratingFunction.html.

テキスト

Wolfram Research (2010), FactorialMomentGeneratingFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/FactorialMomentGeneratingFunction.html.

CMS

Wolfram Language. 2010. "FactorialMomentGeneratingFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FactorialMomentGeneratingFunction.html.

APA

Wolfram Language. (2010). FactorialMomentGeneratingFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FactorialMomentGeneratingFunction.html

BibTeX

@misc{reference.wolfram_2026_factorialmomentgeneratingfunction, author="Wolfram Research", title="{FactorialMomentGeneratingFunction}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/FactorialMomentGeneratingFunction.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_factorialmomentgeneratingfunction, organization={Wolfram Research}, title={FactorialMomentGeneratingFunction}, year={2010}, url={https://reference.wolfram.com/language/ref/FactorialMomentGeneratingFunction.html}, note=[Accessed: 15-September-2026]}