WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Re[z]

複素数 z の実部を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
関数の特性  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Re

Re[z]

複素数 z の実部を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • Re[expr]は，expr が数ではない場合は未評価で残される．
  • Reは自動的にリストに並列的な関数の適用を行う．
  • ReはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (4)

複素数の実部を求める：

Wolfram Language code: Re[2 + 3I]

極形式で表現された複素数の実部を求める：

Wolfram Language code: Re[2Exp[I π / 3]]

複素平面の部分集合上でプロットする：

Wolfram Language code: Plot3D[Re[x + I y], {x, -2, 2}, {y, -2, 2}]

Reを用いて複素平面における領域を指定する：

Wolfram Language code: ComplexRegionPlot[Re[z] > 0, {z, 2}]

スコープ  (29)

数値評価  (7)

数値的に評価する：

Wolfram Language code: Re[1.2]

複素数入力：

Wolfram Language code: Re[(3/2) + (4/5)I]

高精度で評価する：

Wolfram Language code: N[Re[E + I Pi], 25]

混合精度の複素数入力：

Wolfram Language code: Re[1.64 - 2I]
Wolfram Language code: Re[1.6400000000000000000 - 2I]
Wolfram Language code: Re[(164/100) - 2`20I]
Wolfram Language code: Re[(164/100) - 2.5I]

高精度で効率的に評価する：

Wolfram Language code: N[Re[-5^(1/(5))], 100]//Timing
Wolfram Language code: N[Re[-5^(1/(5))], 10000];//Timing

Reは要素単位でリストと行列に縫い込まれる：

Wolfram Language code: Re[{1.2, 1.5I, -1.8I}]
Wolfram Language code: Re[(| | | | :- | :- | | 1 | u | | v | -I |)]

ReはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる：

Wolfram Language code: Re[Interval[{-1, 1}]]
Wolfram Language code: Re[CenteredInterval[-2 + 3I, 1 + 2I]]

特定の値  (6)

固定点におけるReの値：

Wolfram Language code: Table[Re[n], {n, {1, I 7 / 3, -7 / 5 + I}}]

0における値：

Wolfram Language code: Re[0]

無限大における値：

Wolfram Language code: Re[Infinity]
Wolfram Language code: Re[I Infinity]
Wolfram Language code: Re[DirectedInfinity[-1 + I]]
Wolfram Language code: Re[ComplexInfinity]

厳密値入力：

Wolfram Language code: Re[-5^(1/(5))]

複素指数関数について評価する：

Wolfram Language code: Table[Re[Exp[k I 3π / 8]], {k, 8}]

記号的に評価する：

Wolfram Language code: PiecewiseExpand[Re[I x], -2 < x < 2]

可視化  (5)

を実軸上で可視化する：

Wolfram Language code: Plot[Re[x^(1/(4))], {x, -3, 3}, MaxRecursion -> 15]

を実軸上でプロットする：

Wolfram Language code: Plot[Re[E^I x], {x, -2π, 2π}]

Reを複素平面上で可視化する：

Wolfram Language code: ComplexContourPlot[Re[z], {z, 2}, PlotLegends -> Automatic]

Reを三次元で可視化する：

Wolfram Language code: ComplexPlot3D[Re[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic, MeshFunctions -> {Re[#1]&, Im[#1]&}, Mesh -> Automatic]

Reを使って複素平面上の領域を指定する：

Wolfram Language code: ComplexRegionPlot[Re[z^3] > Re[(1/z^3)], {z, 2}]//Quiet

関数の特性  (5)

Reは実数と複素数のすべての入力について定義される：

Wolfram Language code: FunctionDomain[Re[x], x]
Wolfram Language code: FunctionDomain[Re[x], x, Complexes]

Reの値域は数直線全体である：

Wolfram Language code: FunctionRange[Re[x], x, y]

これは，複素平面上でさえ真である：

Wolfram Language code: FunctionRange[Re[x], x, y, Complexes]

Reは奇関数である：

Wolfram Language code: Re[-x] == -Re[x]

Reは微分可能関数ではない：

Wolfram Language code: Re'[x]

差分商は複素平面上では極限を持たない：

Wolfram Language code: Underscript[, hUnderscript[ -> , ℂ]0](Re[x + h] - Re[x]/h)

例えば実方向のような特定の方向にのみ極限がある：

Wolfram Language code: Underscript[, hUnderscript[ -> , ℝ]0](Re[x + h] - Re[x]/h)

ComplexExpandを使って結果を得る：

Wolfram Language code: ComplexExpand[Re'[x]]

TraditionalFormによる表示：

Wolfram Language code: Re[x]//TraditionalForm

関数の恒等式と簡約  (6)

自動簡約：

Wolfram Language code: Re[{Re[z], Im[z], I Re[z], Abs[z], Conjugate[z]}]

実変数 x と y を仮定して展開する：

Wolfram Language code: ComplexExpand[Re[x]]
Wolfram Language code: ComplexExpand[Re[x + I y]]

適切な仮定を使ってReを簡約する：

Wolfram Language code: Simplify[Re[x], x > 0]

複素数を実部と虚部の和として表す：

Wolfram Language code: FullSimplify[Re[z] + I Im[z]]

実部と虚部によって表す：

Wolfram Language code: Abs[x ^ 2]//FunctionExpand

Root式の実部を求める：

Wolfram Language code: Re[Root[# ^ 5 + 11# ^ 2 + 1&, 2]]//RootReduce

アプリケーション  (3)

複素数値の関数の実部として円柱の周囲に流す：

Wolfram Language code: ComplexContourPlot[Re[z - (1/z)], {z, 3}, Contours -> 40, Epilog -> {Disk[{0, 0}, 1]}]

複素関数から二変数実調和関数を構築する：

Wolfram Language code: z ^ 2Sin[z + z ^ 3] + Tan[(1/z)]
Wolfram Language code: ComplexExpand[Re[% /. z -> x + I y]]

実部はラプラス(Laplace)の方程式を満足する：

Wolfram Language code: D[%, x, x] + D[%, y, y]//Simplify

実部 から解析関数 を再構築する：

Wolfram Language code: analyticReconstruct[u_, {x_, y_}, z_] := 2(u //. {x -> z / 2, y -> -I z / 2}) - (u //. {x -> 0, y -> 0})

例題の再構築：

Wolfram Language code: analyticReconstruct[{x ^ 2 - y ^ 2, Exp[x]Cos[y]}, {x, y}, z]//Simplify

結果を検証する：

Wolfram Language code: ComplexExpand[Re[% /. z -> x + I y]]//Simplify

特性と関係  (8)

SimplifyとFullSimplifyを使ってReを含む式を簡約する：

Wolfram Language code: {Re[Exp[I Pi / 5]x], Re[2x + I]}
Wolfram Language code: Simplify[%, x > 3]
Wolfram Language code: FullSimplify[Abs[Re[z]] ≤ Abs[z]]

円板が右半平面にあることを証明する：

Wolfram Language code: FullSimplify[ForAll[z, Implies[Abs[z - 1] ≤ 1, Re[z] ≥ 0]]]

ComplexExpandは変数が実数であると仮定する：

Wolfram Language code: ComplexExpand[Re[(x + I y) ^ 3]]
Wolfram Language code: ComplexExpand[Re[Sin[x + I y]]]

ここでは z は実数であるとは仮定されず，結果はReとImによって与えられる：

Wolfram Language code: ComplexExpand[Abs[z] ^ 2, z, TargetFunctions -> {Re, Im}]

FunctionExpandは変数が実数であるとは仮定しない：

Wolfram Language code: FunctionExpand[Re[z1 + z2 + z3]]
Wolfram Language code: FunctionExpand[Re[(x + I y) ^ 3]]

ReImPlotは関数の実部と虚部をプロットする：

Wolfram Language code: {Plot[{Re[ArcSin[x]], Im[ArcSin[x]]}, {x, -3, 3}], ReImPlot[ArcSin[x], {x, -3, 3}]}

Reを使って複素平面上の領域を表す：

Wolfram Language code: Map[ComplexRegionPlot[#, {z, 3}, PlotPoints -> 40]&, {Re[(1 + I)z - 1] < 0, -1 < Re[z ^ 2] < 1, 0 < Re[(z - 1/z + 1)] < 3, Re[z ^ 7] < 7}]

ReduceはReを含む方程式および不等式を解くことができる：

Wolfram Language code: Reduce[Re[z ^ 2] > 1, z]
Wolfram Language code: Reduce[Re[z ^ 2] == 1 && Re[1 + z] ^ 2 == Abs[z] ^ 2, z]

FindInstanceを使って，領域内のサンプル点を得ることができる：

Wolfram Language code: FindInstance[Re[z ^ 2] > 1, z]

AssumptionsでReを使う：

Wolfram Language code: Integrate[x ^ s, {x, 1, Infinity}, Assumptions -> Re[s] < -1]
Wolfram Language code: Limit[1 / x ^ s, x -> Infinity, Assumptions -> Re[s] > 0]

IntegrateはしばしばReによる条件を生成する：

Wolfram Language code: Integrate[x ^ s, {x, 1, Infinity}]

考えられる問題  (2)

数値引数については，Reは未評価のままでもよい：

Wolfram Language code: {Re[Log[2 + I]], Re[Sqrt[1 + I]]}

追加的な変換を行うことで簡約できるかもしれない：

Wolfram Language code: FunctionExpand[%]

Reは複素変数の関数なので微分できない：

Wolfram Language code: D[Re[z], z]

複素関数なので，Conjugate[z]を含まずにRe[z]を書くことはできない：

Wolfram Language code: FullSimplify[Re[z] == (z + Conjugate[z]/2)]

特に，導関数を定義する極限は方向に依存するので存在しない：

Wolfram Language code: Limit[DifferenceQuotient[Re[z], {z, h}], h -> 0, Direction -> 1]
Wolfram Language code: Limit[DifferenceQuotient[Re[z], {z, h}], h -> 0, Direction -> I]

ComplexExpandを使って実数値変数について微分可能な式を得る：

Wolfram Language code: D[ComplexExpand[Re[x + I y]], y]

おもしろい例題  (1)

Reを使ってのリーマン(Riemann)面の3D投影をプロットする：

Wolfram Language code: ParametricPlot3D[{r Cos[φ], r Sin[φ], Re[Sqrt[r]Exp[I φ / 2]]}, {r, 0, 1}, {φ, 0, 4Pi}, PlotPoints -> 40]
Wolfram Research (1988), Re, Wolfram言語関数， https://reference.wolfram.com/language/ref/Re.html （2021年に更新）.

テキスト

Wolfram Research (1988), Re, Wolfram言語関数， https://reference.wolfram.com/language/ref/Re.html （2021年に更新）.

CMS

Wolfram Language. 1988. "Re." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Re.html.

APA

Wolfram Language. (1988). Re. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Re.html

BibTeX

@misc{reference.wolfram_2026_re, author="Wolfram Research", title="{Re}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Re.html}", note=[Accessed: 22-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_re, organization={Wolfram Research}, title={Re}, year={2021}, url={https://reference.wolfram.com/language/ref/Re.html}, note=[Accessed: 22-June-2026]}