WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Union[list1,list2,…]

listiに現れるすべての個別の要素を分類したリストを与える．

Union[list]

すべての重複する要素を除外して分類したリストを与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
オプション  
SameTest  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Union

Union[list1,list2,…]

listiに現れるすべての個別の要素を分類したリストを与える．

Union[list]

すべての重複する要素を除外して分類したリストを与える．

詳細とオプション

  • listiを集合とみなすとUnionは，これらの和集合を与える．
  • Union[list1,list2,…]は，list1⋃list2⋃…としてStandardFormとInputFormで入力できる．記号⋃ は，unあるいは\[Union]と入力できる．
  • listiは同じ頭部を持たなければならないが，Listである必要はない．
  • Union[list1,…,SameTest->test]は，test を listi内の各要素の対に適用し，それらが同じかどうかを定める．

例題

すべて開く すべて閉じる

例  (3)

個別要素のソートされたリストを与える：

Wolfram Language code: Union[{1, 2, 1, 3, 6, 2, 2}]

すべてのリストから個別要素のソートされたリストを与える：

Wolfram Language code: Union[{a, b, a, c}, {d, a, e, b}, {c, a}]

unを使って入力する：

Wolfram Language code: {a, b, c}⋃{b, c, d}

スコープ  (1)

一意的なリストのリストを与える：

Wolfram Language code: Union[{{1, 2}, {1, 2, 3}}, {{2, 1}, {1, 2}}, {{3, 2, 1}, {1, 2, 3}}]

一般化と拡張  (1)

Unionは，Listに限らず任意の頭部に使うことができる：

Wolfram Language code: Union[f[a, b], f[c, a], f[b, b, a]]

オプション  (4)

SameTest  (4)

絶対値に基づく同等のクラスを使う：

Wolfram Language code: Union[{2, -2, 1, 3, 1}, SameTest -> (Abs[#1] == Abs[#2]&)]

Floorに基づく同等のクラスを使う：

Wolfram Language code: Union[{1.1, 3.4, .5, 7.6, 7.1, 1.9}, SameTest -> (Floor[#1] == Floor[#2]&)]

リスト要素のTotalを使う：

Wolfram Language code: Union[{{1, 2}, {3}, {4, 5, 6}, {9, 6}}, SameTest -> (Total[#1] == Total[#2]&)]

最後と最初の要素の等式を使う：

Wolfram Language code: Union[{{1, 2}, {2, 1}, {3, 2, 1}, {3}, {4, 5}, {5, 4, 3, 2, 1}}, SameTest -> (First[#1] == Last[#2]&)]

アプリケーション  (4)

10，12，20のいずれかの約数を求める：

Wolfram Language code: Union[Divisors[10], Divisors[12], Divisors[20]]

10!のバイナリ分解で生じる数字3個のすべての組合せを求める：

Wolfram Language code: Union[Partition[IntegerDigits[10!, 2], 3, 1]]

反復における個別要素を求める：

Wolfram Language code: Union[NestList[Mod[5#, 11]&, 1, 100]]

関数のリストで使われているオプションを求める：

Wolfram Language code: Union[Flatten[Map[Options[#][[All, 1]]&, {FindFit, FindMinimum, FindRoot}]]]

特性と関係  (3)

ソートされた集合を分けると同じ要素を持つリストが得られる：

Wolfram Language code: ints = RandomInteger[9, 10]
Wolfram Language code: splits = Split[Sort[ints]]

和集合はこれらのリストの第1要素に等しい：

Wolfram Language code: Union[ints] === splits[[All, 1]]

Tallyは同一要素の数を求め，もとの順番で返す：

Wolfram Language code: ints = RandomInteger[9, 10]
Wolfram Language code: tally = Tally[ints]

和集合はTallyで返された要素をソートしたリストである：

Wolfram Language code: Union[ints] === Sort[tally[[All, 1]]]

DeleteDuplicatesは，ソートなしのUnionに似ている：

Wolfram Language code: list = {9, 0, 0, 3, 2, 3, 6, 2, 9, 8, 4, 9, 0, 2, 6, 5, 7, 4, 9, 8};
Wolfram Language code: Union[list]
Wolfram Language code: DeleteDuplicates[list]
Wolfram Language code: Sort[%]

ソートしないと格段にスピードアップする：

Wolfram Language code: list = RandomInteger[10 ^ 5, 10 ^ 7];
Wolfram Language code: {First[Timing[DeleteDuplicates[list]]], First[Timing[Union[list]]]}

考えられる問題  (1)

大きい集合の場合，UnionはSameTestと共に使うとすべてのペアの比較をするので遅くなることがある：

Wolfram Language code: ints = RandomInteger[1000, 1000];
Wolfram Language code: Timing[Length[u = Union[ints, SameTest -> (Floor[#1 / 2] == Floor[#2 / 2]&)]]]

等価クラスの代表が見付かる場合は，それらにUnionを使った方が速いことがある：

Wolfram Language code: Timing[Length[fu = 2 * Union[Floor[ints / 2]]]]

結果は代表の選択を除いて等しい：

Wolfram Language code: Union[u - fu]
Wolfram Research (1988), Union, Wolfram言語関数， https://reference.wolfram.com/language/ref/Union.html （1996年に更新）.

テキスト

Wolfram Research (1988), Union, Wolfram言語関数， https://reference.wolfram.com/language/ref/Union.html （1996年に更新）.

CMS

Wolfram Language. 1988. "Union." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/Union.html.

APA

Wolfram Language. (1988). Union. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Union.html

BibTeX

@misc{reference.wolfram_2026_union, author="Wolfram Research", title="{Union}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/Union.html}", note=[Accessed: 21-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_union, organization={Wolfram Research}, title={Union}, year={1996}, url={https://reference.wolfram.com/language/ref/Union.html}, note=[Accessed: 21-June-2026]}