WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

JarqueBeraALMTest[data]

Jarque–Bera ALM検定を使い，data が正規分布に従っているかどうかを調べる．

JarqueBeraALMTest[data,"property"]

"property"の値を返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
検定  
レポート  
オプション  
Method  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

JarqueBeraALMTest

JarqueBeraALMTest[data]

Jarque–Bera ALM検定を使い，data が正規分布に従っているかどうかを調べる．

JarqueBeraALMTest[data,"property"]

"property"の値を返す．

詳細とオプション

  • JarqueBeraALMTestは data がNormalDistributionから取り出されたという帰無仮説 とそうではないという対立仮説 でJarque–Bera ALMの適合度検定を行う．
  • デフォルトで，確率値つまり 値が返される．
  • 小さい 値は data が 正規分布に従っている可能性が低いことを示す．
  • data は一変量{x1,x2,…}でも多変量{{x1,y1,…},{x2,y2,…},…}でもよい．
  • Jarque–Bera ALM検定は事実上 data の歪度と尖度をNormalDistributionと比較する．
  • 一変量データについては，検定統計はで与えられる．ただし，b_1=Skewness[data]，b_2=Kurtosis[data]で，，，で与えられる有限のサンプルサイズについて 個の補正因子がある．
  • 多変量検定については，一変量限界 値の総和が使われる．総和は のもとでUniformSumDistributionに従うものと想定される．
  • JarqueBeraALMTest[data,dist,"HypothesisTestData"]はHypothesisTestDataオブジェクト htd を返す．これは htd["property"]として追加的な検定結果と特性の抽出に使うことができる．
  • JarqueBeraALMTest[data,dist,"property"]を使って直接"property"を与えることができる．
  • 検定結果のレポートに関連する特性
  • "PValue" 値
    "PValueTable""PValue"のフォーマットされたバージョン
    "ShortTestConclusion"検定結果の簡単な説明
    "TestConclusion"検定結果の説明
    "TestData"検定統計と 値
    "TestDataTable""TestData"のフォーマットされたバージョン
    "TestStatistic"検定統計
    "TestStatisticTable""TestStatistic"のフォーマットされたバージョン
  • 次の特性はどの検定が行われているかに依存しない．
  • データ分布に関連する特性
  • "FittedDistribution"データのフィットした分布
    "FittedDistributionParameters"データの分布母数
  • 使用可能なオプション
  • Method Automatic 値を計算するメソッド
    SignificanceLevel0.05診断とレポートのための切捨て
  • 適合度検定では， のときにのみ が棄却されるような切捨て が選択される．特性"TestConclusion"および"ShortTestConclusion"で使われる の値はSignificanceLevelオプションで制御される．デフォルトで， は0.05に設定されている．
  • Method->"MonteCarlo"の設定では，入力 と同じ長さの 個のデータ集合が のもとにフィットされた分布を使って生成される．次に，JarqueBeraALMTest[si,"TestStatistic"]からのEmpiricalDistributionを使って 値が推定される．

例題

すべて開く すべて閉じる

例  (3)

正規性についてのJarque–Bera ALM検定を行う：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^4];
Wolfram Language code: JarqueBeraALMTest[data]

多変量の正規性についての検定を行う：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, IdentityMatrix[3]], 1000];
Wolfram Language code: JarqueBeraALMTest[data]

Jarque–Bera ALM検定から検定統計を抽出する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^3];
Wolfram Language code: JarqueBeraALMTest[data, "TestStatistic"]

スコープ  (6)

検定  (3)

正規性についてJarque–Bera ALM検定を行う：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 10^4]; data2 = RandomVariate[GammaDistribution[10, 2], 10^4];

正規データの 値は，非正規データの 値よりも大きい：

Wolfram Language code: JarqueBeraALMTest[data1]
Wolfram Language code: JarqueBeraALMTest[data2]

多変量の正規性について検定を行う：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 10^3]; data2 = RandomVariate[LaplaceDistribution[1, 2], {10^3, 2}];
Wolfram Language code: JarqueBeraALMTest[data1]
Wolfram Language code: JarqueBeraALMTest[data2]

繰り返し特性を抽出するためにHypothesisTestDataオブジェクトを作成する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^5];
Wolfram Language code: ℋ = JarqueBeraALMTest[data, "HypothesisTestData"]

抽出に使用できる特性：

Wolfram Language code: ℋ["Properties"]

レポート  (3)

Jarque–Bera ALM検定の結果を表にする：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: ℋ = JarqueBeraALMTest[data, "HypothesisTestData"];

完全な検定表：

Wolfram Language code: ℋ["TestDataTable"]

値の表：

Wolfram Language code: ℋ["PValueTable"]

検定統計：

Wolfram Language code: ℋ["TestStatisticTable"]

カスタマイズしたレポート用にJarque–Bera ALM検定表から項目を取り出す：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 100]; data2 = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: ℋ1 = JarqueBeraALMTest[data1, "TestData"]
Wolfram Language code: ℋ2 = JarqueBeraALMTest[data2, "TestData"]
Wolfram Language code: BarChart[{Labeled[ℋ1, "Set 1"], Labeled[ℋ2, "Set 2"]}, ChartLabels -> {"SubscriptBox[D, n]", "p‐value"}]

"ShortTestConclusion"と"TestConclusion"を使って検定の結論をレポートする：

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[StudentTDistribution[3], 100]];
Wolfram Language code: ℋ = JarqueBeraALMTest[data, "HypothesisTestData"];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

有意水準が異なると，結論も異なることがある：

Wolfram Language code: ℋ = JarqueBeraALMTest[data, "HypothesisTestData", SignificanceLevel -> .001];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

オプション  (3)

Method  (3)

モンテカルロ法に基づくメソッドまたは計算式を使う：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: JarqueBeraALMTest[data, Method -> "MonteCarlo"]
Wolfram Language code: JarqueBeraALMTest[data, Method -> Automatic]

モンテカルロ法に基づくメソッドで使うサンプル数を設定する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: pts = Table[{i, JarqueBeraALMTest[data, Method -> {"MonteCarlo", "MonteCarloSamples" -> i}]}, {i, 5, 1000, 50}];

モンテカルロ推定は，サンプルを増やすと，真の 値に収束する：

Wolfram Language code: pval = JarqueBeraALMTest[data];
Wolfram Language code: ListLinePlot[{pts, {{0, pval}, {1000, pval}}}, PlotStyle -> {Automatic, Dashed}, AxesLabel -> {"# of Samples", "p-Value"}]

モンテカルロ法に基づくメソッドで使われるランダムなシードを設定する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: pts = Table[{i, JarqueBeraALMTest[data, Method -> {"MonteCarlo", "RandomSeed" -> i, "MonteCarloSamples" -> 50}]}, {i, 10}];

シードは生成器の状態に影響を与え，結果の 値にもいくらか影響を与える：

Wolfram Language code: pval = JarqueBeraALMTest[data];
Wolfram Language code: ListLinePlot[{pts, {{0, pval}, {10, pval}}}, PlotStyle -> {Automatic, Dashed}, AxesLabel -> {"Seed", "p-Value"}]

アプリケーション  (2)

Jarque–Bera ALM検定の検出力曲線：

Wolfram Language code: data = Table[RandomVariate[CauchyDistribution[0, 1], {500, i}], {i, n = {10, 15, 20, 25, 30}}];
Wolfram Language code: ℋ = Table[JarqueBeraALMTest[data[[i, j]]], {i, Length[data]}, {j, Length[data[[i]]]}];
Wolfram Language code: pC = Interpolation[Transpose[{n, Table[Probability[x ≤ 0.05, xi], {i, ℋ}]}], InterpolationOrder -> 1];

近似検出力曲線を可視化する：

Wolfram Language code: Plot[pC[x], {x, 10, 30}, PlotRange -> {0, 1}, Ticks -> {n, Automatic}, AxesOrigin -> {7, 0}]

基礎となる分布がCauchyDistribution[0,1]であり，検定サイズが0.05，サンプルサイズが12である場合に，Jarque–Bera ALM検定の検出力を推定する：

Wolfram Language code: pC[12.]

他の分布に一般化されるJarque–Bera ALM検定統計を作成する：

Wolfram Language code: jbTest[data_, c1_, c2_, c3_] := With[{n = Length[data], skew = Skewness[data], kurt = Kurtosis[data]}, n((skew^2/c1) + ((kurt - c2)^2/c3))]

，，の有限サンプル値：

Wolfram Language code: sampleCM[r_] := MomentConvert[CentralMoment[r], "SampleEstimator"]
Wolfram Language code: c1[dist_, n_] := MomentEvaluate[MomentConvert[sampleCM[3]^2, {CentralMoment, n}] / MomentConvert[sampleCM[2]^3, {CentralMoment, n}], dist]
Wolfram Language code: c2[dist_, n_] := MomentEvaluate[MomentConvert[sampleCM[4], {CentralMoment, n}] / MomentConvert[sampleCM[2] ^ 2, {CentralMoment, n}], dist]
Wolfram Language code: c3[dist_, n_] := (MomentEvaluate[MomentConvert[(sampleCM[4] - c2[dist, n] * sampleCM[2] ^ 2) ^ 2, {CentralMoment, n}] / MomentConvert[sampleCM[2] ^ 4, {CentralMoment, n}], dist])

LaplaceDistributionにフィットさせるJarque–Bera ALM検定統計：

Wolfram Language code: c1L[n_] = c1[LaplaceDistribution[μ, σ], n]; c2L[n_] = c2[LaplaceDistribution[μ, σ], n]; c3L[n_] = c3[LaplaceDistribution[μ, σ], n];
Wolfram Language code: jbGen[data_, n_] := (1/n)jbTest[data, c1L[n], c2L[n], c3L[n]]
Wolfram Language code: With[{n = 150}, T = jbGen[#, n]& /@ RandomVariate[LaplaceDistribution[1, 2], {10 ^ 4, n}]];

データの一部に一般化された検定を行う：

Wolfram Language code: With[{n = 150}, t = jbGen[#, n]& /@ RandomVariate[LaplaceDistribution[1, 2], {1000, n}]];

値は予想される通り，一様である：

Wolfram Language code: DistributionFitTest[SurvivalFunction[EmpiricalDistribution[T], t], UniformDistribution[]]

検定は，似た平均と分散を持つHyperbolicDistributionの対立仮説に対して強い：

Wolfram Language code: Histogram[Table[SurvivalFunction[EmpiricalDistribution[T], jbGen[RandomVariate[HyperbolicDistribution[4, 3, 8.36, -9.13], 150], 150]], {10 ^ 3}], Automatic, "PDF"]

特性と関係  (4)

ALM（修正されたラグランジュの乗数）法の方が，従来のJarque–Bera検定より性能が優れている：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {1000, 15}];
Wolfram Language code: s[data_] := Skewness[data]; k[data_] := Kurtosis[data] - 3;

従来のJarque–Bera検定統計：

Wolfram Language code: jb[data_] := (Length[data]/6)(s[data]^2 + (1/4)k[data]^2)
Wolfram Language code: jbpval[t_] := SurvivalFunction[ChiSquareDistribution[2], t]
Wolfram Language code: jbT = jbpval[jb[#]]& /@ data;

値は一様分布に従わない：

Wolfram Language code: Show[Histogram[jbT, Automatic, "PDF"], Graphics[{Thick, Dashed, Line[{{0, 1}, {1, 1}}]}]]
Wolfram Language code: jbalmT = JarqueBeraALMTest[#]& /@ data;

Jarque–Bera ALM検定は小さいサンプルを扱うのに優れている：

Wolfram Language code: Show[Histogram[jbalmT, Automatic, "PDF"], Graphics[{Thick, Dashed, Line[{{0, 1}, {1, 1}}]}]]

Jarque–Bera ALM検定は，従来の検定における0, 6, 3, 24の漸近値ではなく，歪度および尖度の平均と分散に有限サンプル値を使う：

Wolfram Language code: jbTest[data_, c1_, c2_, c3_] := With[{n = Length[data], skew = Skewness[data], kurt = Kurtosis[data]}, n((skew^2/c1) + ((kurt - c2)^2/c3))]
Wolfram Language code: jbTraditional[data_] := jbTest[data, 6, 3, 24]

有限サンプル値は，MomentEvaluateおよびMomentConvertを使って引き出される：

Wolfram Language code: c1 = Factor[MomentEvaluate[MomentConvert[MomentConvert[CentralMoment[3], "SampleEstimator"]^2, {CentralMoment, n}] / MomentConvert[MomentConvert[CentralMoment[2], "SampleEstimator"]^3, {CentralMoment, n}], NormalDistribution[μ, σ]]]
Wolfram Language code: jbALM[data_] := With[{n = Length[data]}, (1/n)jbTest[data, (6(n - 2)/(n + 1)(n + 3)), (3 (n - 1)/n + 1), (24 n (n - 2) (n - 3)/(n + 1)^2 (n + 3) (n + 5))]]

検定統計は，同じ漸近分布に従う：

Wolfram Language code: ListLinePlot[Table[data = RandomVariate[NormalDistribution[], n];{n, jbTraditional[data] - jbALM[data]}, {n, Join[Range[5, 100, 10], Range[101, 1000, 25], Range[1001, 10000, 100]]}], PlotRange -> All, PlotStyle -> Thick]

帰無仮説 のもとのJarque–Bera ALM統計はChiSquareDistributionに従う：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {1000, 2000}];
Wolfram Language code: T = JarqueBeraALMTest[#, "TestStatistic"]& /@ data;

統計のヒストグラムと分布の確率密度関数をプロットする：

Wolfram Language code: Show[Histogram[T, 40, "PDF"], Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 10}, PlotStyle -> Thick]]

カイ二乗分布へのフィットを検定する：

Wolfram Language code: DistributionFitTest[T, ChiSquareDistribution[2], "TestDataTable"]
Wolfram Language code: DistributionFitTest[T, ChiSquareDistribution[2], "ShortTestConclusion"]

Jarque–Bera ALM検定は入力がTimeSeriesのときにのみ値に使うことができる：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: JarqueBeraALMTest[ts]
Wolfram Language code: JarqueBeraALMTest[ts["Values"]]

考えられる問題  (1)

Jarque–Bera ALM検定は， 値が有効であるためには，9より大きいサンプルサイズを必要とする：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 9];
Wolfram Language code: JarqueBeraALMTest[data]

おもしろい例題  (1)

帰無仮説 が真である場合の統計量を計算する：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], {250, 100}];
Wolfram Language code: T1 = JarqueBeraALMTest[#, "TestStatistic"]& /@ data1;

特定の対立仮説によって与えられた検定統計量：

Wolfram Language code: data2 = RandomVariate[ChiSquareDistribution[50], {250, 100}];
Wolfram Language code: T2 = JarqueBeraALMTest[#, "TestStatistic"]& /@ data2;

検定統計量の分布を比較する：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotRange -> {{0, 40}, All}, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}, PlotRange -> All]
Wolfram Research (2010), JarqueBeraALMTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/JarqueBeraALMTest.html.

テキスト

Wolfram Research (2010), JarqueBeraALMTest, Wolfram言語関数， https://reference.wolfram.com/language/ref/JarqueBeraALMTest.html.

CMS

Wolfram Language. 2010. "JarqueBeraALMTest." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/JarqueBeraALMTest.html.

APA

Wolfram Language. (2010). JarqueBeraALMTest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/JarqueBeraALMTest.html

BibTeX

@misc{reference.wolfram_2026_jarqueberaalmtest, author="Wolfram Research", title="{JarqueBeraALMTest}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/JarqueBeraALMTest.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_jarqueberaalmtest, organization={Wolfram Research}, title={JarqueBeraALMTest}, year={2010}, url={https://reference.wolfram.com/language/ref/JarqueBeraALMTest.html}, note=[Accessed: 03-November-2026]}