PositiveDefiniteMatrixQ

如果 m 是显式正定矩阵，则给出 True，否则给出 False.

范例

打开所有单元关闭所有单元

基本范例 (2)

测试 2×2 的实矩阵是否为显式正定矩阵：

Wolfram Language code:

m = (⁠|    |    |
| -- | -- |
| 5  | -1 |
| -1 | 4  |⁠);

Wolfram Language code: PositiveDefiniteMatrixQ[m]

这意味着对于所有的向量，二次型成立：

Wolfram Language code:

Reduce[Subscript[∀, {Subscript[x, 1], Subscript[x, 2]}, Subscript[x, 1] ≠ 0 || Subscript[x, 2] ≠ 0]{Subscript[x, 1], Subscript[x, 2]}.m.{Subscript[x, 1], Subscript[x, 2]} > 0, {Subscript[x, 1], Subscript[x, 2]}, Reals]

可视化二次型的值：

Wolfram Language code:

Plot3D[{Subscript[x, 1], Subscript[x, 2]}.m.{Subscript[x, 1], Subscript[x, 2]}, {Subscript[x, 1], Subscript[x, 2]}∈Disk[], BoxRatios -> 1]

测试 3×3 Hermitian 矩阵是否为正定矩阵：

Wolfram Language code:

PositiveDefiniteMatrixQ[(⁠|                  |               |                 |
| ---------------- | ------------- | --------------- |
| 5.42             | 3.26 + 0.643I | -0.467 - 0.193I |
| 3.26 - 0.643I    | 3.82          | 1.04 - 2.35I    |
| -0.467 + 0.193 I | 1.04 + 2.35 I | 4.88            |⁠)]

范围 (10)

基本用法 (6)

测试一个实机器精度矩阵是否为显式正定矩阵：

Wolfram Language code: m = {{2.3, -1.2}, {0.6, 3.7}};

Wolfram Language code: PositiveDefiniteMatrixQ[m]

测试一个复矩阵否为正定矩阵：

Wolfram Language code: m = {{1, 2I}, {-I, 4}};

Wolfram Language code: PositiveDefiniteMatrixQ[m]

测试一个精确矩阵否为正定矩阵：

Wolfram Language code:

PositiveDefiniteMatrixQ[⁠(|   |         |    |
| - | ------- | -- |
| π | -5      | 2  |
| E | -3      | -3 |
| 5 | Sqrt[2] | 5  |⁠)]

用 PositiveDefiniteMatrixQ 测试任意精度的矩阵：

Wolfram Language code: m = RandomReal[5, {3, 3}, WorkingPrecision -> 15]

随机矩阵通常不是正定矩阵：

Wolfram Language code: PositiveDefiniteMatrixQ[m]

用 PositiveDefiniteMatrixQ 测试符号矩阵：

Wolfram Language code: PositiveDefiniteMatrixQ[{{1, a}, {b, 2}}]

时矩阵变为正定矩阵：

Wolfram Language code: Block[{b = -Conjugate[a]}, PositiveDefiniteMatrixQ[{{1, a}, {b, 2}}]]

PositiveDefiniteMatrixQ 可高效处理大型数值矩阵：

Wolfram Language code: m = RandomReal[1, {1000, 1000}];

Wolfram Language code: AbsoluteTiming[PositiveDefiniteMatrixQ[m]]

Wolfram Language code:

a = m.m^;
AbsoluteTiming[PositiveDefiniteMatrixQ[a]]

特殊矩阵 (4)

用 PositiveDefiniteMatrixQ 测试稀疏矩阵：

Wolfram Language code: SparseArray[{{i_, i_} -> 2., {i_, j_} /; Abs[i - j] == 1 -> -1.}, {10, 10}, 0.]

Wolfram Language code: PositiveDefiniteMatrixQ[%]

用 PositiveDefiniteMatrixQ 测试结构矩阵：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 5, {1, 2} -> 11, {2, 2} -> 25}, {2, 2}, Symmetric[All]]

Wolfram Language code: PositiveDefiniteMatrixQ[%]

单位矩阵是正定矩阵：

Wolfram Language code: PositiveDefiniteMatrixQ[IdentityMatrix[5]]

HilbertMatrix 是正定矩阵：

Wolfram Language code: PositiveDefiniteMatrixQ[HilbertMatrix[5]]

应用 (15)

正定矩阵的几何与代数性质 (4)

考虑一个 2×2 的实正定矩阵及其相关的实二次型：

Wolfram Language code:

m = (⁠|    |    |
| -- | -- |
| 3  | -1 |
| -1 | 3  |⁠);
PositiveDefiniteMatrixQ[m]

Wolfram Language code: q[x_, y_] := {x, y}.m.{x, y}

因为是正定矩阵，所以水平集是椭圆：

Wolfram Language code: ContourPlot[q[x, y], {x, -2, 2}, {y, -2, 2}]

的图则是向上的椭圆抛物面：

Wolfram Language code: Plot3D[q[x, y], {x, y}∈RotationTransform[π / 4][Disk[{0, 0}, {2, Sqrt[2]}]], MeshFunctions -> {#3&}, BoxRatios -> 1]

对于的实正定矩阵，水平集是 -椭圆体：

Wolfram Language code:

m3 = (⁠|    |    |   |
| -- | -- | - |
| 3  | -1 | 0 |
| -1 | 3  | 0 |
| 0  | 0  | 3 |⁠);

Wolfram Language code: PositiveDefiniteMatrixQ[m3]

Wolfram Language code:

ContourPlot3D[{x, y, z}.m3.{x, y, z}, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}, Contours -> {1, 4, 9}, ContourStyle -> Opacity[0.5], Mesh -> None]

通过，Hermitian 矩阵定义了一个实二次型：

Wolfram Language code:

m = (|       |       |
| ----- | ----- |
| 5     | 2 + I |
| 2 - I | 3     |);
q[w_, z_] := {w, z}.m.{w, z}
Reduce[q[w, z]∈Reals, {w, z}]

如果是正定矩阵，则对于所有非零输入，为正：

Wolfram Language code: Reduce[Subscript[∀, {w, z}, w ≠ 0 || z ≠ 0]q[w, z] > 0, {w, z}, Complexes]

输入为正的情况下可视化：

Wolfram Language code:

φ = ArcTan@@Abs[First[Eigenvectors[m]]];
ba = 1 / Sqrt[Eigenvalues[m]];
Plot3D[q[x, y], {x, y}∈RotationTransform[φ]@Disk[{0, 0}, ba], BoxRatios -> 1, Mesh -> None]

对于实值矩阵，只有对称的部分决定是否为正定矩阵. 写为，为对称部分，为非对称部分：

Wolfram Language code:

m = (|   |   |
| - | - |
| 1 | 2 |
| 3 | 4 |);
MatrixForm[s = (m + m/2)]

Wolfram Language code: MatrixForm[a = (m - m/2)]

Wolfram Language code: m == s + a && SymmetricMatrixQ[s] && AntisymmetricMatrixQ[a]

由于为实对称矩阵，，意味着是实矩阵：

Wolfram Language code:

x = RandomComplex[1 + I, 2];
x.s.x//Chop

同样，由于为实非对称矩阵，有或为虚矩阵：

Wolfram Language code:

x = RandomComplex[1 + I, 2];
x.a.x

因此，，当且仅当为正定矩阵，才是正定矩阵：

Wolfram Language code: {PositiveDefiniteMatrixQ[m], PositiveDefiniteMatrixQ[s]}

对于复矩阵，只有 Hermitian 部分决定是否为正定矩阵. 写为，是 Hermitian 矩阵，为反埃尔米特矩阵：

Wolfram Language code:

m = (⁠|         |         |
| ------- | ------- |
| 1 + 5 I | 2 + 6 I |
| 3 + 7 I | 4 + 8I  |⁠);
MatrixForm[h = (m + m/2)]

Wolfram Language code: MatrixForm[a = (m - m/2)]

Wolfram Language code: m == h + a && HermitianMatrixQ[h] && AntihermitianMatrixQ[a]

由于是 Hermitian 矩阵，，意味着是实矩阵：

Wolfram Language code:

x = RandomComplex[1 + I, 2];
x.h.x//Chop

同样，由于为反埃尔米特矩阵，有或是虚矩阵：

Wolfram Language code:

x = RandomComplex[1 + I, 2];
x.a.x//Chop

因此，，当且仅当为正定矩阵，才是正定矩阵：

Wolfram Language code: {PositiveDefiniteMatrixQ[m], PositiveDefiniteMatrixQ[h]}

正定矩阵的来源 (6)

实非奇异 Covariance 矩阵总是对称的和正定的：

Wolfram Language code: Block[{Σ = Covariance[RandomReal[1, {5, 3}]]}, Det[Σ] ≠ 0 && SymmetricMatrixQ[Σ] && PositiveDefiniteMatrixQ[Σ]]

复矩阵是 Hermitian 矩阵：

Wolfram Language code:

Block[{Σ = Covariance[RandomComplex[1 + I, {5, 3}]]}, Det[Σ] ≠ 0 && HermitianMatrixQ[Σ] && PositiveDefiniteMatrixQ[Σ]]

Gram 矩阵是个向量的点积组成的对称矩阵：

Wolfram Language code:

n = 5;
v = RandomReal[1., {n, n}];
m = Table[v[[i]].v[[j]], {i, n}, {j, n}];

如果向量是线性无关的，Gram 矩阵一定是正定矩阵：

Wolfram Language code: {Det[v] ≠ 0, PositiveDefiniteMatrixQ[m]}

从 WishartMatrixDistribution 得到的矩阵是实对称正定矩阵：

Wolfram Language code:

(m |-> m∈Reals && SymmetricMatrixQ[m] && PositiveDefiniteMatrixQ[m]) /@ RandomVariate[WishartMatrixDistribution[5, {{1, 1 / 2, 0}, {1 / 2, 2, -1 / 2}, {0, -1 / 2, 1}}], {10}]

非奇异 Hermitian 矩阵的平方是正定矩阵：

Wolfram Language code: m = RandomVariate[GaussianUnitaryMatrixDistribution[5]];

Wolfram Language code: Det[m] ≠ 0 && HermitianMatrixQ[m]

Wolfram Language code: PositiveDefiniteMatrixQ[MatrixPower[m, 2]]

Lehmer 矩阵是对称正定矩阵：

Wolfram Language code:

lehmer = Table[Min[i, j] / Max[i, j], {i, 5}, {j, 5}];
{SymmetricMatrixQ[lehmer], PositiveDefiniteMatrixQ[lehmer]}

它的逆矩阵是三对角矩阵，同时也是对称正定矩阵：

Wolfram Language code: inv = Inverse[lehmer]

Wolfram Language code: {SymmetricMatrixQ[inv], PositiveDefiniteMatrixQ[inv]}

矩阵 Min[i,j] 一定是对称正定矩阵：

Wolfram Language code:

minij = Table[Min[i, j], {i, 5}, {j, 5}];
{SymmetricMatrixQ[minij], PositiveDefiniteMatrixQ[minij]}

它的逆矩阵是三对角矩阵，同时也是对称正定矩阵：

Wolfram Language code: inv = Inverse[minij]

Wolfram Language code: {SymmetricMatrixQ[inv], PositiveDefiniteMatrixQ[inv]}

正定矩阵的用途 (5)

通过，正定实对称矩阵或 metric 定义了内积：

Wolfram Language code: (g = {{7, 2, 0}, {2, 6, -2}, {0, -2, 5}})//MatrixForm

Wolfram Language code: ip[u_, v_] := u.g.v

验证是对称和正定的：

Wolfram Language code: SymmetricMatrixQ[g] && PositiveDefiniteMatrixQ[g]

正交化 $TemplateBox[{}, Reals]^n$ 标准基，求标准正交基：

Wolfram Language code: {Subscript[e, 1], Subscript[e, 2], Subscript[e, 3]} = Orthogonalize[IdentityMatrix[3], ip]

确认基是关于内积标准正交的：

Wolfram Language code: Table[ip[Subscript[e, i], Subscript[e, j]], {i, 3}, {j, 3}]//Simplify

惯性张量的矩相当于旋转运动的质量. 例如，动能为，取代了公式中的质量，角速度取代了线速度 . 可以用正定对称矩阵来表示. 计算端点在原点和正坐标轴的四面体的惯性矩：

Wolfram Language code: (ℐ = MomentOfInertia[Tetrahedron[{{0, 0, 0}, {4, 0, 0}, {0, 12, 0}, {0, 0, 20}}]])//MatrixForm

验证矩阵是对称的和正定的：

Wolfram Language code: SymmetricMatrixQ[ℐ] && PositiveDefiniteMatrixQ[ℐ]

如果角速度是，计算动能：

Wolfram Language code:

(1/2){Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]}.ℐ.{Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]}//FullSimplify

由于为正定矩阵，只要非零，动能就是正的：

Wolfram Language code:

Resolve[Subscript[∀, {Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]}, {Subscript[ω, x], Subscript[ω, y], Subscript[ω, z]} ≠ {0, 0, 0}]% > 0]

二阶导数检验对函数的临界点进行以下分类：如果 Hessian 矩阵为正定矩阵，则临界点为局部最小值，如果 Hessian 矩阵为负定矩阵，则临界点为局部最大值，如果 Hessian 矩阵为不定矩阵，则临界点为鞍点（如果 Hessian 矩阵不是这三种类型之一，则检验失败）. 求二元函数的临界点：

Wolfram Language code: f[x_, y_] := x ^ 4 + y ^ 4 - 20x ^ 2 - 10x y - 25

Wolfram Language code: grad = Grad[f[x, y], {x, y}]

Wolfram Language code: sol = NSolve[grad == {0, 0}, {x, y}, Reals]

计算 Hessian 矩阵：

Wolfram Language code: hessian = Grad[grad, {x, y}]

三个临界点中的最后一个是鞍点：

Wolfram Language code: IndefiniteMatrixQ[hessian /. sol[[3]]]

前两个点是局部极小点：

Wolfram Language code: PositiveDefiniteMatrixQ /@ (hessian /. sol[[1 ;; 2]])

可视化函数. 红点和蓝点是极小点，绿点是鞍点：

Wolfram Language code:

Show[Plot3D[f[x, y], {x, -5, 5}, {y, -5, 5}, PlotRange -> 200, ClippingStyle -> None, Mesh -> {5, 0}, PlotStyle -> Opacity[.65], BoxRatios -> {1, 1, 3 / 4}, ViewPoint -> {1.2, -2.5, 0}], Graphics3D[{PointSize[.04], Riffle[{Red, Blue, Green}, Point[{x, y, f[x, y]}] /. sol]}]]

求三变量函数的临界点：

Wolfram Language code: f[x_, y_, z_] := 25 - x^2 + 2 x^4 - x y - y^2 + 4 x^2 y^2 + 2 y^4 - 2 x z - 2 y z - z^2 + 4 x^2 z^2 + 4 y^2 z^2 + 2 z^4

Wolfram Language code: grad = Grad[f[x, y, z], {x, y, z}]

Wolfram Language code: sol = NSolve[grad == {0, 0, 0}, {x, y, z}, Reals]

计算 f 的 Hessian 矩阵：

Wolfram Language code: hessian = Grad[grad, {x, y, z}]

前两个临界点是局部极小点：

Wolfram Language code: PositiveDefiniteMatrixQ /@ (hessian /. Take[sol, 2])

最后三个点是鞍点：

Wolfram Language code: IndefiniteMatrixQ /@ (hessian /. Drop[sol, 2])

对该函数而言，任何三个临界点都是线性相关的，因此它们都位于一个平面上：

Wolfram Language code: Minors[{x, y, z} /. sol, 3]//Chop

计算平面的法线：

Wolfram Language code: normal = Apply[Cross, {x, y, z} /. sol[[{1, 3}]]]

可视化函数，极小值为绿色，非极端临界点为红色：

Wolfram Language code:

Show[SliceContourPlot3D[f[x, y, z], {{x, y, z}.normal == 0}, {x, -1, 1}, {y, -1, 1}, {z, -1, 1}, Contours -> 15, ViewVertical -> {-0.2, 0.7, 0.6}, ViewPoint -> {-1.2, -1.2, 2.9}], Graphics3D[{Riffle[{Green, Green, Red, Red, Red}, Sphere[{x, y, z}, 0.05] /. sol]}]]

CholeskyDecomposition 只适用于正定 Hermitian 矩阵：

Wolfram Language code: m = {{4, 0, 0}, {0, 3, 1}, {0, 1, 2}};

Wolfram Language code: PositiveDefiniteMatrixQ[m] && HermitianMatrixQ[m]

Wolfram Language code: b = CholeskyDecomposition[m]

的上三角分解是满足的矩阵：

Wolfram Language code: ConjugateTranspose[b].b == m

属性和关系 (15)

对于任何不是矩阵的 x，PositiveDefiniteMatrixQ[x] 返回 False：

Wolfram Language code: PositiveDefiniteMatrixQ[Sqrt[3]]

如果对于所有非零向量，，则矩阵是正定矩阵：

Wolfram Language code:

m = {{1, 2I}, {-I, 4}};
PositiveDefiniteMatrixQ[m]

Wolfram Language code:

Reduce[Subscript[∀, {Subscript[x, 1], Subscript[x, 2]}, Subscript[x, 1] ≠ 0 || Subscript[x, 2] ≠ 0]Re[{Subscript[x, 1], Subscript[x, 2]}.m.{Subscript[x, 1], Subscript[x, 2]}] > 0, {Subscript[x, 1], Subscript[x, 2]}, Complexes]

与的正负无关：

Wolfram Language code: Block[{x = {1, 1 - I}}, Im[x.m.x]]

Wolfram Language code: Block[{x = {1, -1 - I}}, Im[x.m.x]]

当且仅当实矩阵的对称部分是正定的，实矩阵才是正定矩阵：

Wolfram Language code:

m = (⁠|    |   |
| -- | - |
| 6  | 4 |
| -2 | 8 |⁠);s = Symmetrize[m];

Wolfram Language code: {PositiveDefiniteMatrixQ[m], PositiveDefiniteMatrixQ[s]}

一般情况下，当且仅当矩阵的 Hermitian 部分是正定的，矩阵才是正定矩阵：

Wolfram Language code:

c  = (⁠|     |        |
| --- | ------ |
| 4   | 4 I    |
| -2I | 4 + 2I |⁠);h = Symmetrize[c, Hermitian[All]];

Wolfram Language code: {PositiveDefiniteMatrixQ[c], PositiveDefiniteMatrixQ[h]}

当且仅当实对称矩阵的特征值都是正的，实对称矩阵才是正定矩阵：

Wolfram Language code:

s = (⁠|   |   |
| - | - |
| 2 | 1 |
| 1 | 2 |⁠);

Wolfram Language code: SymmetricMatrixQ[s] && PositiveDefiniteMatrixQ[s]

Wolfram Language code: And @@Positive /@ Eigenvalues[s]

该陈述更普遍适用于 Hermitian 矩阵：

Wolfram Language code:

h = (⁠|    |   |
| -- | - |
| 1  | I |
| -I | 2 |⁠);

Wolfram Language code: {HermitianMatrixQ[h] && PositiveDefiniteMatrixQ[h], And@@Positive /@ Eigenvalues[h]}

普通矩阵的所有特征值可以为正而不是正定矩阵：

Wolfram Language code:

Positive /@ Eigenvalues[(⁠|   |    |
| - | -- |
| 4 | -1 |
| 2 | 0  |⁠)]

Wolfram Language code:

PositiveDefiniteMatrixQ[(⁠|   |    |
| - | -- |
| 4 | -1 |
| 2 | 0  |⁠)]

同样，一个矩阵可以是正定的，但没有正的特征值：

Wolfram Language code:

PositiveSemidefiniteMatrixQ[(⁠|    |   |
| -- | - |
| 6  | 4 |
| -2 | 8 |⁠)]

Wolfram Language code:

λ = Eigenvalues[(⁠|    |   |
| -- | - |
| 6  | 4 |
| -2 | 8 |⁠)];
Positive /@ λ

失败是特征值为复数造成的：

Wolfram Language code: λ

正定矩阵的特征值的实部必须为正：

Wolfram Language code: Positive /@ Re[λ]

当且仅当对角元素有正的实部，对角矩阵才是正定矩阵：

Wolfram Language code:

PositiveDefiniteMatrixQ[(⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 2 | 0 |
| 0 | 0 | 4 |⁠)]

Wolfram Language code:

PositiveDefiniteMatrixQ[(⁠|   |   |   |
| - | - | - |
| 1 | 0 | 0 |
| 0 | 2 | 0 |
| 0 | 0 | 0 |⁠)]

正定矩阵的通用形式为，其中，为对角正定矩阵：

Wolfram Language code:

m = (⁠|                                           |                                            |                                            |
| ----------------------------------------- | ------------------------------------------ | ------------------------------------------ |
| 3.792168950417362                         | 2.973638210582098 + 1.4338467608374894 I   | 2.6847137114282464 + 1.096732668646098 I   |
| 2.5943303334981036 - 1.4338467608374894 I | 3.722968070528689                          | 2.2427900539994767 + 0.15267916356932992 I |
| 2.3008034014752843 - 1.096732668646098 I  | 2.5698503388043816 - 0.15267916356933003 I | 3.1 + I                                    |⁠);
PositiveDefiniteMatrixQ[m]

将划分为 Hermitian 和反厄米特部分：

Wolfram Language code: h = Symmetrize[m, Hermitian[All]];

Wolfram Language code: a = Symmetrize[m, Antihermitian[All]];

根据谱定理，可用 JordanDecomposition 将酉对角化：

Wolfram Language code: {u, d} = JordanDecomposition[h];

矩阵是对角矩阵，且对角元素为正：

Wolfram Language code: d//MatrixForm

矩阵是酉矩阵：

Wolfram Language code: UnitaryMatrixQ[u]

验证：

Wolfram Language code: u.d.u + a - m//Chop

当且仅当是负定矩阵，矩阵才是正定矩阵：

Wolfram Language code:

m = (⁠|                                             |                                             |                                             |                                             |
| ------------------------------------------- | ------------------------------------------- | ------------------------------------------- | ------------------------------------------- |
| 0.8368175179836128 + 0. I                   | 0.08442148190943044 - 0.07261632146865446 I | -1.2128453065519185 + 0.2791488701895241 I  | -0.7176461452206016 + 0.09729452115881893 I |
| 0.08442148190943044 + 0.07261632146865446 I | 3.39669580879013 + 0. I                     | -0.11306601611673339 - 1.0251509468914757 I | -1.3902042643674577 + 0.8867050522199316 I  |
| -1.2128453065519185 - 0.2791488701895241 I  | -0.11306601611673339 + 1.0251509468914757 I | 4.960363408128666 + 0. I                    | 0.3541172390806834 + 0.5132293867878579 I   |
| -0.7176461452206016 - 0.09729452115881893 I | -1.3902042643674577 - 0.8867050522199316 I  | 0.3541172390806834 - 0.5132293867878579 I   | 1.6764327323058408 + 0. I                   |⁠);

Wolfram Language code: {PositiveDefiniteMatrixQ[m], NegativeDefiniteMatrixQ[-m]}

正定矩阵一定是半正定矩阵：

Wolfram Language code: m = {{3, -1}, {1, 2}};

Wolfram Language code: {PositiveDefiniteMatrixQ[m], PositiveSemidefiniteMatrixQ[m]}

不可能是不定或半负定矩阵：

Wolfram Language code: {IndefiniteMatrixQ[m], NegativeSemidefiniteMatrixQ[m]}

正定矩阵是可逆的：

Wolfram Language code:

m = {{3.190023505153258, 2.4571124732137526, 3.1702589583416105}, {2.4571124732137526, 3.7756789190375084, 4.005717103481039}, {3.1702589583416105, 4.005717103481039, 4.806632993087039}};

Wolfram Language code: PositiveDefiniteMatrixQ[m]

Wolfram Language code: mi = Inverse[m]

逆矩阵也是正定矩阵：

Wolfram Language code: PositiveDefiniteMatrixQ[mi]

如果是实正定矩阵，则存在，使得对于任意实向量，有 $TemplateBox[{x}, Transpose].m.x>=delta ||x||^2$ 成立：

Wolfram Language code:

m = (⁠|         |         |         |
| ------- | ------- | ------- |
| (30/11) | (25/12) | (25/17) |
| (26/11) | (5/2)   | (33/17) |
| (15/7)  | (23/9)  | (22/9)  |⁠);

Wolfram Language code: PositiveDefiniteMatrixQ[m]

令为的对称部分的最小特征值：

Wolfram Language code: δ = First[Eigenvalues[Symmetrize[m, Symmetric], -1]]

验证 $TemplateBox[{x}, Transpose].m.x>=delta ||x||^2$ ：

Wolfram Language code: Reduce[ForAll[{x, y, z}, {x, y, z}.m.{x, y, z} ≥ δ{x, y, z}.{x, y, z}], {x, y, z}, Reals]

实对称正定矩阵的行列式和迹为正：

Wolfram Language code: s = MatrixPower[RandomVariate[GaussianOrthogonalMatrixDistribution[5]], 2];

Wolfram Language code: s∈Reals && SymmetricMatrixQ[s] && PositiveDefiniteMatrixQ[s]

Wolfram Language code: {Det[s] > 0, Tr[s] > 0}

这同样适用于正定 Hermitian 矩阵：

Wolfram Language code: h = MatrixPower[RandomVariate[GaussianUnitaryMatrixDistribution[5]], 2];

Wolfram Language code: HermitianMatrixQ[h] && PositiveDefiniteMatrixQ[h]

Wolfram Language code: {Chop[Det[h]] > 0, Tr[h] > 0}

实对称正定矩阵有唯一定义的平方根，使得成立：

Wolfram Language code:

m = {{3.190023505153258, 2.4571124732137526, 3.1702589583416105}, {2.4571124732137526, 3.7756789190375084, 4.005717103481039}, {3.1702589583416105, 4.005717103481039, 4.806632993087039}};

Wolfram Language code: PositiveDefiniteMatrixQ[m] && SymmetricMatrixQ[m]

Wolfram Language code: b = MatrixFunction[Sqrt, m]

Wolfram Language code: m == b.b

平方根是正定实对称矩阵：

Wolfram Language code: {PositiveDefiniteMatrixQ[b], b∈Reals && SymmetricMatrixQ[b]}

正定厄米特矩阵有唯一定义的平方根，使得成立：

Wolfram Language code:

m = {{4.4063915815780526, 2.415609335653971 - 0.9784858036636759 * I, 3.272554434576208 - 0.9581109282797712 * I}, {2.415609335653971 + 0.9784858036636759 * I, 3.2093833346047265, 2.1186156336423365 + 0.44745371013921886 * I}, {3.272554434576208 + 0.9581109282797711 * I, 2.1186156336423365 - 0.4474537101392189 * I, 2.711962460046668}};

Wolfram Language code: PositiveDefiniteMatrixQ[m] && HermitianMatrixQ[m]

Wolfram Language code: b = MatrixFunction[Sqrt, m]//Chop

Wolfram Language code: m - b.b//Chop

平方根是正定厄米特矩阵：

Wolfram Language code: {PositiveDefiniteMatrixQ[b], HermitianMatrixQ[b]}

两个对称正定矩阵的 Kronecker 积是对称正定矩阵：

Wolfram Language code:

m = {{2.9425255996142887, 1.6494147021595955, 3.6136769206595654}, {1.6494147021595955, 2.2267882143758357, 2.2251351542101174}, {3.6136769206595654, 2.2251351542101174, 4.4769591062377}};
n = {{0.10696857615478556, 0.09420715976163785}, {0.09420715976163785, 0.17814922498702113}};

Wolfram Language code: PositiveDefiniteMatrixQ[#] && SymmetricMatrixQ[#]& /@ {m, n}

Wolfram Language code: With[{prod = KroneckerProduct[m, n]}, {PositiveDefiniteMatrixQ[prod], SymmetricMatrixQ[prod]}]

用一个负定矩阵替换其中的一个矩阵，将得到一个负定矩阵：

Wolfram Language code: NegativeDefiniteMatrixQ[-n] && SymmetricMatrixQ[-n]

Wolfram Language code:

With[{prod = KroneckerProduct[m, -n]}, 
	NegativeDefiniteMatrixQ[prod] && SymmetricMatrixQ[prod]]

可能存在的问题 (2)

Hilbert 矩阵式正定矩阵：

Wolfram Language code: m = HilbertMatrix[16];

Wolfram Language code: PositiveDefiniteMatrixQ[m]

m 的最小的特征值太小，在机器精度上无法确定为正：

Wolfram Language code: Eigenvalues[N[m]]

在机器精度上，矩阵 m 的测试结果不是正定矩阵：

Wolfram Language code: PositiveDefiniteMatrixQ[N[m]]

Wolfram Language code: PositiveSemidefiniteMatrixQ[N[m]]

用足够高的精度来计算正的特征值将给出正确答案：

Wolfram Language code: PositiveDefiniteMatrixQ[N[m, 24]]

Wolfram Language code: Positive /@ Eigenvalues[N[m, 24]]

PositiveDefiniteMatrixQ 将给出 False，除非它可以证明一个符号矩阵是正定的：

Wolfram Language code: PositiveDefiniteMatrixQ[{{1 + a Conjugate[a], 0}, {0, 2 + a Conjugate[a]}}]

同时使用 Eigenvalues 和 Reduce 可给出更精确的结果：

Wolfram Language code: Eigenvalues[{{1 + a Conjugate[a], 0}, {0, 2 + a Conjugate[a]}}]

Wolfram Language code: Reduce[Re[%]0, a, Complexes]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

PositiveDefiniteMatrixQ

更多信息

范例

基本范例 (2)

范围 (10)

基本用法 (6)

特殊矩阵 (4)

应用 (15)

正定矩阵的几何与代数性质 (4)

正定矩阵的来源 (6)

正定矩阵的用途 (5)

属性和关系 (15)

可能存在的问题 (2)

文本

CMS

APA

BibTeX

BibLaTeX

PositiveDefiniteMatrixQ

更多信息

范例

基本范例 (2)

范围 (10)

基本用法 (6)

特殊矩阵 (4)

应用 (15)

正定矩阵的几何与代数性质 (4)

正定矩阵的来源 (6)

正定矩阵的用途 (5)

属性和关系 (15)

可能存在的问题 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX