WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Standardize[list]

list 中の要素を，ゼロ平均と単位サンプル分散を持つようにシフトし，再スケールする．

Standardize[list,f1]

list 中の要素を f1[list]シフトし，単位サンプル分散を持つように再スケールする．

Standardize[list,f1,f2]

f1[list]シフトし，f2[list]でスケールする．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

Standardize

Standardize[list]

list 中の要素を，ゼロ平均と単位サンプル分散を持つようにシフトし，再スケールする．

Standardize[list,f1]

list 中の要素を f1[list]シフトし，単位サンプル分散を持つように再スケールする．

Standardize[list,f1,f2]

f1[list]シフトし，f2[list]でスケールする．

詳細

例題

すべて開く すべて閉じる

例  (3)

データの標準得点を計算する：

Wolfram Language code: Standardize[{6.5, 3.8, 6.6, 5.7, 6.0, 6.4, 5.3}]
Wolfram Language code: {Mean[%], Variance[%]}

スケールせずにゼロ平均になるようにシフトする：

Wolfram Language code: Standardize[{6.5, 3.8, 6.6, 5.7, 6.0, 6.4, 5.3}, Mean, 1&]
Wolfram Language code: {Mean[%], Variance[%]}

標準スケールでMedianにシフトする：

Wolfram Language code: Standardize[{6.5, 3.8, 6.6, 5.7, 6.0, 6.4, 5.3}, Median]
Wolfram Language code: {Mean[%], Median[%], Variance[%]}

Medianにシフトし，InterquartileRangeでスケールする：

Wolfram Language code: Standardize[{6.5, 3.8, 6.6, 5.7, 6.0, 6.4, 5.3}, Median, InterquartileRange]
Wolfram Language code: {Mean[%], Median[%], Variance[%], InterquartileRange[%]}

スコープ  (6)

厳密な数値データを標準化する：

Wolfram Language code: Standardize[Range[5]]

記号値：

Wolfram Language code: Simplify[Standardize[{a, b, c}], {a, b, c}∈Reals]

任意精度のデータを標準化する：

Wolfram Language code: Standardize[N[Range[5], 20]]

行列データを列で標準化する：

Wolfram Language code: data = RandomReal[10, {10, 3}]
Wolfram Language code: Standardize[data]
Wolfram Language code: {Mean[%], Variance[%]}//Chop

TimeSeriesを標準化する：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{-0.8665776485273015, -0.6782110300443249, -0.5060797754514599, -1.544046353019984, -1.548861927442106, 2.268550811187895, 0.7674881482532252, -0.33377919918496324, -0.2623443622275032, -0.7898169819548497, -0.2 ... 5074135634818395, -7.993517405936538, -8.11824028466883, -7.421451285939192, -7.617297878523265, -8.63887295423076}}, {{0, 78, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: {Mean[ts], Variance[ts]}
Wolfram Language code: res = Standardize[ts]
Wolfram Language code: {Mean[res], Variance[res]}//Chop

SparseArrayを標準化する：

Wolfram Language code: sp = SparseArray[RandomInteger[1, 10]]
Wolfram Language code: Standardize[sp]

アプリケーション  (3)

正規分布に従う値を標準正規分布にシフトする：

Wolfram Language code: data = RandomReal[NormalDistribution[5, 2], 500];
Wolfram Language code: sdata = Standardize[data];
Wolfram Language code: {ListPlot[Sort[data]], ListPlot[Sort[sdata]]}

理論曲線：

Wolfram Language code: {Plot[InverseCDF[NormalDistribution[Mean[data], StandardDeviation[data]], q], {q, 0, 1}], Plot[InverseCDF[NormalDistribution[], q], {q, 0, 1}]}

列の平均を引くことでデータ行列を中心に寄せる：

Wolfram Language code: data = RandomReal[10, {5, 3}]
Wolfram Language code: cdata = Standardize[data, Mean, 1&]

中心に寄せられたデータの平均は0である：

Wolfram Language code: Mean[cdata]//Chop

共分散構造は変わっていない：

Wolfram Language code: MatrixForm /@ {Covariance[data], Covariance[cdata]}

Standardizeを使ってTimeSeriesを中心に集める：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{-0.8665776485273015, -0.6782110300443249, -0.5060797754514599, -1.544046353019984, -1.548861927442106, 2.268550811187895, 0.7674881482532252, -0.33377919918496324, -0.2623443622275032, -0.7898169819548497, -0.2 ... 5074135634818395, -7.993517405936538, -8.11824028466883, -7.421451285939192, -7.617297878523265, -8.63887295423076}}, {{0, 78, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: Mean[ts]

中心に集める：

Wolfram Language code: res = Standardize[ts, Mean, 1&]
Wolfram Language code: Mean[res]//Chop

分散は変わらない：

Wolfram Language code: Variance[ts] == Variance[res]

特性と関係  (1)

Standardizeを使ってMeanDeviationを計算する：

Wolfram Language code: data = RandomReal[10, 20]
Wolfram Language code: Mean[Abs[Standardize[data, Mean, 1&]]]
Wolfram Language code: MeanDeviation[data]

同様に，MedianDeviationを計算する：

Wolfram Language code: Median[Abs[Standardize[data, Median, 1&]]]
Wolfram Language code: MedianDeviation[data]
Wolfram Research (2008), Standardize, Wolfram言語関数， https://reference.wolfram.com/language/ref/Standardize.html.

テキスト

Wolfram Research (2008), Standardize, Wolfram言語関数， https://reference.wolfram.com/language/ref/Standardize.html.

CMS

Wolfram Language. 2008. "Standardize." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Standardize.html.

APA

Wolfram Language. (2008). Standardize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Standardize.html

BibTeX

@misc{reference.wolfram_2026_standardize, author="Wolfram Research", title="{Standardize}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Standardize.html}", note=[Accessed: 06-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_standardize, organization={Wolfram Research}, title={Standardize}, year={2008}, url={https://reference.wolfram.com/language/ref/Standardize.html}, note=[Accessed: 06-November-2026]}