WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

OrnsteinUhlenbeckProcess[μ,σ,θ]

長期平均μ，ボラティリティsigma，平均回帰速度 θ の定常Ornstein–Uhlenbeck過程を表す．

OrnsteinUhlenbeckProcess[μ,σ,θ,x0]

初期条件 x0のOrnstein–Uhlenbeck過程を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
過程スライス特性  
一般化と拡張  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

OrnsteinUhlenbeckProcess

OrnsteinUhlenbeckProcess[μ,σ,θ]

長期平均μ，ボラティリティsigma，平均回帰速度 θ の定常Ornstein–Uhlenbeck過程を表す．

OrnsteinUhlenbeckProcess[μ,σ,θ,x0]

初期条件 x0のOrnstein–Uhlenbeck過程を表す．

詳細

例題

すべて開く すべて閉じる

例  (3)

ランダムな初期条件でOrnstein–Uhlenbeck過程のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[0, .1, .3], {0, 10, .1}]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

固定初期条件で：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[0, .1, .3, 1], {0, 20, .1}];
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

平均値関数と分散関数：

Wolfram Language code: Mean[OrnsteinUhlenbeckProcess[μ, σ, θ][t]]
Wolfram Language code: Variance[OrnsteinUhlenbeckProcess[μ, σ, θ][t]]

固定初期条件で：

Wolfram Language code: Mean[OrnsteinUhlenbeckProcess[μ, σ, θ, x][t]]
Wolfram Language code: Variance[OrnsteinUhlenbeckProcess[μ, σ, θ, x][t]]

共分散関数：

Wolfram Language code: CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]
Wolfram Language code: Plot3D[CovarianceFunction[OrnsteinUhlenbeckProcess[0, 1, .2], s, t], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

固定初期条件で：

Wolfram Language code: CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ, x], s, t]
Wolfram Language code: Plot3D[CovarianceFunction[OrnsteinUhlenbeckProcess[0, 1, .2, 1], s, t], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

スコープ  (12)

基本的な用法  (7)

経路の集合のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[.3, .5, .4], {0, 1, 0.01}, 4]
Wolfram Language code: ListLinePlot[data, Filling -> Axis]

任意精度でシミュレーションを行う：

Wolfram Language code: RandomFunction[OrnsteinUhlenbeckProcess[1 / 10, 1 / 3, 1 / 2], {0, 1, 1 / 4}, WorkingPrecision -> 20]["Path"]

さまざまな値の平均回帰速度について経路を比較する：

Wolfram Language code: sample[θ_] := (SeedRandom[14];RandomFunction[OrnsteinUhlenbeckProcess[0, 1, θ], {0, 1, .01}])
Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["θ = ", ToString[#]]]& /@ {.1, 1, 10}

さまざまな始点について過程のシミュレーションを行う：

Wolfram Language code: points = {-2, -1, 0, 1}; sample[x_] := RandomFunction[OrnsteinUhlenbeckProcess[0, .5, .3, x], {0, 10, 0.1}];
Wolfram Language code: ListLinePlot[sample[#]& /@ points, PlotRange -> All, Filling -> Axis, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ points)]

過程母数の推定：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[0.8, 1, .2], {0, 1000, 0.01}];
Wolfram Language code: EstimatedProcess[data, OrnsteinUhlenbeckProcess[μ, σ, θ]]

次の推定法を使うことができる：

Wolfram Language code: m = {"LeastSquares", "MaximumConditionalLikelihood"};
Wolfram Language code: FindProcessParameters[data, OrnsteinUhlenbeckProcess[μ, σ, θ, x0], ProcessEstimator -> #]& /@ m

相関関数：

Wolfram Language code: CorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]

固定された始点について：

Wolfram Language code: CorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]], s, t]

絶対相関関数：

Wolfram Language code: AbsoluteCorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]

固定された始点について：

Wolfram Language code: AbsoluteCorrelationFunction[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]], s, t]

過程スライス特性  (5)

一変量SliceDistribution：

Wolfram Language code: OrnsteinUhlenbeckProcess[μ, σ, θ][t]

確率密度関数は時間に依存しない：

Wolfram Language code: Plot[PDF[OrnsteinUhlenbeckProcess[0, 1, 1 / 3][t], x], {x, -3, 3}, Filling -> Axis]
Wolfram Language code: PDF[OrnsteinUhlenbeckProcess[μ, σ, θ][t], x]

固定された始点について：

Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, x0], t]

確率密度関数は時間に依存しない：

Wolfram Language code: Plot[Evaluate@Table[PDF[OrnsteinUhlenbeckProcess[0, 1, .5, 2][t], x], {t, {1 / 2, 1, 2}}], {x, -3, 3}, Filling -> Axis, PlotLegends -> {"t = 1/2", "t = 1", "t = 2"}]
Wolfram Language code: PDF[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]][t], x]

多変量スライス分布：

Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[0, 1, 2], {s, t}]

固定された始点について：

Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[0, 1, 2, 1], {1, 2, 3}]
Wolfram Language code: Mean[%]

式の期待値を計算する：

Wolfram Language code: Expectation[x[t] + x[t] ^ 2, xOrnsteinUhlenbeckProcess[μ, σ, θ]]//Simplify

ある事象の確率を計算する：

Wolfram Language code: Probability[x[t] > -1, xOrnsteinUhlenbeckProcess[μ, σ, θ]]

歪度と尖度は一定である：

Wolfram Language code: Skewness[OrnsteinUhlenbeckProcess[μ, σ, θ][t]]
Wolfram Language code: Skewness[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]][t]]
Wolfram Language code: Kurtosis[OrnsteinUhlenbeckProcess[μ, σ, θ][t]]
Wolfram Language code: Kurtosis[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]][t]]

次数rのモーメント：

Wolfram Language code: Moment[OrnsteinUhlenbeckProcess[μ, σ, θ][t], r]

母関数：

Wolfram Language code: CharacteristicFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]
Wolfram Language code: MomentGeneratingFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

CentralMomentとその母関数：

Wolfram Language code: CentralMoment[OrnsteinUhlenbeckProcess[μ, σ, θ][t], r]
Wolfram Language code: CentralMomentGeneratingFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

FactorialMomentは，記号次数では閉形式がない：

Wolfram Language code: FactorialMoment[OrnsteinUhlenbeckProcess[μ, σ, θ][t], r]
Wolfram Language code: FactorialMoment[OrnsteinUhlenbeckProcess[μ, σ, θ][t], 3]
Wolfram Language code: FactorialMomentGeneratingFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

Cumulantとその母関数：

Wolfram Language code: Cumulant[OrnsteinUhlenbeckProcess[μ, σ, θ][t], r]
Wolfram Language code: CumulantGeneratingFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

一般化と拡張  (1)

Ornstein–Uhlenbeck過程の二次変換：

Wolfram Language code: 𝒫 = TransformedProcess[p[2t + 1] ^ 2 + 3, pOrnsteinUhlenbeckProcess[0, 1, 0.2], t];

この変換過程のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[𝒫, {0, 30, 0.1}, 3];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]

平均値関数と分散関数は一定である：

Wolfram Language code: {Mean[𝒫[t]], Variance[𝒫[t]]}

過程のスライスのシミュレーションを行うことで，結果を証明する：

Wolfram Language code: data1 = RandomVariate[𝒫[1.9], 2000];
Wolfram Language code: {Mean[data1], Variance[data1]}

特性と関係  (9)

ランダムな値から始まるOrnsteinUhlenbeckProcessは弱定常である：

Wolfram Language code: WeakStationarity[OrnsteinUhlenbeckProcess[μ, σ, θ]]

固定値から始まる過程は弱定常ではない：

Wolfram Language code: WeakStationarity[OrnsteinUhlenbeckProcess[μ, σ, θ, a]]

定常Ornstein–Uhlenbeck過程のパワースペクトル：

Wolfram Language code: FourierTransform[CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], h], h, ω, FourierParameters -> {1, 1}]

Ornstein–Uhlenbeckには，明確なStationaryDistributionが含まれる：

Wolfram Language code: StationaryDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ]]

固定した始点で：

Wolfram Language code: StationaryDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, a]]

Ornstein–Uhlenbeck過程は独立増分は持たない：

Wolfram Language code: proc = OrnsteinUhlenbeckProcess[μ, σ, θ];
Wolfram Language code: Expectation[(x[t2] - x[t1])(x[t4] - x[t3]), xproc, Assumptions -> 0 < t1 < t2 < t3 < t4]//Simplify

期待値の積と比較する：

Wolfram Language code: Expectation[(x[t2] - x[t1]), xproc, Assumptions -> 0 < t1 < t2] * Expectation[(x[t4] - x[t3]), xproc, Assumptions -> 0 < t3 < t4]
Wolfram Language code: % === %%

固定された始点で：

Wolfram Language code: proc = OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]];
Wolfram Language code: Expectation[(x[t2] - x[t1])(x[t4] - x[t3]), xproc, Assumptions -> 0 < t1 < t2 < t3 < t4]//Simplify

期待値の積と比較する：

Wolfram Language code: Expectation[(x[t2] - x[t1]), xproc, Assumptions -> 0 < t1 < t2] * Expectation[(x[t4] - x[t3]), xproc, Assumptions -> 0 < t3 < t4]
Wolfram Language code: % === %%

制約条件付き累積分布関数：

Wolfram Language code: Table[Plot[Evaluate@Probability[(x[5] <= Subscript[x, 2])(x[2] == Subscript[x, 1]), xOrnsteinUhlenbeckProcess[0, 1, .2]], {Subscript[x, 2], -4, 6}, Filling -> Axis, PlotLabel -> StringJoin["SubscriptBox[x, 1] = ", ToString[Subscript[x, 1]]]], {Subscript[x, 1], {-1.5, -.4, 1.3, 3}}]
Wolfram Language code: Probability[(x[Subscript[t, 2]] ≤ Subscript[x, 2])(x[Subscript[t, 1]] == Subscript[x, 1]), xOrnsteinUhlenbeckProcess[μ, σ, θ], Assumptions -> 0 < Subscript[t, 1] < Subscript[t, 2] && 0 ≤ Subscript[x, 1] ≤ Subscript[t, 1] && 0 ≤ Subscript[x, 2] ≤ Subscript[t, 2]]//Simplify

固定された初期条件があるOrnstein–Uhlenbeckは，特殊なItoProcessである：

Wolfram Language code: ItoProcess[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]]]

特殊なStratonovichProcessでもある：

Wolfram Language code: StratonovichProcess[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]]]

Ornstein–Uhlenbeck過程は，確率微分方程式の解である：

Wolfram Language code: μ = 1.2;σ = 0.3;θ = 1;T = 5;
Wolfram Language code: noisysol = RandomFunction[OrnsteinUhlenbeckProcess[μ, σ, θ, 2], {0, T, 0.01}, 10 ^ 2]; meanFunction = TimeSeriesThread[Mean, noisysol];
Wolfram Language code: Show[ListLinePlot[noisysol, PlotStyle -> Directive[Opacity[.1]]], ListLinePlot[meanFunction, PlotStyle -> Directive[Black, Thick]]]

対応する平滑化解と比較する：

Wolfram Language code: smoothsol = NDSolve[{P'[t] == θ(μ - P[t]), P[0] == 2}, P, {t, 0, T}]
Wolfram Language code: Plot[P[t] /. smoothsol, {t, 0, T}, PlotRange -> {0.5, 2.5}]

3引数のOrnstein–Uhlenbeckは平均エルゴードである：

Wolfram Language code: proc = OrnsteinUhlenbeckProcess[μ, σ, θ];

この過程は弱定常である：

Wolfram Language code: WeakStationarity[proc]

絶対相関関数を計算する：

Wolfram Language code: abscorr[h_] = AbsoluteCorrelationFunction[proc, h]

ストリップ積分の値を求める：

Wolfram Language code: int[t_] = 1 / (2 * t)Integrate[(1 - Abs[u] / (2 * t))abscorr[u], {u, -2 * t, 2 * t}, Assumptions -> t > 0 && θ > 0]

この過程は μ=0についてのみ平均エルゴードである：

Wolfram Language code: Limit[int[t], t -> ∞, Assumptions -> θ > 0]

整数時におけるOrnstein–Uhlenbeck過程は，一次ARProcessとして振る舞う：

Wolfram Language code: ou = OrnsteinUhlenbeckProcess[μ, σ, θ];

モーメント方程式を作り，ARProcessについての母数を求める：

Wolfram Language code: momEq = And[Mean[ou[t]] == Mean[ARProcess[c, {a}, b][t]], CovarianceFunction[ou, h] == CovarianceFunction[ARProcess[c, {a}, b], h]]
Wolfram Language code: {sol} = Solve[And[(momEq /. h -> 0), momEq /. h -> 1], {a, b, c}, Reals]//FullSimplify[#, θ != 0 && σ > 0]&

ARProcessを作る：

Wolfram Language code: ar = ARProcess[c, {a}, b] /. sol

モーメントの一致を確かめる：

Wolfram Language code: Mean /@ {ou[t], ar[t]}//FullSimplify
Wolfram Language code: CovarianceFunction[#, h]& /@ {ou, ar}//FullSimplify

おもしろい例題  (3)

Ornstein–Uhlenbeck過程のシミュレーションを二次元で行う：

Wolfram Language code: SeedRandom[19];sample = RandomFunction[OrnsteinUhlenbeckProcess[-1, 1, .3], {0, 1, .001}, 2]["ValueList"];
Wolfram Language code: ListLinePlot[Transpose@sample, ColorFunction -> "FallColors"]

Ornstein–Uhlenbeck過程のシミュレーションを三次元で行う：

Wolfram Language code: SeedRandom[123]; sample = Table[RandomFunction[OrnsteinUhlenbeckProcess[0, 1, 1 / 4, 0], {0, 1, 0.01}, 3]["ValueList"], {8}];
Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@sample[[i]]}, {i, 8}]

Ornstein–Uhlenbeck過程からの500経路のシミュレーションを行う：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[0, 1, 1 / 3, 2], {0, 1, .01}, 500];

1におけるスライスを取り，その分布を可視化する：

Wolfram Language code: sd = data["SliceData", 1];
Wolfram Language code: cf = ColorData["Rainbow"]; sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 68]&[HistogramList[sd, {Range[-3, 6, .3]}]];

1におけるスライス分布の経路およびヒストグラム分布をプロットする：

Wolfram Language code: ListLinePlot[data, ImageSize -> 400, PlotRange -> All, AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {1.01, 0}, {0, 8}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, .25}, {.5, .5}}]
Wolfram Research (2012), OrnsteinUhlenbeckProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/OrnsteinUhlenbeckProcess.html.

テキスト

Wolfram Research (2012), OrnsteinUhlenbeckProcess, Wolfram言語関数， https://reference.wolfram.com/language/ref/OrnsteinUhlenbeckProcess.html.

CMS

Wolfram Language. 2012. "OrnsteinUhlenbeckProcess." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/OrnsteinUhlenbeckProcess.html.

APA

Wolfram Language. (2012). OrnsteinUhlenbeckProcess. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/OrnsteinUhlenbeckProcess.html

BibTeX

@misc{reference.wolfram_2026_ornsteinuhlenbeckprocess, author="Wolfram Research", title="{OrnsteinUhlenbeckProcess}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/OrnsteinUhlenbeckProcess.html}", note=[Accessed: 15-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_ornsteinuhlenbeckprocess, organization={Wolfram Research}, title={OrnsteinUhlenbeckProcess}, year={2012}, url={https://reference.wolfram.com/language/ref/OrnsteinUhlenbeckProcess.html}, note=[Accessed: 15-November-2026]}