Wolfram 语言与系统参考资料中心

OrnsteinUhlenbeckProcess

OrnsteinUhlenbeckProcess[μ,σ,θ]

表示稳态 Ornstein–Uhlenbeck 过程，其中长期均值为 μ，波动率为，均值回归速度 θ.

OrnsteinUhlenbeckProcess[μ,σ,θ,x₀]

表示一个 Ornstein–Uhlenbeck 过程，其中初始条件为 x₀.

范例

打开所有单元关闭所有单元

基本范例 (3)

模拟具有随机初始条件的 Ornstein–Uhlenbeck 过程：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[0, .1, .3], {0, 10, .1}]

Wolfram Language code: ListLinePlot[data, Filling -> Axis]

在固定初始条件下：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[0, .1, .3, 1], {0, 20, .1}];

Wolfram Language code: ListLinePlot[data, Filling -> Axis]

均值和方差函数：

Wolfram Language code: Mean[OrnsteinUhlenbeckProcess[μ, σ, θ][t]]

Wolfram Language code: Variance[OrnsteinUhlenbeckProcess[μ, σ, θ][t]]

在固定初始条件下：

Wolfram Language code: Mean[OrnsteinUhlenbeckProcess[μ, σ, θ, x][t]]

Wolfram Language code: Variance[OrnsteinUhlenbeckProcess[μ, σ, θ, x][t]]

协方差函数：

Wolfram Language code: CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], s, t]

Wolfram Language code: Plot3D[CovarianceFunction[OrnsteinUhlenbeckProcess[0, 1, .2], s, t], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

在固定初始条件下：

Wolfram Language code: CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ, x], s, t]

Wolfram Language code:

Plot3D[CovarianceFunction[OrnsteinUhlenbeckProcess[0, 1, .2, 1], s, t], {s, 0, 10}, {t, 0, 10}, ColorFunction -> "Rainbow"]

范围 (12)

基本用途 (7)

模拟路径集合：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[.3, .5, .4], {0, 1, 0.01}, 4]

Wolfram Language code: ListLinePlot[data, Filling -> Axis]

使用任意精度模拟：

Wolfram Language code: RandomFunction[OrnsteinUhlenbeckProcess[1 / 10, 1 / 3, 1 / 2], {0, 1, 1 / 4}, WorkingPrecision -> 20]["Path"]

比较均值回归速度不同值下的路径：

Wolfram Language code: sample[θ_] := (SeedRandom[14];RandomFunction[OrnsteinUhlenbeckProcess[0, 1, θ], {0, 1, .01}])

Wolfram Language code: ListStepPlot[sample[#], Filling -> Axis, PlotLabel -> StringJoin["θ = ", ToString[#]]]& /@ {.1, 1, 10}

模拟各种起始点的过程：

Wolfram Language code:

points = {-2, -1, 0, 1};
sample[x_] := RandomFunction[OrnsteinUhlenbeckProcess[0, .5, .3, x], {0, 10, 0.1}];

Wolfram Language code:

ListLinePlot[sample[#]& /@ points, PlotRange -> All, Filling -> Axis, PlotLegends -> (StringJoin["x = ", ToString[#]]& /@ points)]

过程参数估计：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[0.8, 1, .2], {0, 1000, 0.01}];

Wolfram Language code: EstimatedProcess[data, OrnsteinUhlenbeckProcess[μ, σ, θ]]

如下估计方法可用：

Wolfram Language code: m = {"LeastSquares", "MaximumConditionalLikelihood"};

Wolfram Language code: FindProcessParameters[data, OrnsteinUhlenbeckProcess[μ, σ, θ, x0], ProcessEstimator -> #]& /@ m

过程切片属性 (5)

单变量 SliceDistribution:

Wolfram Language code: OrnsteinUhlenbeckProcess[μ, σ, θ][t]

概率密度函数不取决于时间：

Wolfram Language code: Plot[PDF[OrnsteinUhlenbeckProcess[0, 1, 1 / 3][t], x], {x, -3, 3}, Filling -> Axis]

Wolfram Language code: PDF[OrnsteinUhlenbeckProcess[μ, σ, θ][t], x]

在固定起始点下：

Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, x0], t]

概率密度函数取决于时间：

Wolfram Language code:

Plot[Evaluate@Table[PDF[OrnsteinUhlenbeckProcess[0, 1, .5, 2][t], x], {t, {1 / 2, 1, 2}}], {x, -3, 3}, Filling -> Axis, PlotLegends -> {"t = 1/2", "t = 1", "t = 2"}]

Wolfram Language code: PDF[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]][t], x]

多变量切片分布：

Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[0, 1, 2], {s, t}]

在固定起始点下：

Wolfram Language code: SliceDistribution[OrnsteinUhlenbeckProcess[0, 1, 2, 1], {1, 2, 3}]

Wolfram Language code: Mean[%]

计算表达式的期望：

Wolfram Language code: Expectation[x[t] + x[t] ^ 2, xOrnsteinUhlenbeckProcess[μ, σ, θ]]//Simplify

计算事情的概率：

Wolfram Language code: Probability[x[t] > -1, xOrnsteinUhlenbeckProcess[μ, σ, θ]]

偏度和峰度是常数：

Wolfram Language code: Skewness[OrnsteinUhlenbeckProcess[μ, σ, θ][t]]

Wolfram Language code: Skewness[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]][t]]

Wolfram Language code: Kurtosis[OrnsteinUhlenbeckProcess[μ, σ, θ][t]]

Wolfram Language code: Kurtosis[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]][t]]

阶数为 r 的矩：

Wolfram Language code: Moment[OrnsteinUhlenbeckProcess[μ, σ, θ][t], r]

母函数：

Wolfram Language code: CharacteristicFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

Wolfram Language code: MomentGeneratingFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

CentralMoment 和它的母函数：

Wolfram Language code: CentralMoment[OrnsteinUhlenbeckProcess[μ, σ, θ][t], r]

Wolfram Language code: CentralMomentGeneratingFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

FactorialMoment 在符号式阶数下没有解析形式：

Wolfram Language code: FactorialMoment[OrnsteinUhlenbeckProcess[μ, σ, θ][t], r]

Wolfram Language code: FactorialMoment[OrnsteinUhlenbeckProcess[μ, σ, θ][t], 3]

Wolfram Language code: FactorialMomentGeneratingFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

Cumulant 和母函数：

Wolfram Language code: Cumulant[OrnsteinUhlenbeckProcess[μ, σ, θ][t], r]

Wolfram Language code: CumulantGeneratingFunction[OrnsteinUhlenbeckProcess[μ, σ, θ][t], w]

推广和延伸 (1)

Ornstein–Uhlenbeck 过程的二次转化：

Wolfram Language code: 𝒫 = TransformedProcess[p[2t + 1] ^ 2 + 3, pOrnsteinUhlenbeckProcess[0, 1, 0.2], t];

模拟转化过程：

Wolfram Language code: data = RandomFunction[𝒫, {0, 30, 0.1}, 3];

Wolfram Language code: ListLinePlot[data, PlotRange -> All]

均值和方差函数是常数：

Wolfram Language code: {Mean[𝒫[t]], Variance[𝒫[t]]}

通过模拟过程的切片，可视化结果：

Wolfram Language code: data1 = RandomVariate[𝒫[1.9], 2000];

Wolfram Language code: {Mean[data1], Variance[data1]}

属性和关系 (9)

从随机数开始的 OrnsteinUhlenbeckProcess 是弱稳态的：

Wolfram Language code: WeakStationarity[OrnsteinUhlenbeckProcess[μ, σ, θ]]

从固定值开始的过程不是弱稳态的：

Wolfram Language code: WeakStationarity[OrnsteinUhlenbeckProcess[μ, σ, θ, a]]

稳态 Ornstein–Uhlenbeck 过程的功率谱：

Wolfram Language code: FourierTransform[CovarianceFunction[OrnsteinUhlenbeckProcess[μ, σ, θ], h], h, ω, FourierParameters -> {1, 1}]

Ornstein–Uhlenbeck 过程具有定义良好的 StationaryDistribution:

Wolfram Language code: StationaryDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ]]

在固定起始点下：

Wolfram Language code: StationaryDistribution[OrnsteinUhlenbeckProcess[μ, σ, θ, a]]

Ornstein–Uhlenbeck 过程不具有独立的增量：

Wolfram Language code: proc = OrnsteinUhlenbeckProcess[μ, σ, θ];

Wolfram Language code: Expectation[(x[t2] - x[t1])(x[t4] - x[t3]), xproc, Assumptions -> 0 < t1 < t2 < t3 < t4]//Simplify

与期望的乘积相比：

Wolfram Language code:

Expectation[(x[t2] - x[t1]), xproc, Assumptions -> 0 < t1 < t2] * Expectation[(x[t4] - x[t3]), xproc, Assumptions -> 0 < t3 < t4]

Wolfram Language code: % === %%

在固定起始点下：

Wolfram Language code: proc = OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]];

Wolfram Language code: Expectation[(x[t2] - x[t1])(x[t4] - x[t3]), xproc, Assumptions -> 0 < t1 < t2 < t3 < t4]//Simplify

与期望乘积相比：

Wolfram Language code:

Expectation[(x[t2] - x[t1]), xproc, Assumptions -> 0 < t1 < t2] * Expectation[(x[t4] - x[t3]), xproc, Assumptions -> 0 < t3 < t4]

Wolfram Language code: % === %%

条件累积分布函数：

Wolfram Language code:

Table[Plot[Evaluate@Probability[(x[5] <= Subscript[x, 2])(x[2] == Subscript[x, 1]), xOrnsteinUhlenbeckProcess[0, 1, .2]], {Subscript[x, 2], -4, 6}, Filling -> Axis, PlotLabel -> StringJoin["SubscriptBox[x, 1] = ", ToString[Subscript[x, 1]]]], {Subscript[x, 1], {-1.5, -.4, 1.3, 3}}]

Wolfram Language code:

Probability[(x[Subscript[t, 2]] ≤ Subscript[x, 2])(x[Subscript[t, 1]] == Subscript[x, 1]), xOrnsteinUhlenbeckProcess[μ, σ, θ], Assumptions -> 0 < Subscript[t, 1] < Subscript[t, 2] && 0 ≤ Subscript[x, 1] ≤ Subscript[t, 1] && 0 ≤ Subscript[x, 2] ≤ Subscript[t, 2]]//Simplify

具有固定初始条件的 Ornstein–Uhlenbeck 过程是一个特殊的 ItoProcess:

Wolfram Language code: ItoProcess[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]]]

以及 StratonovichProcess:

Wolfram Language code: StratonovichProcess[OrnsteinUhlenbeckProcess[μ, σ, θ, Subscript[x, 0]]]

Ornstein–Uhlenbeck 过程是随机微分方程的解：

Wolfram Language code: μ = 1.2;σ = 0.3;θ = 1;T = 5;

Wolfram Language code:

noisysol = RandomFunction[OrnsteinUhlenbeckProcess[μ, σ, θ, 2], {0, T, 0.01}, 10 ^ 2];
meanFunction = TimeSeriesThread[Mean, noisysol];

Wolfram Language code:

Show[ListLinePlot[noisysol, PlotStyle -> Directive[Opacity[.1]]], ListLinePlot[meanFunction, PlotStyle -> Directive[Black, Thick]]]

与相应的平滑解比较：

Wolfram Language code: smoothsol = NDSolve[{P'[t] == θ(μ - P[t]), P[0] == 2}, P, {t, 0, T}]

Wolfram Language code: Plot[P[t] /. smoothsol, {t, 0, T}, PlotRange -> {0.5, 2.5}]

具有三个参数的 Ornstein–Uhlenbeck 是均值遍历的：

Wolfram Language code: proc = OrnsteinUhlenbeckProcess[μ, σ, θ];

过程是弱稳态的：

Wolfram Language code: WeakStationarity[proc]

计算绝对相关函数：

Wolfram Language code: abscorr[h_] = AbsoluteCorrelationFunction[proc, h]

求条状积分的数值：

Wolfram Language code: int[t_] = 1 / (2 * t)Integrate[(1 - Abs[u] / (2 * t))abscorr[u], {u, -2 * t, 2 * t}, Assumptions -> t > 0 && θ > 0]

过程只对于 μ=0 是均值遍历的：

Wolfram Language code: Limit[int[t], t -> ∞, Assumptions -> θ > 0]

整数时间处的 Ornstein–Uhlenbeck 过程的表现与一阶 ARProcess 类似：

Wolfram Language code: ou = OrnsteinUhlenbeckProcess[μ, σ, θ];

创建矩方程用来求 ARProcess 的参数：

Wolfram Language code:

momEq = And[Mean[ou[t]] == Mean[ARProcess[c, {a}, b][t]], 
	CovarianceFunction[ou, h] == CovarianceFunction[ARProcess[c, {a}, b], h]]

Wolfram Language code: {sol} = Solve[And[(momEq /. h -> 0), momEq /. h -> 1], {a, b, c}, Reals]//FullSimplify[#, θ != 0 && σ > 0]&

创建 ARProcess:

Wolfram Language code: ar = ARProcess[c, {a}, b] /. sol

检查矩的一致性：

Wolfram Language code: Mean /@ {ou[t], ar[t]}//FullSimplify

Wolfram Language code: CovarianceFunction[#, h]& /@ {ou, ar}//FullSimplify

巧妙范例 (3)

模拟二维空间中的 Ornstein–Uhlenbeck 过程：

Wolfram Language code: SeedRandom[19];sample = RandomFunction[OrnsteinUhlenbeckProcess[-1, 1, .3], {0, 1, .001}, 2]["ValueList"];

Wolfram Language code: ListLinePlot[Transpose@sample, ColorFunction -> "FallColors"]

模拟三维空间中的 Ornstein–Uhlenbeck 过程：

Wolfram Language code:

SeedRandom[123];
sample = Table[RandomFunction[OrnsteinUhlenbeckProcess[0, 1, 1 / 4, 0], {0, 1, 0.01}, 3]["ValueList"], {8}];

Wolfram Language code: Graphics3D@Table[{ColorData["SolarColors"][RandomReal[]], Tube@Line@sample[[i]]}, {i, 8}]

模拟来自 Ornstein–Uhlenbeck 过程的500条路径：

Wolfram Language code: data = RandomFunction[OrnsteinUhlenbeckProcess[0, 1, 1 / 3, 2], {0, 1, .01}, 500];

提取1处的切片，并且可视化分布：

Wolfram Language code: sd = data["SliceData", 1];

Wolfram Language code:

cf = ColorData["Rainbow"];
sliced = BarChart[Last[#], Axes -> False, BarOrigin -> Left, AspectRatio -> 4, ChartStyle -> (cf /@ Rescale[MovingAverage[First[#], 2], {Min[sd], Max[sd]}, {0, 1}]), ImageSize -> 68]&[HistogramList[sd, {Range[-3, 6, .3]}]];

绘制1处切片分布的路径和直方图分布：

Wolfram Language code:

ListLinePlot[data, ImageSize -> 400, PlotRange -> All, 
	AspectRatio -> 3 / 4, Epilog -> Inset[sliced, {1.01, 0}, {0, 8}], PlotStyle -> (cf /@ Rescale[sd]), BaseStyle -> Directive[Thin, Opacity[0.5]], PlotRangePadding -> {{0, .25}, {.5, .5}}]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

OrnsteinUhlenbeckProcess

更多信息

范例

基本范例 (3)

范围 (12)

基本用途 (7)

过程切片属性 (5)

推广和延伸 (1)

属性和关系 (9)

巧妙范例 (3)

文本

CMS

APA

BibTeX

BibLaTeX

OrnsteinUhlenbeckProcess

更多信息

范例

基本范例 (3)

范围 (12)

基本用途 (7)

过程切片属性 (5)

推广和延伸 (1)

属性和关系 (9)

巧妙范例 (3)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX