WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoGridVector[loc{vx,vy},proj]

地理位置 loc における地理投影法 proj による座標の，正規直交座標系における成分 vxと vyを持つ水平二次元ベクトルを表す．

GeoGridVector[loc{vx,vy,vz},proj]

地理位置 loc における，水平成分 vxおよび vyと垂直成分 vzを持つ三次元ベクトルを表す．

GeoGridVector[{loc1,loc2,…}{vec1,vec2,…},proj]

それぞれの地理位置 lociにおける，ベクトル veciの集合を表す．

GeoGridVector[{loc1vec1,loc2vec2,…},proj]

ベクトルの同じ集合を表す．

GeoGridVector[vec,proj]

関連付けられた位置が陰的に指定された地理ベクトルを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
データ指定  
地理投影法の変換  
地理ベクトル配列  
データの抽出  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

GeoGridVector

GeoGridVector[loc{vx,vy},proj]

地理位置 loc における地理投影法 proj による座標の，正規直交座標系における成分 vxと vyを持つ水平二次元ベクトルを表す．

GeoGridVector[loc{vx,vy,vz},proj]

地理位置 loc における，水平成分 vxおよび vyと垂直成分 vzを持つ三次元ベクトルを表す．

GeoGridVector[{loc1,loc2,…}{vec1,vec2,…},proj]

それぞれの地理位置 lociにおける，ベクトル veciの集合を表す．

GeoGridVector[{loc1vec1,loc2vec2,…},proj]

ベクトルの同じ集合を表す．

GeoGridVector[vec,proj]

関連付けられた位置が陰的に指定された地理ベクトルを表す．

詳細

  • GeoGridVector[…]は，地表または他の任意の天体表面の，風速，磁場，スカラー勾配等の任意のベクトルの大きさを表すことができる．
  • GeoGridVectorは，指定された場所の基準楕円体に接する正規直交座標系を使って，データを説明する．
  • GeoGridVectorは，ベクトルデータの容器として，また，GeoVectorENUやGeoVectorのような他のタイプの地理ベクトルデータからの変換器として作用する．
  • GeoGridVector[locvec]におけるベクトル vec の成分は数量でよいが，その単位は互換でなければならない．
  • GeoGridVector[locvec]の場所 loc は，度を単位とする{lat,lon}のペア，地理Entityオブジェクト，あるいはGeoPositionまたはこれに類似の頭部を持つ任意の地理位置オブジェクトとして与えることができる．
  • GeoGridVector[locvec,proj]内の地理投影法 proj は次の形式で指定できる．
  • "proj"デフォルトのパラメータ値がある名前付きの投影法
    {"proj","param1"->val1,"param2"->val2,…}パラメータが細かく指定された投影法
  • 使用可能な投影法名はGeoProjectionData[]で与えられる．
  • 特定の名前付き投影法のデフォルトのパラメータ値はGeoProjectionData[proj]で与えられる．
  • GeoGridVector[…][prop]は地理格子ベクトルの指定された特性を与える．
  • 次は，使用可能な特性である．
  		• "Count"GeoGridVectorオブジェクト中のベクトルの数
    		"Data"GeoGridVectorオブジェクトの第1引数
    		"Depth"ベクトル深度．単一のベクトルについては0，ベクトルのリストは1等
    		"GeoProjection"GeoGridVectorオブジェクトの地理投影法
    		"Location"GeoGridVectorオブジェクトの位置データ
    		"LocationDimension"各位置についての座標数
    		"LocationPackingType"位置がPackedの場合はIntegerまたはReal．それ以外の場合はNone
    		"Vector"GeoGridVectorオブジェクトのベクトルデータ
    		"VectorDimension"各ベクトルの成分数
    		"VectorPackingType"ベクトルがPackedの場合はIntegerまたはReal．それ以外の場合はNone

例題

すべて開く すべて閉じる

例  (2)

自分がいる場所の地理ベクトルをアルベルス図法における座標軸と垂直に揃えて取る：

Wolfram Language code: gv = GeoGridVector[Here -> Quantity[{0, 10}, "Miles" / "Hours"], "Albers"]
Wolfram Language code: GeoGraphics[GeoMarker[gv, "Dart"], GeoRange -> "World", GeoProjection -> "Albers", GeoGridLines -> Automatic, GeoBackground -> "Plain"]

このベクトルは，局所的なメルカトル図法では北を指さない：

Wolfram Language code: GeoGraphics[GeoMarker[gv, "Dart"], GeoGridLines -> Automatic]

ニューヨークにおける2つの直交地理ベクトルを取る：

Wolfram Language code: gv = GeoVector[{Entity["City", {"NewYork", "NewYork", "UnitedStates"}] -> {1, 0}, Entity["City", {"NewYork", "NewYork", "UnitedStates"}] -> {1, 90}}]

これらは，デフォルトの中心化を使ったモルワイデ図法では直交ではない：

Wolfram Language code: ggv = GeoGridVector[gv, {"Mollweide", "Centering" -> {0, 0}}]

上記の図法を使ったGeoGraphics地図に地理格子ベクトルを矢印として示す：

Wolfram Language code: GeoGraphics[GeoMarker[ggv, Placed["Dart", "Start"]], GeoProjection -> {"Mollweide", "Centering" -> {0, 0}}, GeoGridLines -> Automatic, GeoRange -> Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]

スコープ  (11)

データ指定  (4)

地理格子ベクトルの位置を度を単位とした{lat,lon}ペアとして指定する：

Wolfram Language code: GeoGridVector[{20, -50} -> {1, 0}, "Bonne"]

シカゴでボンヌ図法の座標軸と45度で交差する水平速度ベクトルを構築する：

Wolfram Language code: gv = GeoGridVector[Entity["City", {"Chicago", "Illinois", "UnitedStates"}] -> Quantity[{3, 3}, "Nanoteslas"], "Bonne"]

任意の頭部を持つ地理位置オブジェクトとして位置を書き換える：

Wolfram Language code: GeoPosition[gv]
Wolfram Language code: GeoPositionXYZ[gv]
Wolfram Language code: GeoGridPosition[gv, "Bonne"]

GeoPositionが解釈できるものは何でも位置として使用できる：

Wolfram Language code: GeoGridVector["12d 3m 4.5s N, 123d 58m 3.2s W" -> {1, 2}, "Mollweide"]//GeoPosition
Wolfram Language code: GeoGridVector["NullIsland" -> {1, 2}, "Mollweide"]//GeoPosition

任意の単位次元の水平2Dベクトルあるいは3Dベクトルを使う：

Wolfram Language code: GeoGridVector[Entity["City", {"Tokyo", "Tokyo", "Japan"}] -> {1, 1 / 2}, "Mercator"]
Wolfram Language code: GeoGridVector[Entity["City", {"Tokyo", "Tokyo", "Japan"}] -> Quantity[{2, 3}, "Meters" / "Seconds"], "Mercator"]
Wolfram Language code: GeoGridVector[Entity["City", {"Tokyo", "Tokyo", "Japan"}] -> Quantity[{-4, 5, -1}, "Meters" / "Seconds" ^ 2], "Mercator"]

地理投影法の変換  (2)

メルカトル図法の地理格子ベクトルデータを別の地理投影法に変換する：

Wolfram Language code: GeoGridVector[Here -> Quantity[{10, 20}, "Miles" / "Hours"], "Mercator"]
Wolfram Language code: GeoGridVector[%, "Albers"]
Wolfram Language code: GeoGridVector[%, "LambertAzimuthal"]

もとの投影法に変換し直す：

Wolfram Language code: GeoGridVector[%, "Mercator"]

投影法をGeoProjectionDataで与えられるようなデフォルトのパラメータで使う：

Wolfram Language code: GeoProjectionData["Albers"]
Wolfram Language code: GeoGridVector[Here -> Quantity[{1.5, -3.2}, "Miles" / "Hours"], "Albers"]

地理格子ベクトルをデフォルトではないパラメータのアルベルス図法に変換する：

Wolfram Language code: GeoGridVector[%, {"Albers", "Centering" -> Here}]

デフォルトパラメータのアルベルス図法に変換し直す：

Wolfram Language code: GeoGridVector[%, "Albers"]

地理ベクトル配列  (4)

"WinkelTripel"投影の成分を持つ2つのベクトルのGeoGridVectorオブジェクトを指定する：

Wolfram Language code: GeoGridVector[{GeoPosition[{30, -40}] -> {-0.32, -1.06}, GeoPosition[{-20, -150}] -> {0.45, 0.67}}, "WinkelTripel"]

以下は，同じデータを指定する別の方法である：

Wolfram Language code: GeoGridVector[GeoPosition[{{30, -40}, {-20, -150}}] -> {{-0.32, -1.06}, {0.45, 0.67}}, "WinkelTripel"]

数ヶ所の重力場データを同時に計算する：

Wolfram Language code: GeogravityModelData[{Entity["City", {"London", "GreaterLondon", "UnitedKingdom"}], Entity["City", {"Paris", "IleDeFrance", "France"}], Entity["City", {"Amsterdam", "NoordHolland", "Netherlands"}], Entity["City", {"Berlin", "Berlin", "Germany"}]}, GeoVector]

上記をメルカトル図法における単一の地理格子ベクトル配列に変換する：

Wolfram Language code: GeoGridVector[%, "Mercator"]

小さい水平成分の相対サイズと方向を表す：

Wolfram Language code: GeoGraphics[GeoMarker[%, {"Dart", "Circle"}], GeoRange -> {{47, 54}, {-2, 16}}]

百万個のランダムな地理格子ベクトルをそれぞれのランダムな場所に生成する：

Wolfram Language code: ggv = GeoGridVector[RandomGeoPosition[10 ^ 6] -> QuantityArray[RandomReal[{-1, 1}, {10 ^ 6, 2}], "Meters"], "Albers"]

上記を地理ベクトル形式に変換する：

Wolfram Language code: AbsoluteTiming[gv = GeoVector[ggv]]

GeoGridVectorを使って上記をアルベルス図法の投影形式に変換し直す：

Wolfram Language code: AbsoluteTiming[newggv = GeoGridVector[gv, "Albers"]]

差が数値誤差に過ぎないことをチェックする：

Wolfram Language code: CoordinateBounds[newggv["Vector"] - ggv["Vector"]]

百万個のランダムな地理格子ベクトルをそれぞれのランダムな場所に生成する：

Wolfram Language code: ggv = GeoGridVector[RandomGeoPosition[10 ^ 6] -> QuantityArray[RandomReal[{-1, 1}, {10 ^ 6, 2}], "Meters"], "Albers"]

地理格子ベクトルをアルベルス図法からモルワイデ図法に変換する：

Wolfram Language code: AbsoluteTiming[pgv = GeoGridVector[ggv, "Mollweide"]]

GeoGridVectorを使って上記をアルベルス図法に変換し直す：

Wolfram Language code: AbsoluteTiming[newggv = GeoGridVector[pgv, "Albers"]]

差が数値誤差に過ぎないことをチェックする：

Wolfram Language code: CoordinateBounds[newggv["Vector"] - ggv["Vector"]]

データの抽出  (1)

シカゴにおける水平速度ベクトル：

Wolfram Language code: ggv = GeoGridVector[Entity["City", {"Chicago", "Illinois", "UnitedStates"}] -> Quantity[{10, 20}, "Miles" / "Hours"], "Mercator"]

地理ベクトルの場所を抽出する：

Wolfram Language code: ggv["Location"]

地理ベクトルからベクトルデータを抽出する：

Wolfram Language code: ggv["Vector"]

locvec 規則を抽出する：

Wolfram Language code: ggv["LocationVectorRule"]

全特性を抽出する：

Wolfram Language code: ggv["Properties"]
Wolfram Language code: AssociationMap[ggv, %]//Normal//Column

特性と関係  (1)

メルカトル図法のGeoGridVector成分はGeoVectorENU成分と一致する：

Wolfram Language code: enu = GeomagneticModelData[Entity["City", {"Anchorage", "Alaska", "UnitedStates"}], Now, GeoVectorENU]//Normal
Wolfram Language code: GeoGridVector[enu, "Mercator"]

これらの成分は，角歪みや経緯度線の傾きのために，他の投影法では異なる：

Wolfram Language code: GeoGridVector[enu, "Equirectangular"]
Wolfram Research (2019), GeoGridVector, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoGridVector.html.

テキスト

Wolfram Research (2019), GeoGridVector, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoGridVector.html.

CMS

Wolfram Language. 2019. "GeoGridVector." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/GeoGridVector.html.

APA

Wolfram Language. (2019). GeoGridVector. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoGridVector.html

BibTeX

@misc{reference.wolfram_2026_geogridvector, author="Wolfram Research", title="{GeoGridVector}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/GeoGridVector.html}", note=[Accessed: 08-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geogridvector, organization={Wolfram Research}, title={GeoGridVector}, year={2019}, url={https://reference.wolfram.com/language/ref/GeoGridVector.html}, note=[Accessed: 08-November-2026]}