Wolfram 语言与系统参考资料中心

RulePlot

RulePlot[sys]

生成表示计算系统 sys 的规则的图.

RulePlot[sys,init,t]

生成 sys 从初始条件 init 开始向前演化 t 步的图.

RulePlot[sys,evol]

假定 evol 从形式为 sys 的系统导出，生成它的演化图.

范例

打开所有单元关闭所有单元

基本范例 (5)

为基础原胞自动规则 30 返回规则图标：

Wolfram Language code: RulePlot[CellularAutomaton[30]]

绘制 10 步原胞自动演化：

Wolfram Language code: RulePlot[CellularAutomaton[30], {{1}, 0}, 10]

把规则图标包含进去：

Wolfram Language code: RulePlot[CellularAutomaton[30], {{1}, 0}, 10, PlotLegends -> "Icon"]

绘制图灵机演化：

Wolfram Language code: RulePlot[TuringMachine[{596440, 2, 3}], {1, {{}, 0}}, 20]

返回规则图标：

Wolfram Language code: RulePlot[TuringMachine[{596440, 2, 3}]]

生成图灵机的演化过程:

Wolfram Language code: evolution = TuringMachine[{596440, 2, 3}, {1, {{}, 0}}, 5]

用 RulePlot 显示过程，用规则信息确定绘图形式：

Wolfram Language code: RulePlot[TuringMachine[{596440, 2, 3}], evolution]

显示替代系统的规则图标：

Wolfram Language code: RulePlot[SubstitutionSystem[{1 -> {1, 0}, 0 -> {0, 1}}], Appearance -> "Arrow"]

范围 (42)

系统规则 (31)

CellularAutomaton (11)

初等细胞自动机规则 90：

Wolfram Language code: RulePlot[CellularAutomaton[90]]

多于两种颜色的细胞自动机：

Wolfram Language code: RulePlot[CellularAutomaton[{679458, 3}]]

范围大于 1 的细胞自动机：

Wolfram Language code: RulePlot[CellularAutomaton[{1234, 2, 2}]]

范围为分数的细胞自动机：

Wolfram Language code: RulePlot[CellularAutomaton[{9, 2, 3 / 2}]]

总和 3-色细胞自动机：

Wolfram Language code: RulePlot[CellularAutomaton[{1599, {3, 1}}]]

outer 总和 3-色细胞自动机：

Wolfram Language code: RulePlot[CellularAutomaton[{1000, {3, {3, 1, 3}}}]]

广义二维细胞自动机：

Wolfram Language code: RulePlot[CellularAutomaton[{23571113171923, 2, {1, 1}}]]

二维总和 5-邻居规则：

Wolfram Language code: RulePlot[CellularAutomaton[{20, {2, {{0, 1, 0}, {1, 1, 1}, {0, 1, 0}}}, {1, 1}}]]

二维总和 9-邻居规则：

Wolfram Language code: RulePlot[CellularAutomaton[{111, {2, {{1, 1, 1}, {1, 1, 1}, {1, 1, 1}}}, {1, 1}}]]

Outer 二维总和规则：

Wolfram Language code: RulePlot[CellularAutomaton[{222, {2, {{2, 2, 2}, {2, 1, 2}, {2, 2, 2}}}, {1, 1}}]]

用关联指定的规则：

Wolfram Language code: RulePlot[CellularAutomaton[<|"RuleNumber" -> 30|>]]

Wolfram Language code: RulePlot[CellularAutomaton[<|"TotalisticCode" -> 14, "Dimension" -> 2|>]]

Wolfram Language code: RulePlot[CellularAutomaton[<|"OuterTotalisticCode" -> 110, "Dimension" -> 2, "Neighborhood" -> 5|>]]

TuringMachine (8)

图灵机规则 2506：

Wolfram Language code: RulePlot[TuringMachine[2506]]

状态多于两个的图灵机：

Wolfram Language code: RulePlot[TuringMachine[{600720, 3}]]

超过两色的图灵机:

Wolfram Language code: RulePlot[TuringMachine[{596440, 2, 3}]]

由规则指定的图灵机:

Wolfram Language code:

RulePlot[TuringMachine[{{1, 2} -> {1, 1, -1}, {1, 1} -> {1, 2, -1}, {1, 0} -> {2, 1, 1}, {2, 2} -> {1, 0, 1}, {2, 1} -> {2, 2, 1}, {2, 0} -> {1, 2, -1}}]]

为相同的转换规则显式指定状态数 s 和颜色数 k 的值：

Wolfram Language code: rules = {{1, 1} -> {2, 0, -1}, {1, 0} -> {2, 1, 1}, {2, 1} -> {1, 0, 1}, {2, 0} -> {1, 1, -1}};

Wolfram Language code: RulePlot[TuringMachine[{rules, 2, 2}]]

Wolfram Language code: RulePlot[TuringMachine[{rules, 3, 3}]]

单态图灵机头用一个点表示：

Wolfram Language code: RulePlot[TuringMachine[{{1, 1} -> {1, 0, -1}, {1, 0} -> {1, 0, -1}}]]

增加状态数以更改表示：

Wolfram Language code: RulePlot[TuringMachine[{{{1, 1} -> {1, 0, -1}, {1, 0} -> {1, 0, -1}}, 2, 2}]]

未充分指定的图灵机不具有适用于所有 s k 输入配置的规则：

Wolfram Language code: RulePlot[TuringMachine[{{1, 0} -> {2, 1, 1}, {2, 1} -> {1, 0, 1}, {2, 0} -> {1, 1, -1}}]]

非确定性图灵机为相同的输入配置指定不同的规则：

Wolfram Language code: RulePlot[TuringMachine[{{1, 0} -> {1, 0, -1}, {1, 0} -> {1, 0, 1}}]]

SubstitutionSystem (8)

两个字符的字符串代换系统：

Wolfram Language code: RulePlot[SubstitutionSystem[{"a" -> "ba", "b" -> "aa"}]]

多于两个字符的字符串代换系统：

Wolfram Language code: RulePlot[SubstitutionSystem[{"a" -> "ba", "b" -> "da", "c" -> "ca", "d" -> "bc"}]]

长度为 2 的字符串的字符串代换系统：

Wolfram Language code: RulePlot[SubstitutionSystem[{"aa" -> "bc", "ab" -> "aa", "ba" -> "ab", "cb" -> "ac", "cc" -> "ba"}]]

不同长度的字符串的字符串代换系统：

Wolfram Language code: RulePlot[SubstitutionSystem[{"aa" -> "ba", "ab" -> "c", "bac" -> "aba", "bba" -> "b", "c" -> "bc"}]]

给出两位整数的代换系统：

Wolfram Language code: RulePlot[SubstitutionSystem[{0 -> {0, 1}, 1 -> {0, 0}}]]

给出多于两位整数的代换系统：

Wolfram Language code: RulePlot[SubstitutionSystem[{0 -> {0, 1}, 1 -> {2, 3}, 2 -> {1, 2}, 3 -> {2, 0}}]]

给出不同长度的整数的代换系统：

Wolfram Language code: RulePlot[SubstitutionSystem[{0 -> {0, 1, 3}, 1 -> {2, 3}, 2 -> {1}, 3 -> {2, 0}}]]

二维代换系统：

Wolfram Language code: RulePlot[SubstitutionSystem[{0 -> {{0, 0}, {0, 0}}, 1 -> {{0, 1}, {1, 1}}}]]

Wolfram Language code: RulePlot[SubstitutionSystem[{0 -> {{0, 0, 0}, {0, 0, 0}}, 1 -> {{1, 0, 0}, {1, 1, 1}}}]]

BooleanFunction (4)

两个变量的布尔函数：

Wolfram Language code: RulePlot[BooleanFunction[8, 2]]

多于两个变量的布尔函数：

Wolfram Language code: RulePlot[BooleanFunction[251084, 5]]

基于真值向量的布尔函数：

Wolfram Language code: RulePlot[BooleanFunction[{True, True, True, False, False, False, False, False}]]

基于真值规则表的布尔函数：

Wolfram Language code:

RulePlot[BooleanFunction[{
	{True, True, True} -> 0, {True, True, False} -> 0, 
	{True, False, True} -> 0, {True, False, False} -> 1, 
	{False, True, True} -> 0, {False, True, False} -> 0, 
	{False, False, True} -> 1, {False, False, False} -> 1
	}]]

系统演化 (11)

CellularAutomaton (5)

把规则 30 向前推演 10 步：

Wolfram Language code: RulePlot[CellularAutomaton[30], {0, 0, 1, 1, 1, 0, 0}, 10]

从 1 开始，以 0 为背景向前推演 50 步：

Wolfram Language code: RulePlot[CellularAutomaton[30], {{1}, 0}, 50]

3-色细胞自动机的演进：

Wolfram Language code: RulePlot[CellularAutomaton[{679458, 3}], {{1}, 0}, 120]

从 1 开始，以重复的 0110 块为背景向前推演：

Wolfram Language code: RulePlot[CellularAutomaton[{679458, 3}], {{1}, {0, 1, 1, 0}}, 120]

3-色总和细胞自动机的演进：

Wolfram Language code: RulePlot[CellularAutomaton[{2049, {3, 1}}], {{1}, 0}, 100]

3-色 outer 总和细胞自动机的演进：

Wolfram Language code: RulePlot[CellularAutomaton[{50010, {3, {3, 1, 3}}}], {{1}, 0}, 100]

由关联指定的规则的演进：

Wolfram Language code: RulePlot[CellularAutomaton[<|"RuleNumber" -> 23898, "Range" -> 3 / 2|>], {{1}, 0}, 80]

Wolfram Language code: RulePlot[CellularAutomaton[<|"TotalisticCode" -> 1599, "Colors" -> 3|>], {{1}, 0}, 200]

TuringMachine (6)

2 个状态、2-色图灵机的演进，从四个 0 的纸带开始：

Wolfram Language code: RulePlot[TuringMachine[2506], {1, {0, 0, 0, 0}}, 20]

从无限个 0 的纸带开始推演：

Wolfram Language code: RulePlot[TuringMachine[2506], {1, {{}, 0}}, 20]

3 个状态、2-色图灵机的演进：

Wolfram Language code: RulePlot[TuringMachine[{956440, 3}], {1, {{}, 0}}, 20]

从 1 开始，背景为 0，开始推演：

Wolfram Language code: RulePlot[TuringMachine[{956440, 3}], {1, {{1}, 0}}, 20]

2 个状态、3-色图灵机的演进：

Wolfram Language code: RulePlot[TuringMachine[{596440, 2, 3}], {1, {{}, 0}}, 20]

读写头的初始状态为 2 的演进：

Wolfram Language code: RulePlot[TuringMachine[{596440, 2, 3}], {2, {{}, 0}}, 20]

由规则指定的图灵机的演进，以重复的 021 块为背景开始推演：

Wolfram Language code:

RulePlot[TuringMachine[{
	{1, 0} -> {1, 2, 1}, {1, 1} -> {1, 2, 1}, {1, 2} -> {2, 0, -1}, 
	{2, 0} -> {2, 1, -1}, {2, 1} -> {1, 2, 1}, {2, 2} -> {2, 0, -1}
	}], {1, {{}, {0, 2, 1}}}, 50]

非确定性图灵机可以根据其规则的顺序给出不同的演变：

Wolfram Language code: RulePlot[TuringMachine[{{1, 0} -> {1, 0, -1}, {1, 0} -> {1, 0, 1}}], {1, {{}, 0}}, 10, PlotLegends -> "Icon"]

Wolfram Language code: RulePlot[TuringMachine[{{1, 0} -> {1, 0, 1}, {1, 0} -> {1, 0, -1}}], {1, {{}, 0}}, 10, PlotLegends -> "Icon"]

未充分指定的图灵机不具有适用于所有 s k 输入配置的规则：

Wolfram Language code: RulePlot[TuringMachine[{{1, 0} -> {2, 1, 1}, {2, 1} -> {1, 0, 1}, {2, 0} -> {1, 1, -1}}], {1, {{}, 0}}, 10]

指定一套完整的规则消除固定点：

Wolfram Language code:

RulePlot[TuringMachine[{{1, 1} -> {2, 0, -1}, {1, 0} -> {2, 1, 1}, {2, 1} -> {1, 0, 1}, {2, 0} -> {1, 1, -1}}], {1, {{}, 0}}, 10]

选项 (19)

Appearance (4)

用六边形：

Wolfram Language code: RulePlot[CellularAutomaton[{9, 2, 1 / 2}], Appearance -> "Hexagons"]

用砖形：

Wolfram Language code: RulePlot[CellularAutomaton[{9, 2, 1 / 2}], Appearance -> "Bricks"]

有时获取简单的结果显示原胞的值没关系：

Wolfram Language code: RulePlot[CellularAutomaton[30], Appearance -> "Simplified"]

缩短规则集的显示：

Wolfram Language code: RulePlot[CellularAutomaton[{31469, 5}], Appearance -> "Short"]

ColorRules (1)

为显式数值或模式指定颜色规则：

Wolfram Language code: RulePlot[CellularAutomaton[{1234, 3}], ColorRules -> {0 -> White, 1 -> Red, _ -> Purple}]

Frame (1)

不使用边框：

Wolfram Language code: RulePlot[CellularAutomaton[30], Frame -> False]

FrameStyle (2)

把边框设置为蓝色：

Wolfram Language code: RulePlot[CellularAutomaton[30], FrameStyle -> Blue]

给出框架的合成指令：

Wolfram Language code: RulePlot[CellularAutomaton[30], FrameStyle -> Directive[Orange, Dashed]]

Mesh (1)

缺省情况下，在每个格子周围画上网格：

Wolfram Language code: RulePlot[CellularAutomaton[30], PlotTheme -> "Web"]

不要画出网格：

Wolfram Language code: RulePlot[CellularAutomaton[30], Mesh -> False, PlotTheme -> "Web"]

MeshStyle (2)

蓝色网格：

Wolfram Language code: RulePlot[CellularAutomaton[30], MeshStyle -> Blue]

对网格给出组合指令：

Wolfram Language code: RulePlot[CellularAutomaton[30], MeshStyle -> Directive[Orange, Thick]]

PlotLegends (3)

用文字给出描述规则的图例：

Wolfram Language code: RulePlot[CellularAutomaton[30], PlotLegends -> "Text"]

用图标给出描述规则的图例：

Wolfram Language code: RulePlot[CellularAutomaton[30], {{1}, 0}, 20, PlotLegends -> "Icon"]

给出任意图例：

Wolfram Language code: RulePlot[CellularAutomaton[30], {{1}, 0}, 100, PlotLegends -> Placed[Text["complex behavior"], Below]]

PlotMarkers (2)

把图灵机的读写头标记设为灰色：

Wolfram Language code: RulePlot[TuringMachine[{596440, 2, 3}], {1, {{}, 0}}, 20, PlotMarkers -> Gray]

画出默认标记的轮廓：

Wolfram Language code:

RulePlot[TuringMachine[{596440, 2, 3}], {1, {{}, 0}}, 20, PlotMarkers -> Directive[EdgeForm[{Black, AbsoluteThickness[1]}], 
	FaceForm[]]]

PlotTheme (2)

采用网络主题：

Wolfram Language code: RulePlot[CellularAutomaton[30], PlotTheme -> "Web"]

使用没有网格的该主题：

Wolfram Language code: RulePlot[CellularAutomaton[30], PlotTheme -> "Web", Mesh -> False]

使用科学绘图主题：

Wolfram Language code:

RulePlot[TuringMachine[{
	{1, 0} -> {1, 2, 1}, {1, 1} -> {1, 2, 1}, {1, 2} -> {2, 0, -1}, 
	{2, 0} -> {2, 1, -1}, {2, 1} -> {1, 2, 1}, {2, 2} -> {2, 0, -1}, 
	{3, 0} -> {5, 2, -1}, {3, 1} -> {3, 2, 1}, {3, 2} -> {3, 1, 1}, 
	{4, 0} -> {5, 0, -1}, {4, 1} -> {4, 1, 1}, {4, 2} -> {4, 0, 1}, 
	{5, 0} -> {5, 1, 0}, {5, 1} -> {5, 2, -1}, {5, 2} -> {5, 0, -1}, 
	{6, 0} -> {3, 2, 1}, {6, 1} -> {5, 0, -1}, {6, 2} -> {6, 0, -1}
	}], PlotTheme -> "Scientific"]

Spacings (1)

改变边框内的间距：

Wolfram Language code: RulePlot[CellularAutomaton[30], Spacings -> 1]

改变图标的每个边的间距：

Wolfram Language code: RulePlot[CellularAutomaton[30], Spacings -> {{1, 2}, {3, 4}}]

应用 (2)

使用 ArrayPlot 将规则 30 可视化，并使用 RulePlot 绘制 CellularAutomaton 的规则：

Wolfram Language code: ArrayPlot[CellularAutomaton[30, {{1}, 0}, 50], PlotTheme -> "Web"]

Wolfram Language code: RulePlot[CellularAutomaton[30], PlotTheme -> "Web"]

用 RulePlot 来为 CellularAutomaton 的演化图加上图例：

Wolfram Language code: RulePlot[CellularAutomaton[30], {{1}, 0}, 50, PlotLegends -> "Icon"]

属性和关系 (2)

用 ArrayPlot 绘制细胞自动机的演进：

Wolfram Language code: ArrayPlot[CellularAutomaton[90, {{1}, 0}, 50]]

用 RulePlot 绘制演进图和规则图标：

Wolfram Language code: RulePlot[CellularAutomaton[90], {{1}, 0}, 50, PlotLegends -> "Icon"]

用 ArrayPlot 绘制图灵机的演进：

Wolfram Language code: ArrayPlot[Last /@ TuringMachine[2506, {1, {{}, 0}}, 20]]

用 RulePlot 绘制演进图和机器的读写头：

Wolfram Language code: RulePlot[TuringMachine[2506], {1, {{}, 0}}, 20]

Top

	CellularAutomaton[spec]	元胞自动机
	TuringMachine[spec]	图灵机
	SubstitutionSystem[spec]	替代系统
	BooleanFunction[spec]	布尔函数

Appearance	Automatic	整体外观
ColorRules	Automatic	用于根据数值确定颜色的规则
Frame	Automatic	是否在规则外面画上边框
FrameStyle	Automatic	边框的样式
Mesh	Automatic	是否画上网格
MeshStyle	Automatic	网格的样式
PlotLegends	None	包含的图例
PlotMarkers	Automatic	图灵机的标记等
PlotTheme	$PlotTheme	规则图的整体主题
Spacings	Automatic	纵向和横向间距

		"Contiguous"	状态间没有间距
		"Stacked"	状态间加上小间距
		"Arrow"	状态间加上箭头
		"Squares"	正方形单元
		"Bricks"	砖形单元
		"Hexagons"	六边形单元
		"Simplified"	简化的规则实例
		"Short"	显示简少的规则

	"Icon"	用图标作为图例
	"Text"	用文字作为图例
	expr	任意图例

RulePlot

更多信息和选项

范例

基本范例 (5)

范围 (42)

系统规则 (31)

CellularAutomaton (11)

TuringMachine (8)

SubstitutionSystem (8)

BooleanFunction (4)

系统演化 (11)

CellularAutomaton (5)

TuringMachine (6)

选项 (19)

Appearance (4)

ColorRules (1)

Frame (1)

FrameStyle (2)

Mesh (1)

MeshStyle (2)

PlotLegends (3)

PlotMarkers (2)

PlotTheme (2)

Spacings (1)

应用 (2)

属性和关系 (2)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX