"Julia" (外部評価システム)

詳細

Juliaバージョン0.7以降がサポートされる．ExternalFunctionのサポートには，Julia 1.2以降が必要である．
Wolfram言語でJuliaが使えるよう設定するためには，ワークフローの「ExternalEvaluate用にJuliaを設定する」の手順に従うとよい．

ExternalEvaluateの使用法

ExternalEvaluate["Julia",code] はJulia REPLでコード列を実行し，Wolfram言語式として結果を返す．
ExternalEvaluate["Julia""String",code] はJulia REPLでコード列を実行し，Wolfram言語の文字列として出力を返す．

データ型

Juliaに組み込まれた次の型がサポートされている：

Bool	True \| False	ブール値True/False
Int8, Int16, Int32, etc.	Integer	整数
Float16, Float32, etc.	Real	実数
Complex{Float16}, Complex{Float32}, etc.	Complex	複素数（Juliaから返される場合のみ）
String	String	文字列
Array	List	オブジェクトのリスト
Dict	Association	連想の配列
Set	List	重複のない非順序集合
Tuple	List	固定長のコンテナ
Date, DateTime		日付，日付区間
NaN	Indeterminate	非数値
nothing	Null	戻り値なし

使用法

列のテンプレート(<*…*>)は，Wolfram言語の式を評価したりJuliaコード列に挿入したりするのに使うことができる．

例題

すべて開くすべて閉じる

例 (1)

Juliaでを評価して結果を返す：

Wolfram Language code: ExternalEvaluate["Julia", "2+2"]

配列はリストとして返される：

Wolfram Language code: ExternalEvaluate["Julia", "[1,2,3,4]"]

>とタイプしてドロップダウンメニューからJuliaを選ぶと，評価にExternalEvaluateを使うコードのセルが得られる：

map(sqrt, 1:1:10)

日付はDateObject式としてJuliaから返される：

Wolfram Language code: ExternalEvaluate["Julia", "using Dates; DateTime(2022)"]

スコープ (20)

Juliaでブール文を評価すると結果が戻る：

Wolfram Language code: ExternalEvaluate["Julia", "true || false"]

Juliaで文字列を連結すると結果が戻る：

Wolfram Language code: ExternalEvaluate["Julia", "\"hello\" * \" \" * \"world\""]

Juliaの辞書は連想として返される：

Wolfram Language code: ExternalEvaluate["Julia", "Dict(\"one\"=>1, \"two\"=>2, \"three\"=>3)"]

Juliaの配列はListとして返される：

Wolfram Language code: ExternalEvaluate["Julia", "[1 2 3;4 5 6]"]

セッションオプション (9)

"ReturnType" (3)

Julia評価システムでは，デフォルトの戻り型は"Expression"である：

Wolfram Language code: ExternalEvaluate["Julia", "2+2"] === ExternalEvaluate["Julia" -> "Expression", "2+2"]

"Expression"戻り型では，数，文字列，リスト，連想は自動的にインポートされる：

Wolfram Language code: ExternalEvaluate["Julia", "[1, 2, 3]"]

Wolfram Language code: MatchQ[%, {__Integer}]

"String"戻り型は，Julia関数の repr を呼び出すことによって結果の列を返す：

Wolfram Language code: ExternalEvaluate["Julia" -> "String", "[1, 2, 'א']"]

Wolfram Language code: ExternalEvaluate["Julia", "repr([1, 2, 'א'])"]

"Version" (1)

"Version"を使うと，特定のバージョンのJuliaだけを確実に使うことができる：

Wolfram Language code: ExternalEvaluate[{"Julia", "Version" -> "1.7"}, "repr(VERSION)"]

マイナーバージョンやパッチバージョンを指定することができる：

Wolfram Language code: ExternalEvaluate[{"Julia", "Version" -> "1.8.2"}, "repr(VERSION)"]

"Evaluator" (1)

指定された"Evaluator"を使ってJuliaセッションを開始する：

Wolfram Language code:

session = StartExternalSession[{"Julia", "Evaluator" -> "C:\\Users\\WolframUser\\AppData\\Local\\Programs\\Julia-1.8.2\\bin\\julia.exe"}]

セッションで使われる評価子をチェックする：

Wolfram Language code: session["Evaluator"]

セッションを終了する：

Wolfram Language code: DeleteObject[session]

"SessionProlog" (1)

Wolfram Language code: ExternalEvaluate[{"Julia", "SessionProlog" -> "print(\"session started\")"}, "print(\"evaluating code\"); 2+2"]

"SessionEpilog" (1)

"SessionEpilog"を使って，セッションの最後に副作用を実行する：

Wolfram Language code: ExternalEvaluate[{"Julia", "SessionEpilog" -> "print(\"session ended\")"}, "print(\"evaluating code\"); 2+2"]

"Prolog" (1)

"Prolog"を使って，それぞれの評価の前に副作用を実行する：

Wolfram Language code: ExternalEvaluate[{"Julia", "SessionProlog" -> "n=0", "Prolog" -> "print(\"n was \", n)"}, {"n += 3", "n += 3"}]

"Epilog" (1)

"Epilog"を使ってそれぞれの評価の後に副作用を実行する：

Wolfram Language code:

ExternalEvaluate[{"Julia", "SessionProlog" -> "n=0", "Prolog" -> "print(\"n was \", n)", "Epilog" -> "print(\"n is \", n)"}, {"n += 3", "n += 3"}]

コマンドオプション (10)

"Command" (3)

Juliaコードの列が与えられたときだけ，コマンドは直接実行される：

Wolfram Language code: ExternalEvaluate["Julia", "2+2"]

上記は次の形式を使ったコマンドに等しい：

Wolfram Language code: ExternalEvaluate["Julia", <|"Command" -> "2+2"|>]

Fileラッパーを使ってファイルのコードを実行する：

Wolfram Language code:

ExternalEvaluate["Julia", {
	<|"Command" -> File["ExampleData/add.jl"]|>, 
	<|"Command" -> "add2(3)"|>
	}]

上記は次の形式を使ったコマンドに等しい：

Wolfram Language code:

ExternalEvaluate["Julia", {
	File["ExampleData/add.jl"], 
	"add2(3)"
	}]

CloudObjectにコードを置く：

Wolfram Language code: cloudObj = CloudExport["print(\"Hello World!\")", "Text", CloudObject["hello-world-jl"]]

クラウドから直接評価する：

Wolfram Language code: ExternalEvaluate["Julia", <|"Command" -> cloudObj|>]

上は，次のフォームを使ってコマンドを書くことと同じである：

Wolfram Language code: ExternalEvaluate["Julia", cloudObj]

"ReturnType" (1)

デフォルトでは，コマンドはセッションの生成中に指定される"ReturnType"を使って実行される：

Wolfram Language code:

ExternalEvaluate[
	{"Julia", "ReturnType" -> "String"}, 
	"Dict('a'=> 2)"
	]

コマンドで"ReturnType"を指定すると，セッションの"ReturnType"が上書きされる：

Wolfram Language code:

ExternalEvaluate[
	{"Julia", "ReturnType" -> "String"}, 
	{
	<|"Command" -> "Dict('a'=> 2)"|>, 
	<|"Command" -> "Dict('a'=> 2)", "ReturnType" -> "Expression"|>
	}
	]

"Arguments" (2)

"Arguments"を使って，引数で評価の結果を呼び出す：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "+", "Arguments" -> {0, 5}|>
	]

リスト以外の引数が与えられると，関数には単独の引数が渡される：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "repr", "Arguments" -> 1|>
	]

第一引数としてリストを渡す必要がある場合は，追加のリストで明示的にそれをラップしなければならない：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	{
	<|"Command" -> "repr", "Arguments" -> 1|>, 
	<|"Command" -> "repr", "Arguments" -> {1}|>, 
	<|"Command" -> "repr", "Arguments" -> {{1}}|>
	}
	]

"Command"内で関数を定義し，"Arguments"で直接それを呼び出すことができる：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "f(a, b)= a+b", "Arguments" -> {1, 2}|>
	]

Ruleを使っても同じ結果を得ることができる：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	"f(a, b)= a+b" -> {1, 3}
	]

ExternalFunctionを生成することによって引数を渡すこともできる：

Wolfram Language code: session = StartExternalSession["Julia"]

Wolfram Language code: function = ExternalFunction[session, "f(a, b)= a+b"]

Wolfram Language code: function[1, 3]

Wolfram Language code: DeleteObject[session]

"Constants" (1)

"Constants"を使って，コマンドを実行する前に永続的な大域的変数を設定する：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Constants" -> <|"a" -> 2, "b" -> 3|>, "Command" -> "a + b + 2"|>
	]

"TemplateArguments" (3)

コマンドを実行するとき，TemplateExpressionを行内に埋め込むことができる：

Wolfram Language code:

x = RandomReal[]
ExternalEvaluate["Julia", "1 + <* x *>"]

"TemplateArguments"を使ってTemplateSlotを明示的に埋めることができる：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "2 + ``", "TemplateArguments" -> 1|>
	]

リスト以外の引数が与えられると，テンプレートには単独のテンプレート引数が渡される：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "repr(``)", "TemplateArguments" -> 1|>
	]

第一引数としてリストを渡す必要がある場合，それを明示的に追加のリストでラップしなければならない：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	{
	<|"Command" -> "repr(``)", "TemplateArguments" -> 1|>, 
	<|"Command" -> "repr(``)", "TemplateArguments" -> {1}|>, 
	<|"Command" -> "repr(``)", "TemplateArguments" -> {{1}}|>
	}
	]

テンプレートスロットに名前を付け，Associationを使うと，テンプレートに名前付きの引数を渡すことができる：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "collect(range(`start`, `length`, `end`))", "TemplateArguments" -> <|"start" -> 1, "end" -> 10, "length" -> 10|>|>
	]

アプリケーション (2)

JuliaのStatisticsパッケージの mean 関数を使う：

Wolfram Language code:

session = StartExternalSession["Julia"];
ExternalEvaluate[session, "using Pkg; Pkg.add(\"Statistics\")"];
mean = ExternalEvaluate[session, "using Statistics; mean"]

関数を使う：

Wolfram Language code: mean[Range[50]]

セッションを終了する：

Wolfram Language code: DeleteObject[session]

JuliaのOrdinaryDiffEqパッケージを使って放射性崩壊問題を解く：

Wolfram Language code:

session = StartExternalSession["Julia"];
ExternalEvaluate[session, "using Pkg; Pkg.add(\"OrdinaryDiffEq\")"];

Wolfram Language code:

{t, u} = ExternalEvaluate[session, "using OrdinaryDiffEq
c1 = 5.730
u0=1.0
tspan = (0.0, 1.0)
radioactivedecay(u,p,t) =-c1*u
prob = ODEProblem(radioactivedecay,u0,tspan)
sol = solve(prob,Tsit5())
[sol.t,sol.u]
"];

Wolfram言語で解をプロットする：

Wolfram Language code:

ListLinePlot[Transpose[{t, u}], 
	PlotLabel -> "Carbon-14 half-life", 
	PlotStyle  -> Red, 
	Epilog -> Point[Transpose[{t, u}]], 
	ImageSize -> 400, 
	Frame -> True, 
	FrameLabel -> {"Time in thousands of years", "Percentage left"}
	]

特性と関係 (2)

Julia関数を呼び出すWolfram言語関数を定義する：

Wolfram Language code: session = StartExternalSession["Julia"];

Wolfram Language code: sqrt = ExternalFunction[session, "sqrt"]

Wolfram Language code: sqrt[4]

セッションを終了する：

Wolfram Language code: DeleteObject[session]

NumericArrayは同じ要素タイプを持つ配列としてJuliaに送られる：

Wolfram Language code: session = StartExternalSession["Julia"]

次は入ってくる配列に対するネイティブのJulia型を示す：

Wolfram Language code: juliaTypeOf = ExternalFunction[session, "typeof"];juliaTypeOf[NumericArray[Range[100], "UnsignedInteger16"]]

セッションを終了する：

Wolfram Language code: DeleteObject[session]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

"Julia" (外部評価システム)

詳細

ExternalEvaluateの使用法

データ型

使用法

例題

例 (1)

スコープ (20)

セッションオプション (9)

"ReturnType" (3)

"Version" (1)

"Evaluator" (1)

"SessionProlog" (1)

"SessionEpilog" (1)

"Prolog" (1)

"Epilog" (1)

コマンドオプション (10)

"Command" (3)

"ReturnType" (1)

"Arguments" (2)

"Constants" (1)

"TemplateArguments" (3)

アプリケーション (2)

特性と関係 (2)

"Julia" (外部評価システム)

詳細

ExternalEvaluateの使用法

データ型

使用法

例題

例 (1)

スコープ (20)

セッションオプション (9)

"ReturnType" (3)

"Version" (1)

"Evaluator" (1)

"SessionProlog" (1)

"SessionEpilog" (1)

"Prolog" (1)

"Epilog" (1)

コマンドオプション (10)

"Command" (3)

"ReturnType" (1)

"Arguments" (2)

"Constants" (1)

"TemplateArguments" (3)

アプリケーション (2)

特性と関係 (2)

関連項目

関連するガイド

関連するワークフロー

履歴