WOLFRAM

Wolfram 语言与系统参考资料中心

FilledCurve[{segment1,segment2,…}]

表示一条填充曲线，它依次包含 segment1、segment2 等等.

FilledCurve[{component1,component2,…}]

表示由不同的填充分量曲线 component1、component2 等等组成的列表.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
曲线  
说明  
样式  
坐标  
区域  
推广和延伸  
选项  
VertexTextureCoordinates  
应用  
图形、图标等  
文本效果  
文本标题  
棋盘形格局  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

FilledCurve

FilledCurve[{segment1,segment2,…}]

表示一条填充曲线，它依次包含 segment1、segment2 等等.

FilledCurve[{component1,component2,…}]

表示由不同的填充分量曲线 component1、component2 等等组成的列表.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (4)

来自 Bézier 曲线上的填充曲线：

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};
Wolfram Language code: Graphics[FilledCurve[{BezierCurve[a]}]]

具有混合曲线段的填充曲线：

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}, {-1, 0}};
Wolfram Language code: Graphics[FilledCurve[{BezierCurve[a], Line[b]}]]

含有一个洞的填充曲线：

Wolfram Language code: pts = {{0, 1}, {-1, -(1/2)}, {1, -(1/2)}};
Wolfram Language code: Graphics[FilledCurve[{{Line[2pts]}, {Line[pts]}}]]

自相交的填充曲线：

Wolfram Language code: Graphics[FilledCurve[{{Line[pts]}, {Line[TranslationTransform[{1, (1/2)}][pts]]}}]]

具有不同样式的填充曲线：

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}, {-1, 0}};curve = FilledCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}];
Wolfram Language code: {Graphics[{Pink, curve}], Graphics[{EdgeForm[Thick], Pink, curve}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, curve}]}

纹理映射的实心曲线：

Wolfram Language code: Graphics[{Texture[ExampleData[{"TestImage", "House"}]], FilledCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}, VertexTextureCoordinates -> {{{0, (1/2)}, {(1/2), 1}, {1, (1/2)}, {(1/2), (1/12)}, {0, (1/2)}}, {{(1/4), (1/2)}, {(1/2), (3/4)}, {(3/4), (1/2)}, {(1/2), (7/24)}, {(1/4), (1/2)}}}]}]

范围  (15)

曲线  (9)

说明  (3)

具有单个线段的填充曲线：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[Line[{{-1, 0}, {-1, 1}, {0, 2}, {1, 1}, {1, 0}}]]}]

具有单个 Bézier 曲线段的填充曲线：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[BezierCurve[{{-1, 0}, {-1, 2}, {1, 2}, {1, 0}}]]}]

具有单个 B-样条曲线段的填充曲线：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[BSplineCurve[{{-1, 0}, {-1, 1}, {0, 0}, {1, 1}, {1, 0}}]]}]

含有混合曲线段的填充曲线：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{BSplineCurve[{{-2, 0}, {-1, 1}, {0, -1}, {1, 1}, {2, 0}}], Line[{{2, -1}, {-2, -1}}]}]}]

含有一个洞的填充曲线：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {Line[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}]}]

含有不同的洞的填充曲线：

Wolfram Language code: pts = {{0, 1}, {-(Sqrt[3]/2), -(1/2)}, {(Sqrt[3]/2), -(1/2)}};
Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[4pts]}, {Line[TranslationTransform[{-1, 0}][pts]]}, {Line[TranslationTransform[{1, 0}][pts]]}}]}]

含有多个分量的填充曲线：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[3pts]}, {Line[2pts]}, {Line[pts]}}]}]

自相交的填充曲线：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[pts]}, {Line[TranslationTransform[{(Sqrt[3]/2), (1/2)}][pts]]}, {Line[TranslationTransform[{Sqrt[3], 1}][pts]]}}]}]

样式  (3)

颜色指令指定填充曲线的面的颜色：

Wolfram Language code: Table[Graphics[{c, FilledCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定内部和边界的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], FilledCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}]}]

JoinForm 可用于指定边界连接处的类型：

Wolfram Language code: a = {{-2, 0}, {0, 2}, {2, 0}, {0, -2}};curve = FilledCurve[{{Line[2a]}, {Line[a]}}];
Wolfram Language code: {Graphics[{EdgeForm[{JoinForm["Bevel"], Thickness[0.05]}], Pink, curve}, PlotRange -> 5], Graphics[{EdgeForm[{JoinForm["Meter"], Thickness[0.05]}], Pink, curve}, PlotRange -> 5]Graphics[{EdgeForm[{JoinForm["Round"], Thickness[0.05]}], Pink, curve}, PlotRange -> 5]}

坐标  (3)

使用 Scaled 坐标：

Wolfram Language code: Graphics[FilledCurve[BezierCurve[{Scaled[{0, 0}], Scaled[{.5, 1}], Scaled[{1, 0}]}]], Frame -> True]

使用 ImageScaled 坐标：

Wolfram Language code: Graphics[FilledCurve[BezierCurve[{ImageScaled[{0, 0}], ImageScaled[{.5, 1}], ImageScaled[{1, 0}]}]], Frame -> True]

使用 Offset 坐标：

Wolfram Language code: Graphics[FilledCurve[BezierCurve[{Offset[{10, 10}, {0, 0}], Offset[{0, 50}, {.5, 1}], Offset[{-10, 10}, {1, 0}]}]], Frame -> True]

区域  (6)

嵌入维度：

Wolfram Language code: RegionEmbeddingDimension[FilledCurve[{BSplineCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}]}]]

几何维度：

Wolfram Language code: RegionDimension[FilledCurve[{BSplineCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}]}]]

判断点是否为区域的成员：

Wolfram Language code: {RegionMember[FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}], {0, 0}], RegionMember[FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}], {1, 2}]}

弧长：

Wolfram Language code: ℛ = FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}];
Wolfram Language code: {ArcLength[ℛ], RegionMeasure[ℛ]}

形心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Yellow, ℛ}, {Red, Point[c]}}]

到一个点的距离：

Wolfram Language code: ℛ = FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}];
Wolfram Language code: {RegionDistance[ℛ, {1, 1}], RegionDistance[ℛ, {0, 0}]}

到填充曲线上最近点的距离：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 4}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

到一个点的有符号距离：

Wolfram Language code: ℛ = FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1}], SignedRegionDistance[ℛ, {0, 0}]}

到填充曲线的有符号距离：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Exclusions -> Norm[{x, y}] == 1, Mesh -> None]

填充曲线是有界的：

Wolfram Language code: ℛ = FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}];
Wolfram Language code: BoundedRegionQ[ℛ]

区域的界限：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{{EdgeForm[Directive[Dashed, Red]], Opacity[0.1], Yellow, Rectangle@@Transpose[rr]}, ℛ}]

推广和延伸  (2)

每个曲线段可以有自己的用于精细控制的选项：

Wolfram Language code: pts = {{0., -0.5}, {0.5, -0.5}, {0.5, 0.5}, {0., 0.5}, {-0.5, 0.5}, {-0.5, -0.5}, {0., -0.5}}; w = {1, .5, .5, 1, .5, .5, 1}; k = {0, 0, 0, 1 / 4, 1 / 2, 1 / 2, 3 / 4, 1, 1, 1};
Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{BSplineCurve[2pts, SplineDegree -> 2, SplineKnots -> k, SplineWeights -> w]}, {BSplineCurve[pts, SplineDegree -> 2, SplineKnots -> k, SplineWeights -> w]}}]}]

默认情况下，Bézier 线段在不考虑连接处的切线下进行连接：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[{{0, 0}, {2, 2}}], BezierCurve[{{4, 2}, {5, 1}, {6, 0}}]}}]}]

Automatic 可用于 Bézier 线段的第一个坐标处，以创建平滑连接：

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[{{0, 0}, {2, 2}}], BezierCurve[{Automatic, {5, 1}, {6, 0}}]}}]}]

选项  (2)

VertexTextureCoordinates  (2)

在实心 Bézier 曲线下的纹理映射：

Wolfram Language code: Graphics[{Texture[ExampleData[{"TestImage", "House"}]], FilledCurve[{BezierCurve[{{-1, 0}, {0, 1}, {1, 0}}]}, VertexTextureCoordinates -> {{0, 0}, {1 / 2, 1}, {1, 0}}]}]

纹理映射方法映射到多条分量曲线：

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}, {-1, 0}};
Wolfram Language code: Graphics[{Texture[ExampleData[{"TestImage", "House"}]], FilledCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}, VertexTextureCoordinates -> {{{0, (1/2)}, {(1/2), 1}, {1, (1/2)}, {(1/2), (1/12)}, {0, (1/2)}}, {{(1/4), (1/2)}, {(1/2), (3/4)}, {(3/4), (1/2)}, {(1/2), (7/24)}, {(1/4), (1/2)}}}]}]

应用  (5)

图形、图标等  (2)

定义一个含有填充曲线的字母：

Wolfram Language code: a = FilledCurve[{{Line[{{2, 3}, {0.8125, 0.625}}], BezierCurve[{{0.6875, 0.375}, {0.375, 0.25}, {1.125, 0.25}}, SplineDegree -> 2], BezierCurve[{{0.8125, 0.375}, {0.9375, 0.625}}], Line[{{1.3125, 1.375}, {2.4375, 1.375}, {2.8125, 0.625}}], BezierCurve[{{2.9375, 0.375}, {2.625, 0.25}, {3.625, 0.25}}, SplineDegree -> 2], BezierCurve[{{3.3125, 0.375}, {3.1875, 0.625}}]}, {Line[{{1.875, 2.5}, {1.375, 1.5}, {2.375, 1.5}}]}}];
Wolfram Language code: Graphics[a]
Wolfram Language code: Graphics[{EdgeForm[Blue], LightGray, a}]

从一个图形中提取填充曲线：

Wolfram Language code: g = First[[image]];
Wolfram Language code: Head[g]

沿着原点旋转图标：

Wolfram Language code: Graphics[{EdgeForm[Gray], Table[{Hue[(t/2 π)], Rotate[g, t, {0, 0}]}, {t, 0, 2 π, (π/6)}]}]

文本效果  (1)

以填充曲线的方式在图形中导入文本，使用 PDF 作为中间格式：

Wolfram Language code: text = First[First[ImportString[ExportString[Style["Wolfram", Italic, FontSize -> 24, FontFamily -> "Times"], "PDF"], {"PDF", "PageGraphics"}, "TextMode" -> "Outlines"]]];

使用不同的边和面的格式，绘制字体的边线：

Wolfram Language code: Graphics[{EdgeForm[Black], ColorData["Crayola", "Sunglow"], text}]

通过平移投射阴影：

Wolfram Language code: Graphics[{Gray, Translate[text, {1, -1}], Red, text}]

三维文本效果：

Wolfram Language code: Graphics[{EdgeForm[Opacity[0.5]], Table[{ColorData["TemperatureMap"][t], Translate[text, 4{-t, t}]}, {t, 0, 1, (1/10)}]}, ImageSize -> Medium]

文本标题  (1)

将文本以填充曲线的方式导入：

Wolfram Language code: text = First[First[ImportString[ExportString[Style["MATHEMATICA", FontSize -> 72, FontFamily -> "Geogia"], "PDF"], {"PDF", "PageGraphics"}, "TextMode" -> "Outlines"]]];
Wolfram Language code: Graphics[text, Frame -> True]

使用 BSplineFunction 创建包络函数：

Wolfram Language code: top = BSplineFunction[{60, 200, 160}]; middle = BSplineFunction[{45, 150, -30, 45}];bottom = BSplineFunction[{-90, -100, 30}];
Wolfram Language code: Plot[{top[t], middle[t], bottom[t]}, {t, 0, 1}]

根据 坐标和包络函数，定义一个函数来重新调整 坐标的尺寸：

Wolfram Language code: stretch[x_, t_, f_, g_] := Rescale[x, {10, 60}, {f[t], g[t]}]

通过替换坐标，改变填充曲线的形式：

Wolfram Language code: banner1 = text /. {x_Real, y_Real} :> {x, stretch[y, (x/430), bottom, middle]}; banner2 = text /. {x_Real, y_Real} :> {430 - x, stretch[y, 1 - (x/430), middle, top]};

显示：

Wolfram Language code: Graphics[{EdgeForm[Black], Blue, banner1, Red, banner2}]

棋盘形格局  (1)

创建一个瓦片的曲线边缘：

Wolfram Language code: e1 = {{-(Sqrt[3]/2), -(1/2)}, {-(Sqrt[3]/6), 0}, {(Sqrt[3]/6), -1}, {(Sqrt[3]/2), -(1/2)}};
Wolfram Language code: Graphics[BezierCurve[{e1}], Axes -> True]

通过旋转 120° 得到其他边缘：

Wolfram Language code: e2 = Map[RotationTransform[120Degree], e1]; e3 = Map[RotationTransform[120Degree], e2];

利用填充曲线生成带有 Bézier 曲线边缘的一个瓦片：

Wolfram Language code: tile = FilledCurve[{BezierCurve[e1], BezierCurve[Rest[e2]], BezierCurve[Rest[e3]]}];
Wolfram Language code: Graphics[{EdgeForm[Gray], FaceForm[Opacity[(1/2), Blue]], tile}, Axes -> True, Frame -> True, PlotRange -> 1]

通过旋转和平移，以瓦片形式平铺这个平面：

Wolfram Language code: Graphics[{EdgeForm[Opacity[(1/4), White]], FaceForm[Red], Table[With[{p = OddQ[i]⊻OddQ[j]} , {If[p, ColorData["HTML", "Crimson"], ColorData["HTML", "DarkBlue"]], Translate[Rotate[tile, (π/3) Boole[p], {0, 0}], {(Sqrt[3] i/2), (3 j/2) + (1/2) Boole[p]}]}], {i, 10}, {j, 4}]}]

使用线型边缘：

Wolfram Language code: % /. BezierCurve[a_] :> Line[a]

属性和关系  (1)

默认情况下，填充曲线的每个分量通过在顶端添加一个线段使自身闭合：

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}};
Wolfram Language code: Graphics[{EdgeForm[Blue], Pink, FilledCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}]}]

相反地，默认情况下，JoinedCurve 并不使曲线闭合：

Wolfram Language code: Graphics[JoinedCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}]]

使用 CurveClosed 选项使曲线中的分量是闭合的：

Wolfram Language code: Graphics[JoinedCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}, CurveClosed -> True]]

可能存在的问题  (1)

在线段中指定的 VertexColors 选项被忽略：

Wolfram Language code: Graphics[{EdgeForm[Thick], Pink, FilledCurve[Line[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Red, Green, Blue, Yellow}]]}]

巧妙范例  (2)

随机填充曲线：

Wolfram Language code: Module[{a = FilledCurve[{{Line[{{2, 3}, {0.8125, 0.625}}], BezierCurve[{{0.6875, 0.375}, {0.375, 0.25}, {1.125, 0.25}}, SplineDegree -> 2], BezierCurve[{{0.8125, 0.375}, {0.9375, 0.625}}], Line[{{1.3125, 1.375}, {2.4375, 1.375}, {2.8125, 0.625}}], BezierCurve[{{2.9375, 0.375}, {2.625, 0.25}, {3.625, 0.25}}, SplineDegree -> 2], BezierCurve[{{3.3125, 0.375}, {3.1875, 0.625}}]}, {Line[{{1.875, 2.5}, {1.375, 1.5}, {2.375, 1.5}}]}}]}, Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], Translate[Rotate[Scale[a, RandomReal[5]], RandomReal[2Pi]], RandomReal[20, {2}]]}, {30}]]]

波浪型文本标题：

Wolfram Language code: Module[{l = Cases[First[First[ImportString[ExportString[Style["Mathematica", Bold, FontFamily -> "Helvetica", FontSize -> 12], "PDF"], {"PDF", "PageGraphics"}, "TextOutlines" -> True]]], FilledCurve[a__] :> {EdgeForm[Black], Yellow, FilledCurve[a]}, Infinity]}, Animate[Graphics[{l /. {x_Real, y_Real} :> {x, y + 6 Sin[(x/12) + t]}}], {t, 0, 8 π}, AnimationRunning -> False, SaveDefinitions -> True]]
Wolfram Research (2010)，FilledCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FilledCurve.html （更新于 2018 年）.

文本

Wolfram Research (2010)，FilledCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FilledCurve.html （更新于 2018 年）.

CMS

Wolfram 语言. 2010. "FilledCurve." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2018. https://reference.wolfram.com/language/ref/FilledCurve.html.

APA

Wolfram 语言. (2010). FilledCurve. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FilledCurve.html 年

BibTeX

@misc{reference.wolfram_2026_filledcurve, author="Wolfram Research", title="{FilledCurve}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/FilledCurve.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_filledcurve, organization={Wolfram Research}, title={FilledCurve}, year={2018}, url={https://reference.wolfram.com/language/ref/FilledCurve.html}, note=[Accessed: 07-September-2026]}