WOLFRAM

Wolfram 语言与系统参考资料中心

VideoGenerator[imagespec]

用 imagespec 生成的帧生成视频.

VideoGenerator[<|"Image"imagespec,"Audio"audiospec|>]

返回包含由 audioexpr 生成的音频数据的视频.

VideoGenerator[…,dur]

生成一段持续时间为 dur 的视频.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
从图像到视频  
从函数到视频  
音频视频  
选项  
AudioEncoding  
BitRate  
CompressionLevel  
Show More Show More
FrameRate  
GeneratedAssetFormat  
GeneratedAssetLocation  
OverwriteTarget  
RasterSize  
SampleRate  
VideoEncoding  
VideoTransparency  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

VideoGenerator

VideoGenerator[imagespec]

用 imagespec 生成的帧生成视频.

VideoGenerator[<|"Image"imagespec,"Audio"audiospec|>]

返回包含由 audioexpr 生成的音频数据的视频.

VideoGenerator[…,dur]

生成一段持续时间为 dur 的视频.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

生成不同图形的视频：

Wolfram Language code: VideoGenerator[Plot[Sin[4 * # x], {x, 0, 10}]&]

通过旋转三维图形生成视频：

Wolfram Language code: VideoGenerator[Graphics3D[GeometricTransformation[Icosahedron[], RotationTransform[2 π # / 10., {0, 0, 1}]], SphericalRegion -> True]&, 2π]

范围  (8)

从图像到视频  (3)

从单个图像创建一个两秒钟长的视频：

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"]
Wolfram Language code: v = VideoGenerator[i, Quantity[2, "Seconds"]]

指定要生成的帧数：

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"]; v = VideoGenerator[i, Quantity[36, "Frames"]]

验证结果的帧数：

Wolfram Language code: Import[Information[v, "ResourcePath"], "FrameCount"]

从图像列表创建视频：

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"]; listOfImages = NestList[ImageApply[RotateLeft, #]&, i, 2]
Wolfram Language code: VideoGenerator[listOfImages]

显示帧颜色值的时间序列：

Wolfram Language code: VideoMapTimeSeries[Mean[#Image]&, v]//ListLinePlot[#, Rule[...]]&

从函数到视频  (3)

从旋转的图像创建视频：

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"];
Wolfram Language code: dur = 3; VideoGenerator[ImageRotate[i, 2π # / dur, Full, Masking -> Full, Padding -> "Fixed"]&, dur]

使用一个函数，将时间作为输入，并将其光栅化为图像：

Wolfram Language code: f[time_] := Rasterize[Round[time, .01], RasterSize -> 300]; VideoGenerator[f, 3]

使用函数来生成两个视频轨道：

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"]; f[time_] := {Blur[i, 20 * time], ColorQuantize[i, Round[2 + 2 * time]]}; v = VideoGenerator[f]

该函数在第一个轨道中生成半径增大的模糊的帧：

Wolfram Language code: VideoFrameList[Video[v, VideoTrackSelection -> 1], 3]

该函数在第二个轨道中生成颜色增加的量化图像：

Wolfram Language code: VideoFrameList[Video[v, VideoTrackSelection -> 2], 3]

音频视频  (2)

创建具有一个音频轨道的视频：

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"]; a = ExampleData[{"Audio", "PianoScale"}];
Wolfram Language code: v = VideoGenerator[<|"Image" -> i, "Audio" -> a|>, Duration[a]]
Wolfram Language code: Thumbnail /@ VideoFrameList[v, 2]
Wolfram Language code: AudioPlot[Audio[v]]

使用函数生成视频和音频轨道：

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"];imageFunction[time_] := Blur[i, 20 * time];audioFunction[time_] := .5 * TriangleWave[300 time + 200 * time ^ 2]; v = VideoGenerator[<|"Image" -> imageFunction, "Audio" -> audioFunction|>]

图像函数将时间作为输入，并将其光栅化为 Image：

Wolfram Language code: VideoFrameList[v, 3]

音频函数将时间作为输入，用它来控制三角波的频率：

Wolfram Language code: Spectrogram[Audio[v]]

选项  (13)

AudioEncoding  (1)

使用 AudioEncoding 选项指定要使用的音频编码：

Wolfram Language code: encoder = RandomChoice[$AudioEncoders["MP4"]]
Wolfram Language code: a = ExampleData[{"Audio", "PianoScale"}];v = VideoGenerator[<|"Image" -> ResourceData["Sample Image: White Dog on a Beach"], "Audio" -> a|>, Duration[a], AudioEncoding -> encoder[[1]]]
Wolfram Language code: Information[v, "AudioTracks"]

BitRate  (1)

指定要使用的近似比特率：

Wolfram Language code: Information[VideoGenerator[RandomImage[], BitRate -> Quantity[100, "Kilobits"/"Seconds"]], "BitRate"]

CompressionLevel  (1)

使用 CompressionLevel 选项控制结果的文件大小；

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"]; videos = Table[VideoGenerator[i, CompressionLevel -> c], {c, 0, 1, .2}];

比较不同压缩级别的文件大小和最后一帧的质量：

Wolfram Language code: Labeled[VideoExtractFrames[#, Quantity[-1, "Frames"]], FileSize[Information[#, "ResourcePath"]]]& /@ videos

FrameRate  (1)

默认的帧速率为每秒 30 帧：

Wolfram Language code: Information[VideoGenerator[RandomImage[]], "VideoTracks"][[1, "FrameRate"]]

指定要使用的帧速率：

Wolfram Language code: i = ResourceData["Sample Image: White Dog on a Beach"]; video = VideoGenerator[i, FrameRate -> 15];
Wolfram Language code: Information[video, "VideoTracks"][[1, "FrameRate"]]

GeneratedAssetFormat  (1)

指定所得文件的格式：

Wolfram Language code: v = VideoGenerator[RandomImage[], GeneratedAssetFormat -> "QuickTime"];
Wolfram Language code: FileFormat[Information[v, "ResourcePath"]]

GeneratedAssetLocation  (2)

资源会在 $WolframDocumentsDirectory 的 "Video" 文件夹中自动生成：

Wolfram Language code: Information[VideoGenerator[RandomImage[]], "ResourcePath"]

指定由 VideoGenerator 创建的资源的位置：

Wolfram Language code: v = VideoGenerator[RandomImage[], GeneratedAssetLocation -> "file.mp4"]; Information[v, "ResourcePath"]

将 LocalObject 用作产生的 Video 对象的资源：

Wolfram Language code: v = VideoGenerator[RandomImage[], GeneratedAssetLocation -> LocalObject[]]; Information[v, "ResourcePath"]

OverwriteTarget  (1)

默认情况下，如果文件已经存在，则不会被覆盖：

Wolfram Language code: VideoGenerator[RandomImage[], GeneratedAssetLocation -> "file.mp4"]

通过指定 OverwriteTargetTrue 覆盖现有文件：

Wolfram Language code: v = VideoGenerator[RandomImage[], GeneratedAssetLocation -> "file.mp4", OverwriteTarget -> True]; Information[v, "ResourcePath"]

RasterSize  (1)

默认情况下，如果视频轨道规范生成了 Graphics 对象，则对结果进行栅格化：

Wolfram Language code: v = VideoGenerator[Graphics[Disk[]]]; Information[v, "VideoTracks"]

使用 RasterSize 选项控制栅格化：

Wolfram Language code: v = VideoGenerator[Graphics[Disk[]], RasterSize -> {100, 100}]; Information[v, "VideoTracks"]

如果视频轨道规范生成了 Image，则指定 RasterSize 选项将调整结果的大小：

Wolfram Language code: v = VideoGenerator[RandomImage[1, 400], RasterSize -> {100, 100}]; Information[v, "VideoTracks"]

SampleRate  (2)

默认情况下，如果音轨规范是 Audio 对象，则将保留采样率：

Wolfram Language code: a = Audio["ExampleData/rule30.wav"]; AudioSampleRate[a]
Wolfram Language code: v = VideoGenerator[<|"Image" -> RandomImage[], "Audio" -> a|>]; Information[v, "AudioTracks"]

使用 SampleRate 选项重新采样音频输入：

Wolfram Language code: v = VideoGenerator[<|"Image" -> RandomImage[], "Audio" -> a|>, SampleRate -> 16000]; Information[v, "AudioTracks"]

如果音轨规范是一个函数，则默认样本为 Hz：

Wolfram Language code: v = VideoGenerator[<|"Image" -> RandomImage[], "Audio" -> (Sin[4000#]&)|>]; Information[v, "AudioTracks"]

使用 SampleRate 选项控制结果的采样率：

Wolfram Language code: v = VideoGenerator[<|"Image" -> RandomImage[], "Audio" -> (Sin[4000#]&)|>, SampleRate -> 16000]; Information[v, "AudioTracks"]

VideoEncoding  (1)

使用 VideoEncoding 选项指定要使用的视频编码：

Wolfram Language code: encoder = RandomChoice[$VideoEncoders["MP4"]]
Wolfram Language code: v = VideoGenerator[ResourceData["Sample Image: White Dog on a Beach"], VideoEncoding -> encoder[[1]]]
Wolfram Language code: Information[v, "VideoTracks"]

VideoTransparency  (1)

默认情况下，在输出中不保留生成的帧中的 alpha 通道：

Wolfram Language code: v = VideoGenerator[Plot[Sin[4 * # x], {x, 0, 10}]&];
Wolfram Language code: Information[VideoExtractFrames[v, Quantity[1, "Frames"]], "Transparency"]

默认情况下，在输出中保留生成的帧中的 alpha 通道：

Wolfram Language code: v = VideoGenerator[Plot[Sin[4 * # x], {x, 0, 10}]&, VideoTransparency -> Automatic];
Wolfram Language code: Information[VideoExtractFrames[v, Quantity[1, "Frames"]], "Transparency"]

应用  (6)

通过将静止图像添加到音频信号来创建视频：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}]
Wolfram Language code: v = VideoGenerator[<|"Image" -> ExampleData[{"TestImage", "Moon"}], "Audio" -> a|>, Duration[a]]

生成旋转三维图形的视频：

Wolfram Language code: g = ExampleData[{"Geometry3D", "Cow"}][[1, 2]];
Wolfram Language code: VideoGenerator[Graphics3D[{EdgeForm[], GeometricTransformation[g, RotationTransform[360 / 5 # Degree, {0, 0, 1}]]}, SphericalRegion -> True, Boxed -> False]&, 5]

通过围绕三维对象移动视点来生成视频：

Wolfram Language code: bass = ExampleData[{"Geometry3D", "BassGuitar"}][[1]];

可视化视点轨迹：

Wolfram Language code: trajectory[t_] := {1, 10Sin[2t], 4Cos[2t]} ParametricPlot3D[trajectory[t], {t, 0, 5}]

生成 Video：

Wolfram Language code: VideoGenerator[Rasterize@Graphics3D[bass, ViewPoint -> trajectory[#], PlotRange -> {{-25, 25}, {-25, 25}, {-20, 25}}]&, 5]//Parallelize

创建一个 Video 对象，该对象显示元胞自动机的演化：

Wolfram Language code: c = CellularAutomaton[30, {{1}, 0}, {{0, 200}}]; Image[c]
Wolfram Language code: VideoGenerator[Image@ArrayPad[c[[ ;; Round[1 + # * 100]]], {{0, 200 - Round[1 + # * 100]}, 0}]&, 2]

创建一个 Video 对象，显示一个沿台阶向下弹跳的球.

首先，求解控制球运动的微分方程：

Wolfram Language code: ballsteps = NDSolve[{x''[t] == 0, y''[t] == -9.8, y[0] == 6, y'[0] == 0, x[0] == 0, x'[0] == 1, a[0] == 5, WhenEvent[Mod[x[t], 1] == 0, If[a[t] > 0, a[t] -> a[t] - 1, "RemoveEvent"]], WhenEvent[y[t] == a[t], {x'[t], y'[t]} -> .9{x'[t], -y'[t]}]}, {x, y, a}, {t, 0, 15}, DiscreteVariables -> {a}]; trajectory = {x[t], y[t]} /. ballsteps[[1]]

预计算“台阶”背景：

Wolfram Language code: staircase = Plot[Clip[Floor[6 - x], {0, Infinity}], {x, -1, 15}, Filling -> 0, Exclusions -> None]

显示球在台阶上的位置演变：

Wolfram Language code: VideoGenerator[Show[Graphics[{Red, Disk[trajectory /. t -> #, .2]}, PlotRange -> {{-1, 10}, {0, 7}}], staircase]&, 15, FrameRate -> 15]

创建一个视频，显示从香槟到芝加哥的旅行方向：

Wolfram Language code: td = TravelDirections[{Entity["City", {"Champaign", "Illinois", "UnitedStates"}], Entity["City", {"Chicago", "Illinois", "UnitedStates"}]}]

提取形成路径的点：

Wolfram Language code: points = Join@@td["TravelPath"][[1]]["LatitudeLongitude"]; points//Short

创建视频：

Wolfram Language code: VideoGenerator[ With[{i = Max[1, Round[# * Length[points] / 10]]}, GeoGraphics[{PointSize[Large], Red, Point@GeoPosition@points[[i]], Black, GeoPath[points[[Max[1, i - 400] ;; i]]]}, RasterSize -> {500, 500}]]&, 10, FrameRate -> 10]

属性和关系  (3)

并行生成昂贵的帧以加快计算速度：

Wolfram Language code: disk[time_] := Graphics[Disk[{0, 0}, .1 + time], PlotRange -> {{-1, 1}, {-1, 1}}]
Wolfram Language code: VideoGenerator[disk];//AbsoluteTiming
Wolfram Language code: Parallelize[VideoGenerator[disk]];//AbsoluteTiming

使用 Animate 在笔记本中创建动画：

Wolfram Language code: Animate[Plot[Sin[x + a], {x, 0, 10}], {a, 0, 5}, AnimationRunning -> False]

VideoGenerator 可以达到相同的结果，但不显示任何控件：

Wolfram Language code: VideoGenerator[Plot[Sin[x + #], {x, 0, 10}]&, 5]

由于它可以创建视频文件，因此结果在笔记本之外也可以更轻松地共享.

单独生成的视频和音频对象可以使用 VideoCombine 组合.

生成没有音频的视频：

Wolfram Language code: v = VideoGenerator[Plot[Sin[x + #], {x, 0, 10}]&, 5]

生成音频样本：

Wolfram Language code: a = AudioGenerator[TriangleWave[200#]&, 5]

使用 VideoCombine 将两者合并：

Wolfram Language code: VideoCombine[{v, a}]

可能存在的问题  (1)

并行生成昂贵的帧以加快计算速度：

Wolfram Language code: disk[time_] := Graphics[Disk[{0, 0}, time], ImageSize -> {700, 700}]
Wolfram Language code: VideoGenerator[disk];//AbsoluteTiming
Wolfram Language code: Parallelize[VideoGenerator[disk]];//AbsoluteTiming

并行化无法使已经快速且具有多线程的函数受益：

Wolfram Language code: image[time_] := RandomImage[]
Wolfram Language code: VideoGenerator[image, 4];//AbsoluteTiming
Wolfram Language code: Parallelize[VideoGenerator[image, 4]];//AbsoluteTiming
Wolfram Research (2020)，VideoGenerator，Wolfram 语言函数，https://reference.wolfram.com/language/ref/VideoGenerator.html （更新于 2021 年）.

文本

Wolfram Research (2020)，VideoGenerator，Wolfram 语言函数，https://reference.wolfram.com/language/ref/VideoGenerator.html （更新于 2021 年）.

CMS

Wolfram 语言. 2020. "VideoGenerator." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/VideoGenerator.html.

APA

Wolfram 语言. (2020). VideoGenerator. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/VideoGenerator.html 年

BibTeX

@misc{reference.wolfram_2026_videogenerator, author="Wolfram Research", title="{VideoGenerator}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/VideoGenerator.html}", note=[Accessed: 04-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_videogenerator, organization={Wolfram Research}, title={VideoGenerator}, year={2021}, url={https://reference.wolfram.com/language/ref/VideoGenerator.html}, note=[Accessed: 04-November-2026]}