WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

VideoMapList[f,video]

Videoオブジェクト video の1フレームに相当するデータに f を適用し，結果のリストを返す．

VideoMapList[f,video,n]

n 個の動画フレームに相当する重なり合うパーティションに f を適用する．

VideoMapList[f,video,n,d]

オフセット d で f をパーティションに適用する．

VideoMapList[f,{video1,video2,…},…]

各 videoiから抽出された入力リストに f を適用する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
入力  
関数指定  
パーティション指定  
オプション  
Alignment  
VideoPadding  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

VideoMapList

VideoMapList[f,video]

Videoオブジェクト video の1フレームに相当するデータに f を適用し，結果のリストを返す．

VideoMapList[f,video,n]

n 個の動画フレームに相当する重なり合うパーティションに f を適用する．

VideoMapList[f,video,n,d]

オフセット d で f をパーティションに適用する．

VideoMapList[f,{video1,video2,…},…]

各 videoiから抽出された入力リストに f を適用する．

詳細とオプション

  • VideoMapListを使って，オブジェクト検出，モーション検出あるいは動作認識のような，動画中の時間的・空間的事象が検出できる．
  • VideoMapListは，f を連想に適用した結果に相当する，部分的な動画データや動画フレーム，音声データ，時間等の特性を含む，値のリストを返す．
  • VideoMapList[f,video,n]を使うとパーティションが1画像フレーム分スライドする．
  • 関数 f は次の引数を使って動画と音声のデータにアクセスできる．
  • #ImageImageオブジェクトとしての動画フレーム
    #AudioAudioオブジェクトとしての音声のチャンク
    #Time動画の初めからの時間
    #TimeIntervalパーティション全体に対応する時間
    #FrameIndex現行出力フレームの指標
    #InputFrameIndex現行入力フレームの指標
  • VideoMapList[f,{video1,video2,…},…]で各引数に与えられるデータは，i 番目の要素が videoiから抽出されたデータに対応するリストである．
  • フレーム変数の n と d はフレーム数を指定するスカラー，あるいは時間Quantityオブジェクトとして与えることができる．
  • 次は，サポートされるオプションである．
  • Alignment Automaticタイムスタンプとパーティションのアライメント
    VideoPadding Automatic最終フレーム以降のフレームに使う充填
  • デフォルトで，#Timeの値は各パーティションの中心に揃えられる．Left，Rightあるいはからまでの値を使って別の揃え方を指定する．
  • VideoMapListは，$VideoDecodersで指定された動画コンテナとコーデックをサポートする．

例題

すべて開く すべて閉じる

例  (2)

各フレームの平均強度を計算する：

Wolfram Language code: v = Video["ExampleData/fish.mp4"];
Wolfram Language code: mean = VideoMapList[ImageMeasurements[#Image, "MeanIntensity"]&, v];
Wolfram Language code: ListLinePlot[mean]

連続する2つのフレーム間の距離を計算する：

Wolfram Language code: v = Video["ExampleData/fish.mp4"];
Wolfram Language code: dist = VideoMapList[ImageDistance@@#Image&, v, 2]; ListLinePlot[dist, PlotRange -> All]

スコープ  (5)

入力  (1)

複数の動画のフレームについて関数を計算する：

Wolfram Language code: v1 = Video["ExampleData/rule30.mp4"]; v2 = Video["ExampleData/fish.mp4"];
Wolfram Language code: VideoMapList[Subtract@@(Mean /@ #Image)&, {v1, v2}]//Transpose//ListLinePlot

一つの動画が他の動画よりも長い場合は，VideoPaddingオプションを使って短い方の充填方法が制御できる：

Wolfram Language code: VideoMapList[Subtract@@(Mean /@ #Image)&, {v1, v2}, VideoPadding -> "Fixed"]//Transpose//ListLinePlot

関数指定  (2)

関数 f は各パーティションのデータを保持しているAssociationを受け取る：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];

与えられた連想のキーをチェックする：

Wolfram Language code: Quiet[VideoMapList[(Print[Keys[#]];Return[])&, v]];

個々の動画フレームを処理する：

Wolfram Language code: list = VideoMapList[ImageMeasurements[#Image, "StandardDeviation"]&, v];

結果をプロットする：

Wolfram Language code: ListLinePlot[Transpose@list, PlotRange -> All]

関数 f はAudioオブジェクトとして与えられた音声データを操作することができる：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];

画像データと音声データの両方について時間同期の測定値を計算する：

Wolfram Language code: list = VideoMapList[Append[ImageMeasurements[#Image, "StandardDeviation"], AudioMeasurements[#Audio, "StandardDeviation"]]&, v];

結果をプロットする：

Wolfram Language code: ListLinePlot[Transpose@list, ...]

パーティション指定  (2)

4つのフレームに相当するパーティションを処理する：

Wolfram Language code: v = Import["http://exampledata.wolfram.com/popcorn.mov"];
Wolfram Language code: VideoMapList[ImageMeasurements[Blend[#Image], "Mean"]&, v, 4]//Transpose//ListLinePlot

時間Quantityを使ってパーティションサイズを指定する：

Wolfram Language code: VideoMapList[ImageMeasurements[Blend[#Image], "Mean"]&, v, Quantity[200, "Milliseconds"]]//Transpose//ListLinePlot

デフォルトで，1フレームのオフセットが使われる：

Wolfram Language code: v = Import["http://exampledata.wolfram.com/popcorn.mov"];
Wolfram Language code: VideoMapList[ImageMeasurements[Blend[#Image], "Mean"]&, v, 4]//Transpose//ListLinePlot

4フレームのオフセットを使う：

Wolfram Language code: VideoMapList[ImageMeasurements[Blend[#Image], "Mean"]&, v, 4, 4]//Transpose//ListLinePlot

時間Quantityを使ってオフセットを指定する：

Wolfram Language code: VideoMapList[ImageMeasurements[Blend[#Image], "Mean"]&, v, 4, Quantity[500, "Milliseconds"]]//Transpose//ListLinePlot

Scaled量を使ってパーティションサイズに比例するオフセットを指定する：

Wolfram Language code: VideoMapList[ImageMeasurements[Blend[#Image], "Mean"]&, v, 4, Scaled[1 / 2]]//Transpose//ListLinePlot

オプション  (2)

Alignment  (1)

デフォルトで，"Time"キーの値は各パーティションの中央に揃えられる：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];
Wolfram Language code: Normal[VideoMapList[#Time&, v]][[ ;; 3]]

AlignmentRightを使って各パーティションの末尾に計算された特性を返す：

Wolfram Language code: Normal[VideoMapList[#Time&, v, Alignment -> Right]][[ ;; 3]]

–1（左）から1（右）までのカスタムの整列範囲を使う：

Wolfram Language code: Normal[VideoMapList[#Time&, v, Alignment -> -.5]][[ ;; 3]]

各パーティションの境界は，パーティションの最初のフレームの開始時間と最後のフレームの終了時間である．この時間は"TimeInterval"キーを使って調べることができる：

Wolfram Language code: Normal[VideoMapList[#TimeInterval&, v]][[ ;; 3]]

VideoPadding  (1)

片方の動画のトラックがもう一方より短いときは，時間を超えた部分に黒いフレームが使われる：

Wolfram Language code: v1 = FrameListVideo[Table[ConstantImage[RandomColor[]], 6], FrameRate -> 1];
Wolfram Language code: v2 = VideoCombine[{v1, AudioGenerator["Sin", 10]}]
Wolfram Language code: RGBColor@@@VideoMapList[Mean[#Image]&, v2]

VideoPaddingを使って異なる色による充填を指定する：

Wolfram Language code: RGBColor@@@VideoMapList[Mean[#Image]&, v2, VideoPadding -> Red]

"Fixed"充填を使って最後のフレームを繰り返す：

Wolfram Language code: RGBColor@@@VideoMapList[Mean[#Image]&, v2, VideoPadding -> "Fixed"]

アプリケーション  (3)

各フレームの平均強度を計算する：

Wolfram Language code: v = Video["ExampleData/Caminandes.mp4"];
Wolfram Language code: mean = VideoMapList[ImageMeasurements[#Image, "MeanIntensity"]&, v];
Wolfram Language code: ListLinePlot[mean]

動画中の顔を求める：

Wolfram Language code: v = Video["http://exampledata.wolfram.com/office.ts"];
Wolfram Language code: res = VideoMapList[FindFaces[#Image]&, v];

検出された顔の数を時間の経過に沿ってプロットする：

Wolfram Language code: ListLinePlot[Length /@ res]

フレームの一つの中で検出された顔をハイライトする：

Wolfram Language code: HighlightImage[VideoExtractFrames[v, Quantity[200, "Frames"]], res[[200]]]

フレームごとの主調色を計算する：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];
Wolfram Language code: colors = VideoMapList[DominantColors[#Image]&, v];

主調色の重み付きクラウドを作成する：

Wolfram Language code: Tally[Flatten[colors], ColorDistance[##] < .2&]
Wolfram Language code: WordCloud[%]

主調色を時間の経過に沿って可視化する：

Wolfram Language code: Flatten[Partition[PadRight[#, Max[Length /@ colors] + 1, Transparent]& /@ colors, 100], {{1, 3}, {2}}]//Image

特性と関係  (2)

VideoMapListは各評価について変化する次元のリストを返すことができる：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];
Wolfram Language code: VideoMapList[DominantColors[First[#Image]]&, v, Quantity[2, "Seconds"], Quantity[2, "Seconds"]]//Column

VideoMapTimeSeriesはそのような結果は保存できない：

Wolfram Language code: VideoMapTimeSeries[DominantColors[First[#Image]]&, v, Quantity[2, "Seconds"], Quantity[2, "Seconds"]]

VideoMapListは結果に対応する時間は返さない：

Wolfram Language code: v = Video["ExampleData/bullfinch.mkv"];
Wolfram Language code: VideoMapList[ImageMeasurements[First[#Image], "MeanIntensity"]&, v, Quantity[2, "Seconds"], Quantity[2, "Seconds"]]

VideoMapTimeSeriesを使って時間も返すようにする：

Wolfram Language code: VideoMapTimeSeries[ImageMeasurements[First[#Image], "MeanIntensity"]&, v, Quantity[2, "Seconds"], Quantity[2, "Seconds"]]
Wolfram Language code: Normal[%]
Wolfram Research (2020), VideoMapList, Wolfram言語関数， https://reference.wolfram.com/language/ref/VideoMapList.html （2021年に更新）.

テキスト

Wolfram Research (2020), VideoMapList, Wolfram言語関数， https://reference.wolfram.com/language/ref/VideoMapList.html （2021年に更新）.

CMS

Wolfram Language. 2020. "VideoMapList." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/VideoMapList.html.

APA

Wolfram Language. (2020). VideoMapList. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VideoMapList.html

BibTeX

@misc{reference.wolfram_2026_videomaplist, author="Wolfram Research", title="{VideoMapList}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/VideoMapList.html}", note=[Accessed: 05-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_videomaplist, organization={Wolfram Research}, title={VideoMapList}, year={2021}, url={https://reference.wolfram.com/language/ref/VideoMapList.html}, note=[Accessed: 05-July-2026]}