WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Polygon[{p1,p2,…}]

点 piを持つ，塗り潰された多角形を表す．

Polygon[{p1,…,pn}{{q1,…,qm},…}]

穴{q1,…,qm},…がある多角形を表す．

Polygon[{poly1,poly2,…}]

多角形 polyiの集合を表す．

Polygon[{p1,…,pn},data]

data 中の整数 i として与えられている座標を piと解釈すべき多角形を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
座標  
領域  
オプション  
VertexColors  
VertexNormals  
VertexTextureCoordinates  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Polygon

Polygon[{p1,p2,…}]

点 piを持つ，塗り潰された多角形を表す．

Polygon[{p1,…,pn}{{q1,…,qm},…}]

穴{q1,…,qm},…がある多角形を表す．

Polygon[{poly1,poly2,…}]

多角形 polyiの集合を表す．

Polygon[{p1,…,pn},data]

data 中の整数 i として与えられている座標を piと解釈すべき多角形を表す．

詳細とオプション

  • Polygonは，幾何領域としてあるいはグラフィックスプリミティブとして使うことができる．
  • Polygon[{p1,…,pn}]は，線分{p1,p2},…,{pn-1,pn}と{pn,p1}で閉じた曲線内のすべての点を表す平面領域である．
  • 平面上のある点から任意の方向に向かう半直線が境界線と奇数回交差するなら，その点は多角形の要素である．
  • Polygon[{p1,…,pn}{{q1,…,qm},…}]は，外側多角形Polygon[{p1,…,pn}]と1つあるいは複数の内側多角形Polygon[{q1,…,qm}],…からなる穴のある多角形を指定する．
  • ある点が外側多角形には含まれるが任意の内側多角形には含まれないなら，その点は多角形の要素である．
  • Polygon[{poly1,poly2,…}]は，穴があるまたは穴がない多角形 polyiの集合で，幾何学計算では polyiの和集合として扱われる．
  • Polygon[{p1,…,pn},data]は，事実上，data 中の座標として現れる整数 i を対応する piで置換する．
  • Polygon[{p1,…,pn},{b1,…,bn}]多角形の境界点{pb1,…,pbk}
    Polygon[{p1,…,pn},{{o1,…,ok}{{i1,…,il},…}]外側多角形の境界点{po1,…,pok}と内側多角形の境界点{pi1,…,pil}等
    Polygon[{p1,…,pn},{{b1,…,bn},{o1,…,ok}{{i1,…,il},…},…}]複数の多角形の集合
  • 点 piは，幾何領域として任意の埋込み次元を持つことができるが，すべてが1つの平面上で同じ埋込み次元を持たなければならない．
  • グラフィックスでは，点 piは，Scaled，Offset，ImageScaled，Dynamicの各式でよい．
  • グラフィックスの描画は，FaceForm，EdgeForm，Texture，Specularity，Opacity，色の各指示子の影響を受ける．
  • FaceForm[front,back]を使って3Dにおける多面体の表と裏に異なるスタイルを指定することができる．表は右辺規則と最初の3点の方向で定義される．
  • 次は，グラフィックスで使用可能なオプションおよび設定値である．
  • VertexColors Automatic補間される頂点の色
    VertexNormals Automatic陰影付けのための有効な頂点法線
    VertexTextureCoordinates Noneテクスチャのための座標
  • Polygonは，GeometricSceneの記号の点と一緒に使うことができる．

例題

すべて開く すべて閉じる

例  (2)

多角形：

Wolfram Language code: pol = Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}]

そのグラフィックス画像：

Wolfram Language code: Graphics[pol]

その面積：

Wolfram Language code: Area[pol]

さまざまにスタイル付けされた3D多角形：

Wolfram Language code: pol = Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}];
Wolfram Language code: {Graphics3D[{Pink, pol}], Graphics3D[{EdgeForm[Thick], Pink, pol}], Graphics3D[{EdgeForm[Dashed], Pink, pol}]}

スコープ  (22)

グラフィックス  (12)

指定  (3)

一群の多角形：

Wolfram Language code: p2 = {{0, 0}, {1, 0}, {0, 1}};
Wolfram Language code: Graphics[Polygon[{p2, p2 + 1}]]
Wolfram Language code: p3 = {{1, 0, 0}, {1, 1, 1}, {0, 0, 1}};
Wolfram Language code: Graphics3D[Polygon[{p3, p3 + 1}]]

複数の頂点を持つ多角形：

Wolfram Language code: Graphics[Polygon[Table[{Cos[2π k / 6], Sin[2π k / 6]}, {k, 0, 5}]]]
Wolfram Language code: Graphics3D[Polygon[Table[{Cos[2π k / 6], Sin[2π k / 6], 0}, {k, 0, 5}]]]

穴のある多角形：

Wolfram Language code: Graphics[Polygon[{{0, 0}, {2, 0}, {1, Sqrt[3]}} -> {{{(1/2), (1/2 Sqrt[3])}, {(3/2), (1/2 Sqrt[3])}, {1, (2/Sqrt[3])}}}]]
Wolfram Language code: Graphics3D[Polygon[{{0, 0, 0}, {2, 0, 0}, {1, Sqrt[3], 0}} -> {{{(1/2), (1/2 Sqrt[3]), 0}, {(3/2), (1/2 Sqrt[3]), 0}, {1, (2/Sqrt[3]), 0}}}]]

スタイリング  (6)

色指示子で多角形の面の色を指定する：

Wolfram Language code: Table[Graphics[{c, Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}]}], {c, {Red, Green, Blue, Yellow}}]
Wolfram Language code: Table[Graphics3D[{c, Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

Textureを使って多角形の面に使用するテクスチャが指定できる：

Wolfram Language code: {Graphics[{Texture[ExampleData[{"TestImage", "JellyBeans2"}]], Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexTextureCoordinates -> {{1, 0}, {0.5, 1}, {0, 0}}]}], Graphics3D[{Texture[ExampleData[{"TestImage", "JellyBeans2"}]], Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {0.5, 1}}]}, Lighting -> "Neutral"]}

Textureは異なるOpacityで使うことができる：

Wolfram Language code: Table[Graphics[{Opacity[o], Texture[ExampleData[{"TestImage", "House"}]], Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexTextureCoordinates -> {{1, 0}, {0.5, 1}, {0, 0}}]}], {o, {0.25, 0.5, 0.75, 1}}]

Textureは異なるLightingで使うことができる：

Wolfram Language code: Table[Graphics3D[{Texture[ExampleData[{"TestImage", "Sailboat"}]], Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {0.5, 1}}]}, Lighting -> {{"Directional", c, {4, -4, 4}}}], {c, {Red, Green, Yellow, White}}]

FaceFormおよびEdgeFormを使って内部と境界のスタイルが指定できる：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Polygon[{{0, 0}, {0, 1}, {1, 1}, {1, 0}}]}]
Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], Polygon[{{0, 0, 0}, {1, 1, 0}, {1, 1, 1}, {0, 0, 1}}]}]

三次元では，FaceFormを使って表面と裏面に異なる特性が指定できる：

Wolfram Language code: p = {FaceForm[Yellow, Blue], Polygon[{{1, 0, 0}, {0, Sqrt[3], 0}, {-1, 0, 0}}]};
Wolfram Language code: {Graphics3D[p, ViewPoint -> Top], Graphics3D[p, ViewPoint -> Bottom]}

FaceFormを使って3Dの外側と内側に別々のテクスチャを設定する：

Wolfram Language code: vtc = {{0, 0}, {1, 0}, {1, 1}, {0, 1}}; coords = {{{0, 0, 0}, {0, 1, 0}, {1, 1, 0}, {1, 0, 0}}, {{0, 0, 0}, {1, 0, 0}, {1, 0, 1}, {0, 0, 1}}, {{1, 0, 0}, {1, 1, 0}, {1, 1, 1}, {1, 0, 1}}, {{1, 1, 0}, {0, 1, 0}, {0, 1, 1}, {1, 1, 1}}, {{0, 1, 0}, {0, 0, 0}, {0, 0, 1}, {0, 1, 1}}};
Wolfram Language code: Graphics3D[{FaceForm[Texture[[image]], Texture[[image]]], Polygon[coords, VertexTextureCoordinates -> Table[vtc, {6}]]}, Lighting -> "Neutral"]

VertexColorsを使って頂点における色が指定できる：

Wolfram Language code: Graphics[Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexColors -> {Red, Green, Blue}]]
Wolfram Language code: Graphics3D[Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}, VertexColors -> {Red, Green, Blue}]]

3Dの多角形については，法線はVertexNormalsを使って頂点で指定することができる：

Wolfram Language code: n = {1, -1, 1};
Wolfram Language code: Graphics3D[{Yellow, Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}, VertexNormals -> {-n, n, n}]}]

座標  (3)

スケールされた(Scaled)座標を使う：

Wolfram Language code: Graphics[Polygon[{Scaled[{0, 0}], Scaled[{.5, 1}], Scaled[{1, 0}]}], Frame -> True]
Wolfram Language code: Graphics3D[Polygon[{Scaled[{0, 0, .2}], Scaled[{.5, 1, .8}], Scaled[{1, 0, .2}]}], Axes -> True]

2Dで画像がスケールされた(ImageScaled)座標を使う：

Wolfram Language code: Graphics[Polygon[{ImageScaled[{0, 0}], ImageScaled[{.5, 1}], ImageScaled[{1, 0}]}], Frame -> True]

2DでOffset座標を使う：

Wolfram Language code: Graphics[Polygon[{Offset[{10, 10}, {0, 0}], Offset[{0, -20}, {.5, 1}], Offset[{-10, 10}, {1, 0}]}], Frame -> True]

領域  (10)

埋込み次元：

Wolfram Language code: RegionEmbeddingDimension[Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]]

幾何次元：

Wolfram Language code: RegionDimension[Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]]

点の帰属判定：

Wolfram Language code: ℛ = Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}];
Wolfram Language code: {RegionMember[ℛ, {2 / 3, 1 / 3, 2 / 3}], RegionMember[ℛ, {0, 0, 0}]}

点の帰属条件を求める：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

面積：

Wolfram Language code: ℛ = Polygon[{{1, 0}, {1, 1}, {0, 0}}];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];
Wolfram Language code: {RegionDistance[ℛ, {3, 4}], RegionDistance[ℛ, {1, 1}]}

これをプロットする：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -4, 4}, {y, -4, 4}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

点からの符号付き距離：

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];
Wolfram Language code: {SignedRegionDistance[ℛ, {3, 4}], SignedRegionDistance[ℛ, {1, 1}]}

これをプロットする：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

領域内の最近点：

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];
Wolfram Language code: RegionNearest[ℛ, {3, 4}]

最近点：

Wolfram Language code: pts = Table[4{Cos[k 2 π / 25], Sin[k 2π / 25]}, {k, 0., 24}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

多角形は有界である：

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];
Wolfram Language code: BoundedRegionQ[ℛ]

領域を求める：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

多角形上でIntegrate：

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];
Wolfram Language code: Integrate[x ^ 2 + y ^ 2, {x, y}∈ℛ]

多角形上で最適化する：

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];
Wolfram Language code: Minimize[{x y - x, {x, y}∈ℛ}, {x, y}]

多角形内で方程式を解く：

Wolfram Language code: ℛ = Polygon[{{-2, 0}, {-1, 3 / 2}, {1, 3 / 2}, {2, 0}, {1, -3 / 2}, {-1, -3 / 2}}];
Wolfram Language code: Solve[x^2 + y^2 == 4 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Graphics[{{LightBlue, EdgeForm[Gray], ℛ}, {Green, Circle[{0, 0}, 2]}, {Red, PointSize[Medium], Point[{x, y} /. %]}}]

オプション  (7)

VertexColors  (2)

頂点に色がある多角形：

Wolfram Language code: Graphics[Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexColors -> {Red, Green, Blue}]]

3D多角形の頂点の色を指定する：

Wolfram Language code: Graphics3D[Polygon[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}, VertexColors -> {Red, Green, Blue}]]

VertexNormals  (1)

辺のベクトルのクロス積を使って法線ベクトルを計算する：

Wolfram Language code: {p1, p2, p3} = {{1, 0, 0}, {1, 1, 1}, {0, 0, 1}};
Wolfram Language code: n = Cross[p2 - p1, p3 - p1]

{1,-1,1}の方向を指している法線を持つ三角形：

Wolfram Language code: Graphics3D[{Yellow, Polygon[{p1, p2, p3}, VertexNormals -> {n, n, n}]}]

法線を変更すると陰影付けに影響する：

Wolfram Language code: Graphics3D[{Yellow, Polygon[{p1, p2, p3}, VertexNormals -> {-n, n, n}]}]

VertexTextureCoordinates  (4)

テクスチャマップされた多角形：

Wolfram Language code: Graphics[{Texture[ExampleData[{"TestImage", "Flower"}]], Polygon[{{1, 0}, {0, Sqrt[3]}, {-1, 0}}, VertexTextureCoordinates -> {{1, 0}, {0.5, 1}, {0, 0}}]}]

2D多角形のテクスチャマッピング：

Wolfram Language code: Graphics[{Texture[ExampleData[{"TestImage", "Airplane2"}]], Polygon[{{1, 1}, {3, 1}, {3, 3}, {1, 3}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}]

3D多面体のテクスチャマッピング：

Wolfram Language code: Graphics3D[{Texture[ExampleData[{"TestImage", "Airplane2"}]], Polygon[{{-1, -1, 0}, {1, -1, 0}, {1, 1, 0}, {-1, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}]}, Lighting -> "Neutral"]

統一されていないテクスチャ座標値を使ってテクスチャを繰り返す：

Wolfram Language code: {Graphics[{Texture[ExampleData[{"TestImage", "Mandrill"}]], Polygon[{{1, 1}, {3, 1}, {3, 3}, {1, 3}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 2}, {0, 2}}]}], Graphics3D[{Texture[ExampleData[{"TestImage", "Mandrill"}]], Polygon[{{-1, -1, 0}, {1, -1, 0}, {1, 1, 0}, {-1, 1, 0}}, VertexTextureCoordinates -> {{0, 0}, {2, 0}, {2, 2}, {0, 2}}]}, Lighting -> "Neutral"]}

VertexColorsはテクスチャマッピングに優先する：

Wolfram Language code: Graphics3D[{Texture[[image]], Polygon[{{-1, -1, -1}, {1, -1, -1}, {1, 1, -1}, {-1, 1, -1}}, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Red, Green, Blue, Purple}]}, Lighting -> "Neutral"]

アプリケーション  (3)

個の頂点を持つ多角形を定義する：

Wolfram Language code: ngon[p_, q_] := Polygon[Table[{Cos[2Pi k q / p], Sin[2Pi k q / p]}, {k, p}]]

正多角形：

Wolfram Language code: Row[Table[Graphics[{EdgeForm[Red], LightRed, ngon[n, 1]}, ImageSize -> 70], {n, 3, 14}]]

星形多角形：

Wolfram Language code: Row[Reap[Table[Table[If[CoprimeQ[p, q], Sow[Graphics[{EdgeForm[Green], LightGreen, ngon[p, q]}, ImageSize -> 70]]], {q, 2, p / 2}], {p, 5, 12}]][[2, 1]]]

正六角形を定義する：

Wolfram Language code: h[x_, y_] := Polygon[Table[{Cos[2Pi k / 6] + x, Sin[2Pi k / 6] + y}, {k, 6}]]

正六角形を敷き詰める：

Wolfram Language code: Graphics[{EdgeForm[Opacity[.7]], StandardBlue, Table[h[3i + 3((-1) ^ j + 1) / 4, Sqrt[3] / 2j], {i, 5}, {j, 10}]}]

PolyhedronDataから多角形面を得る：

Wolfram Language code: p = N[PolyhedronData["TruncatedIcosahedron", "Faces", "Polygon"]];

各面を重心について縮小する：

Wolfram Language code: shrink[t_, Polygon[x_List, opts___]] := Module[{c = Plus@@x / Length[x]}, Polygon[Map[(c + (1 - t)(# - c))&, x], opts]]
Wolfram Language code: Animate[Graphics3D[{FaceForm[Yellow, Green], p /. y_Polygon :> shrink[s, y]}, PlotRange -> 2.5], {s, 0, .8}, SaveDefinitions -> True, AnimationRunning -> False, AnimationDirection -> ForwardBackward, DefaultDuration -> 1]

特性と関係  (4)

GraphicsComplexは，多くの頂点を共有する多角形を効率的に生成する方法を提供する：

Wolfram Language code: v = {{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}};
Wolfram Language code: i = {{1, 2, 5}, {2, 3, 5}, {3, 4, 5}, {4, 1, 5}};
Wolfram Language code: {Graphics3D[{Opacity[.7], GraphicsComplex[v, Polygon[i]]}], Graphics3D[{GraphicsComplex[v, Line[i]]}]}

Normalをグラフィックス複合体に適用すると通常の多角形が生成できる：

Wolfram Language code: Normal[GraphicsComplex[v, Polygon[i]]]

PolygonはTriangleを一般化したものである：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}}]; Subscript[ℛ, 2] = Triangle[{{0, 0}, {1, 0}, {1, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

PolygonはRectangleを一般化したものである：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}]; Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3つの頂点があるSimplexはPolygonの特殊ケースである：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}}]; Subscript[ℛ, 2] = Simplex[{{0, 0}, {1, 0}, {1, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2から始まる任意次元で：

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}}]; Subscript[ℛ, 2] = Simplex[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

考えられる問題  (3)

三次元では，頂点が平面上にない場合，多角形の三角形分割は予測できない：

Wolfram Language code: Graphics3D[Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}}]]
Wolfram Language code: Graphics3D[Polygon[RandomReal[1, {10, 3}]]]

退化した多角形は有効な幾何領域ではない：

Wolfram Language code: Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 0}, {0, 0, 1}}]
Wolfram Language code: RegionQ[%]

アンチエイリアス処理の結果として個々の多角形間に継ぎ目が現れることがある：

Wolfram Language code: Graphics[{Gray, Table[Polygon[{{x, 0}, {x + 1, 0}, {x + 1, 1}, {x, 1}}], {x, 0, 2}]}]

単一の多角形オブジェクトを使うことで継ぎ目を避けることができる：

Wolfram Language code: Graphics[{Gray, Polygon[Table[{{x, 0}, {x + 1, 0}, {x + 1, 1}, {x, 1}}, {x, 0, 2}]]}]

おもしろい例題  (3)

ランダムな三角形の集合：

Wolfram Language code: Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], Polygon[RandomReal[1, {3, 2}]]}, {30}]]
Wolfram Language code: Graphics3D[Table[{EdgeForm[Black], Opacity[.7], Hue[RandomReal[]], Polygon[RandomReal[1, {3, 3}]]}, {30}], Lighting -> "Neutral"]

デジタル花弁：

Wolfram Language code: With[{d = 2Pi / 12}, Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], Polygon[{(8 - r){Cos[d(q - 1)], Sin[d(q - 1)]}, (8 - r){Cos[d(q + 1)], Sin[d(q + 1)]}, (10 - r){Cos[d q], Sin[d q]}}]}, {r, 6}, {q, 12}]]]

回転する星：

Wolfram Language code: Animate[Graphics[Rotate[Polygon[Table[{Cos[t], Sin[t]}, {t, 0, 4Pi, 4Pi / 5}]], θ, {0, 0}], PlotRange -> 1.2], {θ, 0, 2π}, AnimationRunning -> False]
Wolfram Research (1988), Polygon, Wolfram言語関数， https://reference.wolfram.com/language/ref/Polygon.html （2019年に更新）.

テキスト

Wolfram Research (1988), Polygon, Wolfram言語関数， https://reference.wolfram.com/language/ref/Polygon.html （2019年に更新）.

CMS

Wolfram Language. 1988. "Polygon." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Polygon.html.

APA

Wolfram Language. (1988). Polygon. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Polygon.html

BibTeX

@misc{reference.wolfram_2026_polygon, author="Wolfram Research", title="{Polygon}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Polygon.html}", note=[Accessed: 06-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_polygon, organization={Wolfram Research}, title={Polygon}, year={2019}, url={https://reference.wolfram.com/language/ref/Polygon.html}, note=[Accessed: 06-November-2026]}