WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ImageTransformation[image,f]

位置 p の画素それぞれが image 中の位置 f[p]に対応する画像を与える．

ImageTransformation[image,f,size]

指定サイズの画像を与える．

ImageTransformation[video,…]

動画のフレームを変換する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
データ  
変換関数  
サイズ  
オプション  
Background  
DataRange  
Masking  
PlotRange  
Padding  
Resampling  
アプリケーション  
特性と関係  
インタラクティブな例題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

ImageTransformation

ImageTransformation[image,f]

位置 p の画素それぞれが image 中の位置 f[p]に対応する画像を与える．

ImageTransformation[image,f,size]

指定サイズの画像を与える．

ImageTransformation[video,…]

動画のフレームを変換する．

詳細とオプション

  • ImageTransformation[image,f]は，逆変換とも呼ばれるもので，出力画像の位置{x,y}の各画素の値を入力 image の位置 f[{x,y}]から得ることができる．
  • 変換関数 f は以下のいずれでもよい．
  • f任意の関数 f
    TransformationFunction[…]変換関数
  • 動画入力の変換関数は，時間の関数（開始時点からの秒数）でもよい．この関数は時点 t で位置 p における各画素が位置 f[t][p]に対応するフレームを返す．
  • ImageTransformationは，任意の2Dおよび3D画像に使うことができる．
  • size の可能な設定
  • Automatic自動の画像サイズ
    All入力画像サイズと同じ
    width明示的な width で高さは自動
    {width,height}明示的な width と height
    {width,depth,height}三次元の明示的な width，depth，height
  • width，depth，height に使用可能な設定については，ImageResizeの関数ページを参照のこと．
  • 2Dでは，入力画像の座標系の範囲はであると想定される．ただし， は縦横比である．デフォルトで，画像の左下隅が座標に相当する．
  • 3Dでは，入力画像の座標系範囲はであると想定される．ただし，は画像の次元である．画像の左前下隅は，デフォルトで，座標に対応する．
  • DataRangeオプションを指定することで，他の座標系を指定することができる．
  • ImageTransformationで使用可能なオプション
  • Background 0使用する背景色
    DataRange Automaticもとの画像の座標範囲
    Masking Full変換する関心領域
    Padding 0充填法
    PlotRange Automatic結果の画像の座標範囲
    Resampling Automaticリサンプリングの方法
  • デフォルトで，ImageTransformationは入力画像と同じ縦横比の画像を返す．
  • DataRangeでよく使われる設定値
  • Automatic2Dでは，3Dでは
    Full2Dでは，3Dでは
    {{left,right},{bottom,top}}二次元の明示的な座標範囲
    {{left,right},{front,back},{bottom,top}}三次元の明示的な座標範囲
  • 結果画像の座標系はPlotRangeオプションで指定する．次は，使われる設定値である．
  • AutomaticDataRangeの設定値と等しい
    All変換された全画素を含もうとする
    Full入力画像と同じ範囲
    {{left,right},…}明示的な座標範囲
  • ImageTransformation[image,f]では，結果画像の画素の次元は image の次元とPlotRangeとDataRangeの比率に基づく．
  • Maskingオプションは以下のいずれかである．
  • All入力画像のみ
    Full入力画像および充填
    mask任意のマスク画像

例題

すべて開く すべて閉じる

例  (2)

画像を変換する：

Wolfram Language code: ImageTransformation[[image], FractionalPart[2.5#]&]

3D画像の変換：

Wolfram Language code: ImageTransformation[[image], FractionalPart[2.5#]&]

スコープ  (13)

データ  (4)

グレースケールの画像を変換する：

Wolfram Language code: ImageTransformation[[image], # ^ 2&]

カラー画像を変換する：

Wolfram Language code: ImageTransformation[[image], # ^ 2&]

動画のフレームを変換する：

Wolfram Language code: ImageTransformation[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-83a60)"]\), # ^ 2&]

3D画像を変換する：

Wolfram Language code: ImageTransformation[[image], # ^ 2&]

変換関数  (7)

変換に任意の関数を使う：

Wolfram Language code: i = [image]; ImageTransformation[i, Sin[Pi #] ^ 2&]
Wolfram Language code: ImageTransformation[i, # Total[#]&]
Wolfram Language code: ImageTransformation[i, FractionalPart[2 # Total[#]]&]

と の画素位置で明示的に操作する：

Wolfram Language code: ImageTransformation[[image], {#[[1]] ^ 2, #[[2]] #[[1]]}&]

垂直次元のみを操作する：

Wolfram Language code: ImageTransformation[[image], {#[[1]], 1 - Sqrt[#[[2]]]}&]

行列変換を行う：

Wolfram Language code: ImageTransformation[[image], {{1, 1 / 2}, {2, -1}}.#&]

TransformationFunctionを使って変換を指定する：

Wolfram Language code: ImageTransformation[[image], RotationTransform[30 °]]

動画のフレームを時間と位置の関数として変換する：

Wolfram Language code: transform[t_][pos_] := FractionalPart[t 2.5pos]
Wolfram Language code: ImageTransformation[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-83a60)"]\), transform]

3D変換関数を使う：

Wolfram Language code: ImageTransformation[[image], TransformationFunction[(| | | | | | - | --- | - | - | | 1 | 0.3 | 0 | 0 | | 0 | 1 | 0 | 0 | | 0 | 0 | 1 | 0 | | 0 | 0 | 0 | 1 |)]]

サイズ  (2)

デフォルトで，出力画像は入力画像と同じ大きさになる：

Wolfram Language code: i = [image];
Wolfram Language code: ImageTransformation[i, # ^ 2&]
Wolfram Language code: ImageDimensions[i] == ImageDimensions[%]

結果の画像の大きさを指定する：

Wolfram Language code: ImageTransformation[i, # ^ 2&, 100]

幅と高さを明示的に指定する：

Wolfram Language code: ImageTransformation[i, # ^ 2&, {200, 100}]

スケールされた値を使う：

Wolfram Language code: ImageTransformation[i, # ^ 2&, Scaled[0.5]]

名前付きのサイズを使う：

Wolfram Language code: ImageTransformation[i, # ^ 2&, Tiny]

Allを使ってもとの画像と同じ大きさの画像を得る：

Wolfram Language code: ImageTransformation[[image], RotationTransform[45°, {0.5, 0.5}], #, PlotRange -> (⁠| | | | ------------------- | ------------------- | | (1/2) (1 - Sqrt[2]) | (1/2) + (1/Sqrt[2]) | | (1/2) (1 - Sqrt[2]) | (1/2) + (1/Sqrt[2]) |⁠)]& /@ {All, Automatic}

3D画像の幅を狭くして上下により長くする：

Wolfram Language code: ImageTransformation[\!\(\*Graphics3DBox[«10»]\), Identity, {Scaled[1 / 2], Scaled[1 / 2], Scaled[2]}]

オプション  (7)

Background  (1)

デフォルトで黒の背景が使われる：

Wolfram Language code: i = [image]; ImageTransformation[i, RotationTransform[-10°], Masking -> All]

背景に特定の色を使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[-10 °], Background -> Red, Masking -> All]

透過的な背景を使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[-10 °], Background -> Transparent, Masking -> All]

アルファチャンネルがある画像は，デフォルトで，透明な背景を使う：

Wolfram Language code: ImageTransformation[SetAlphaChannel[i], RotationTransform[-10 °]]

DataRange  (2)

デフォルトで，Automatic DataRangeが使われる：

Wolfram Language code: i = [image]; ImageTransformation[i, TranslationTransform[{-0.2, -0.2}], DataRange -> Automatic]

平行移動を画素座標で定義するときは，DataRangeFullを使う：

Wolfram Language code: ImageTransformation[i, TranslationTransform[{-40, -40}], DataRange -> Full]

カスタムのDataRangeを指定する：

Wolfram Language code: ImageTransformation[i, TranslationTransform[{-0.2, -0.2}], DataRange -> {{0, 1}, {0, 0.5}}]

軸について対称となるようにデータ範囲を選んで垂直の鏡映を表示する：

Wolfram Language code: ImageTransformation[i, ReflectionTransform[{0, 1}], DataRange -> #]& /@ {Automatic, {Automatic, {-.5, .5}}}

3D画像に適用された鏡映変換：

Wolfram Language code: ImageTransformation[\!\(\*Graphics3DBox[«8»]\), ReflectionTransform[{0, 0, 1}], DataRange -> {Automatic, Automatic, {-.5, .5}}]

Masking  (1)

デフォルトで，Masking->Fullが使われる．充填はもとの画像の外側の画素に使われる：

Wolfram Language code: i = [image]; ImageTransformation[i, RotationTransform[30°], Padding -> "Fixed", Masking -> Full]

Masking->Allとすると，もとの画像の外側にある画素にはBackgroundオプションの値が使われる：

Wolfram Language code: ImageTransformation[i, RotationTransform[30°], Background -> Red, Masking -> All]

任意のマスクを使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[30°], Masking -> Graphics[{White, Disk[]}, Background -> Black], Background -> Red]

PlotRange  (1)

デフォルトで，出力画像のプロット範囲は入力画像と同じになる：

Wolfram Language code: i = [image]; ImageTransformation[i, RotationTransform[45°]]

PlotRange->Allを使って変換された画像の画素をすべて見る：

Wolfram Language code: ImageTransformation[i, RotationTransform[45°], PlotRange -> All]

明示的なプロット範囲の値を使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[45°], PlotRange -> {{0, Sqrt[2]}, {-(1/Sqrt[2]), Sqrt[2] - (1/Sqrt[2])}}]

画像の中心を中心にして回転させる：

Wolfram Language code: ImageTransformation[i, RotationTransform[35°, {0.5, 0.5}]]

PlotRangeFullオプションで画素座標を使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[35°, ImageDimensions[i] / 2], PlotRange -> Full]

Padding  (1)

デフォルトで，Padding0が使われる：

Wolfram Language code: i = [image];
Wolfram Language code: ImageTransformation[i, RotationTransform[30 °], Padding -> 0]

名前付きの色を使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[30° ], Padding -> Blue]

画像の外側の値に固定充填を使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[30 ° ], Padding -> "Fixed"]

周期的充填を使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[30 ° ], Padding -> "Periodic"]

透過的な充填を使う：

Wolfram Language code: ImageTransformation[i, RotationTransform[30 ° ], Padding -> Transparent]

Resampling  (1)

デフォルトで，リサンプリングのメソッドは自動的に選択され，使用可能などのメソッドも使われ可能性がある：

Wolfram Language code: Table[Show[ImageTransformation[[image], Identity, 150, Resampling -> m], Magnification -> 1], {m, {Automatic, "NearestLeft"}}]

アプリケーション  (6)

画像のペアから変換関数を決定して未知の幾何変換をもとに戻す：

Wolfram Language code: i = [image];j = [image]; tf = FindGeometricTransform[j, i, TransformationClass -> "Rigid"][[2]]

変換された画像に変換関数を適用する：

Wolfram Language code: ImageTransformation[j, tf, DataRange -> Full]

写真をモザイクにする：

Wolfram Language code: ImageTransformation[[image], 8Floor[# / 8] + 1&, DataRange -> Full]

降雨効果を与える：

Wolfram Language code: g = Function[p, With[{C = 150., R = 35.}, {p[[1]] + (R * Cos[(p[[1]] - C) * 360 * 2 / R] / 6), p[[2]]}]]; ImageTransformation[[image], g, DataRange -> Full]

タイル表示効果を付ける：

Wolfram Language code: i = [image]; ImageTransformation[i, If[Min[FractionalPart[5 # + .5]] < .1, {-1, -1}, # - .02 Floor[5 # + .5]]&, PlotRange -> {{0, 1.1}, {0, .08 + ImageAspectRatio[i]}}, Padding -> 1]

テキスト行を垂直軸に沿って囲む：

Wolfram Language code: ImageTransformation[\!\(\*GraphicsBox[«3»]\), # + {0, .02Sin[ 20#[[1]]]}&]

充填を使って画像領域を広げる：

Wolfram Language code: ImageTransformation[\!\(\*GraphicsBox[«3»]\), # + {0, .02Sin[ 20#[[1]]]}&, Padding -> 1]

画像の鏡映：

Wolfram Language code: ImageTransformation[[image], ReflectionTransform[{1, 0}, {.5, 0}]]

特性と関係  (2)

デフォルトで，返された画像はもとの画像と同じ大きさおよび縦横比である：

Wolfram Language code: ImageTransformation[[image], 2#&]

関数とその逆関数を使った変換を行うと，補間によって少しぼやけたもとの画像が返される：

Wolfram Language code: ImageTransformation[ImageTransformation[[image], Sqrt], # ^ 2&]

インタラクティブな例題  (1)

上記の指定の代りに，自動または明示的なプロット範囲を使う：

Wolfram Language code: Manipulate[ImageTransformation[[image], Subscript[f, s / 200]], {{s, {100, 100}}, Locator}, ContinuousAction -> False, Initialization :> {Subscript[f, s_][pt_] := Module[{r = (Norm[pt - s]^2/Norm[s]), a = ArcTan@@(pt - s)}, s + r{Cos[a], Sin[a]}]}]

おもしろい例題  (6)

画像を数学的に変換する：

Wolfram Language code: ImageTransformation[[image], Sin[2Pi #] ^ 2&]
Wolfram Language code: ImageTransformation[[image], Sin[Pi #]Sin[Pi Reverse[#]]&]
Wolfram Language code: ImageTransformation[[image], Sin[3 Pi #]Sin[Pi Reverse[#]]&]

画像を戯画化する：

Wolfram Language code: f[pt_] := With[{s = {.5, .5}}, Module[{r, a}, r = Sqrt[Norm[pt - s]Max[s]];a = ArcTan@@(pt - s); s + r{Cos[a], Sin[a]}]]; ImageTransformation[[image], f]

魚眼効果：

Wolfram Language code: f[pt_] := With[{s = {0.55, 0.55}}, Module[{r, a}, r = Norm[pt - s]^2 / Norm[s];a = ArcTan@@(pt - s); s + r{Cos[a], Sin[a]}]] ImageTransformation[[image], f]

螺線状の鏡効果：

Wolfram Language code: f[pt_] := With[{s = {.5, .5}}, Module[{r, a}, r = Norm[pt - s]^2 / Max[s];a = ArcTan@@(pt - s) / Pi * 180; pt + {Mod[(a / 200 + r / 2.), 16 / 200.] - 8 / 200., 0}]] ImageTransformation[[image], f]

肖像写真を歪める：

Wolfram Language code: f[x_, y_] := {x + 10Sin[.05 x], y + 5Sin[.1 y]} ImageTransformation[[image], f@@#&, DataRange -> Full]

曲線的な歪み：

Wolfram Language code: f[pt_] := With[{s = {.5, .5}}, Module[{r, a, an}, r = Norm[pt - s];a = ArcTan@@(pt - s);an = a + 2r; s + r{Cos[an], Sin[an]}]]; ImageTransformation[[image], f]
Wolfram Research (2010), ImageTransformation, Wolfram言語関数， https://reference.wolfram.com/language/ref/ImageTransformation.html （2021年に更新）.

テキスト

Wolfram Research (2010), ImageTransformation, Wolfram言語関数， https://reference.wolfram.com/language/ref/ImageTransformation.html （2021年に更新）.

CMS

Wolfram Language. 2010. "ImageTransformation." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ImageTransformation.html.

APA

Wolfram Language. (2010). ImageTransformation. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ImageTransformation.html

BibTeX

@misc{reference.wolfram_2026_imagetransformation, author="Wolfram Research", title="{ImageTransformation}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ImageTransformation.html}", note=[Accessed: 19-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_imagetransformation, organization={Wolfram Research}, title={ImageTransformation}, year={2021}, url={https://reference.wolfram.com/language/ref/ImageTransformation.html}, note=[Accessed: 19-October-2026]}