WOLFRAM

Wolfram 语言与系统参考资料中心

RotationTransform[θ]

给出 TransformationFunction，表示在二维平面内，绕原点旋转 θ 角度.

RotationTransform[θ,p]

绕二维点 p 做二维旋转.

RotationTransform[θ,w]

沿三维向量 w 的方向作三维旋转.

RotationTransform[θ,w,p]

绕 w 轴，向 p 点的三维旋转.

RotationTransform[{u,v}]

绕原点旋转，转换向量 u 的方向到向量 v 的方向.

RotationTransform[{u,v},p]

绕点 p 的旋转，转换向量 u 的方向到向量 v 的方向.

RotationTransform[θ,{u,v},…]

在向量 u 和向量 v 确定的平面内，旋转 θ 弧度.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
基本  
图像变换  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关的工作流程
相关演示项目
历史
按以下格式引用：

RotationTransform

RotationTransform[θ]

给出 TransformationFunction，表示在二维平面内，绕原点旋转 θ 角度.

RotationTransform[θ,p]

绕二维点 p 做二维旋转.

RotationTransform[θ,w]

沿三维向量 w 的方向作三维旋转.

RotationTransform[θ,w,p]

绕 w 轴，向 p 点的三维旋转.

RotationTransform[{u,v}]

绕原点旋转，转换向量 u 的方向到向量 v 的方向.

RotationTransform[{u,v},p]

绕点 p 的旋转，转换向量 u 的方向到向量 v 的方向.

RotationTransform[θ,{u,v},…]

在向量 u 和向量 v 确定的平面内，旋转 θ 弧度.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

一个 θ 弧度的二维旋转变换：

Wolfram Language code: r = RotationTransform[θ]

旋转一个向量：

Wolfram Language code: r[{x, y}]

绕 轴旋转：

Wolfram Language code: r = RotationTransform[θ, {0, 0, 1}]
Wolfram Language code: r[{x, y, z}]

把一个二维图形绕原点旋转 30°：

Wolfram Language code: Graphics[GeometricTransformation[Rectangle[], RotationTransform[30Degree]], Frame -> True]

绕 轴旋转:

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "GraphicsComplex"];
Wolfram Language code: Manipulate[Graphics3D[{EdgeForm[None], GeometricTransformation[cow, RotationTransform[k Pi / 8, {1, 0, 0}]]}], {k, -1, 1}, SaveDefinitions -> True]

范围  (9)

绕点 {px,py} 旋转 θ 弧度：

Wolfram Language code: RotationTransform[θ, {px, py}]

关于点 {px,py,pz}，绕 轴旋转 θ 弧度：

Wolfram Language code: RotationTransform[θ, {1, 0, 0}, {px, py, pz}]

在 平面，一个二维旋转 θ 弧度：

Wolfram Language code: RotationTransform[θ, {{1, 0}, {0, 1}}]

在 平面，一个三维旋转 θ 弧度：

Wolfram Language code: RotationTransform[θ, {{1, 0, 0}, {0, 1, 0}}]

在 平面，一个四维旋转 θ 弧度：

Wolfram Language code: RotationTransform[θ, {{1, 0, 0, 0}, {0, 1, 0, 0}}]

在由 s{1,-1,1}+t{1,1,1} 确定的平面内，一个三维旋转 θ 弧度：

Wolfram Language code: r = RotationTransform[θ, {{1, -1, 1}, {1, 1, 1}}]

旋转向量 {1,1,1}：

Wolfram Language code: r[{1, -1, 1}]//Together

假定所有的数都是实数，产生一个符号矢量的变换：

Wolfram Language code: ComplexExpand[RotationTransform[Pi, {x, y, z}], TargetFunctions -> {Re, Im}]//Simplify

假定 {x,y,z} 是单位矢量，进一步简化结果：

Wolfram Language code: Simplify[%, x ^ 2 + y ^ 2 + z ^ 2 == 1]

应用于二维图形的旋转：

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, RotationTransform[Pi / 6, {1, 1}]]}]

应用于三维图形的旋转：

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, RotationTransform[Pi / 6, {0, 0, 1}, {1, 1, 1}]]}, Boxed -> False]

应用  (5)

基本  (2)

经过一个球体上的点 u 和 v，确定圆的参数：

Wolfram Language code: GreatCircle[{u_, v_}, θ_] := RotationTransform[θ, {u, v}][Normalize[u]];

圆穿过 {1,-1,1}/√3 和 {1,1,1}/√3 ：

Wolfram Language code: {u, v} = Normalize /@ {{1, -1, 1}, {1, 1, 1}};
Wolfram Language code: GreatCircle[{u, v}, θ]//Together

绘制圆：

Wolfram Language code: c = ParametricPlot3D[ Evaluate[GreatCircle[{u, v}, θ]], {θ, 0, 2π}]

在单位球体内显示圆和点：

Wolfram Language code: g = Show[ c, Graphics3D[{PointSize[0.02], Point[{u, v}], Opacity[0.5], Sphere[]}], PlotRange -> All]

用 GeometricTransformation：

Wolfram Language code: Show[Graphics3D[{Red, Table[GeometricTransformation[Point[u], RotationTransform[θ, {u, v}]], {θ, 0, 2Pi, 2Pi / 50.}]}], g]

旋转一个字符：

Wolfram Language code: Graphics[Table[GeometricTransformation[Style[Text["Q"], FontSize -> Scaled[1.3]], RotationTransform[a, {0, 1}]], {a, Pi / 5 Range[10]}]]

图像变换  (3)

使用 RotationTransform 关于 {0,0} 原点旋转图像：

Wolfram Language code: i = [image];
Wolfram Language code: ImageTransformation[i, RotationTransform[10°, {0, 0}]]

关于图像中心选择：

Wolfram Language code: ImageTransformation[i, RotationTransform[10°, {0.5, 0.5 ImageAspectRatio[i]}]]

在标准图像坐标系统中指定不同的旋转中心：

Wolfram Language code: HighlightImage[ImageTransformation[i, RotationTransform[10°, {20, 50}], DataRange -> Full], {PointSize[Large], {20, 50}}]

关于 轴旋转三维图像：

Wolfram Language code: ImageTransformation[[image], RotationTransform[Pi / 8, {0, 0, 1}]]

关于 轴旋转三维图像：

Wolfram Language code: ImageTransformation[[image], RotationTransform[Pi / 8, {0, 0, 1}]]

属性和关系  (9)

旋转变换是等量变换，即保持距离：

Wolfram Language code: t = RotationTransform[π / 3, {3, 4}];
Wolfram Language code: {p1, p2} = {{10, 17}, {1, 2}}; {tp1, tp2} = t[{p1, p2}];
Wolfram Language code: EuclideanDistance[p1, p2] == EuclideanDistance[tp1, tp2]//FullSimplify

旋转变换的线性部分由 RotationMatrix 给出：

Wolfram Language code: t = RotationTransform[π / 3, {1, 2, 3}]; m = TransformationMatrix[t][[1 ;; 3, 1 ;; 3]];
Wolfram Language code: m == RotationMatrix[π / 3, {1, 2, 3}]

对于实旋转，线性部分的矩阵是 OrthogonalMatrixQ：

Wolfram Language code: OrthogonalMatrixQ[m]

RotationTransform[θ,{u,v}] 的逆是 RotationTransform[-θ,{u,v}]：

Wolfram Language code: Composition[RotationTransform[θ, {{1, 0, 0}, {0, 0, 1}}], RotationTransform[-θ, {{1, 0, 0}, {0, 0, 1}}]]//Simplify

RotationTransform[θ,{u,v}] 的逆是 RotationTransform[θ,{v,u}]：

Wolfram Language code: Composition[RotationTransform[θ, {{1, 0, 0}, {0, 0, 1}}], RotationTransform[θ, {{0, 0, 1}, {1, 0, 0}}]]//Simplify

如果 u 或者 v 不是实数, 关系会更复杂：

Wolfram Language code: Composition[RotationTransform[Pi / 3, {{1, 0, 1}, {1 + I, 0, 1}}], RotationTransform[Pi / 3, {{1 + I, 0, 1}, {1, 0, 1}}]]//Simplify

RotationTransform[θ] 的逆由 RotationTransform[-θ] 得到：

Wolfram Language code: Composition[RotationTransform[θ], RotationTransform[-θ]]//Simplify

RotationTransform[θ,w] 的逆由 RotationTransform[-θ,w] 得到：

Wolfram Language code: Composition[RotationTransform[θ, {0, 0, 1}], RotationTransform[-θ, {0, 0, 1}]]//Simplify

RotationTransform[θ,w] 的逆由 RotationTransform[θ,-w] 得到：

Wolfram Language code: Composition[RotationTransform[θ, {0, 0, 1}], RotationTransform[θ, -{0, 0, 1}]]//Simplify

如果 w 不是实数, 关系会更复杂：

Wolfram Language code: Composition[RotationTransform[θ, {1, I, 0}], RotationTransform[θ, -{1, I, 0}]]//Simplify

旋转的分解是一个旋转：

Wolfram Language code: Composition[RotationTransform[Pi / 2, {1, 0, 0}], RotationTransform[Pi / 2, {0, 0, 1}]] == RotationTransform[2Pi / 3, {1, -1, 1}]

用 Rotate 作图形旋转：

Wolfram Language code: {Graphics[Rotate[Rectangle[], Pi / 6, {0, 0}]], Graphics[GeometricTransformation[Rectangle[], RotationTransform[Pi / 6]]]}
Wolfram Language code: {Graphics3D[Rotate[Cuboid[], Pi / 6, {0, 0, 1}, {0, 0, 0}]], Graphics3D[GeometricTransformation[Cuboid[], RotationTransform[Pi / 6, {0, 0, 1}]]]}

可能存在的问题  (1)

旋转的次序非常重要：

Wolfram Language code: rx = RotationTransform[θ, {1, 0, 0}]; ry = RotationTransform[ϕ, {0, 1, 0}];

不同顺序的旋转，结果是不同的：

Wolfram Language code: Composition[rx, ry][{x, y, z}] - Composition[ry, rx][{x, y, z}]

巧妙范例  (1)

关于点 p 旋转三维对象：

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "GraphicsComplex"];
Wolfram Language code: p = {0, 0, -0.251619};

在 平面上，沿着 轴旋转：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k + 2], 0.5], GeometricTransformation[cow, RotationTransform[k Pi / 8, {1, 0, 0}, p]]}, {k, -1, 1}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

在 平面内，沿着 轴旋转：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k + 2], 0.5], GeometricTransformation[cow, RotationTransform[k Pi / 8, {0, 1, 0}, p]]}, {k, -1, 1}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

在 平面内，沿着 轴旋转：

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k + 2], 0.5], GeometricTransformation[cow, RotationTransform[k Pi / 8, {0, 0, 1}, p]]}, {k, -1, 1}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]
Wolfram Research (2007)，RotationTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RotationTransform.html.

文本

Wolfram Research (2007)，RotationTransform，Wolfram 语言函数，https://reference.wolfram.com/language/ref/RotationTransform.html.

CMS

Wolfram 语言. 2007. "RotationTransform." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/RotationTransform.html.

APA

Wolfram 语言. (2007). RotationTransform. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/RotationTransform.html 年

BibTeX

@misc{reference.wolfram_2026_rotationtransform, author="Wolfram Research", title="{RotationTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/RotationTransform.html}", note=[Accessed: 03-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_rotationtransform, organization={Wolfram Research}, title={RotationTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/RotationTransform.html}, note=[Accessed: 03-November-2026]}