Wolfram言語＆システムドキュメントセンター

GeoDisplacement

GeoDisplacement[{dist,α}]

ある測地位置からの，長さ dist で初期方位 α の測地移動を表す．

GeoDisplacement[{dist,α},pathtype]

長さ dist，初期方位 α の pathtype タイプの経路に沿った移動を表す．

GeoDisplacement[loc₁,loc₂,pathtype]

loc₁からloc₂に到達するために必要な，pathtype タイプの経路に沿った移動を返す．

GeoDisplacement

GeoDisplacement[{dist,α}]

ある測地位置からの，長さ dist で初期方位 α の測地移動を表す．

GeoDisplacement[{dist,α},pathtype]

長さ dist，初期方位 α の pathtype タイプの経路に沿った移動を表す．

GeoDisplacement[loc₁,loc₂,pathtype]

loc₁からloc₂に到達するために必要な，pathtype タイプの経路に沿った移動を返す．

詳細

距離 dist は，Quantity長として，あるいはメートル単位の数で与えることができる．
方位 α は時計回りに真北（測地北）から測られる．これは，Quantity角，度を単位とした数，DMS文字列，"N"あるいは"SouthWest"のような名前付きのコンパスの点として与えることができる．
GeoDisplacement[loc₁,loc₂,pathtype]中の位置 loc_iは，地理Entityオブジェクト，度を単位とした{lat,lon}ペア，GeoPositionオブジェクト，あるいは他の任意の測地位置指定として与えることができる．
GeoDisplacement[loc₁,loc₂]はタイプ"Geodesic"の経路を仮定する．
使用可能な経路タイプのリストは，GeoPathのドキュメントを参照のこと．
GeoDisplacementは，連続する移動の計算にはGeoDestinationと，その描画にはGeoPathと使うことができる．

例題

すべて開くすべて閉じる

例 (4)

ある位置から10000キロメートル動いた目的地を計算する：

Wolfram Language code: GeoDestination[GeoPosition[{40, 30}], GeoDisplacement[{Quantity[10000, "Kilometers"], Quantity[45, "AngularDegrees"]}]]

目的地までの途中の位置のリストを計算する：

Wolfram Language code: GeoDestination[GeoPosition[{40, 30}], GeoDisplacement[{Range[0, 10 ^ 7, 10 ^ 6], 45}]]

方位がランダムな，1測地ステップ1000kmで70測地ステップのランダム経路：

Wolfram Language code:

GeoGraphics[GeoPath[Flatten@{GeoPosition[{0, 0}], Table[GeoDisplacement[{10 ^ 6, RandomReal[{0, 360}]}], {70}]}, VertexColors -> Table[Hue[i / 100], {i, 0, 70}]]]

東京からパリまでの航程線に沿った距離と方向を計算する：

Wolfram Language code:

GeoDisplacement[Entity["City", {"Tokyo", "Tokyo", "Japan"}], Entity["City", {"Paris", "IleDeFrance", "France"}], "Rhumb"]

測地線に沿った距離と方向を計算する：

Wolfram Language code:

GeoDisplacement[Entity["City", {"Tokyo", "Tokyo", "Japan"}], Entity["City", {"Paris", "IleDeFrance", "France"}], "Geodesic"]

世界地図上で，航程線（赤）と測地線（青）を比較する：

Wolfram Language code:

GeoGraphics[{Red, GeoPath[{Entity["City", {"Tokyo", "Tokyo", "Japan"}], %%}], Blue, GeoPath[{Entity["City", {"Tokyo", "Tokyo", "Japan"}], %}]}, GeoRange -> "World"]

スコープ (9)

初期方位40度の測地線に沿った相対移動：

Wolfram Language code: GeoDisplacement[{Quantity[100, "Kilometers"], Quantity[40, "AngularDegrees"]}]

航程線に沿った相対移動：

Wolfram Language code: GeoDisplacement[{Quantity[100, "Kilometers"], Quantity[40, "AngularDegrees"]}, "Rhumb"]

大楕円に沿った相対移動：

Wolfram Language code: GeoDisplacement[{Quantity[100, "Kilometers"], Quantity[40, "AngularDegrees"]}, "GreatEllipse"]

距離はメートル単位の数で与えることができる：

Wolfram Language code: GeoDisplacement[{10 ^ 5, Quantity[40, "AngularDegrees"]}]

任意単位のQuantity長として与えることもできる：

Wolfram Language code: GeoDisplacement[{Quantity[2, "Kilometers"], Quantity[40, "AngularDegrees"]}]

結果はメートルに自動変換される：

Wolfram Language code: GeoDisplacement[{Quantity[5000., "Feet"], Quantity[40, "AngularDegrees"]}]

方位は度を単位とした数で与えることができる：

Wolfram Language code: GeoDisplacement[{Quantity[100, "Kilometers"], 40}]

任意単位のQuantity角として与えることもできる：

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], Quantity[40, "AngularDegrees"]}]

結果は自動的に度に変換される：

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], Quantity[2., "Radians"]}]

方位はDMS文字列として指定することもできる：

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "43d 23m 31.s"}]

名前付きのコンパスの点を使うこともできる：

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "NE"}]

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "NorthEast"}]

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "NNW"}]

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "North-NorthWest"}]

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "SEbE"}]

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "SouthEastByEast"}]

伝統的な主な8つの風向名もまた，使うことができる：

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "Levante"}]

Wolfram Language code: GeoDisplacement[{Quantity[100., "Miles"], "Libeccio"}]

同じ測地線に沿った複数の相対移動のGeoDisplacement指定：

Wolfram Language code: GeoDisplacement[{Range[0, 10 ^ 7, 10 ^ 6], 40}]