ScheduledTask

timespec で定義されるスケジュールで評価される，スケジュールされたタスクを表す．

詳細とオプション

CloudDeploy[ScheduledTask[…]]は，スケジュールされたタスクがクラウド内で実行されるように配備する．
SessionSubmit，LocalSubmit，CloudSubmitは，ローカルシステムあるいはクラウドの現行セッションのバックグラウンドで評価されるようにスケジュールされたタスクを送信する．
スケジュールされたタスクは，TaskSuspend，TaskResume等の関数を使って制御することができる．
引数 expr は，評価するWolfram言語のコード，CloudObject，Wolfram言語の入力を含むFileのいずれでもよい．
次の時間 period 指定を与えることができる．

	"Hourly"	1時間に1回実行
	"Daily"	1日に1回実行
	"Weekly"	1週間に1回実行
	"Monthly"	1ヶ月に1回実行
	"Yearly"	1年に1回実行
	Quantity[...]	指定された時間間隔で実行

次の timespec 指定を与えることができる．
period period ごとに実行

{period} period の後で1回実行

{period, count} count 回だけ実行
次の指定でタスクの実行時期を制限することができる．
{start,timespec} 日付 start から実行

{timespec,end} 日付 end に終了

{start,timespec,end} 日付 start から end まで実行
start と end のパラメータはDateObjectとして，あるいは他の時間指定で与えることができる．
追加的な timespec 指定を与えることができる．

	DateObject[patt]	指定されたパターンにマッチする時に実行
	"cronspec"	Unixのクロン指定で指定された時に実行
	Now	すぐに実行
	None	オンデマンドのみで実行

DateObject[patt]では，パターン patt の形式は{y,m,d,h,m,s}である．ただし，後半の要素は除外することができる．各要素は，整数，n₁|n₂|…の形式の整数の選択，あるいは可能な任意の値を表す_でよい．日の要素に関しては，文字通りの日を，Monday等の曜日を表す記号で置換することもできる．
使用可能なオプション

AutoRemove	False	最終のスケジュールされた実行後にタスクを取り除く
NotificationFunction	Automatic	通知の出し方
TimeZone	Automatic	スケジュールの時刻帯

NotificationFunctionの目的で，出力が$FailedオブジェクトまたはFailureオブジェクトのときはタスクが失敗したとみなされる．
クラウドでは，スケジュールされたタスクが実行される正確な時刻は，一般に，負荷分散の必要条件によって決定される．
クラウドにおけるタスクを反復する際のタスクとタスクの間の最短時間は，クラウド設定とその指針によって決定される．一般に，1時間の何分の1かである．

例題

すべて開くすべて閉じる

例 (4)

ローカルセッションでスケジュールされたタスクを作る：

Wolfram Language code: obj = SessionSubmit[ScheduledTask[Print[Now, " ", MemoryInUse[]], Quantity[1, "Minutes"]]]

Print出力はメッセージウィンドウに表示される．

タスクを削除する：

Wolfram Language code: TaskRemove[obj]

別のカーネルでスケジュールされたタスクを作る：

Wolfram Language code:

obj = LocalSubmit[ScheduledTask[Now, Quantity[15, "Seconds"]], 
	HandlerFunctions -> <|"ResultReceived" -> Print|>, 
	HandlerFunctionsKeys -> "EvaluationResult"
	]

Print出力はメッセージウィンドウに表示される．

タスクを削除する：

Wolfram Language code: TaskRemove[obj]

次の1ヶ月間，タスクの所有者に毎日気温を電子メールで通知するスケジュールされたクラウドタスクを作る：

Wolfram Language code:

obj = CloudSubmit[ScheduledTask[SendMail[<|"To" -> $CloudUserID, "Subject" -> DateString[], "Body" -> AirTemperatureData[]|>], "Hourly"]]

タスクを削除する：

Wolfram Language code: TaskRemove[obj]

日付と気温を1時間ごとに記録するスケジュールされたクラウドタスクを配備する：

Wolfram Language code: obj = CloudDeploy[ScheduledTask[PutAppend[{Now, AirTemperatureData[]}, CloudObject["results.log"]], "Hourly"]]

このタスクを手動で実行してスケジュールされている次の実行を待たずにテストする：

Wolfram Language code: TaskExecute[obj]

過去の結果のリストを取り出す：

Wolfram Language code: ReadList[CloudObject["results.log"]]

タスクを削除する：

Wolfram Language code: TaskRemove[obj]

スコープ (9)

時間指定 (9)

スケジュールがないタスクを作成する：

Wolfram Language code: task = SessionSubmit[ScheduledTask[Print[Now], None]]

手動でタスクをトリガする：

Wolfram Language code: TaskExecute[task]

タスクを削除する：

Wolfram Language code: TaskRemove[task]

timespec のNowを使って即座に実行されるタスクを現行のカーネルセッションで送信する：

Wolfram Language code: task = SessionSubmit[ScheduledTask[MessageDialog["Done"], Now]]

このタスクは自動的に削除される：

Wolfram Language code: Tasks[]

即座に実行されるタスクをクラウドに送信する：

Wolfram Language code: task = CloudSubmit[ScheduledTask[SendMail["Done"], Now]]

タスクは実行後はクラウドからなくなる：

Wolfram Language code: FileExistsQ[CloudObject["uuid:" <> task["TaskUUID"]]]

スケジュールがないタスクを配備する：

Wolfram Language code: task = CloudDeploy[ScheduledTask[SendMail["Done with deployed task."], Now]]

（CloudDeployではなくCloudSubmitで作成した）タスクは，配備され実行された後もクラウドに存在し続ける：

Wolfram Language code: FileExistsQ[task]

配備したタスクを削除する：

Wolfram Language code: TaskRemove[task]

実行の進捗状況を表示しながら合計10回毎秒実行されるタスクを作成する：

Wolfram Language code:

n = 0;
ProgressIndicator[Dynamic[n], {0, 10}]
task = SessionSubmit[ScheduledTask[Print[Now, " ", n++], {Quantity[1, "Seconds"], 10}]]

明日からカウントダウンの電子メールを毎日送信するタスクを配備する：

Wolfram Language code:

thisYear = First[DateList[]]
task = CloudDeploy[ScheduledTask[SendMail[StringTemplate["`1` left in `2`"][DateObject[{thisYear + 1, 1, 1}] - Today, thisYear]], {Tomorrow, "Daily"}]]

このタスクを検査するために，すぐに実行するようにトリガする：

Wolfram Language code: TaskExecute[task]

タスクを削除する：

Wolfram Language code: TaskRemove[task]

1年の終りまで毎日カウントダウンの電子メールを送信するタスクを配備する：

Wolfram Language code:

thisYear = First[DateList[]]
beginningOfNextYear = DateObject[{thisYear + 1, 1, 1}]
task = CloudDeploy[ScheduledTask[SendMail[StringTemplate["`1` left in `2`"][beginningOfNextYear - Today, thisYear]], {"Daily", beginningOfNextYear}]]

このタスクを検査するために，すぐに実行するようにトリガする：

Wolfram Language code: TaskExecute[task]

タスクを削除する：

Wolfram Language code: TaskRemove[task]

明日から始めて1年の終わりまで毎日カウントダウンの電子メールを送信するタスクを配備する：

Wolfram Language code:

thisYear = First[DateList[]]
beginningOfNextYear = DateObject[{thisYear + 1, 1, 1}]
task = CloudDeploy[ScheduledTask[SendMail[StringTemplate["`1` left in `2`"][beginningOfNextYear - Today, thisYear]], {Tomorrow, "Daily", beginningOfNextYear}]]

このタスクを検査するために，すぐに実行するようにトリガする：

Wolfram Language code: TaskExecute[task]

タスクを削除する：

Wolfram Language code: TaskRemove[task]

1週間の特定の曜日の午前7時に実行されるタスクを作成する：

Wolfram Language code:

task = CloudDeploy[ScheduledTask[SendMail["Reminder: office hours today, 11-12"], DateObject[{_, _, Monday | Wednesday | Thursday, 7}]]]

次の実行曜日が想定通りであることを確認する：

Wolfram Language code: ScheduledTaskInformation[task, "NextRunDate"]

タスクを削除する：

Wolfram Language code: TaskRemove[task]

"cronspec"指定を使って週日に金融商品の始値を記録するようにスケジュールされたタスクを作成する：

Wolfram Language code: obj = CloudDeploy[ScheduledTask[{Now, FinancialData["QQQ", "Open"]}, "* 10 * * 1,2,3,4,5"]]

タスクを削除する：

Wolfram Language code: TaskRemove[obj]

毎日1回クラウド内でタイムスタンプを更新するようにスケジュールされたクラウドタスクを作成する：

Wolfram Language code: time = DateList[];

Wolfram Language code: var = CloudSave[time];

Wolfram Language code:

obj = With[{co = var}, CloudSubmit[ScheduledTask[time = DateList[];CloudSave[time, co], "Daily"]]
	]

現在のタイムスタンプを取得する：

Wolfram Language code: CloudGet[var]

TaskExecuteを使ってスケジュールされたタスクのクラウドオブジェクトを実行する：

Wolfram Language code: TaskExecute[obj]

タイムスタンプが更新された：

Wolfram Language code: CloudGet[var]

タスクを削除する：

Wolfram Language code: TaskRemove[obj];

一般化と拡張 (1)

TaskSuspendを使って，クラウドのスケジュールされたタスクの実行を一時停止する：

Wolfram Language code: obj = CloudSubmit[ScheduledTask[TimeObject[], "Daily"]]

Wolfram Language code: TaskSuspend[obj]

タスクを削除する：

Wolfram Language code: TaskRemove[obj]

オプション (1)

NotificationFunction (1)

通知によって，指定されたグループの人々にタスク評価のステータスのメッセージを送ることができる．毎回実行後に複数のグループに通知するタスクを配備する：

Wolfram Language code:

co = CloudSubmit[ScheduledTask[{Now, AirTemperatureData[]}, "Daily", 
	NotificationFunction -> {{$CloudUserID, "a@b.com"} -> All}
	]]

タスクが非同期実行されるようにする：

Wolfram Language code: TaskExecute[co]

タスクが再度実行されるようにする：

Wolfram Language code: TaskExecute[co]

タスクを削除する：

Wolfram Language code: TaskRemove[co]

アプリケーション (2)

スケジュールされたタスクに基づいて警告の電子メールを送るアプリケーションを作る：

Wolfram Language code: CheckForFullMoon[] := If[MoonPhase[Tomorrow] > 0.99, SendLunarAlertMail[]]

Wolfram Language code:

SendLunarAlertMail[] := SendMail[<|"To" -> $CloudUserID, "Subject" -> "Alert: Full Moon", "Body" -> {"There will be a full moon tomorrow: " <> DateString[Tomorrow], "

", MoonPhase[Tomorrow, "Icon"], "

", "http://www.wolframalpha.com/input/?i=moon+phase"}|>]

毎日午後6時に評価し，翌日の月相をチェックするようにスケジュールされたタスクを作る：

Wolfram Language code: obj = CloudSubmit[ScheduledTask[CheckForFullMoon[], DateObject[{_, _, _, 18}]]]

タスクを削除する：

Wolfram Language code: TaskRemove[obj]

TimeZone (1)

$TimeZoneをGMT+2に設定して使用するタスクを配備する：

Wolfram Language code:

task = CloudDeploy[ScheduledTask[CloudPut[{$TimeZone, $TimeZoneEntity, Now, DateString[]}, "result"], None, TimeZone -> 2]]

タスクが直ちに実行されるようにトリガする：

Wolfram Language code: TaskExecute[task]

実行されるまで少し待った後，時刻帯設定が適用されたことに注意しつつそれが書き込んだ結果オブジェクトから読み取る：

Wolfram Language code: CloudGet["result"]

タスクを削除する：

Wolfram Language code: DeleteObject[task]

考えられる問題 (3)

数値を含む時刻指定は曖昧に見えることがある：

Wolfram Language code: CloudSubmit[ScheduledTask[{Now, AirTemperatureData[]}, {Tomorrow, 3600}]]

明示的な周期と反復回数を指定することで曖昧さを解決する：

Wolfram Language code: obj = CloudSubmit[ScheduledTask[{Now, AirTemperatureData[]}, {Tomorrow, {3600, Infinity}}]]

タスクを削除する：

Wolfram Language code: TaskRemove[obj];

暦に合わせる名前付きの周期の"Monthly"および"Yearly"は，配備された日付が次の月（年）には存在しない場合は，その月（年）には実行されない（例："Yearly"タスクが2月29日に配備された場合）：

Wolfram Language code: task = CloudDeploy[ScheduledTask[{Now, AirTemperatureData[]}, "Yearly"]]

Wolfram Language code: ScheduledTaskInformation[task, "NextRunDate"]

Wolfram Language code: DateObject[{2028, 2, 29, 18, 33, 0}, "Instant", "Gregorian", -6.]

タスクを削除する：

Wolfram Language code: TaskRemove[task]

この問題を避けるためには，月末に向けて問題が起こりうる日付を避けるように開始する日付を制御するとよい：

Wolfram Language code: task = CloudDeploy[ScheduledTask[{Now, AirTemperatureData[]}, {DateObject["2024-02-28"], "Yearly"}]]

ScheduledTaskのクラウド評価には，メモリ使用量と評価時間の制限がある．その制限はユーザのクラウドプランによって決定される．具体的な数値はCloudAccountDataの"ScheduledTaskMemoryLimit"および"ScheduledTaskEvaluationTimeLimit"で確認できる：

Wolfram Language code: CloudAccountData /@ {"ScheduledTaskMemoryLimit", "ScheduledTaskEvaluationTimeLimit"}

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ScheduledTask

詳細とオプション

例題

例 (4)

スコープ (9)

時間指定 (9)

一般化と拡張 (1)

オプション (1)

NotificationFunction (1)

アプリケーション (2)

TimeZone (1)

考えられる問題 (3)

テキスト

CMS

APA

BibTeX

BibLaTeX

	period	period ごとに実行
	{period}	period の後で1回実行
	{period, count}	count 回だけ実行

	{start,timespec}	日付 start から実行
	{timespec,end}	日付 end に終了
	{start,timespec,end}	日付 start から end まで実行

ScheduledTask

詳細とオプション

例題

例 (4)

スコープ (9)

時間指定 (9)

一般化と拡張 (1)

オプション (1)

NotificationFunction (1)

アプリケーション (2)

TimeZone (1)

考えられる問題 (3)

関連項目

関連するガイド

関連するワークフロー

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX