WOLFRAM

Wolfram 语言与系统参考资料中心

MatrixPropertyDistribution[expr,xmdist]

表示矩阵属性 expr 的分布，其中矩阵值随机变量 x 遵循矩阵分布 mdist.

MatrixPropertyDistribution[expr,{x1mdist1,x2mdist2,…}]

表示一个分布，其中 x1, x2, … 是遵循矩阵分布 mdist1, mdist2, … 的独立变量.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
参见
相关指南
历史
按以下格式引用：

MatrixPropertyDistribution

MatrixPropertyDistribution[expr,xmdist]

表示矩阵属性 expr 的分布，其中矩阵值随机变量 x 遵循矩阵分布 mdist.

MatrixPropertyDistribution[expr,{x1mdist1,x2mdist2,…}]

表示一个分布，其中 x1, x2, … 是遵循矩阵分布 mdist1, mdist2, … 的独立变量.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

对高斯正交矩阵 估计 的均值：

Wolfram Language code: Mean[MatrixPropertyDistribution[Tr[x.x], xGaussianOrthogonalMatrixDistribution[2]]]//N

得出随机线性系统的样本解：

Wolfram Language code: RandomVariate[MatrixPropertyDistribution[LinearSolve[m, {v1, v2, v3}], {mCircularRealMatrixDistribution[3], {v1, v2, v3}MultinormalDistribution[{0, 0, 0}, IdentityMatrix[3]]}]]

估计随机矩阵的条件数取 Log10 的分布：

Wolfram Language code: matrixCondNum[mat_] := Norm[Inverse[mat]]Norm[mat]
Wolfram Language code: log10cn = RandomVariate[MatrixPropertyDistribution[Log10[matrixCondNum[x]], xWishartMatrixDistribution[10, HilbertMatrix[5]]], 10 ^ 5];
Wolfram Language code: SmoothHistogram[log10cn, Filling -> Axis]

范围  (3)

定义一个矩阵自变量的标量值函数的分布：

Wolfram Language code: MatrixPropertyDistribution[Tr[𝓂.𝓂^], 𝓂MatrixNormalDistribution[IdentityMatrix[3], IdentityMatrix[3]]]

估计函数的均值：

Wolfram Language code: Mean[%]//N

定义一个矩阵自变量的向量值函数的分布：

Wolfram Language code: MatrixPropertyDistribution[Diagonal[𝓂], 𝓂InverseWishartMatrixDistribution[5, IdentityMatrix[3]]]

服从分布的样本：

Wolfram Language code: RandomVariate[%, 3]

从一个随机矩阵和一个随机向量中定义分布：

Wolfram Language code: cov = {{1, 1 / 2, 0}, {1 / 2, 1, 1 / 2}, {0, 1 / 2, 1}};
Wolfram Language code: 𝒟 = MatrixPropertyDistribution[{x1, x2, x3}.𝓂.{x1, x2, x3}, {𝓂WishartMatrixDistribution[100, cov], {x1, x2, x3}MultinormalDistribution[{0, 0, 0}, cov]}];

估计分布的四分点：

Wolfram Language code: RandomVariate[𝒟, 10 ^ 5]//Quartiles

应用  (4)

GaussianOrthogonalMatrixDistribution 中矩阵的样本行列式：

Wolfram Language code: n = 2; dets = RandomVariate[MatrixPropertyDistribution[Det[x], xGaussianOrthogonalMatrixDistribution[n]], 10 ^ 6];

比较直方图与已知的 PDF：

Wolfram Language code: detpdf[y_] := (1/Sqrt[2])Exp[y] Piecewise[{{Erfc[Sqrt[2 y]], y ≥ 0}, {1, y < 0}}]
Wolfram Language code: Show[Histogram[dets, {0.1}, PDF], Plot[detpdf[y], {y, -5, 4}, Exclusions -> None]]

估计 GaussianUnitaryMatrixDistribution 中的矩阵的谱密度：

Wolfram Language code: spectrum𝒟[n_] := MatrixPropertyDistribution[Eigenvalues[x], xGaussianUnitaryMatrixDistribution[n]];

已知解析式如下：

Wolfram Language code: spectralPDF[n_Integer, y_] := Sqrt[(2/π n)]Exp[-2n y ^ 2]Sum[(1/2^jj!)HermiteH[j, Sqrt[2n] y]^2, {j, 0, n - 1}]

对较小的矩阵，有典型振荡模式：

Wolfram Language code: n = 3; eigvs = Join@@RandomVariate[spectrum𝒟[n], 10 ^ 5];

把样本的直方图与已知的 PDF 进行比较：

Wolfram Language code: Show[Histogram[eigvs / (2Sqrt[n]), {0.05}, PDF], Plot[spectralPDF[n, x]//Evaluate, {x, -1.5, 1.5}]]

密度顶点数目等于矩阵尺寸：

Wolfram Language code: n = 4; eigvs = Join@@RandomVariate[spectrum𝒟[n], 10 ^ 5];
Wolfram Language code: Show[Histogram[eigvs / (2Sqrt[n]), {0.05}, PDF], Plot[spectralPDF[n, x]//Evaluate, {x, -1.5, 1.5}]]

在大矩阵的限制下，密度收敛于 WignerSemicircleDistribution：

Wolfram Language code: n = 250; eigvs = Join@@RandomVariate[spectrum𝒟[n], 10 ^ 2];
Wolfram Language code: Show[Histogram[eigvs / (2Sqrt[n]), {0.05}, PDF], Plot[PDF[WignerSemicircleDistribution[1], x], {x, -1.5, 1.5}, Exclusions -> None]]

推测黎曼 ζ 函数的零点与 Hermitian 算符和矩阵的特征值相关. 比较零点的标准化间隔和 GaussianUnitaryMatrixDistribution 中样本的标准化堆积特征值的间隔：

Wolfram Language code: n = 10 ^ 2; eigs = RandomVariate[MatrixPropertyDistribution[Take[Sort[Eigenvalues[x]], {1, 3}Quotient[n, 4]], xGaussianUnitaryMatrixDistribution[n]], 10 ^ 3];

比较标准化间隔的直方图与已知的 PDF：

Wolfram Language code: spacings = Flatten[(Differences[#] Sqrt[4 n - Most[#] ^ 2]& /@ eigs) / (2 Pi)];
Wolfram Language code: WignerSurmise[x_, 2] := 2(4 x / Pi) ^ 2 Exp[(-4 / Pi) x ^ 2]
Wolfram Language code: Show[Histogram[spacings, 50, PDF], Plot[WignerSurmise[x, 2], {x, 0, 2.5}]]

比较这个 PDF 与从第 个零（Odzlyko）开始的零级数的临界线里的 ζ 函数的零点的标准化间隔：

Wolfram Language code: zeros = TemporalData[EventSeries, {{{2.6765339564884753*^11, 2.6765339564936237*^11, 2.6765339564968164*^11, 2.67653395649862*^11, 2.6765339565015765*^11, 2.6765339565043427*^11, 2.676533956505809*^11, 2.6765339565083447*^11, 2.6765339565105847*^ ... 676533982146852*^11, 2.6765339821491986*^11, 2.6765339821520862*^11, 2.6765339821532565*^11, 2.676533982157319*^11, 2.6765339821604626*^11}}, {{0, 9999, 1}}, 1, {"Discrete", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> None}}, False, 10.3]; zlist = zeros["Values"];

检查它们确实都是零点：

Wolfram Language code: {#, RiemannSiegelZ[#]}& /@ RandomChoice[zlist, 3]

比较标准化间隔的直方图与随机矩阵的已知 PDF：

Wolfram Language code: Show[Histogram[(Differences[zlist]/2 Pi) Log[(Most[zlist]/2 Pi)], 50, PDF], Plot[WignerSurmise[x, 2], {x, 0, 2.5}]]

定义 WishartMatrixDistribution 的缩放条件数的分布：

Wolfram Language code: n = 200; wmd = WishartMatrixDistribution[n, IdentityMatrix[n, SparseArray]]; cn𝒟 = MatrixPropertyDistribution[(1/n)Sqrt[(Max[#]/Min[#])]&[Eigenvalues[𝓂]], 𝓂wmd];

对较大矩阵的缩放条件数取样并查看它是否与渐近解析式的分布一致：

Wolfram Language code: asymp𝒟 = ProbabilityDistribution[(2κ + 4/κ^3)Exp[-(2/κ) - (2/κ^2)], {κ, 0, Infinity}];
Wolfram Language code: data = RandomVariate[cn𝒟, 2000];
Wolfram Language code: Show[ Histogram[data, {0.8}, PDF], Plot[PDF[asymp𝒟, κ], {κ, 0.1, 30}, PlotRange -> All]]

渐近缩放条件数分布有有限均值：

Wolfram Language code: generalizedMean = Expectation[κ^α, κasymp𝒟, Assumptions -> 0 < α < 1]
Wolfram Language code: meanScaledCN = Limit[generalizedMean, α -> 1, Direction -> 1]

模拟 LinearSolve 是否能判定随机矩阵为病态矩阵：

Wolfram Language code: lucQ[m_] := Quiet[Check[LinearSolve[m];0, 1], LinearSolve::luc]
Wolfram Language code: condIndicators = RandomVariate[MatrixPropertyDistribution[lucQ[𝓂], 𝓂wmd], 5000];

推断随机 Wishart 矩阵是病态矩阵的概率：

Wolfram Language code: FindDistributionParameters[condIndicators, BernoulliDistribution[p]]

使用渐进分布来推测最大和最小特征值的临界比：

Wolfram Language code: (n InverseSurvivalFunction[asymp𝒟, p /. %]) ^ 2
Wolfram Research (2015)，MatrixPropertyDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html.

文本

Wolfram Research (2015)，MatrixPropertyDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html.

CMS

Wolfram 语言. 2015. "MatrixPropertyDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html.

APA

Wolfram 语言. (2015). MatrixPropertyDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_matrixpropertydistribution, author="Wolfram Research", title="{MatrixPropertyDistribution}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html}", note=[Accessed: 11-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_matrixpropertydistribution, organization={Wolfram Research}, title={MatrixPropertyDistribution}, year={2015}, url={https://reference.wolfram.com/language/ref/MatrixPropertyDistribution.html}, note=[Accessed: 11-July-2026]}