Wolfram 语言与系统参考资料中心

Fibonacci

Fibonacci[n]

给出斐波那契数 .

Fibonacci[n,x]

给出斐波那契多项式 .

范例

打开所有单元关闭所有单元

基本范例 (6)

计算斐波那契数：

Wolfram Language code: Table[Fibonacci[n], {n, 20}]

在实数的子集上绘图：

Wolfram Language code: Plot[Fibonacci[1 / 2, x], {x, -10, 10}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Fibonacci[5 / 3, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[Fibonacci[1 / 2, x], {x, 0, 5}]

在 Infinity 的级数展开：

Wolfram Language code: Series[Fibonacci[1 / 2, x], {x, ∞, 5}]//FullSimplify

在奇点处的级数展开式：

Wolfram Language code: Series[Fibonacci[1 / 2, x], {x, -2I, 3}, Assumptions -> x > 1]//Normal//FullSimplify

范围 (43)

数值计算 (6)

数值计算：

Wolfram Language code: Fibonacci[5.8, 3]

Wolfram Language code: Fibonacci[8]

高精度计算：

Wolfram Language code: N[Fibonacci[15 / 17], 50]

输出的精度与输入的精度一致：

Wolfram Language code: Fibonacci[0.2114411444411100011, 5]

复数输入：

Wolfram Language code: N[Fibonacci[5, 8 - I]]

高精度条件下进行高效计算：

Wolfram Language code: Fibonacci[4750, 5`100]//Timing

Wolfram Language code: Fibonacci[71.56, 5`100000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Fibonacci[0.4, Interval[{0.5, 0.6}]]

Wolfram Language code: Fibonacci[1 / 3, CenteredInterval[1 / 2, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Fibonacci[ Around[.2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: Fibonacci[3, {{-1, 0}, {0, 5}}]

或用 MatrixFunction 计算矩阵形式的 Fibonacci 函数：

Wolfram Language code: MatrixFunction[Fibonacci[3, #]&, {{-1, 0}, {0, 5}}]

特殊值 (6)

Fibonacci 在固定点处的值：

Wolfram Language code: Table[Fibonacci[3, x ], {x, 1, 5}]

符号 n 和 x 的 Fibonacci 多项式：

Wolfram Language code: Fibonacci[n, x]//FunctionExpand

零处的值：

Wolfram Language code: Fibonacci[1, 0]

Wolfram Language code: Fibonacci[0, 0]

求满足的值：

Wolfram Language code: xval = x /. FindRoot[Fibonacci[3, x ] == 5, {x, 3}]

Wolfram Language code: Plot[Fibonacci[3, x ], {x, 0, 5}, Epilog -> Style[Point[{xval, Fibonacci[3, xval ]}], PointSize[Large], Red]]

计算 Fibonacci[7,x] 多项式：

Wolfram Language code: Fibonacci[7, x]

计算 Fibonacci[1/2,x]：

Wolfram Language code: Fibonacci[1 / 2, x]//FunctionExpand

可视化 (5)

绘制 Fibonacci 函数：

Wolfram Language code: Plot[Fibonacci[x], {x, -2, 2}]

绘制各阶 Fibonacci 多项式：

Wolfram Language code: Plot[{Fibonacci[1, x], Fibonacci[2, x], Fibonacci[3, x], Fibonacci[4, x]}, {x, -2, 2}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Fibonacci[3, z]], {z, -1 - I, 1 + I}, Contours -> 24]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Fibonacci[3, z]], {z, -1 - I, 1 + I}, Contours -> 24]

绘制两个变化参数的实部：

Wolfram Language code: Plot3D[Re[Fibonacci[n, z]], {n, 0, 5}, {z, -1, 1}, PlotRange -> All]

2 型和 3 型 Fibonacci 多项式有不同的分支切割结构：

Wolfram Language code: Plot3D[Im[Fibonacci[3, x + I y]], {x, -3, 3}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, Abs[x] > 1}}]

Wolfram Language code: Plot3D[Im[Fibonacci[3, x + I y]], {x, -3, 3}, {y, -0.5, 0.5}, Exclusions -> {{y == 0, -1 < x < 1}}]

函数的属性 (14)

Fibonacci 对所有实数有定义：

Wolfram Language code: FunctionDomain[Fibonacci[n, z], z]

Fibonacci 的近似值域：

Wolfram Language code: FunctionRange[Fibonacci[2, x], x, y]

Wolfram Language code: FunctionRange[Fibonacci[2, z], z, y, Complexes]

偶数阶的 Fibonacci 多项式是奇函数：

Wolfram Language code: Fibonacci[2, -x] == -Fibonacci[2, x]

奇数阶的 Fibonacci 多项式是偶函数：

Wolfram Language code: Fibonacci[1, -x] == Fibonacci[1, x]

Fibonacci 具有镜像属性：

Wolfram Language code: Fibonacci[1, Conjugate[z]] == Conjugate[Fibonacci[1, z]]

Fibonacci 逐项作用于列表的各个元素：

Wolfram Language code: Fibonacci[{1, 2, 3, 4, 5}]

Fibonacci 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[Fibonacci[n, x], x, Assumptions -> n∈ℝ]

对于奇数，Fibonacci 既不是非递减，也不是非递增：

Wolfram Language code: FunctionMonotonicity[Fibonacci[5, x], x]

对于偶数，Fibonacci 不是非递减：

Wolfram Language code: FunctionMonotonicity[Fibonacci[2, x], x]

对于奇数，Fibonacci 不是单射函数：

Wolfram Language code: Table[FunctionInjective[Fibonacci[n, x], x], {n, 4}]

Wolfram Language code: Plot[{Fibonacci[3, x], Fibonacci[4, x], 5}, {x, -3, 3}]

对于奇数，Fibonacci 不是满射函数：

Wolfram Language code: Table[FunctionSurjective[Fibonacci[n, x], x], {n, 4}]

Wolfram Language code: Plot[{Fibonacci[3, x], Fibonacci[4, x], -2}, {x, -3, 3}]

对于奇数，Fibonacci 非负：

Wolfram Language code: Table[FunctionSign[Fibonacci[n, x], x], {n, 4}]

Fibonacci 没有奇点或断点：

Wolfram Language code: FunctionSingularities[Fibonacci[n, x], x]

Wolfram Language code: FunctionDiscontinuities[Fibonacci[n, x], x]

对于奇数，Fibonacci 是凸函数：

Wolfram Language code: Table[FunctionConvexity[Fibonacci[n, x], x], {n, 7}]

TraditionalForm 格式：

Wolfram Language code: Fibonacci[n]//TraditionalForm

微分 (3)

关于 n 的一阶导数：

Wolfram Language code: D[Fibonacci[n], n]

Wolfram Language code: D[Fibonacci[n, x], n]

关于 x 的一阶导数：

Wolfram Language code: D[Fibonacci[n, x], x]

关于 n 的高阶导数：

Wolfram Language code: Table[D[Fibonacci[n], {n, k}], {k, 1, 3}]//FullSimplify

绘制关于 n 的高阶导数：

Wolfram Language code: Plot[%, {n, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

关于 n 的阶导数的公式：

Wolfram Language code: D[Fibonacci[n], {n, k}]// FullSimplify

积分 (3)

使用 Integrate 计算不定积分：

Wolfram Language code: Integrate[Fibonacci[x], x]// FullSimplify

定积分：

Wolfram Language code: Integrate[Fibonacci[x], {x, 3, 15}]

更多积分：

Wolfram Language code: Integrate[ Fibonacci[x] Fibonacci[5 - x] , x]//FullSimplify

Wolfram Language code: Integrate[E ^ (-t)Fibonacci[t], {t, 0, Infinity}]

级数展开 (4)

使用 Series 求泰勒展开：

Wolfram Language code: Series[Fibonacci[x], {x, 0, 2}]

绘制附近的前三个近似：

Wolfram Language code:

terms = Normal@Table[Series[Fibonacci[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Fibonacci[x], terms}, {x, -5, 5}]

使用 SeriesCoefficient 进行级数展开的一般项：

Wolfram Language code: SeriesCoefficient[Fibonacci[x], {x, 0, n}]

求在 Infinity 处的级数展开：

Wolfram Language code: Series[Fibonacci[x], {x, Infinity, 1}]//Normal

普通点的泰勒展开：

Wolfram Language code: Series[Fibonacci[x], {x, x0, 2}]// FullSimplify

函数恒等与化简 (2)

Fibonacci 的普通生成函数：

Wolfram Language code: GeneratingFunction[Fibonacci[n], n, x]

递推关系：

Wolfram Language code: Fibonacci[n + 1, x] == x Fibonacci[n, x] + Fibonacci[n - 1, x]//FullSimplify

推广和延伸 (2)

斐波那契多项式：

Wolfram Language code: Table[Fibonacci[n, x], {n, 10}]

在无穷大处的级数展开：

Wolfram Language code: Series[Fibonacci[n, x], {x, Infinity, 5}]//FullSimplify

应用 (13)

求斐波那契递归方程：

Wolfram Language code: RSolve[{f[n] == f[n - 1] + f[n - 2], f[2] == f[1] == 1}, f[n], n]

Wolfram Language code: FullSimplify[Table[First[f[n] /. %], {n, 10}]]

求解另一个斐波那契递归方程：

Wolfram Language code: RSolve[{f[n] == f[n - 1] + f[n - 2], f[1] == a, f[2] == b}, f[n], n]

Wolfram Language code: FullSimplify[Table[First[f[n] /. %], {n, 10}]]

求连续斐波那契数的比率：

Wolfram Language code: Table[Fibonacci[n + 1] / Fibonacci[n], {n, 15}]

与连分数的比较：

Wolfram Language code: Table[FromContinuedFraction[Table[1, {n}]], {n, 15}]

黄金比率的收敛：

Wolfram Language code: N[%]

斐波那契替换系统：

Wolfram Language code: NestList[StringReplace[#, {"A" -> "AB", "B" -> "A"}]&, "A", 6]

Wolfram Language code: StringCount[%, "A"]

斐波那契系数：

Wolfram Language code: Fibonomial[n_, k_] := Product[Fibonacci[n + j - k] / Fibonacci[j], {j, k}]

Wolfram Language code: Array[Fibonomial, {7, 7}]//Grid

统计写入一个整数的方式的数量，作为斐波那契数的和：

Wolfram Language code:

fibonacciSumCount[n_] := SeriesCoefficient[Series[Product[1 + z ^ Fibonacci[k], {k, Ceiling[Log[GoldenRatio, n]] + 2}], {z, 0, n}], n]

绘制前 100 个整数的统计：

Wolfram Language code: ListPlot[Table[fibonacciSumCount[n], {n, 100}]]

Lamé 定理限定了用欧几里德算法计算有多少步骤：

Wolfram Language code: 𝒻[n_] := NestWhile[(# + 1)&, 1, Fibonacci[#] < n&] - 1

Wolfram Language code: maxEuclideanAlgorithmSteps[a_, b_] := Min[𝒻[Min[a, b]] - 1, 𝒻[Max[a, b]] - 2]

绘制最大的步骤数量：

Wolfram Language code: ListPlot3D[Table[maxEuclideanAlgorithmSteps[a, b], {a, 100}, {b, 100}]]

求大于 1000000 的第一个斐波那契数：

Wolfram Language code: NestWhile[(# + 1)&, 1, Fibonacci[#] <= 10 ^ 6&]

Wolfram Language code: Fibonacci[%]

绘制斐波那契数的离散倒数：

Wolfram Language code: ListLinePlot[Table[NestWhile[(# + 1)&, 1, Fibonacci[#] <= n&], {n, 200}]]

在复平面上绘制 Fibonacci 的绝对值：

Wolfram Language code: Plot3D[Abs[Fibonacci[x + I y]], {x, -5, 5}, {y, -1, 1}]

求多项式的因子数：

Wolfram Language code: ListPlot[Table[Length[FactorList[Fibonacci[n, x]]], {n, 50}]]

如果能整除，那么也能整除：

Wolfram Language code: fm = Fibonacci[30]

Wolfram Language code: ffm = Fibonacci[fm];

Wolfram Language code: And @@ Table[Divisible[ffm, Fibonacci[n]], {n, Divisors[fm]}]

这是一个更一般的恒等式的一个特例：

Wolfram Language code:

{Table[GCD[Fibonacci[n], Fibonacci[k]], {n, 5}, {k, 5}]//MatrixForm, 
	Table[Fibonacci[GCD[n, k]], {n, 5}, {k, 5}]//MatrixForm}

对于一个固定的自然数，序列表现出关于的周期性：

Wolfram Language code: DiscretePlot[Mod[Fibonacci[n], 7], {n, 0, 35}]

对于，周期等于：

Wolfram Language code: Table[Mod[Fibonacci[n + 16] - Fibonacci[n], 7], {n, 0, 15}]

建立正整数的齐肯多夫表示 [MathWorld]：

Wolfram Language code:

ZeckendorfRepresentation[n_Integer ? Positive] := Reap[Module[{m = n, f = Fibonacci}, 
	While[m > 0, m -= f@Sow[NestWhile[# + 1&, 1, f[#] ≤ m&] - 1]]]][[2, -1]]

Wolfram Language code: ZeckendorfRepresentation[2011]

Wolfram Language code: Total[Fibonacci[%]]

定义正整数的斐波那契乘法：

Wolfram Language code:

FibonacciTimes[n_, m_] := Total[Fibonacci[Outer[Plus, ZeckendorfRepresentation[n], ZeckendorfRepresentation[m]]], Infinity]

斐波那契乘法表：

Wolfram Language code: Outer[FibonacciTimes, Range[6], Range[6]]//Grid

验证斐波那契数乘法是满足结合律的：

Wolfram Language code:

Table[FibonacciTimes[FibonacciTimes[n, m], k] == FibonacciTimes[n, FibonacciTimes[m, k]], {n, 1, 6}, {m, 1, 6}, {k, 1, 6}]//Flatten//Union

属性和关系 (15)

斐波那契数 (13)

展开基本函数的项：

Wolfram Language code: FunctionExpand[Fibonacci[n]]

Wolfram Language code: FullSimplify[Table[%, {n, 10}]]

极限率：

Wolfram Language code: Limit[Fibonacci[n] / Fibonacci[n - 1], n -> Infinity]

直接递归定义：

Wolfram Language code: f[n_] := f[n] = f[n - 1] + f[n - 2]

Wolfram Language code: f[1] = f[2] = 1;

Wolfram Language code: Table[f[n], {n, 20}]

状态空间的递归定义：

Wolfram Language code: g[0] = {1, 1};

Wolfram Language code: g[n_Integer ? Positive] := g[n] = {{1, 1}, {1, 0}}.g[n - 1]

Wolfram Language code: f[n_] := Last[g[n]]

Wolfram Language code: Table[f[n], {n, 0, 10}]

用 MatrixPower 表示的解析解：

Wolfram Language code: Table[Last[MatrixPower[{{1, 1}, {1, 0}}, n].{1, 1}], {n, 0, 10}]

涉及斐波那契数的化简：

Wolfram Language code: FullSimplify[Fibonacci[n + 1]Fibonacci[n - 1] - Fibonacci[n]^2, n > 0 && n∈Integers]

符号和：

Wolfram Language code: Underoverscript[∑, k = 0, n]Fibonacci[k]Fibonacci[n - k]

生成函数：

Wolfram Language code: Underoverscript[∑, k = 0, ∞]Fibonacci[k] x^k//FullSimplify

作为系数的斐波那契数：

Wolfram Language code: Series[%, {x, 0, 10}]

表示一个分式的斐波那契数，作为一个代数数：

Wolfram Language code: Fibonacci[1 / 3]//FunctionExpand // RootReduce

可以用 DifferenceRoot 来表示 Fibonacci：

Wolfram Language code: DifferenceRootReduce[Fibonacci[k], k]

Wolfram Language code: DifferenceRootReduce[Fibonacci[k, x], k]

Fibonacci 的级数扩展式中一般项：

Wolfram Language code: SeriesCoefficient[Fibonacci[x], {x, 0, n}]

Fibonacci 的母函数：

Wolfram Language code: GeneratingFunction[Fibonacci[n], n, x]

Wolfram Language code: Series[%, {x, 0, 10}]

FindSequenceFunction 可以识别 Fibonacci 序列：

Wolfram Language code: Table[Fibonacci[n], {n, 10}]

Wolfram Language code: FindSequenceFunction[%, n]

Fibonacci 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[Fibonacci[n], n, x]

斐波那契多项式 (2)

展开为初等函数的项：

Wolfram Language code: FunctionExpand[Fibonacci[n, x]]

直接构建斐波那契多项式：

Wolfram Language code: Table[Underoverscript[∑, m = 0, Floor[(n - 1/2)]]Binomial[n - m - 1, m] x^n - 2 m - 1, {n, 5}]

Wolfram Language code: Table[Fibonacci[n, x], {n, 5}]

可能存在的问题 (3)

过大参数给出的结果太大，以致于不能直接计算结果：

Wolfram Language code: Fibonacci[10 ^ 16.]

整数参数的结果对非整数可能不成立：

Wolfram Language code: FullSimplify[Fibonacci[2n] == Fibonacci[n + 1]^2 - Fibonacci[n - 1]^2, n∈Integers]

Wolfram Language code: Fibonacci[2n] == Fibonacci[n + 1]^2 - Fibonacci[n - 1]^2 /. n -> 2.5

矩阵幂的表示仅对整数有效：

Wolfram Language code: MatrixPower[{{1, 1}, {1, 0}}, 2.5]

Wolfram Language code: Fibonacci[{{n + 1, n}, {n, n - 1}}] /. n -> 2.5

巧妙范例 (8)

模 10 的斐波那契数：

Wolfram Language code: Mod[Array[Fibonacci, 100], 10]

Wolfram Language code: ListLinePlot[Mod[Array[Fibonacci, 200], 10]]

模 n 的斐波那契数 [更多信息]：

Wolfram Language code: ListLinePlot[Table[Mod[Fibonacci[n], n], {n, 200}]]

统计第 100 万个 Fibonacci 数中，数字1, 2, ..., 9, 0 的数量：

Wolfram Language code: DigitCount[Fibonacci[10 ^ 6]]

Fibonacci 消除实部和虚部的等高线：

Wolfram Language code: ContourPlot[{Re[Fibonacci[x + I y]] == 0, Im[Fibonacci[x + I y]] == 0}, {x, -8, 8}, {y, -8, 8}]

斐波那契正数和负数的 LogPlot 图：

Wolfram Language code: LogPlot[Abs[Fibonacci[x]] + 1, {x, -10, 10}]

当斐波那契数对非负数参数是非递减的，斐波那契函数处理单一局部的最小值：

Wolfram Language code: Plot[Fibonacci[n], {n, 0, 4}, Prolog -> {PointSize[0.02], Point[Table[{k, Fibonacci[k]}, {k, 0, 4}]]}]

既然生成函数是有理类型，这些和结果是有理数：

Wolfram Language code: Underoverscript[∑, k = 1, ∞]2^-k Fibonacci[k]

Wolfram Language code: Underoverscript[∑, k = 1, ∞]10^-k Fibonacci[k]

Wolfram Language code: ArrayPlot[Mod[Table[CoefficientList[Fibonacci[n, x], x], {n, 60}], 2]]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Fibonacci

更多信息

范例

基本范例 (6)

范围 (43)

数值计算 (6)

特殊值 (6)

可视化 (5)

函数的属性 (14)

微分 (3)

积分 (3)

级数展开 (4)

函数恒等与化简 (2)

推广和延伸 (2)

应用 (13)

属性和关系 (15)

斐波那契数 (13)

斐波那契多项式 (2)

可能存在的问题 (3)

巧妙范例 (8)

文本

CMS

APA

BibTeX

BibLaTeX

Fibonacci

更多信息

范例

基本范例 (6)

范围 (43)

数值计算 (6)

特殊值 (6)

可视化 (5)

函数的属性 (14)

微分 (3)

积分 (3)

级数展开 (4)

函数恒等与化简 (2)

推广和延伸 (2)

应用 (13)

属性和关系 (15)

斐波那契数 (13)

斐波那契多项式 (2)

可能存在的问题 (3)

巧妙范例 (8)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX