WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoPositionXYZ[{x,y,z}]

直交地心座標系の位置を表す．

GeoPositionXYZ[{x,y,z},datum]

指定された測地系を参照する点を表す．

GeoPositionXYZ[{{x1,y1,z1},{x2,y2,z2},…},datum]

直交地心座標系における点の配列を表す．

GeoPositionXYZ[entity]

指定された地理実体の直交地心位置を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
位置指定  
地理位置配列  
座標の抽出  
一般化と拡張  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

GeoPositionXYZ

GeoPositionXYZ[{x,y,z}]

直交地心座標系の位置を表す．

GeoPositionXYZ[{x,y,z},datum]

指定された測地系を参照する点を表す．

GeoPositionXYZ[{{x1,y1,z1},{x2,y2,z2},…},datum]

直交地心座標系における点の配列を表す．

GeoPositionXYZ[entity]

指定された地理実体の直交地心位置を返す．

詳細

  • GeoPositionXYZは地心地球固定デカルト座標系を使う．
  • GeoPositionXYZ[{x,y,z}]座標の数値 x,y,z はメートル単位であると仮定される．
  • GeoPositionXYZ[{x,y,z,t}]は，GMT時刻帯における，1900年1月1日からの秒で計測された時間 t を含む．
  • 明示的な時間を含まないGeoPositionXYZオブジェクトは，現行の日付を想定する．
  • GeoPositionXYZ[{x,y,z}]はデフォルトの測地系"ITRF00"を仮定する．
  • 基準測地系は名前で指定できる．次は，よく使われる名前付きの測地系である．
  • "ITRF00"ITRF (international Terrestrial Reference Frame) 2000
    "NAD27"1927年の北米測地系(North American Datum)
    "NAD83CORS96"1983年の北米測地系(CORS96)
  • 名前付き測地系と基準楕円体の完全リストはGeodesyData[]で与えられる．
  • GeoPositionXYZ[GeoPositionXYZ[{x,y,z},datum1],datum2]は測地系間の変換を行う．
  • GeoPositionXYZ[pos]あるいはGeoPositionXYZ[pos,datum]は，任意の地理的場所からの変換を行う．地理的場所のタイプGeoPosition，GeoPositionXYZ，GeoPositionENU，GeoGridPositionを使用することができる．
  • GeoPositionXYZ[pos]は，pos と同じ測地系を使って任意のタイプの測地位置を変換する．
  • 拡張された実体については，GeoPositionXYZ[entity]は，可能な場合は実体の地理的中心の位置を使う．
  • GeoPositionXYZ[…][prop]はデカルト地理位置の指定された特性を与える．
  • 次は，使用可能な特性である．
  		• "AbsoluteTime"1900年1月1日（グリニッジ標準時）からの秒数としての日付
    		"，Count"GeoPositionXYZオブジェクト内の場所の数
    		"Data"GeoPositionXYZオブジェクトの第1引数
    		"DateList"グリニッジ標準時による日付リスト{y,m,d,h,m,s}
    		"DateObject"完全な日付オブジェクト
    		"Datum"GeoPositionXYZオブジェクトの測地系
    		"Depth"点の深さ：単一の位置については0，位置のリストについては1，…
    		"Dimension"各位置の座標数
    		"PackingType"データがパックされている場合はIntegerまたはReal．それ以外の場合はNone
    "X"数値座標 x （単位：メートル）
    "Y"数値座標 y（単位：メートル）
    "Z"数値座標 z（単位：メートル）
    "XYZ"数値 {x,y,z}3つ組（単位：メートル）
    "XY"数値 {x,y} ペア（単位：メートル）
    "XZ"数値 {x,z} ペア（単位：メートル）
    "YZ"数値 {y,z} ペア（単位：メートル）

例題

すべて開く すべて閉じる

例  (4)

地心デカルト座標（単位：メートル）で定義される測地点：

Wolfram Language code: GeoPositionXYZ[{148217.79, -4.88253*^6, 4.0877119*^6}]

{lat,lon,height}形式に変換する：

Wolfram Language code: GeoPosition[%]

測地位置の直交座標：

Wolfram Language code: GeoPositionXYZ[Entity["City", {"Paris", "IleDeFrance", "France"}]]

国際宇宙ステーションの現在の直交座標と時刻：

Wolfram Language code: SatelliteData[Entity["Satellite", "25544"], "Position"]//GeoPositionXYZ

地心座標をデフォルトの"ITRF00"測地系から"NAD83CORS96"測地系に変換する：

Wolfram Language code: GeoPositionXYZ[GeoPositionXYZ[{0, 0, 0}], "NAD83CORS96"]

マイクロメートル未満の数値誤差で"ITRF00"測地系に変換し直す：

Wolfram Language code: GeoPositionXYZ[%, "ITRF00"]

スコープ  (12)

位置指定  (6)

地球の中心に対して x, y, z の値（単位：メートル）で指定された測地位置：

Wolfram Language code: GeoPositionXYZ[{130000., -5000000., 4000000.}]

これを，高さをメートル単位で含む lat-lon 指定に変換する：

Wolfram Language code: GeoPosition[%]

1900年からの時間の情報を秒単位で含める：

Wolfram Language code: GeoPositionXYZ[{130000., -5000000., 4000000., DateObject[]}]

メルカトル図法を使い，平面地図に投影する．時間情報は保存される：

Wolfram Language code: GeoGridPosition[%, "Mercator"]

地理実体の地球の中心に対しての位置を求める：

Wolfram Language code: GeoPositionXYZ[Entity["City", {"Tokyo", "Tokyo", "Japan"}]]

座標を任意の長さの単位のQuantityオブジェクトとして与える：

Wolfram Language code: GeoPositionXYZ[Quantity[{130., -5000., 4000.}, "Kilometers"]]
Wolfram Language code: GeoPositionXYZ[Quantity[{80., -3100., 2500.}, "Miles"]]

他の測地位置タイプからGeoPositionXYZに変換する：

Wolfram Language code: GeoPositionXYZ[GeoPosition[{0., 0.}]]
Wolfram Language code: GeoPositionXYZ[GeoGridPosition[{10., -20.}, "Mercator"]]
Wolfram Language code: GeoPositionXYZ[GeoPositionENU[{1000., 2310., -10.}, GeoPosition[{10., 23.}]]]

位置をある測地系から他に変換する：

Wolfram Language code: GeoPositionXYZ[GeoPositionXYZ[{130000., -5000000., 4000000.}, "ITRF90"], "WGS72"]

もとの測地系に変換し直す：

Wolfram Language code: GeoPositionXYZ[%, "ITRF90"]

地理位置配列  (4)

計算を速くするために，第1引数に位置の配列を使う：

Wolfram Language code: triples = RandomReal[6371000, {10000, 3}];

点はすべて一度に変換される：

Wolfram Language code: AbsoluteTiming[r1 = GeoPosition[GeoPositionXYZ[triples]];]

ここでは，各点が個別に変換されている：

Wolfram Language code: AbsoluteTiming[r2 = GeoPosition /@ GeoPositionXYZ /@ triples;]

結果は数値誤差に到るまで一致する：

Wolfram Language code: First[r1] - (First /@ r2)//Abs//Max

測地系の変更は点の配列を第1引数として使っても速くなる：

Wolfram Language code: triples = RandomReal[6371000, {10000, 3}];
Wolfram Language code: AbsoluteTiming[r1 = GeoPositionXYZ[GeoPositionXYZ[triples, "WGS72"], "ITRF90"];]
Wolfram Language code: AbsoluteTiming[r2 = GeoPositionXYZ[GeoPositionXYZ[#, "WGS72"], "ITRF90"]& /@ triples;]
Wolfram Language code: First[r1] - (First /@ r2)//Abs//Max

GeoPositionXYZは，すべての点の長さと深さが同じである限り，点のネストしたリストを含むことができる：

Wolfram Language code: GeoPositionXYZ[{{{1., 2., 3.}, {4., 5., 6.}}, {{7., 8., 9.}}}]

操作してもネスト構造は残る：

Wolfram Language code: GeoGridPosition[%, "Mercator"]
Wolfram Language code: GeoPositionXYZ[%]

しかで，これは，最初の点には時間指定があるが2番目の点にはないので許されない：

Wolfram Language code: GeoPositionXYZ[{{1, 2, 3, 0}, {4, 5, 6}}]

次は，2番目の点が最初の点より深いので許されない：

Wolfram Language code: GeoPositionXYZ[{{1, 2, 3}, {{4, 5, 6}}}]

地理位置のリストを単一の地理位置配列に変換する：

Wolfram Language code: {GeoPositionXYZ[{0, 0, 0}], GeoPositionXYZ[{150000., -5000000., 4000000.}], GeoPositionXYZ[{5000000., -300000., 4000000.}]}
Wolfram Language code: GeoPositionXYZ[%]

地理位置のリストに変換し直す：

Wolfram Language code: Thread[%]

座標の抽出  (2)

特性を使ってGeoPositionXYZオブジェクトから情報を抽出する：

Wolfram Language code: p = GeoPositionXYZ[Here]
Wolfram Language code: p["Properties"]
Wolfram Language code: AssociationMap[p, %]//Normal//Column

特性を使ってGeoPositionXYZ配列から情報を抽出する：

Wolfram Language code: p = GeoPositionXYZ[RandomGeoPosition["World", {10, 20}]]

点は全部で200個ある：

Wolfram Language code: p["Count"]

これは，点の行列である．したがって，点の深さは2である：

Wolfram Language code: p["Depth"]

各点の次元は，x,y,z の座標の3である：

Wolfram Language code: p["Dimension"]

座標の配列はReal型でパックされている：

Wolfram Language code: p["PackingType"]

他の任意の特性は配列の点に対応する値の配列を返す：

Wolfram Language code: p["AbsoluteTime"]//Dimensions
Wolfram Language code: p["DateList"]//Dimensions

一般化と拡張  (3)

半径100キロの球の上の位置を使う：

Wolfram Language code: GeoPosition[{32., -73.4}, Quantity[100, "Kilometers"]]

3Dベクトルに変換する：

Wolfram Language code: GeoPositionXYZ[%]

ベクトル成分はメートル単位で与えられる：

Wolfram Language code: Norm[%["XYZ"]]

指定された半軸の楕円体上の位置を使う：

Wolfram Language code: GeoPosition[{-29.4, 32.7}, {Quantity[1, "Kilometers"], Quantity[900, "Meters"]}]

3Dベクトルに変換する：

Wolfram Language code: GeoPositionXYZ[%]

楕円体上のGeoPositionオブジェクトに変換し直す：

Wolfram Language code: GeoPosition[%]

地球以外の地理基準モデル上の位置：

Wolfram Language code: SolarSystemFeatureData[Entity["SolarSystemFeature", "TychoBraheMars"], "Position"]
Wolfram Language code: GeoPositionXYZ[%]

計算は，次の長さの半軸を持つ楕円体について行われる：

Wolfram Language code: PlanetData[Entity["Planet", "Mars"], {"EquatorialRadius", "PolarRadius"}]

アプリケーション  (2)

地表の100個のランダムな点：

Wolfram Language code: points = RandomGeoPosition["World", 100]

上記の点を平面地図上にプロットする：

Wolfram Language code: GeoGraphics[Point[points]]

3D空間でプロットする：

Wolfram Language code: ListPointPlot3D[GeoPositionXYZ[points]["XYZ"], BoxRatios -> 1]

3Dの点情報を経緯度に変換する．例として，多面体の頂点を取る：

Wolfram Language code: Show[Graphics3D[gc = N@PolyhedronData["Icosahedron", "GraphicsComplex"]], Boxed -> False]

12個の頂点を適切な半径の球の上のGeoPositionXYZ 配列として表す：

Wolfram Language code: xyz = GeoPositionXYZ[gc[[1]], Norm[gc[[1, 1]]]]

{lat,lon}ペアのリスト（単位：度）に変換する：

Wolfram Language code: latlon = QuantityMagnitude[LatitudeLongitude[xyz], "AngularDegrees"]

20明太の20の面の測地線周長を含むGeoPathオブジェクトを構築する：

Wolfram Language code: geopaths = GeoPath[Extract[latlon, List /@ gc[[2, 1]]]];

"Equirectangular"図法による，これらの頂点間の測地線：

Wolfram Language code: GeoGraphics[geopaths, GeoProjection -> "Equirectangular"]

方位図法を使う：

Wolfram Language code: GeoGraphics[geopaths, GeoProjection -> "LambertAzimuthal"]

特性と関係  (6)

緯度と経度の原点の三次元位置：

Wolfram Language code: GeoPositionXYZ[GeoPosition[{0, 0}]]

北極と南極の三次元位置：

Wolfram Language code: GeoPositionXYZ[GeoPosition[{90, 0}]]
Wolfram Language code: GeoPositionXYZ[GeoPosition[{-90, 0}]]

以下の半軸を持つ楕円体について，測地座標を直交座標に変換する：

Wolfram Language code: a = 1.; b = 0.5;

測地緯度60°，経度0，測地高0.15の点 p を取る：

Wolfram Language code: p = GeoPosition[{60., 0., 0.15}, {a, b}]

これを直交座標に変換する：

Wolfram Language code: pxyz = GeoPositionXYZ[p]

測地座標に変換し直す：

Wolfram Language code: GeoPosition[pxyz]

同じ緯度と経度で高さが0の点 q を取る：

Wolfram Language code: q = GeoPosition[{60., 0., 0.}, {a, b}]
Wolfram Language code: qxyz = GeoPositionXYZ[q]

楕円体を垂直に切断したものの上で，座標間の関係を表す：

Wolfram Language code: pxz = {pxyz["X"], pxyz["Z"]} qxz = {qxyz["X"], qxyz["Z"]}

青い線は q における接線に垂直で， 軸に対して60°の角度である：

Wolfram Language code: Graphics[{Circle[{0, 0}, {a, b}], PointSize[Medium], Red, Point[pxz], Line[{{0, 0}, pxz}], Blue, Point[qxz], Line[{pxz, pxz - 0.75{Cos[60Degree], Sin[60Degree]}}]}, Axes -> True]

測地垂直線に沿った p の測地高は p と q の距離である：

Wolfram Language code: Norm[pxz - qxz]

GeoPositionXYZ[{}]は測地位置の空配列を表す：

Wolfram Language code: GeoPositionXYZ[{}]

位置は1つも含まれていない：

Wolfram Language code: %["Count"]

GeoPositionXYZ[]は無効なシンタックスである：

Wolfram Language code: GeoPositionXYZ[]

GeoPositionXYZは，地球を中心とした位置を与える．GeoPositionENUは使用する中心を指定する：

Wolfram Language code: GeoPositionXYZ[Entity["City", {"NewYork", "NewYork", "UnitedStates"}]]

ニューヨークはワシントンの接平面より8kmを超える距離だけ下にある：

Wolfram Language code: GeoPositionENU[Entity["City", {"NewYork", "NewYork", "UnitedStates"}], Entity["City", {"Washington", "DistrictOfColumbia", "UnitedStates"}]]

GeoPositionXYZは，この中心についてはGeoPositionENUと一致する：

Wolfram Language code: b = GeodesyData["ITRF00", "SemiminorAxis"]
Wolfram Language code: center = GeoPosition[{90, -90, -b}]

地球上の任意の場所を選ぶ：

Wolfram Language code: loc = GeoPosition[{-30, 140}];
Wolfram Language code: GeoPositionXYZ[loc]
Wolfram Language code: GeoPositionENU[loc, center]

GeoPositionXYZ位置の対蹠点の座標の符号は逆になる：

Wolfram Language code: GeoAntipode[GeoPositionXYZ[{1.34*^6, -4.66*^6, 4.13*^6}]]
Wolfram Research (2008), GeoPositionXYZ, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoPositionXYZ.html （2019年に更新）.

テキスト

Wolfram Research (2008), GeoPositionXYZ, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoPositionXYZ.html （2019年に更新）.

CMS

Wolfram Language. 2008. "GeoPositionXYZ." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/GeoPositionXYZ.html.

APA

Wolfram Language. (2008). GeoPositionXYZ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoPositionXYZ.html

BibTeX

@misc{reference.wolfram_2026_geopositionxyz, author="Wolfram Research", title="{GeoPositionXYZ}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/GeoPositionXYZ.html}", note=[Accessed: 13-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_geopositionxyz, organization={Wolfram Research}, title={GeoPositionXYZ}, year={2019}, url={https://reference.wolfram.com/language/ref/GeoPositionXYZ.html}, note=[Accessed: 13-November-2026]}