MomentOfInertia[reg,pt,v]
点 pt を通り方向が v の軸の周りを回転する領域 reg についての慣性モーメントを計算する.
MomentOfInertia[reg]
物体の中心と相対的な領域 reg についての慣性モーメント行列を計算する.
MomentOfInertia[reg,pt]
点 pt と相対的な慣性モーメント行列を計算する.
MomentOfInertia
MomentOfInertia[reg,pt,v]
点 pt を通り方向が v の軸の周りを回転する領域 reg についての慣性モーメントを計算する.
MomentOfInertia[reg]
物体の中心と相対的な領域 reg についての慣性モーメント行列を計算する.
MomentOfInertia[reg,pt]
点 pt と相対的な慣性モーメント行列を計算する.
詳細とオプション
- 慣性モーメントは,回転の慣性,断面の慣性モーメント,質量慣性モーメントとしても知られている.慣性モーメント行列は回転慣性行列あるいは角質量行列としても知られている.
- 慣性モーメントは剛体の回転加速度に対しての抵抗であり,並進加速度に対する抵抗である質量の回転類似である.
-

並進加速度 力
,加速度
,質量 

回転加速度 トルク
,回転加速度
,慣性モーメント 
- MomentOfInertia[reg,pt]は,点 pt についての慣性モーメント行列を与え,以下で与えられる.
-

2D慣性モーメント行列 
3D慣性モーメント行列 - ただし,reg は-pt 平行移動された領域 reg である.
- 慣性モーメント行列 ℐ を使い,式
を通して任意の方向 v への慣性を計算することができる.2Dでは v は
-
平面でなければならない. » - MomentOfInertiaは剛体の質量密度が一定であるという仮定の下に結果を計算する.
- 変化する質量密度
については,IntegrateあるいはNIntegrateを使い,以下の式に従って対応する慣性モーメント行列を計算する. » -
例題
すべて開く すべて閉じる例 (4)
MomentOfInertia[Ball[], {1, 1, 0}, {0, 0, 1}]Graphics3D[{Ball[], Thick, InfiniteLine[{1, 1, 0}, {0, 0, 1}]}]ベクトルが省略された場合は,その点の周りの慣性モーメント行列が与えられる:
ℐ = MomentOfInertia[Ball[], {1, 1, 0}]この行列と正規化されたベクトルを使って,任意の軸の周りの慣性モーメントを求めることができる:
{0, 0, 1}.ℐ.{0, 0, 1}点が省略された場合は,質量の中心の周りの慣性モーメント行列が与えられる:
MomentOfInertia[Ball[]]これはRegionCentroidで中心点を指定することに等しい:
MomentOfInertia[Ball[], RegionCentroid[Ball[]]]MomentOfInertia[Ball[{0, 0, 0}, r], {0, 0, 0}, {1, 1, 1}]スコープ (26)
特別な領域 (15)
長さ
,幅
のRectangle:
reg = Rectangle[{-l / 2, -w / 2}, {l / 2, w / 2}];
MomentOfInertia[reg, Assumptions -> l > 0 && w > 0]//MatrixFormRegion[reg /. {l -> 3, w -> 2}]半径
のDisk:
reg = Disk[{0, 0}, r];
MomentOfInertia[reg, Assumptions -> r > 0]//MatrixFormRegion[reg /. {r -> 1}]reg = Disk[{0, 0}, {a, b}];
MomentOfInertia[reg, Assumptions -> a > 0 && b > 0]//MatrixFormRegion[reg /. {a -> 3, b -> 2}]半径が
と
のAnnulus:
reg = Annulus[{0, 0}, {Subscript[r, 1], Subscript[r, 2]}];
MomentOfInertia[reg, Assumptions -> Subscript[r, 2] > Subscript[r, 1] > 0]//MatrixFormRegion[reg /. {Subscript[r, 1] -> 1, Subscript[r, 2] -> 2}]長さ
,半径
のStadiumShape:
reg = StadiumShape[{{-l / 2, 0}, {l / 2, 0}}, r];
MomentOfInertia[reg, Assumptions -> l > 0 && r > 0]//MatrixFormRegion[reg /. {r -> 1, l -> 2}]辺の長さが
と
の直角Triangle:
reg = Triangle[{{0, 0}, {a, 0}, {0, b}}];
MomentOfInertia[reg, Assumptions -> a > 0 && b > 0]//MatrixFormRegion[reg /. {a -> 4, b -> 3}]長さ
,幅
,高さ
のCuboid:
body = Cuboid[{-l / 2, -w / 2, -h / 2}, {l / 2, w / 2, h / 2}];
MomentOfInertia[body, Assumptions -> l > 0 && w > 0 && h > 0]//MatrixFormRegion[body /. {l -> 3, w -> 2, h -> 1}]半径
のBall:
body = Ball[{0, 0, 0}, r];
MomentOfInertia[body, Assumptions -> r > 0]//MatrixFormRegion[body /. {r -> 1}]半軸が
,
,
のEllipsoid:
body = Ellipsoid[{0, 0, 0}, {a, b, c}];
MomentOfInertia[body, Assumptions -> a > 0 && b > 0 && c > 0]//MatrixFormRegion[body /. {a -> 5, b -> 4, c -> 3}]半径が
と
のSphericalShell:
body = SphericalShell[{0, 0, 0}, {Subscript[r, 1], Subscript[r, 2]}];
MomentOfInertia[body, Assumptions -> Subscript[r, 2] > Subscript[r, 1] > 0]//MatrixFormGraphics3D[{Opacity[0.7], body /. {Subscript[r, 1] -> 1, Subscript[r, 2] -> 2}}]長さ
,半径
のCylinder:
body = Cylinder[{{-l / 2, 0, 0}, {l / 2, 0, 0}}, r];
MomentOfInertia[body, Assumptions -> l > 0 && r > 0]//MatrixFormRegion[body /. {r -> 1, l -> 2}]長さ
,半径
のCapsuleShape:
body = CapsuleShape[{{-l / 2, 0, 0}, {l / 2, 0, 0}}, r];
MomentOfInertia[body, Assumptions -> l > 0 && r > 0]//MatrixFormRegion[body /. {r -> 1, l -> 2}]辺の長さが
,
,
の直角Tetrahedron:
body = Tetrahedron[{{0, 0, 0}, {a, 0, 0}, {0, b, 0}, {0, 0, c}}];
MomentOfInertia[body, Assumptions -> a > 0 && b > 0 && c > 0]//MatrixFormRegion[body /. {a -> 5, b -> 4, c -> 3}]辺の長さが
と
,高さが
の直角Pyramid:
body = Pyramid[{{-a / 2, -b / 2, 0}, {a / 2, -b / 2, 0}, {a / 2, b / 2, 0}, {-a / 2, b / 2, 0}, {0, 0, h}}];
MomentOfInertia[body, Assumptions -> a > 0 && b > 0 && h > 0]//MatrixFormRegion[body /. {a -> 5, b -> 4, h -> 3}]辺の長さが
と
,高さが
の直角Prism:
body = Prism[{{0, -b / 2, h}, {-a / 2, -b / 2, 0}, {a / 2, -b / 2, 0}, {0, b / 2, h}, {-a / 2, b / 2, 0}, {a / 2, b / 2, 0}}];
MomentOfInertia[body, Assumptions -> a > 0 && b > 0 && h > 0]//MatrixFormRegion[body /. {a -> 5, b -> 4, h -> 3}]数式定義領域 (2)
ImplicitRegionとして表現される円板の慣性行列:
MomentOfInertia[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]]MomentOfInertia[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}], {1, 1, 1}, {1, 1, 1}]ParametricRegionとして表現される円板の慣性モーメント:
MomentOfInertia[ParametricRegion[{r Cos[θ], r Sin[θ]}, {{r, 0, 1}, {θ, 0, 2π}}], {1, 1}, {1, 2}]MomentOfInertia[ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}], {1, 1}, {1, 2}]MomentOfInertia[ParametricRegion[{r Cos[θ], r Sin[θ], z}, {{r, 0, 1}, {θ, 0, 2π}, {z, 0, 2}}], {1, 1, 1}, {1, 2, 3}]メッシュ領域 (2)
2DにおけるMeshRegionの慣性モーメント行列:
reg = DelaunayMesh[RandomReal[1, {10, 2}]]MomentOfInertia[reg]reg = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2, 3, 4, 2}}]}]MomentOfInertia[reg]reg = DelaunayMesh[RandomReal[1, {20, 3}]]MomentOfInertia[reg]MomentOfInertia[reg, {1, 0, 1}]BoundaryMeshRegionの慣性モーメント行列:
reg = ConvexHullMesh[RandomReal[1, {10, 2}]]MomentOfInertia[reg]reg = ConvexHullMesh[RandomReal[1, {30, 3}]]MomentOfInertia[reg]派生領域 (3)
RegionIntersectionの慣性モーメント:
reg = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];Region[reg]MomentOfInertia[reg, {0, 0}, {1, 0}]TransformedRegionの慣性モーメント行列:
reg = TransformedRegion[Disk[{0, 0}, 1], ShearingTransform[Pi / 3, {1, 0}, {0, 1}]];Region[reg]MomentOfInertia[reg]RegionBoundaryの慣性モーメント行列:
reg = RegionBoundary[Simplex[2]];Region[reg]MomentOfInertia[reg]地理的領域 (2)
MomentOfInertiaは地理実体の多角形に使うことができる:
ℛ = Polygon[["france"]];MomentOfInertia[ℛ]GeoPositionを使った多角形:
ℛ = Polygon[GeoPosition[{{{40.083441, -88.235716}, {40.083607, -88.257488}, {40.082603, -88.257149},
{40.076136999999996, -88.25740499999999}, {40.076178, -88.270888}, {40.076516, -88.271558},
{40.083686, -88.271512}, {40.083659999999995, -88.267046}, ... 33323}, {40.098112, -88.228687},
{40.095216, -88.228627}, {40.095179, -88.238547}, {40.094480999999995, -88.238546},
{40.094508999999995, -88.23267}, {40.094106, -88.232556}, {40.090666999999996, -88.232477},
{40.090741, -88.235745}}}]];MomentOfInertia[ℛ]GeoPositionXYZを使った多角形:
ℛ = Polygon[GeoPositionXYZ[{{{150451.6968462432, -4.884430486484052*^6, 4.085078564164219*^6},
{148595.27532671497, -4.884475441490381*^6, 4.085092666620835*^6},
{148626.35829777512, -4.884546311005128*^6, 4.0850073717259285*^6},
{148618.5908634042 ... 7*^6, 4.0860187668081024*^6},
{150697.56410771207, -4.8836599487428395*^6, 4.085984535480795*^6},
{150711.88303095422, -4.883905546449982*^6, 4.0856924143435075*^6},
{150433.15479548014, -4.883908845676418*^6, 4.0856987003255524*^6}}}]];MomentOfInertia[ℛ]GeoPositionENUを使った多角形:
ℛ = Polygon[GeoPositionENU[{{{3378.2547059731055, -3369.2234780923936, -0.7440009205072329},
{1521.3211635380246, -3351.391253626573, -0.022340134218666208},
{1550.2571145363192, -3462.8657556618973, -0.08899812728964207},
{1528.5672303494055, -418 ... 63383291193, -0.37494203351275246},
{3654.121991908476, -2566.7472331234085, -0.5214977847472255},
{3375.420726854886, -2558.6597093173914, -0.3648706331350695}}},
GeoPosition[{40.11379115639895, -88.2753251202516, -1.0415787873318691}]]];MomentOfInertia[ℛ]GeoGridPositionを使った多角形の慣性モーメント:
ℛ = Polygon[GeoGridPosition[{{{-0.9950503945490105, 1.2366760550756015},
{-0.9952074890903578, 1.2369207053693891}, {-0.9952196732768064, 1.2369073327446167},
{-0.9953160063787643, 1.236848436956935}, {-0.9954141759436825, 1.2369993898475449},
{-0. ... 197645333103}, {-0.9949098578570917, 1.2368130881428654},
{-0.9948663952535768, 1.2367477711687371}, {-0.9948714472169538, 1.2367426500757825},
{-0.9949211061652593, 1.2367089232486177}, {-0.9949439717990124, 1.236746107097628}}}, "Bonne"]];MomentOfInertia[ℛ]CSG領域 (1)
2DのCSGRegionの慣性モーメント行列:
ℛ = CSGRegion["Difference", {Disk[], Rectangle[{-1 / 2, -1 / 2}]}]MomentOfInertia[ℛ]ℛ = CSGRegion["Difference", {Cube[2], Cylinder[{{0, 2, 0}, {0, -2, 0}}, 1 / 2]}]MomentOfInertia[ℛ]細分割領域 (1)
2DのSubdivisionRegionの慣性モーメント行列:
ℛ = SubdivisionRegion[Rectangle[]]MomentOfInertia[ℛ]ℛ = SubdivisionRegion[Tetrahedron[]]MomentOfInertia[ℛ]アプリケーション (11)
MomentOfInertiaは質量密度が一定して1である物体の慣性モーメントを与える.長さ
,幅
,高さ
で質量密度が一定して
であるCuboidの慣性モーメントを計算する:
body = Cuboid[{-l / 2, -w / 2, -h / 2}, {l / 2, w / 2, h / 2}];
(ℐ = ρ MomentOfInertia[body, Assumptions -> l > 0 && w > 0 && h > 0])//MatrixForm質量密度が
の物体の質量はm=ρ Volume[body]で与えられる.慣性モーメントを物体の質量
を使って表す:
m Cancel[ℐ / (ρ Volume[body])]//MatrixFormreg = Triangle[{{-1, 0}, {2, 0}, {0, 3}}];
reg3D = RegionProduct[reg, Point[{0}]];
(ℐ = MomentOfInertia[reg3D])//MatrixForm上部左の2×2部分行列は2D領域の慣性モーメントと同値である:
MomentOfInertia[reg]//MatrixForm行列のその他の唯一の非零項目は対角上にある.これは
軸周りの部分の極モーメントであり,垂直軸定理によって対角上の他の2項目の合計に等しい:
ℐ[[3, 3]] == ℐ[[1, 1]] + ℐ[[2, 2]]Graphics3D[{Opacity[0.7], reg3D}, ImageSize -> Tiny]物体の主軸は慣性モーメント行列の固有ベクトルによって与えられる:
reg = CapsuleShape[{{1, 1, 1}, {1, 2, 3.}}, 1];
rimat = MomentOfInertia[reg]principalaxes = Eigenvectors[rimat]Graphics3D[{Blue, Opacity[.3], reg, Red, Thick, InfiniteLine[RegionCentroid[reg], #]& /@ principalaxes}]慣性モーメント行列が対角行列の場合,主軸は座標軸に一致する:
reg = CapsuleShape[{{1, 1, 1}, {1, 1, 3}}, 1];
rimat = MomentOfInertia[reg]principalaxes = Eigenvectors[rimat]Graphics3D[{Blue, Opacity[.3], reg, Red, Thick, InfiniteLine[RegionCentroid[reg], #]& /@ principalaxes}]慣性モーメント行列はEllipsoidを定義する行列であると考えることができる:
reg = CapsuleShape[{{1, 1, 1}, {1, 2, 3}}, 1];
ℐ = MomentOfInertia[reg];慣性楕円体は
として定義することができる.ただし,
は重心である:
inertiaellipsoid = Ellipsoid[RegionCentroid[reg], Inverse[ℐ]];Eigensystemを使って主軸を求める:
principalaxes = Eigenvectors[ℐ]Graphics3D[{{Blue, Opacity[.3], reg}, Red, inertiaellipsoid, Green, InfiniteLine[RegionCentroid[reg], #]& /@ principalaxes}]回転剛体の角運動量は
で与えられる.ただし,
は慣性モーメントであり,
は角速度である.半径が1で一様密度が1の球体が
軸の周囲を長さが調節可能な
である紐の上で回転すると仮定する.
のとき,角速度は
である.角速度
を
の関数として求める:
Graphics3D[{{Ball[{10, 0, 0}]}, Line[{{0, 0, 0}, {10, 0, 0}}], {Dashed, Blue, Line[Table[10{Cos[2k Pi / 99], Sin[2k Pi / 99], 0}, {k, 100}]]}, {Red, Arrow[Tube[{{0, 0, -2}, {0, 0, 2}}]]}}, ImageSize -> Small]ℐ = MomentOfInertia[Ball[{r, 0, 0}], {0, 0, 0}, {0, 0, 1}, Assumptions -> r > 0]物体にトルクが適用されなければその角運動量
は一定のままであるという角運動量保存則に従って
を計算する:
Solve[ℐ ω == (ℐ /. r -> 10)1, ω]Plot[ω /. %[[1]], {r, 2, 12}, AxesOrigin -> {0, 0}]回転剛体の運動エネルギーは
で与えられる.ただし,
は慣性モーメントで
は角速度である.半径
で一様密度
の球体が角速度
で中心を通る軸の周りを回転する際の運動エネルギーを計算する:
ℐ = ρ MomentOfInertia[Ball[{0, 0, 0}, r], {0, 0, 0}, {0, 0, 1}, Assumptions -> r > 0]energy = (ℐ ω^2/2)運動エネルギー回生システム(KERS)は,ブレーキをかけたときの車の運動エネルギーを保存する.エネルギーは半径
,長さ
の回転スチールシリンダーに保存されると仮定する.スチールの密度が
であると仮定すると,
のエネルギーを保存するためには,このシリンダーはどの程度の速度で回転しなければならないだろうか:
cyl = Cylinder[{{0, 0, 0}, {50, 0, 0}}, 20];Graphics3D[{{Opacity[0.5], cyl}, {Red, Arrow[Tube[{{0, 0, 0}, {70, 0, 0}}]]}}, ImageSize -> Small]ρ = Quantity[7.8, "Grams" / "Centimeters" ^ 3];
ℐ = ρ Quantity[MomentOfInertia[cyl, {0, 0, 0}, {1, 0, 0}], "Centimeters" ^ 5]Solve[(ℐ ω^2/2) == Quantity[1, "KilowattHours"] && ω > 0, ω]UnitConvert[Quantity[ω , "Radians"] /. First[%], "rpm"]剛体の運動エネルギーは
で与えられる.ただし,
は角速度で
は慣性モーメント行列である.辺の長さが 2,4,6 の直方体が異なる軸の周りを回転する際の回転エネルギーを求める.どの場合も,回転物体の質量は等しいが,回転軸と相対的にどのように質量が分配されるかは異なり,慣性モーメントで表される:
ℐ = MomentOfInertia[Cuboid[{-1, -2, -3}, {1, 2, 3}], {0, 0, 0}]{1, 0, 0}.ℐ.{1, 0, 0}Graphics3D[{{Opacity[0.5], Cuboid[{-1, -2, -3}, {1, 2, 3}]}, {Red, Arrow[Tube[{{0, 0, 0}, {3, 0, 0}}]]}}]{0, 1, 0}.ℐ.{0, 1, 0}Graphics3D[{{Opacity[0.5], Cuboid[{-1, -2, -3}, {1, 2, 3}]}, {Green, Arrow[Tube@{{0, 0, 0}, {0, -4, 0}}]}}]{0, 0, 1}.ℐ.{0, 0, 1}Graphics3D[{{Opacity[0.5], Cuboid[{-1, -2, -3}, {1, 2, 3}]}, {Blue, Arrow[Tube@{{0, 0, 0}, {0, 0, 5}}]}}]回転剛体について,トルク
と角加速度
の関係は
で与えられる.ただし,
は慣性モーメントである.一辺の長さが1メートルで角加速度が
の鉛の立方体に必要なトルクを計算する:
cube = Cuboid[{-1 / 2, -1 / 2, -1 / 2}, {1 / 2, 1 / 2, 1 / 2}];
Graphics3D[{{Opacity[0.5], cube}, {Red, Arrow[Tube@{{0, 0, -1}, {0, 0, 1}}]}}]ρ = Quantity[11.34, "Grams" / "Centimeters" ^ 3];
ℐ = ρ Quantity[MomentOfInertia[cube, {0, 0, 0}, {0, 0, 1}], "Meters" ^ 5]α = Quantity[1, 1 / "Seconds" ^ 2];
τ = ℐ αUnitConvert[%, "Newtons" * "Meters"]平行軸の定理は,任意の軸の周りの慣性モーメント
と物体の中心を通る平行軸の周りの慣性モーメント
の関係
を与える.ただし,
は総質量で
は軸の間の距離である:
body = Cylinder[{{1, 2, 3}, {4, 5, 6}}, 7];
c = RegionCentroid[body];
p = {2, 2, 2};
v = {2, 1, 0};axis = InfiniteLine[p, v];
axis0 = InfiniteLine[c, v];
Graphics3D[{{Opacity[0.5], body}, {Green, axis}, {Blue, axis0}, {Red, Point[c]}}]MomentOfInertia[body, p, v] == MomentOfInertia[body, c, v] + RegionMeasure[body] RegionDistance[axis, c] ^ 2特性と関係 (11)
点が省略された場合は,RegionCentroidがデフォルトであると解釈される:
body = Cuboid[];MomentOfInertia[body] == MomentOfInertia[body, RegionCentroid[body]]指定された点
について,物体を
だけ平行移動して原点の周りの慣性モーメントを計算しても同じ結果が得られる:
body = Cylinder[];
pt = {1, 2, 3};MomentOfInertia[body, pt] == MomentOfInertia[TransformedRegion[body, TranslationTransform[-pt]], {0, 0, 0}]body = Pyramid[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}];
pt = {1, 1, 1}; v = {1, 2, 3};Integrate[RegionDistance[InfiniteLine[pt, v], {x, y, z}] ^ 2, {x, y, z}∈body] == MomentOfInertia[body, pt, v]body = Tetrahedron[{{1, 0, 0}, {1, 0, 1}, {1, 1, 1}, {0, 0, 1}}];Integrate[{{y ^ 2 + z ^ 2, -x y, -x z}, {-y x, x ^ 2 + z ^ 2, -y z}, {-z x, -z y, x ^ 2 + y ^ 2}}, {x, y, z}∈body] == MomentOfInertia[body, {0, 0, 0}]Integrateを使って質量密度
が変化する物体についての慣性モーメントを計算する:
body = Ball[{0, 0, 0}, r];ρ = Exp[-x^2]Exp[-y^2]Exp[-z^2];Integrate[{{y ^ 2 + z ^ 2, -x y, -x z}, {-y x, x ^ 2 + z ^ 2, -y z}, {-z x, -z y, x ^ 2 + y ^ 2}}ρ, {x, y, z}∈body, Assumptions -> r > 0]MomentOfInertia[Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}]]SymmetricMatrixQ[%]MomentOfInertia[Tetrahedron[{{1, 0, 0}, {1, 0, 1}, {1, 1, 1}, {0, 0, 1}}]]PositiveSemidefiniteMatrixQ[%]2Dの慣性モーメント行列はRegionMomentを使って計算することができる:
reg = Ellipsoid[{1, 2}, {{1, 2}, {-3, 2}}];
reg0 = TransformedRegion[reg, TranslationTransform[-RegionCentroid[reg]]];
m[ind_] := RegionMoment[reg0, ind]{{m[{0, 2}], -m[{1, 1}]}, {-m[{1, 1}], m[{2, 0}]}}MomentOfInertia[reg] == %3Dの慣性モーメント行列はRegionMomentを使って計算することができる:
reg = Parallelepiped[{1, 2, 3}, {{1, 1, 0}, {1, 0, 1}, {0, 1, 1}}];
reg0 = TransformedRegion[reg, TranslationTransform[-RegionCentroid[reg]]];
m[ind_] := RegionMoment[reg0, ind]{{m[{0, 2, 0}] + m[{0, 0, 2}], -m[{1, 1, 0}], -m[{1, 0, 1}]}, {-m[{1, 1, 0}], m[{2, 0, 0}] + m[{0, 0, 2}], -m[{0, 1, 1}]}, {-m[{1, 0, 1}], -m[{0, 1, 1}], m[{2, 0, 0}] + m[{0, 2, 0}]}}MomentOfInertia[reg] == %Pointの慣性モーメントは点から軸までの距離の二乗である:
point = {1, 2, 3};
pt = {0, 0, 0};
v = {1, 1, 1};
axis = InfiniteLine[pt, v];MomentOfInertia[Point@point, pt, v] == RegionDistance[axis, point] ^ 2pts = Tuples[Range[5], 3];MomentOfInertia[Point@pts, pt, v] == Total[RegionDistance[axis, pts] ^ 2]bodies = {Cuboid[], Ball[{2, 2, 2}]};
pt = {0, 0, 0};
v = {1, 1, 1};MomentOfInertia[RegionUnion@@bodies, pt, v] == Total[MomentOfInertia[#, pt, v]& /@ bodies]Graphics3D[{{Opacity[0.7], bodies}, {Red, InfiniteLine[pt, v]}}]テキスト
Wolfram Research (2016), MomentOfInertia, Wolfram言語関数, https://reference.wolfram.com/language/ref/MomentOfInertia.html.
CMS
Wolfram Language. 2016. "MomentOfInertia." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MomentOfInertia.html.
APA
Wolfram Language. (2016). MomentOfInertia. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MomentOfInertia.html
BibTeX
@misc{reference.wolfram_2026_momentofinertia, author="Wolfram Research", title="{MomentOfInertia}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/MomentOfInertia.html}", note=[Accessed: 11-November-2026]}
BibLaTeX
@online{reference.wolfram_2026_momentofinertia, organization={Wolfram Research}, title={MomentOfInertia}, year={2016}, url={https://reference.wolfram.com/language/ref/MomentOfInertia.html}, note=[Accessed: 11-November-2026]}