WOLFRAM

Wolfram 语言与系统参考资料中心

FeatureExtract[examples]

使用基于给定示例训练的特征提取器，为每个 example 提取特征.

FeatureExtract[examples,spec]

使用指定的特征提取器方法 spec 提取特征.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
输入形状  
提取器规范  
特征类型  
选项  
FeatureNames  
FeatureTypes  
应用  
数据集可视化  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

FeatureExtract

FeatureExtract[examples]

使用基于给定示例训练的特征提取器，为每个 example 提取特征.

FeatureExtract[examples,spec]

使用指定的特征提取器方法 spec 提取特征.

更多信息和选项

  • FeatureExtract 通常用于将原始数据处理为可用特征（例如，用于训练机器学习算法）.
  • FeatureExtract 可用于许多类型的数据，包括数字、文本、音频、图像、图和时间序列，以及这些类型的组合.
  • examples 的可能值有：
  • example未经训练的单一示例
    {example1,…}训练示例的列表
    Dataset[…]Dataset 对象
    Tabular[…]Tabular 对象
  • 各 examplei 可以是单一数据元素、数据元素列表、数据元素关联或者 Dataset 对象.
  • spec 的可能值有：
  • extractor使用指定的提取器方法
    partextractor对特定示例部分应用提取器
    {part1extractor1,…}为特定部分指定提取器
  • 在 FeatureExtract[examples,{part1extractor1,…}] 中，extractori 都分别应用于 examples.
  • 可能的特征提取器方法 extractor 包括：
  • Automatic自动提取
    Identity给出无变化的数据
    "ConformedData"一致化的图像、颜色、日期等
    "NumericVector"来自任意数据的数值向量
    "name"命名提取器方法
    f对各个示例应用函数 f
    {extractor1,extractor2,…}依次使用一系列提取器
  • 可能的 part 形式有：
  • All每个示例的所有部分
    i每个示例的第 i 个部分
    {i1,i2,…}每个示例的第 i1、i2、… 个部分
    "key"每个示例中具有指定键的部分
    {"key1","key2",…}每个示例中名称为 "keyi" 的部分
  • 当明确指定部分时，提取特征时将删除任何未提及的部分.
    • 提取器
  • FeatureExtract[examples] 等价于 FeatureExtract[examples, Automatic]，而这通常又等价于FeatureExtract[examples, "NumericVector"].
  • "NumericVector" 方法通常会将示例转换为数值向量，填补缺失数据，并使用 DimensionReduction 降低维度.
  • 针对单一数据类型的特征提取器方法仅适用于与其类型兼容的数据元素. 其他数据元素将保持不变而返回.
  • 当仅提供一个示例时，并非所有特定的特征提取器都可用——例如，向量处理器将假定列表是标量特征的列表.
  • 具体的提取器是：
  • 数值数据：
  • "DiscretizedVector"离散化的数值数据
    "DimensionReducedVector"降维的数值向量
    "MissingImputed"缺失值被估算的数据
    "StandardizedVector"用 Standardize 处理过的数值数据
  • 标称数据：
  • "IndicatorVector"用指示向量“独热编码”的名义数据
    "IntegerVector"用整数编码的名义数据
  • 文本：
  • "LowerCasedText"每个字符均为小写的文本
    "SegmentedCharacters"分割成字符的文本
    "SegmentedWords"分割成单词的文本
    "SentenceVector"文字的语义向量
    "TFIDF"词频逆向文件频率向量
    "WordVectors"文字的语义向量序列（仅限英文）
  • 图像：
  • "FaceFeatures"来自人脸图像的语义向量
    "ImageFeatures"图像的语义向量
    "PixelVector"图像像素值向量
  • 音频对象：
  • "AudioFeatures"音频对象的语义向量序列
    "AudioFeatureVector"音频对象的语义向量
    "LPC"音频线性预测系数
    "MelSpectrogram"用对数频次分组的音频频谱图
    "MFCC"音频梅尔频率倒谱系数向量序列
    "SpeakerFeatures"讲话者的语义向量序列
    "SpeakerFeatureVector"讲话者的语义向量
    "Spectrogram"音频频谱图
  • 视频对象：
  • "VideoFeatures"来自视频对象的语义向量序列
    "VideoFeatureVector"来自视频对象的语义向量
  • 图：
  • "GraphFeatures"总结图的属性的数值向量
  • 分子：
  • "AtomPairs"来自原子对的布尔向量以及它们之间的路径长度
    "MoleculeExtendedConnectivity"来自枚举的分子子图的布尔向量
    "MoleculeFeatures"概括分子属性的数值向量
    "MoleculeTopologicalFeatures"来自圆形原子邻域的布尔向量
    • 选项
  • 可以给出以下选项：
  • FeatureNames Automatic赋给 examplei 的元素的名称
    FeatureTypes Automatic对 examplei 的元素要假定的特征类型
    RandomSeeding1234应该在内部对伪随机数生成器进行什么样的初始化
  • RandomSeeding 的可能设置包括：
  • Automatic每次函数调用时自动重新播种
    Inherited使用外部播种的随机数字
    seed用明确给定的整数或字符串作为种子
  • FeatureExtract[…] 等价于 FeatureExtraction[…,"ExtractedFeatures"].

范例

打开所有单元 关闭所有单元

基本范例  (4)

从简单的数据集提取特征：

Wolfram Language code: FeatureExtract[{{1.4, "A"}, {1.5, "A"}, {2.3, "B"}, {5.4, "B"}}]

从图像提取特征：

Wolfram Language code: FeatureExtract[{[image], [image], [image], [image], [image]}]

使用 "StandardizedVector" 提取器方法标准化的数字值：

Wolfram Language code: FeatureExtract[{{1.4, 30.1}, {1.5, 46.3}, {2.3, 27.4}, {5.4, 51.2}}, "StandardizedVector"]

通过链接提取程序方法 "SegmentedCharacters" 和 "TFIDF" 提取字符的 TFIDF 向量：

Wolfram Language code: FeatureExtract[{"the cat is grey", "my cat is fast", "this dog is scary", "the big dog"}, {"SegmentedCharacters", "TFIDF"}] // MatrixForm

范围  (26)

输入形状  (9)

提取特征列表：

Wolfram Language code: FeatureExtract[{"A rose by any other name", "It was the worst of times"}]

从具有多个特征的示例列表中提取：

Wolfram Language code: FeatureExtract[{{"It was the best of times.", "Charles Dickens"}, {"A journey of a thousand miles begins with a single step.", "Laozi (attrib.)"}, {"To be or not to be, that is the question.", "William Shakespere"}}]

在混合类型数据集上提取特征：

Wolfram Language code: FeatureExtract[{{"the cat is grey", [image]}, {"my cat is fast", [image]}, {"this dog is scary", [image]}, {"the big dog", [image]}}]

从格式化为关联列表的数据集中提取特征：

Wolfram Language code: FeatureExtract[{<|"age" -> 32, "height" -> 160, "gender" -> "female"|>, <|"height" -> 183, "age" -> 41, "gender" -> "female"|>, <|"height" -> 123, "age" -> 30, "gender" -> "female"|>, <|"height" -> 175, "age" -> 21, "gender" -> "male"|>, <|"height" -> 150, "age" -> 11, "gender" -> "male"|>, <|"age" -> 52, "height" -> 164, "gender" -> "female"|>}]

从以特征列表形式给出的数据中提取特征：

Wolfram Language code: FeatureExtract[<|"age" -> {32, 41, 30, 21, 11, 52}, "height" -> {160, 183, 123, 175, 150, 164}, "gender" -> {"female", "female", "female", "male", "male", "female"}|>]

从 Tabular 中提取的特征：

Wolfram Language code: FeatureExtract[Tabular[Association["RawSchema" -> Association["ColumnProperties" -> Association["age" -> Association["ElementType" -> "Integer64"], "height" -> Association["ElementType" -> "Integer64"], "gender" -> Association["ElementType" -> "String"]], "KeyColumns" -> None, "Backend" -> "WolframKernel"], "Options" -> {}, "BackendData" -> Association["ColumnData" -> DataStructure["ColumnTable", {{TabularColumn[Association["Data" -> {{32, 41, 30, 21, 11, 52}, {}, None}, "ElementType" -> "Integer64"]], TabularColumn[Association[ "Data" -> {{160, 183, 123, 175, 150, 164}, {}, None}, "ElementType" -> "Integer64"]], TabularColumn[Association["Data" -> {{3, {0, 6, 12, 18, 22, 26, 32}, "femalefemalefemalemalemalefemale"}, {}, None}, "ElementType" -> "String"]]}}]]]]]

从 Dataset 中提取的特征：

Wolfram Language code: FeatureExtract[Dataset[{Association["age" -> 32, "height" -> 160, "gender" -> "female"], Association["age" -> 41, "height" -> 183, "gender" -> "female"], Association["age" -> 30, "height" -> 123, "gender" -> "female"], Association["age" -> 21, "height" -> 175, "gender" -> "male"], Association["age" -> 11, "height" -> 150, "gender" -> "male"], Association["age" -> 52, "height" -> 164, "gender" -> "female"]}]]

从包含缺失值的数据集中提取特征：

Wolfram Language code: FeatureExtract[{{1.4, Missing[], "A"}, {1.5, 50.2, "A"}, {Missing[], 42.3, "B"}, {5.4, 61.7, "B"}}]

使用不需要训练的提取器从单个示例中提取特征：

Wolfram Language code: FeatureExtract["Some text.", "WordVectors"]//Shallow

提取器规范  (8)

在单个文本特征上指定特征提取器 "SentenceVector"：

Wolfram Language code: FeatureExtract["the cat is cute", "SentenceVector"]//Short

使用 "SentenceVector" 方法提取特征，然后使用 "DimensionReducedVector" 降低维度：

Wolfram Language code: FeatureExtract[{"the cat is grey", "my cat is fast", "this dog is scary", "the big dog"}, {"SentenceVector", "DimensionReducedVector"}]

使用 "TFIDF" 方法在文本和图像上提取特征：

Wolfram Language code: FeatureExtract[{{"the cat is grey", [image]}, {"my cat is fast", [image]}, {"this dog is scary", [image]}, {"the big dog", [image]}}, "TFIDF"]

由于 "TFIDF" 不应用于图像，特征仅从文本部分提取.

通过位置指定多个特征的特征提取：

Wolfram Language code: FeatureExtract[{{"Glucose", Molecule["Glucose"]}, {"Water", Molecule["Water"]}, {"Acetic Acid", Molecule["Acetic Acid"]}}, {1 -> { "SentenceVector", "DimensionReducedVector"}, 2 -> {"MoleculeFeatures", "DimensionReducedVector"}}]

仅在第二个名义变量上通过 "IndicatorVector" 方法提取特征：

Wolfram Language code: FeatureExtract[{{"Yes", "A"}, {"No", "A"}, {"No", "B"}, {"Maybe", "B"}, {"No", "C"}}, 2 -> "IndicatorVector"] // MatrixForm

使用 Identity 提取程序方法也复制第一个变量：

Wolfram Language code: FeatureExtract[{{"Yes", "A"}, {"No", "A"}, {"No", "B"}, {"Maybe", "B"}, {"No", "C"}}, {2 -> "IndicatorVector", 1 -> Identity}]

可以多次复制一个变量：

Wolfram Language code: FeatureExtract[{{"Yes", "A"}, {"No", "A"}, {"No", "B"}, {"Maybe", "B"}, {"No", "C"}}, {2 -> "IndicatorVector", 1 -> Identity, 1 -> Identity}]

通过键值指定多个特征上的特征提取：

Wolfram Language code: FeatureExtract[Tabular[Association["RawSchema" -> Association["ColumnProperties" -> Association["Name" -> Association["ElementType" -> "String"], "Molecule" -> Association["ElementType" -> "InertExpression"]], "KeyColumns" -> None, "Backend" -> "WolframKernel"], "Options" -> {}, "BackendData" -> Association["ColumnData" -> DataStructure["ColumnTable", {{TabularColumn[Association["Data" -> {{3, {0, 7, 12, 23}, "GlucoseWaterAcetic Acid"}, {}, None}, "ElementType" -> "String"]], TabularColumn[ Association["Data" -> {{Molecule[{"O", "C", "C", "O", "C", "O", "C", "O", "C", "O", "C", "O", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H"}, {Bond[{1, 2}, "Double"], Bond[{2, 3}, "Single"], Bond[{3, 4}, "Single"], Bond[{3, 5}, "Single"], Bond[{5, 6}, "Single"], Bond[{5, 7}, "Single"], Bond[{7, 8}, "Single"], Bond[{7, 9}, "Single"], Bond[{9, 10}, "Single"], Bond[{9, 11}, "Single"], Bond[ {11, 12}, "Single"], Bond[{2, 13}, "Single"], Bond[{3, 14}, "Single"], Bond[ {4, 15}, "Single"], Bond[{5, 16}, "Single"], Bond[{6, 17}, "Single"], Bond[{7, 18}, "Single"], Bond[{8, 19}, "Single"], Bond[{9, 20}, "Single"], Bond[{10, 21}, "Single"], Bond[{11, 22}, "Single"], Bond[{11, 23}, "Single"], Bond[{12, 24}, "Single"]}, {StereochemistryElements -> {Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 3, "Direction" -> "Counterclockwise"], Association[ "StereoType" -> "Tetrahedral", "ChiralCenter" -> 5, "Direction" -> "Clockwise"], Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 7, "Direction" -> "Counterclockwise"], Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 9, "Direction" -> "Counterclockwise"]}}], Molecule[{"O", "H", "H"}, {Bond[{1, 2}, "Single"], Bond[{1, 3}, "Single"]}, {}], Molecule[{"C", "C", "O", "O", "H", "H", "H", "H"}, {Bond[{1, 2}, "Single"], Bond[ {2, 3}, "Double"], Bond[{2, 4}, "Single"], Bond[{1, 5}, "Single"], Bond[{1, 6}, "Single"], Bond[{1, 7}, "Single"], Bond[{4, 8}, "Single"]}, {}]}, {}, None}, "ElementType" -> "InertExpression", "CachedOriginalExpression" -> {Molecule[{"O", "C", "C", "O", "C", "O", "C", "O", "C", "O", "C", "O", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H", "H"}, {Bond[{1, 2}, "Double"], Bond[{2, 3}, "Single"], Bond[{3, 4}, "Single"], Bond[{3, 5}, "Single"], Bond[{5, 6}, "Single"], Bond[{5, 7}, "Single"], Bond[{7, 8}, "Single"], Bond[{7, 9}, "Single"], Bond[{9, 10}, "Single"], Bond[{9, 11}, "Single"], Bond[{11, 12}, "Single"], Bond[{2, 13}, "Single"], Bond[{3, 14}, "Single"], Bond[{4, 15}, "Single"], Bond[{5, 16}, "Single"], Bond[{6, 17}, "Single"], Bond[{7, 18}, "Single"], Bond[{8, 19}, "Single"], Bond[{9, 20}, "Single"], Bond[{10, 21}, "Single"], Bond[{11, 22}, "Single"], Bond[{11, 23}, "Single"], Bond[{12, 24}, "Single"]}, {StereochemistryElements -> {Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 3, "Direction" -> "Counterclockwise"], Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 5, "Direction" -> "Clockwise"], Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 7, "Direction" -> "Counterclockwise"], Association["StereoType" -> "Tetrahedral", "ChiralCenter" -> 9, "Direction" -> "Counterclockwise"]}}], Molecule[{"O", "H", "H"}, {Bond[{1, 2}, "Single"], Bond[{1, 3}, "Single"]}, {}], Molecule[{"C", "C", "O", "O", "H", "H", "H", "H"}, {Bond[{1, 2}, "Single"], Bond[{2, 3}, "Double"], Bond[{2, 4}, "Single"], Bond[{1, 5}, "Single"], Bond[{1, 6}, "Single"], Bond[{1, 7}, "Single"], Bond[{4, 8}, "Single"]}, {}]}]]}}]]]], {"Name" -> { "SentenceVector", "DimensionReducedVector"}, "Molecule" -> { "MoleculeFeatures", "DimensionReducedVector"}}]

使用自定义函数生成特征提取器：

Wolfram Language code: data = {DateObject[{2014, 5, 5}, TimeObject[{9, 53, 6.30158}, TimeZone -> -5.], TimeZone -> -5.], DateObject[{2000, 1, 1}, TimeObject[{0, 0, 0.}, TimeZone -> -5.], TimeZone -> -5.], DateObject[{2006, 12}], DateObject[{2007, 8, 23}], DateObject[{2016, 4, 4}, TimeObject[{15, 59, 18.2738}, TimeZone -> -4.], TimeZone -> -4.]};
Wolfram Language code: FeatureExtract[data, {AbsoluteTime[#], #["Year"]}&]

将自定义提取器与 "StandardizedVector" 方法链接起来：

Wolfram Language code: FeatureExtract[data, {{AbsoluteTime[#], #["Year"]}&, "StandardizedVector"}]

处理之前确认数据：

Wolfram Language code: FeatureExtract[{[image], [image], [image], [image]}, {"ConformedData", "ImageFeatures", "DimensionReducedVector"}]

特征类型  (9)

提取文本数据的特征：

Wolfram Language code: FeatureExtract[{"the cat is grey", "my cat is fast", "this dog is scary", "the big dog"}]

从文本中计算词频-逆向文件频率向量：

Wolfram Language code: FeatureExtract[{"the cat is grey", "my cat is fast", "this dog is scary", "the big dog"}, "TFIDF"] // MatrixForm

默认情况下，文本将被分割成单词. 得到的结果相同：

Wolfram Language code: FeatureExtract[{"the cat is grey", "my cat is fast", "this dog is scary", "the big dog"}, {"SegmentedWords", "TFIDF"}] // MatrixForm

使用 "IndicatorVector" 方法对名义变量提取特征：

Wolfram Language code: FeatureExtract[{{"Yes", "A"}, {"No", "A"}, {"No", "B"}, {"Maybe", "B"}, {"No", "C"}}, "IndicatorVector"] // MatrixForm

从 DateObject 实例列表中提取特征：

Wolfram Language code: FeatureExtract[{DateObject[{2014, 5, 5, 9, 53, 6.30158}, "Instant", "Gregorian", -6.], DateObject[{2000, 1, 1, 0, 0, 0.}, "Instant", "Gregorian", -6.], DateObject[{2006, 12}, "Month", "Gregorian", -6.], DateObject[{2007, 8, 23}, "Day", "Gregorian", -6.], DateObject[{2016, 4, 4, 15, 59, 18.2738}, "Instant", "Gregorian", -4.]}]

在 Graph 实例列表上训练特征提取器：

Wolfram Language code: FeatureExtract[{[image], [image], [image], [image]}]

在 TimeSeries 实例列表上训练特征提取器：

Wolfram Language code: FeatureExtract[{TemporalData[TimeSeries, {{{0, 1, 0, 3, 0, 0, 0, 0, 2, 1, 0, 3, 0, 0, 0, 0, 0, 0, 0, 1, 0, 1, 0, 0, 0, 0, 0, 0, 0, 2, 0, 0, 36, 0, 6, 1, 2, 8, 6, 24, 20, 31, 68, 45, 140, 116, 65, 376, 322, 382, 516, 544, 767, 1133, 1788, 1360, 5886, 5412 ... tion[{2020, 1, 23, 0, 0, 0.}, {2020, 10, 5, 0, 0, 0.}, {1, "Day"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {DateFunction -> Automatic, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, True, 12.2], TemporalData[TimeSeries, {{{0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 1, 1, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 2, 0, 23, 2, 1, 3, 5, 4, 13, 6, 11, 9, 20, 11, 6, 23, 14, 38, 50, 86, 66, 103, 37, 121, 70, 1 ... {TemporalData`DateSpecification[{2020, 1, 23, 0, 0, 0.}, {2020, 10, 5, 0, 0, 0.}, {1, "Day"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, True, 12.2], TemporalData[TimeSeries, {{{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 1, 0, 0, 0, 2, 0, 9, 0, 7, 5, 6, 7, 14, 99, 0, 11, 38, 121, 51, 249, 172, 228, 572, 331, 323, 307, ... TemporalData`DateSpecification[{2020, 1, 23, 0, 0, 0.}, {2020, 10, 5, 0, 0, 0.}, {1, "Day"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, True, 12.2], TemporalData[TimeSeries, {{{0, 0, 0, 0, 0, 0, 0, 0, 2, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 1, 9, 0, 4, 0, 3, 0, 8, 17, 14, 4, 27, 24, 33, 52, 54, 53, 61, 71, 57, 163, 182, 196 ... {TemporalData`DateSpecification[{2020, 1, 23, 0, 0, 0.}, {2020, 10, 5, 0, 0, 0.}, {1, "Day"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, True, 12.2], TemporalData[TimeSeries, {{{0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 2, 6, 0, 4, 9, 12, 20, 11, 28, 9, 26, 68, 35, 46, 101, 92, 21, 48, 69 ... {TemporalData`DateSpecification[{2020, 1, 23, 0, 0, 0.}, {2020, 10, 5, 0, 0, 0.}, {1, "Day"}]}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}, ValueDimensions -> 1}}, True, 12.2]}]

从 Molecule 数据中提取特征：

Wolfram Language code: FeatureExtract[{Molecule["Sucrose"], Molecule["Butane"], Molecule["Pentane"]}]

从选择的 Audio 实例中提取特征：

Wolfram Language code: FeatureExtract[{Audio[Sound[Table[SoundNote[i, If[i == 12, 0.5, 0.1], "Violin"], {i, 0, 12}]]], Audio[Sound[Table[SoundNote[i, If[i == 12, 0.5, 0.1], "Cello"], {i, 0, 12}]]], Audio[Sound[Table[SoundNote[i, If[i == 12, 0.5, 0.1], "Trumpet"], {i, 0, 12}]]]}]

从包含缺失值的数据集中提取特征：

Wolfram Language code: FeatureExtract[{{1.4, Missing[], "A"}, {1.5, 50.2, "A"}, {Missing[], 42.3, "B"}, {5.4, 61.7, "B"}}]

选项  (2)

FeatureNames  (1)

使用 FeatureNames 命名特征，并在部分规范中引用它们的名称：

Wolfram Language code: FeatureExtract[{{2.3, "male"}, {4.8, Missing[]}, {Missing[], "female"}, {5.2, "female"}}, {"age" -> Identity, "gender" -> "IndicatorVector"}, FeatureNames -> {"age", "gender"}] // MatrixForm

FeatureTypes  (1)

在简单数据集上通过 "IndicatorVector" 方法提取特征：

Wolfram Language code: FeatureExtract[{{1, "A"}, {2, "A"}, {2, "B"}, {1, "B"}}, "IndicatorVector"]//MatrixForm

第一个特征被诠释为数值型，由于 "IndicatorVector" 方法仅作用于名义特征，第一个特征不变化.

使用 FeatureTypes 执行作为名义第一个特征的诠释：

Wolfram Language code: FeatureExtract[{{1, "A"}, {2, "A"}, {2, "B"}, {1, "B"}}, "IndicatorVector", FeatureTypes -> <|1 -> "Numerical"|>]// MatrixForm

应用  (1)

数据集可视化  (1)

建立一个狗图片的数据集：

Wolfram Language code: dataset = {[image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image], [image]};

从这个数据集中提取特征：

Wolfram Language code: features = FeatureExtract[dataset];

将所提取的向量的维度降为 2：

Wolfram Language code: xy = DimensionReduce[features, 2, Method -> "TSNE"]

在特征位置可视化图片：

Wolfram Language code: ListPlot[List /@ xy, PlotMarkers -> (Image[#, ImageSize -> 40]& /@ dataset)]

使用 FeatureSpacePlot 可以直接获取相似的可视化：

Wolfram Language code: FeatureSpacePlot[dataset]

属性和关系  (2)

提取没有训练示例的特征等价于 FeatureExtraction[None,...]：

Wolfram Language code: data = "This is a sentence"
Wolfram Language code: FeatureExtract[data, "SentenceVector"] == FeatureExtraction[None, "SentenceVector"][data]

FeatureExtract[…] 等价于 FeatureExtraction[…,"ExtractedFeatures"]：

Wolfram Language code: data = {"the cat is grey", "my cat is fast", "this dog is scary", "the big dog"};
Wolfram Language code: FeatureExtract[data, "TFIDF"] == FeatureExtraction[data, "TFIDF", "ExtractedFeatures"]

可能存在的问题  (1)

没有训练数据的特征提取将在需要时使用内置默认值：

Wolfram Language code: FeatureExtract[[image], "ConformedData", FeatureTypes -> "Image"]//Information

输入相同的数据作为训练数据可能会产生不同的结果：

Wolfram Language code: FeatureExtract[{[image]}, "ConformedData", FeatureTypes -> "Image"]//Information
Wolfram Research (2016)，FeatureExtract，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FeatureExtract.html （更新于 2025 年）.

文本

Wolfram Research (2016)，FeatureExtract，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FeatureExtract.html （更新于 2025 年）.

CMS

Wolfram 语言. 2016. "FeatureExtract." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/FeatureExtract.html.

APA

Wolfram 语言. (2016). FeatureExtract. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FeatureExtract.html 年

BibTeX

@misc{reference.wolfram_2026_featureextract, author="Wolfram Research", title="{FeatureExtract}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/FeatureExtract.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_featureextract, organization={Wolfram Research}, title={FeatureExtract}, year={2025}, url={https://reference.wolfram.com/language/ref/FeatureExtract.html}, note=[Accessed: 11-September-2026]}