"Julia" (外部计算系统)

ExternalEvaluate 用法

ExternalEvaluate["Julia",code] 在 Julia REPL 中执行代码字符串并以 Wolfram 语言表达式的形式返回结果.
ExternalEvaluate["Julia""String",code] 在 Julia REPL 中执行代码字符串并以 Wolfram 语言字符串的形式返回输出.

数据类型

支持以下 Julia 内置类型：

Bool	True \| False	布尔 True/False 值
Int8, Int16, Int32, etc.	Integer	整数
Float16, Float32, etc.	Real	实数
Complex{Float16}, Complex{Float32}, etc.	Complex	复数（仅支持从 Julia 返回的复数）
String	String	字符的字符串
Array	List	对象列表
Dict	Association	关联数组
Set	List	没有重复元素的无序组
Tuple	List	固定长度的容器
Date, DateTime		日期，日期间隔
NaN	Indeterminate	非数字
nothing	Null	无返回值

使用说明

字符串模板 (<*…*>) 可用于计算并将 Wolfram 语言表达式插入 Julia 代码字符串中.

范例

打开所有单元关闭所有单元

基本范例 (1)

在 Julia 中计算 2+2 并返回结果：

Wolfram Language code: ExternalEvaluate["Julia", "2+2"]

数组以列表形式返回：

Wolfram Language code: ExternalEvaluate["Julia", "[1,2,3,4]"]

类型 > 并在下拉菜单中选择 Julia 可以获取一个使用 ExternalEvaluate 进行计算的代码单元格：

map(sqrt, 1:1:10)

日期是以 DateObject 表达式的形式从 Julia 返回：

Wolfram Language code: ExternalEvaluate["Julia", "using Dates; DateTime(2022)"]

范围 (20)

在 Julia 中计算布尔语句并返回结果：

Wolfram Language code: ExternalEvaluate["Julia", "true || false"]

在 Julia 中拼接字符串并返回结果：

Wolfram Language code: ExternalEvaluate["Julia", "\"hello\" * \" \" * \"world\""]

Julia 中的词典词条作为关联返回：

Wolfram Language code: ExternalEvaluate["Julia", "Dict(\"one\"=>1, \"two\"=>2, \"three\"=>3)"]

Julia 中的数组以 List 的形式返回：

Wolfram Language code: ExternalEvaluate["Julia", "[1 2 3;4 5 6]"]

会话选项 (9)

"ReturnType" (3)

对于 Julia 运算系统，默认的返回类型是 "Expression"：

Wolfram Language code: ExternalEvaluate["Julia", "2+2"] === ExternalEvaluate["Julia" -> "Expression", "2+2"]

数字、字符串、列表和关联会自动导入 "Expression" 返回类型：

Wolfram Language code: ExternalEvaluate["Julia", "[1, 2, 3]"]

Wolfram Language code: MatchQ[%, {__Integer}]

返回类型为 "String"，通过调用 Julia 函数 repr，返回一个字符串的结果：

Wolfram Language code: ExternalEvaluate["Julia" -> "String", "[1, 2, 'א']"]

Wolfram Language code: ExternalEvaluate["Julia", "repr([1, 2, 'א'])"]

"Version" (1)

你可以使用 "Version" 来确保只使用一个特定的 Julia 版本：

Wolfram Language code: ExternalEvaluate[{"Julia", "Version" -> "1.7"}, "repr(VERSION)"]

你可以指定一个次要或补丁版本：

Wolfram Language code: ExternalEvaluate[{"Julia", "Version" -> "1.8.2"}, "repr(VERSION)"]

"Evaluator" (1)

使用指定的 "Evaluator" 启动一个 Julia 会话：

Wolfram Language code:

session = StartExternalSession[{"Julia", "Evaluator" -> "C:\\Users\\WolframUser\\AppData\\Local\\Programs\\Julia-1.8.2\\bin\\julia.exe"}]

检查会话中使用的运算器：

Wolfram Language code: session["Evaluator"]

关闭该会话：

Wolfram Language code: DeleteObject[session]

"SessionProlog" (1)

Wolfram Language code: ExternalEvaluate[{"Julia", "SessionProlog" -> "print(\"session started\")"}, "print(\"evaluating code\"); 2+2"]

"SessionEpilog" (1)

用 "SessionEpilog" 在会话结束时执行一些小指令：

Wolfram Language code: ExternalEvaluate[{"Julia", "SessionEpilog" -> "print(\"session ended\")"}, "print(\"evaluating code\"); 2+2"]

"Prolog" (1)

使用 "Prolog" 可在每次评估前运行一个副作用：

Wolfram Language code: ExternalEvaluate[{"Julia", "SessionProlog" -> "n=0", "Prolog" -> "print(\"n was \", n)"}, {"n += 3", "n += 3"}]

"Epilog" (1)

使用 "Epilog" 可在每次评估后运行一个副作用：

Wolfram Language code:

ExternalEvaluate[{"Julia", "SessionProlog" -> "n=0", "Prolog" -> "print(\"n was \", n)", "Epilog" -> "print(\"n is \", n)"}, {"n += 3", "n += 3"}]

命令选项 (10)

"Command" (3)

当只提供一个 Julia 代码字符串时，命令会直接执行：

Wolfram Language code: ExternalEvaluate["Julia", "2+2"]

上面的内容相当于用这种形式写命令：

Wolfram Language code: ExternalEvaluate["Julia", <|"Command" -> "2+2"|>]

使用 File 包装器来运行文件中的代码：

Wolfram Language code:

ExternalEvaluate["Julia", {
	<|"Command" -> File["ExampleData/add.jl"]|>, 
	<|"Command" -> "add2(3)"|>
	}]

上面的内容相当于用这种形式写命令：

Wolfram Language code:

ExternalEvaluate["Julia", {
	File["ExampleData/add.jl"], 
	"add2(3)"
	}]

将代码放入 CloudObject 中：

Wolfram Language code: cloudObj = CloudExport["print(\"Hello World!\")", "Text", CloudObject["hello-world-jl"]]

从云端直接运行：

Wolfram Language code: ExternalEvaluate["Julia", <|"Command" -> cloudObj|>]

相当于用以下形式编写命令：

Wolfram Language code: ExternalEvaluate["Julia", cloudObj]

"ReturnType" (1)

默认情况下，该命令使用创建会话时指定的 "ReturnType" 执行：

Wolfram Language code:

ExternalEvaluate[
	{"Julia", "ReturnType" -> "String"}, 
	"Dict('a'=> 2)"
	]

在命令中指定 "ReturnType" 将覆盖会话的 "ReturnType"：

Wolfram Language code:

ExternalEvaluate[
	{"Julia", "ReturnType" -> "String"}, 
	{
	<|"Command" -> "Dict('a'=> 2)"|>, 
	<|"Command" -> "Dict('a'=> 2)", "ReturnType" -> "Expression"|>
	}
	]

"Arguments" (2)

使用 "Arguments" 来调用带参数的运算结果：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "+", "Arguments" -> {0, 5}|>
	]

当提供一个非列表参数时，则传递单个参数给函数：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "repr", "Arguments" -> 1|>
	]

如果你需要传递列表作为第一个参数，该列表必须明确包装在一个额外的列表中：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	{
	<|"Command" -> "repr", "Arguments" -> 1|>, 
	<|"Command" -> "repr", "Arguments" -> {1}|>, 
	<|"Command" -> "repr", "Arguments" -> {{1}}|>
	}
	]

你可以在 "Command" 中定义一个函数，然后用 "Arguments" 直接调用它：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "f(a, b)= a+b", "Arguments" -> {1, 2}|>
	]

通过使用 Rule 可以达到同样的效果：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	"f(a, b)= a+b" -> {1, 3}
	]

你也可以通过创建一个 ExternalFunction 来传递参数：

Wolfram Language code: session = StartExternalSession["Julia"]

Wolfram Language code: function = ExternalFunction[session, "f(a, b)= a+b"]

Wolfram Language code: function[1, 3]

Wolfram Language code: DeleteObject[session]

"Constants" (1)

使用 "Constants" 可以在命令运行前永久地设置全局变量：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Constants" -> <|"a" -> 2, "b" -> 3|>, "Command" -> "a + b + 2"|>
	]

"TemplateArguments" (3)

在运行命令时，你可以内联一个 TemplateExpression：

Wolfram Language code:

x = RandomReal[]
ExternalEvaluate["Julia", "1 + <* x *>"]

可使用 "TemplateArguments" 对 TemplateSlot 进行填充：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "2 + ``", "TemplateArguments" -> 1|>
	]

当提供非列表参数时，单个模板参数传递给模板：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "repr(``)", "TemplateArguments" -> 1|>
	]

如果你需要传递列表作为第一个参数，该列表必须明确用一个额外列表进行包装：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	{
	<|"Command" -> "repr(``)", "TemplateArguments" -> 1|>, 
	<|"Command" -> "repr(``)", "TemplateArguments" -> {1}|>, 
	<|"Command" -> "repr(``)", "TemplateArguments" -> {{1}}|>
	}
	]

可为模板槽命名，并使用 Association 来向模板传递命名的参数：

Wolfram Language code:

ExternalEvaluate[
	"Julia", 
	<|"Command" -> "collect(range(`start`, `length`, `end`))", "TemplateArguments" -> <|"start" -> 1, "end" -> 10, "length" -> 10|>|>
	]

应用 (2)

使用 Julia 中统计包中的 mean 函数：

Wolfram Language code:

session = StartExternalSession["Julia"];
ExternalEvaluate[session, "using Pkg; Pkg.add(\"Statistics\")"];
mean = ExternalEvaluate[session, "using Statistics; mean"]

使用该函数：

Wolfram Language code: mean[Range[50]]

关闭会话：

Wolfram Language code: DeleteObject[session]

使用 Julia 中的 OrdinaryDiffEq 程序包解决包解决放射性衰变问题：

Wolfram Language code:

session = StartExternalSession["Julia"];
ExternalEvaluate[session, "using Pkg; Pkg.add(\"OrdinaryDiffEq\")"];

Wolfram Language code:

{t, u} = ExternalEvaluate[session, "using OrdinaryDiffEq
c1 = 5.730
u0=1.0
tspan = (0.0, 1.0)
radioactivedecay(u,p,t) =-c1*u
prob = ODEProblem(radioactivedecay,u0,tspan)
sol = solve(prob,Tsit5())
[sol.t,sol.u]
"];

使用 Wolfram 语言绘制解：

Wolfram Language code:

ListLinePlot[Transpose[{t, u}], 
	PlotLabel -> "Carbon-14 half-life", 
	PlotStyle  -> Red, 
	Epilog -> Point[Transpose[{t, u}]], 
	ImageSize -> 400, 
	Frame -> True, 
	FrameLabel -> {"Time in thousands of years", "Percentage left"}
	]

属性和关系 (2)

定义一个调用 Julia 函数的 Wolfram 语言函数：

Wolfram Language code: session = StartExternalSession["Julia"];

Wolfram Language code: sqrt = ExternalFunction[session, "sqrt"]

Wolfram Language code: sqrt[4]

关闭会话：

Wolfram Language code: DeleteObject[session]

NumericArray 作为一个具有相同元素类型的数组被发送到 Julia：

Wolfram Language code: session = StartExternalSession["Julia"]

表示传入数组的本地 Julia 类型：

Wolfram Language code: juliaTypeOf = ExternalFunction[session, "typeof"];juliaTypeOf[NumericArray[Range[100], "UnsignedInteger16"]]

关闭会话：

Wolfram Language code: DeleteObject[session]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

"Julia" (外部计算系统)

更多信息

ExternalEvaluate 用法

数据类型

使用说明

范例

基本范例 (1)

范围 (20)

会话选项 (9)

"ReturnType" (3)

"Version" (1)

"Evaluator" (1)

"SessionProlog" (1)

"SessionEpilog" (1)

"Prolog" (1)

"Epilog" (1)

命令选项 (10)

"Command" (3)

"ReturnType" (1)

"Arguments" (2)

"Constants" (1)

"TemplateArguments" (3)

应用 (2)

属性和关系 (2)

"Julia" (外部计算系统)

更多信息

ExternalEvaluate 用法

数据类型

使用说明

范例

基本范例 (1)

范围 (20)

会话选项 (9)

"ReturnType" (3)

"Version" (1)

"Evaluator" (1)

"SessionProlog" (1)

"SessionEpilog" (1)

"Prolog" (1)

"Epilog" (1)

命令选项 (10)

"Command" (3)

"ReturnType" (1)

"Arguments" (2)

"Constants" (1)

"TemplateArguments" (3)

应用 (2)

属性和关系 (2)

参见

相关指南

相关的工作流程

历史