	"ssh://user@hostname:port/path"	SSHを使ってアクセスできる，指定されたマシン上のカーネル
	"ssh://hostname"	指定されたマシン上のデフォルトのパス
	"hostname"	"ssh://hostname"に等しい
	"wstp://server:port/pool"	WSTPServer上のカーネル
	"wstp://server"	デフォルトのポートとカーネルプールを使う
	"Local"	デフォルトのローカルカーネル
	"localhost"	同一マシン上のカーネル
	n	n 個のローカル並列カーネル
	"file:///path/to/wolfram"	同一マシン上の指定されたカーネル
	"file://"	同一マシン上のデフォルトカーネル
	"https://www.wolframcloud.com/"	Wolfram Cloud内のカーネル
	"lwg://host.example.com:port/path"	LightweightGridサーバ上のカーネル
	"lwg://host.example.com:port"	LightweightGridマネージャへのデフォルトパスを使う
	"lwg://host.example.com"	LightweightGridサーバのデフォルトポート(3737)を使う
	LinkObject[…]	実行中のカーネルへのWSTPリンク

リモートマシンのカーネルの追加的な設定は，Wolfram Lightweight GridとCluster Integration Packageで使用できるようにすることができる．
ProgressReportingオプションは，カーネル起動の進捗レポートを行うかどうかを指定する．
デフォルト値はProgressReporting:>$ProgressReportingである．

例題

すべて開くすべて閉じる

例 (4)

デフォルトカーネルを起動する：

Wolfram Language code: LaunchKernels[]

実行中の全カーネルを終了し，デフォルトのローカルカーネルだけを起動する：

Wolfram Language code: CloseKernels[];LaunchKernels["Local"];$KernelCount

実行中の全カーネルを終了し，12個のローカルカーネルを起動する：

Wolfram Language code: CloseKernels[]; LaunchKernels[12];$KernelCount

LaunchKernelsは，デフォルトで，進捗情報を表示する：

Wolfram Language code: LaunchKernels[{"ssh://andromeda/?64", 24, "ssh://vega/?4"}];

スコープ (13)

カーネル指定 (4)

$DefaultParallelKernelsに記載されているデフォルトカーネルを起動する：

Wolfram Language code: $DefaultParallelKernels

Wolfram Language code: LaunchKernels[]

すでに実行されているものに加え，さらに2個のローカルカーネルを起動する：

Wolfram Language code: $KernelCount

Wolfram Language code: LaunchKernels[2]

Wolfram Language code: Kernels[]

リモートマシンでカーネルを起動する：

Wolfram Language code: LaunchKernels["ssh://prokyon?2"]

KernelConfigurationを使って希望するカーネルの追加的な詳細を指定する：

Wolfram Language code: LaunchKernels[KernelConfiguration["localhost", "KernelCommand" -> "wolfram141", "KernelCount" -> 4]]

Wolfram Language code: ParallelEvaluate[{First[$CommandLine], $Version}]

ローカルカーネル (3)

絶対パスで与えられた特定のローカルカーネルを使う：

Wolfram Language code: LaunchKernels["file:///usr/local/bin/wolfram141?4"]

KernelConfigurationで特性を指定することもできる：

Wolfram Language code: LaunchKernels[KernelConfiguration["localhost", "KernelCommand" -> "/usr/local/bin/wolfram141", "KernelCount" -> 2]]

ローカルカーネルについては，並列カーネルのデフォルト数は，ライセンスが許す限り$ProcessorCountに等しい：

Wolfram Language code: KernelConfiguration["Local"]["KernelCount"]

Wolfram Language code: $ProcessorCount

SSHカーネル (3)

リモートカーネルへのパスとカーネル数をURLパラメータとして取得する：

Wolfram Language code: LaunchKernels["ssh://prokyon//usr/local/bin/wolfram140?4"]

パスとカーネル数をKernelConfigurationの特性として指定することもできる：

Wolfram Language code: LaunchKernels[KernelConfiguration["ssh://prokyon", "KernelCommand" -> "/usr/local/bin/wolfram140", "KernelCount" -> 4]]

適切なカーネルコマンドを自動的に選択するためにリモートのオペレーティングシステムを指定する：

Wolfram Language code: LaunchKernels[KernelConfiguration["ssh://mac.example.com", "OperatingSystem" -> "MacOSX", "KernelCount" -> 4]]

Wolfram Language code: ParallelEvaluate[First[$CommandLine], First[Kernels[]]]

URLの短縮形を使う場合は，"?n"で並列カーネルの数が指定できる：

Wolfram Language code: LaunchKernels["ssh://andromeda?64"];

Wolfram Language code: $KernelCount

WSTPServerカーネル (1)

WSTPServerに接続して並列カーネルの数をリクエストする：

Wolfram Language code: LaunchKernels["wstp://raspi8?2"]

LWGカーネル (1)

LightweightGridサーバからデフォルトのポートとマネージャURLを使って2つの並列カーネルを起動する：

Wolfram Language code: LaunchKernels["lwg://gcov.wolfram.com?2"]

リンクカーネル (1)

並列サブカーネルとして使用可能な2つのカーネルを起動する：

Wolfram Language code: links = Table[LinkLaunch["wolfram -subkernel"], 2]

これらを並列計算に使用する：

Wolfram Language code: LaunchKernels[links]

Wolfram Language code: ParallelEvaluate[$ProcessID]

一般化と拡張 (1)

すべてのカーネルを終了する：

Wolfram Language code: CloseKernels[]

前に実行されていたカーネルのコピーを起動する：

Wolfram Language code: LaunchKernels[%]

オプション (2)

ProgressReporting (2)

一時的な進捗レポートは表示しない：

Wolfram Language code: LaunchKernels[24, ProgressReporting -> False];

$ProgressReportingのデフォルト値がFalseであっても進捗レポートを表示する：

Wolfram Language code: LaunchKernels["ssh://andromeda/?64", ProgressReporting -> True];

アプリケーション (1)

使用カーネル数を変えて同じ計算を行いスピードアップを見る：

Wolfram Language code:

Block[{$ProgressReporting = False}, 
	Table[
	CloseKernels[];LaunchKernels[n];
	{n, AbsoluteTiming[ParallelDo[Pause[0.1], {8}]][[1]]}, 
	{n, 1, 4}]
	]

特性と関係 (1)

配布された定義と共有変数は実行中のカーネルおよび新たなカーネルに適用される：

Wolfram Language code:

n = 17; DistributeDefinitions[n];
xs = 0;SetSharedVariable[xs];

Wolfram Language code: ParallelEvaluate[{n, xs++}]

ParallelNeedsで読み込まれたパッケージもまた実行中のカーネルおよび新たなカーネルに適用される：

Wolfram Language code: ParallelNeeds["ComputerArithmetic`"]

実行中のすべてのカーネルを終了し，新たなカーネルを起動する：

Wolfram Language code: CloseKernels[];LaunchKernels[]

新たなカーネルは前に配布された定義と共有変数を継承している：

Wolfram Language code: ParallelEvaluate[{n, xs++}]

新たなカーネルは先に読み込まれたパッケージも継承している：

Wolfram Language code: ParallelEvaluate[$ContextPath, First[Kernels[]]]

考えられる問題 (3)

実行中のカーネルがある場合，LaunchKernels[]はデフォルトカーネルを起動しない：

Wolfram Language code: $KernelCount

Wolfram Language code: LaunchKernels[]

実行中のすべてのカーネルを終了した後，デフォルトのカーネルを起動する：

Wolfram Language code: CloseKernels[];LaunchKernels[]

カーネルは最初に必要となったときに自動的に起動されることがある：

Wolfram Language code: $KernelCount

Wolfram Language code: ParallelTable[Prime[i], {i, 10}]

Wolfram Language code: $KernelCount

カーネルを手動で終了する：

Wolfram Language code: CloseKernels[];

これで，自動的に起動されたカーネルがなくなった：

Wolfram Language code: ParallelTable[Prime[i], {i, 10}]

使用できるカーネルがない場合，ほとんどの並列計算は連続的に行われる：

Wolfram Language code: CloseKernels[];

Wolfram Language code: ParallelTable[Prime[i], {i, 5}]

おもしろい例題 (1)

リモートマシン上のカーネルを指定する：

Wolfram Language code: threadripper = KernelConfiguration["ssh://andromeda"]

プロセッサコアの数を尋ねる：

Wolfram Language code: RemoteEvaluate[threadripper, $ProcessorCount]

返されたカーネル数でカーネル指定を更新する：

Wolfram Language code: threadripper = KernelConfiguration[threadripper, "KernelCount" -> %]

Wolfram Language code: Information[threadripper]

並列カーネルを起動する：

Wolfram Language code: LaunchKernels[threadripper];

Wolfram Language code: $KernelCount

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

LaunchKernels

詳細とオプション

例題

例 (4)