---
title: "SumConvergence"
language: "en"
type: "Symbol"
summary: "SumConvergence[f, n] gives conditions for the sum \\[Sum]n^\\[Infinity] f to be convergent. SumConvergence[f, {n1, n2, ...}] gives conditions for the multiple sum \\[Sum]n1^\\[Infinity] \\[Sum]n2^\\[Infinity] ... f to be convergent. SumConvergence[f, {n, a, \\[Infinity]}] gives conditions for the sum \\[Sum]n = a \\[Infinity] f to be convergent on the interval [a, \\[Infinity]). SumConvergence[f, {n, a, \\[Infinity]}, ..., {m, b, \\[Infinity]}] gives conditions for the multiple sum \\[Sum]n = a \\[Infinity] ... \\[Sum]m = b \\[Infinity] f to be convergent."
keywords: 
- convergence test
- convergent series
- infinite series
- divergent series
canonical_url: "https://reference.wolfram.com/language/ref/SumConvergence.html"
source: "Wolfram Language Documentation"
related_guides: 
  - 
    title: "Discrete Calculus"
    link: "https://reference.wolfram.com/language/guide/DiscreteCalculus.en.md"
related_functions: 
  - 
    title: "Sum"
    link: "https://reference.wolfram.com/language/ref/Sum.en.md"
  - 
    title: "Limit"
    link: "https://reference.wolfram.com/language/ref/Limit.en.md"
  - 
    title: "DiscreteLimit"
    link: "https://reference.wolfram.com/language/ref/DiscreteLimit.en.md"
  - 
    title: "DiscreteMaxLimit"
    link: "https://reference.wolfram.com/language/ref/DiscreteMaxLimit.en.md"
  - 
    title: "Series"
    link: "https://reference.wolfram.com/language/ref/Series.en.md"
  - 
    title: "Reduce"
    link: "https://reference.wolfram.com/language/ref/Reduce.en.md"
  - 
    title: "VerifyConvergence"
    link: "https://reference.wolfram.com/language/ref/VerifyConvergence.en.md"
  - 
    title: "Regularization"
    link: "https://reference.wolfram.com/language/ref/Regularization.en.md"
  - 
    title: "DiscretePlot"
    link: "https://reference.wolfram.com/language/ref/DiscretePlot.en.md"
---
# SumConvergence

SumConvergence[f, n] gives conditions for the sum $\sum _n^{\infty } f$ to be convergent.

SumConvergence[f, {n1, n2, …}] gives conditions for the multiple sum $\sum _{n_1}^{\infty } \sum _{n_2}^{\infty } \ldots  f$ to be convergent.

SumConvergence[f, {n, a, ∞}] gives conditions for the sum $\sum _{n=a}^{\infty } f$ to be convergent  on the interval $[a,\infty )$.

SumConvergence[f, {n, a, ∞}, …, {m, b, ∞}] gives conditions for the multiple sum $\sum _{n=a}^{\infty } \ldots \sum _{m=b}^{\infty } f$ to be convergent.

## Details and Options

* The following options can be given:

|             |               |                                       |
| ----------- | ------------- | ------------------------------------- |
| Assumptions | \$Assumptions | assumptions to make about parameters  |
| Direction   | 1             | direction of summation                |
| Method      | Automatic     | method to use for convergence testing |

* Possible values for ``Method`` include:

|                |                       |
| -------------- | --------------------- |
| "IntegralTest" | the integral test     |
| "RaabeTest"    | Raabe's test          |
| "RatioTest"    | D'Alembert ratio test |
| "RootTest"     | Cauchy root test      |

* With the default setting ``Method -> Automatic``, a number of additional tests specific to different classes of sequences are used.

* For multiple sums, convergence tests are performed for each independent variable.

## Examples (38)

### Basic Examples (4)

Test for convergence of the sum $\sum _n^{\infty } \frac{1}{n}$ :

```wl
In[1]:= SumConvergence[1 / n, n]

Out[1]= False
```

Test the convergence of $\sum _n^{\infty } \frac{3^n n^2}{n!}$ :

```wl
In[2]:= SumConvergence[3 ^ n n ^ 2 / n!, n]

Out[2]= True
```

---

Find the condition for convergence of $\sum _n^{\infty } \frac{1}{n^{\alpha }}$ :

```wl
In[1]:= SumConvergence[1 / n ^ α, n]

Out[1]= Re[α] > 1
```

---

Test for convergence of the sum $\sum _{n=a}^{\infty } \frac{1}{n^2}$ :

```wl
In[1]:= SumConvergence[1 / n ^ 2, {n, 1, ∞}]

Out[1]= True

In[2]:= SumConvergence[1 / n ^ 2, {n, 0, ∞}]

Out[2]= False
```

---

Find the conditions for convergence of $\sum _{n=5}^{\infty } \frac{1}{(n-a)^2}$ :

```wl
In[1]:= SumConvergence[1 / (n - a) ^ 2, {n, 5, Infinity}]

Out[1]= a∉ℤ || a < 5
```

### Scope (16)

#### Numerical Sums (8)

Exponential or geometric sums:

```wl
In[1]:= SumConvergence[(-1 / 2) ^ n, n]

Out[1]= True

In[2]:= SumConvergence[2 ^ n, n]

Out[2]= False
```

Plot the partial sums:

```wl
In[3]:= DiscretePlot[Sum[(-1 / 2) ^ n, {n, 0, k}], {k, 25}, PlotRange -> All, AxesOrigin -> {0, 0}]

Out[3]= [image]
```

---

Polynomial exponential sums:

```wl
In[1]:= SumConvergence[(1 / 2) ^ n n ^ 3, n]

Out[1]= True

In[2]:= SumConvergence[(1 / 2) ^ n n ^ 10, n]

Out[2]= True

In[3]:= DiscretePlot[Sum[(1 / 2) ^ n n ^ 10, {n, 0, k}], {k, 50}]

Out[3]= [image]
```

---

Rational sums:

```wl
In[1]:= SumConvergence[1 / n, n]

Out[1]= False

In[2]:= SumConvergence[(n + 3) / ((n ^ 2 + 2)(n + 1)), n]

Out[2]= True
```

Convergence picture:

```wl
In[3]:= {DiscretePlot[Sum[1 / n, {n, 1, k}], {k, 25}], DiscretePlot[Sum[(n + 3) / ((n ^ 2 + 2)(n + 1)), {n, 1, k}], {k, 1, 25}]}

Out[3]= {[image], [image]}
```

---

Special functions:

```wl
In[1]:= SumConvergence[HarmonicNumber[n] / ((2n + 1)(3n + 1)), n]

Out[1]= True

In[2]:= SumConvergence[PolyGamma[n] / n!, n]

Out[2]= True

In[3]:= SumConvergence[Zeta[n] (-1) ^ n / Log[n], n]

Out[3]= True

In[4]:= DiscretePlot[Sum[Zeta[n] (-1) ^ n / Log[n], {n, 2, k}], {k, 25}]

Out[4]= [image]
```

---

Piecewise functions:

```wl
In[1]:= SumConvergence[Max[1 / n, 1 / n ^ 2] + UnitStep[7 - n] / n ^ 4, n]

Out[1]= False

In[2]:= SumConvergence[(1/n^2 + Floor[(n/1 + n) + Floor[(12/1 + n^2)]]), n]

Out[2]= True

In[3]:= SumConvergence[Boole[n ^ 2 < 1000]n, n]

Out[3]= True

In[4]:= DiscretePlot[Sum[Boole[n ^ 2 < 1000] n, {n, k}], {k, 50}]

Out[4]= [image]
```

---

Slowly converging sums in the Abel–Dini scale:

```wl
In[1]:= SumConvergence[1 / (n Log[n] Log[Log[n]]), n]

Out[1]= False

In[2]:= SumConvergence[1 / (n Log[n]Log[Log[n]] ^ 2), n]

Out[2]= True

In[3]:= DiscretePlot[Sum[1 / (n Log[n]Log[Log[n]] ^ 2), {n, 10, k}], {k, 10, 100}]

Out[3]= [image]
```

---

Alternating sums:

```wl
In[1]:= SumConvergence[(-1) ^ n, n]

Out[1]= False

In[2]:= SumConvergence[(-1) ^ n / (2n + 1), n]

Out[2]= True

In[3]:= DiscretePlot[Sum[(-1) ^ n / (2n + 1), {n, 0, k}], {k, 25}]

Out[3]= [image]
```

---

Complex-valued sums:

```wl
In[1]:= SumConvergence[Exp[n 2Pi I / 8] / n, n]

Out[1]= True

In[2]:= SumConvergence[1 / (n ^ 2 + I n + 2I), n]

Out[2]= True

In[3]:= {DiscretePlot[s = Sum[Exp[n 2Pi I / 8] / n, {n, k}];{Re[s], Im[s]}, {k, 25}], DiscretePlot[s = Sum[1 / (n ^ 2 + I n + 2I), {n, k}];{Re[s], Im[s]}, {k, 25}]}

Out[3]= {[image], [image]}
```

#### Parametric Sums (6)

Exponential or geometric series:

```wl
In[1]:= SumConvergence[x ^ n, n]

Out[1]= Abs[x] < 1

In[2]:= SumConvergence[1 / x ^ n, n]

Out[2]= Abs[x] > 1
```

Parameter region for convergence:

```wl
In[3]:= {With[{x = u + I v}, RegionPlot[Abs[x] < 1, {u, -2, 2}, {v, -2, 2}]], With[{x = u + I v}, RegionPlot[Abs[x] > 1, {u, -2, 2}, {v, -2, 2}]]}

Out[3]= {[image], [image]}
```

---

Power series:

```wl
In[1]:= SumConvergence[x ^ n / n!, n]

Out[1]= True

In[2]:= SumConvergence[(-3) ^ n x ^ (2 n) / n, n]

Out[2]= Abs[x] < (1/Sqrt[3]) || x == (1/Sqrt[3]) || (1/Sqrt[3]) + x == 0
```

---

The convergence region for $\sum _{n=-\infty }^{-1} x^n+\sum _{n=0}^{\infty } \left(\frac{x}{2}\right)^n$ :

```wl
In[1]:= SumConvergence[(x / 2) ^ n, n] && SumConvergence[x ^ (-n), n]

Out[1]= Abs[x] < 2 && Abs[x] > 1

In[2]:= With[{x = u + I v}, RegionPlot[Abs[x] < 2 && Abs[x] > 1, {u, -2, 2}, {v, -2, 2}]]

Out[2]= [image]
```

---

Combined series:

```wl
In[1]:= SumConvergence[1 / n ^ (x + 1), n] && SumConvergence[(x / 2) ^ n, n] && SumConvergence[1 / x ^ n, n]

Out[1]= Re[x] > 0 && Abs[x] < 2 && Abs[x] > 1

In[2]:= With[{x = u + I v}, RegionPlot[Re[x] > 0 && Abs[x] < 2 && Abs[x] > 1, {u, -2, 2}, {v, -2, 2}]]

Out[2]= [image]
```

---

Piecewise sums:

```wl
In[1]:= SumConvergence[Piecewise[{{a ^ n, n ≥ 0}, {b ^ n, n < 0}}]z ^ n, n]

Out[1]= Abs[a] < (1/Abs[z])

In[2]:= RegionPlot[Abs[a z] < 1, {a, -2, 2}, {z, -2, 2}]

Out[2]= [image]
```

Assuming ``z = u + I v`` to be complex:

```wl
In[3]:= With[{z = u + I v}, RegionPlot3D[Abs[a z] < 1, {a, -2, 2}, {u, -2, 2}, {v, -2, 2}, AxesLabel -> {a, u, v}]]

Out[3]= [image]
```

---

A multivariate sum:

```wl
In[1]:= SumConvergence[a ^ n b ^ m, {n, m}]

Out[1]= Abs[a] < 1 && Abs[b] < 1

In[2]:= RegionPlot[Abs[a] < 1 && Abs[b] < 1, {a, -2, 2}, {b, -2, 2}]

Out[2]= [image]
```

#### Convergence on Intervals (2)

Test the convergence of $\sum _n \frac{1}{n^3}$ on different intervals:

```wl
In[1]:= SumConvergence[1 / n ^ 3, {n, 1, ∞}]

Out[1]= True

In[2]:= SumConvergence[1 / n ^ 3, {n, 0, ∞}]

Out[2]= False

In[3]:= SumConvergence[1 / n ^ 3, {n, a, ∞}]

Out[3]= a∈ℤ && a ≥ 1
```

---

Test the convergence of a parametric sum on different intervals:

```wl
In[1]:= SumConvergence[1 / (3n + a) ^ 2, {n, 1, ∞}]

Out[1]= -(a/3)∉ℤ || a > -3

In[2]:= SumConvergence[1 / (3n + a) ^ 2, {n, -1, ∞}]

Out[2]= -(a/3)∉ℤ || a > 3

In[3]:= SumConvergence[1 / (3n + a) ^ 2, {n, -∞, ∞}]

Out[3]= -3 < a < 0 || (-(a/3)∉ℤ && a < 0) || ((a/3)∉ℤ && a > -3) || (-(a/3)∉ℤ && (a/3)∉ℤ)
```

### Options (10)

#### Method (10)

Test the convergence of $\sum _{n=1}^{\infty } \frac{a^n}{n!}$ using the ratio test:

```wl
In[1]:= SumConvergence[a ^ n / n!, n, Method -> "RatioTest"]

Out[1]= True
```

---

Test the convergence of $\sum _{n=1}^{\infty } \frac{(2 n+1)!}{n (5 n)!}$ using the ratio test:

```wl
In[1]:= SumConvergence[(2n + 1)! / ((5 n)! n), n, Method -> "RatioTest"]

Out[1]= True
```

---

In this case the ratio test is inconclusive:

```wl
In[1]:= SumConvergence[1 / n, n, Method -> "RatioTest"]

Out[1]= SumConvergence[(1/n), n, Method -> "RatioTest"]
```

---

Test the convergence of $\sum _{n=1}^{\infty } \frac{x^n}{n}$ using the root test:

```wl
In[1]:= SumConvergence[x ^ n / n, n, Method -> "RootTest"]

Out[1]= Abs[x] < 1
```

---

Test the convergence of $\sum _{n=0}^{\infty } \left(\frac{2 n+3}{5 n-4}\right)^n$ using the root test:

```wl
In[1]:= SumConvergence[((2n + 3/5n - 4))^n, n, Method -> "RootTest"]

Out[1]= True
```

---

In this case the root test is inconclusive:

```wl
In[1]:= SumConvergence[(1 - 1 / n) ^ n, n, Method -> "RootTest"]

Out[1]= SumConvergence[(1 - (1/n))^n, n, Method -> "RootTest"]
```

---

The Raabe test works well for rational functions:

```wl
In[1]:= SumConvergence[n / (n ^ 3 + 2n + 1), n, Method -> "RaabeTest"]

Out[1]= True

In[2]:= SumConvergence[1 / Sqrt[n], n, Method -> "RaabeTest"]

Out[2]= False

In[3]:= SumConvergence[(Underoverscript[∏, k = 1, n](2 k - 1)/Underoverscript[∏, k = 1, n]2 k), n, Method -> "RaabeTest"]

Out[3]= False
```

In this case the Raabe test is inconclusive:

```wl
In[4]:= SumConvergence[x ^ n, n, Method -> "RaabeTest"]

Out[4]= SumConvergence[x^n, n, Method -> "RaabeTest"]
```

---

Test the convergence of $\sum _{n=2}^{\infty } \frac{1}{\log ^2(n)}$ using the integral test:

```wl
In[1]:= SumConvergence[1 / Log[n] ^ 2, n, Method -> "IntegralTest"]

Out[1]= False
```

---

Test the convergence of $\sum _{n=2}^{\infty } \frac{1}{n \log (n) \log ^2(\log (n))}$ using the integral test:

```wl
In[1]:= SumConvergence[1 / (n Log[n] Log[Log[n]] ^ 2), n, Method -> "IntegralTest"]

Out[1]= True
```

---

In this case the integral test is inconclusive:

```wl
In[1]:= SumConvergence[1 / Prime[n], n, Method -> "IntegralTest"]

Out[1]= SumConvergence[(1/Prime[n]), n, Method -> "IntegralTest"]
```

### Applications (3)

Find the radius of convergence of a power series:

```wl
In[1]:= SumConvergence[x ^ n, n]

Out[1]= Abs[x] < 1

In[2]:= Sum[x ^ n, {n, 0, Infinity}, GenerateConditions -> True]

Out[2]= ConditionalExpression[1/(1 - x), Abs[x] < 1]
```

---

Find the interval of convergence for a real power series:

```wl
In[1]:= SumConvergence[(x ^ n) / (n 3 ^ n), n]

Out[1]= Abs[x] < 3 || x == -3
```

As a real power series, this converges on the interval ``[-3, 3)`` :

```wl
In[2]:= SumConvergence[(x ^ n) / (n 3 ^ n), n, Assumptions -> x∈Reals]

Out[2]= -3 ≤ x < 3
```

---

Prove convergence of Ramanujan's formula for $\frac{1}{\pi }$ :

```wl
In[1]:= SumConvergence[Sqrt[8] / 9801(4n)!(1103 + 26390n) / (n!) ^ 4 / 396 ^ (4n), n]

Out[1]= True
```

Sum it:

```wl
In[2]:= Sqrt[8] / 9801Sum[(4n)!(1103 + 26390n) / (n!) ^ 4 / 396 ^ (4n), {n, 0, Infinity}]

Out[2]= (1/π)
```

### Properties & Relations (4)

Convergence properties are not affected by multiplication of constants:

```wl
In[1]:= {SumConvergence[2 1 / n, n], SumConvergence[1 / n, n]}

Out[1]= {False, False}
```

---

Convergence is not affected by translating arguments:

```wl
In[1]:= {SumConvergence[1 / n ^ 2, n], SumConvergence[1 / (n - 5) ^ 2, n]}

Out[1]= {True, True}
```

---

``SumConvergence`` is automatically called by ``Sum``:

```wl
In[1]:= SumConvergence[1 / n ^ 2, n]

Out[1]= True

In[2]:= Sum[1 / n ^ 2, {n, ∞}]

Out[2]= (π^2/6)
```

Many conditions generated by ``Sum`` are in effect convergence conditions:

```wl
In[3]:= Sum[x ^ n, {n, ∞}, GenerateConditions -> True]

Out[3]= ConditionalExpression[-(x/(-1 + x)), Abs[x] < 1]

In[4]:= SumConvergence[x ^ n, n]

Out[4]= Abs[x] < 1
```

With the setting ``VerifyConvergence -> False``, typically a regularized value is returned:

```wl
In[5]:= Sum[(-1) ^ n, {n, ∞}, VerifyConvergence -> False]

Out[5]= -(1/2)
```

---

``SumConvergence`` is used in sum transforms such as ``ZTransform``:

```wl
In[1]:= ZTransform[a ^ n, n, z, GenerateConditions -> True]

Out[1]= ConditionalExpression[z/(-a + z), Abs[z] > Abs[a]]

In[2]:= SumConvergence[a ^ n z ^ (-n), n]

Out[2]= Abs[a] < Abs[z]
```

``GeneratingFunction`` :

```wl
In[3]:= GeneratingFunction[a ^ n, n, x, GenerateConditions -> True]

Out[3]= ConditionalExpression[1/(1 - a*x), Abs[x] < 1/Abs[a]]

In[4]:= SumConvergence[a ^ n x ^ n, n]

Out[4]= Abs[a] < (1/Abs[x])
```

``ExponentialGeneratingFunction``:

```wl
In[5]:= ExponentialGeneratingFunction[a ^ n n!, n, x, GenerateConditions -> True]

Out[5]= ConditionalExpression[1/(1 - a*x), Abs[x] < 1/Abs[a]]

In[6]:= SumConvergence[a ^ n n! x ^ n / n!, n]

Out[6]= Abs[a] < (1/Abs[x])
```

``FourierSequenceTransform``:

```wl
In[7]:= FourierSequenceTransform[a ^ n UnitStep[n], n, ω, GenerateConditions -> True]

Out[7]= ConditionalExpression[E^(I*ω)/(-a + E^(I*ω)), E^Im[ω]*Abs[a] < 1]

In[8]:= SumConvergence[a ^ n Exp[-I n ω], n]

Out[8]= Abs[a] < E^-Im[ω]
```

### Neat Examples (1)

Conditionally convergent periodic sums:

```wl
In[1]:= f[n_, p_] := (Mod[n, p] - Mean[Mod[Range[0, p - 1], p]]) / Log[n]

In[2]:= Table[SumConvergence[f[n, p], n], {p, 3, 30, 5}]

Out[2]= {True, True, True, True, True, True}

In[3]:= Table[DiscretePlot[Sum[f[n, p], {n, 2, m}], {m, 2, 75}, PlotLabel -> (Mod[n, p] - Mean[Mod[Range[0, p - 1], p]]) / Log[n]], {p, 3, 30, 5}]

Out[3]= {[image], [image], [image], [image], [image], [image]}
```

## See Also

* [`Sum`](https://reference.wolfram.com/language/ref/Sum.en.md)
* [`Limit`](https://reference.wolfram.com/language/ref/Limit.en.md)
* [`DiscreteLimit`](https://reference.wolfram.com/language/ref/DiscreteLimit.en.md)
* [`DiscreteMaxLimit`](https://reference.wolfram.com/language/ref/DiscreteMaxLimit.en.md)
* [`Series`](https://reference.wolfram.com/language/ref/Series.en.md)
* [`Reduce`](https://reference.wolfram.com/language/ref/Reduce.en.md)
* [`VerifyConvergence`](https://reference.wolfram.com/language/ref/VerifyConvergence.en.md)
* [`Regularization`](https://reference.wolfram.com/language/ref/Regularization.en.md)
* [`DiscretePlot`](https://reference.wolfram.com/language/ref/DiscretePlot.en.md)

## Related Guides

* [Discrete Calculus](https://reference.wolfram.com/language/guide/DiscreteCalculus.en.md)

## History

* [Introduced in 2008 (7.0)](https://reference.wolfram.com/language/guide/SummaryOfNewFeaturesIn70.en.md) \| [Updated in 2010 (8.0)](https://reference.wolfram.com/language/guide/SummaryOfNewFeaturesIn80.en.md) ▪ [2025 (14.2)](https://reference.wolfram.com/language/guide/SummaryOfNewFeaturesIn142.en.md)