WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AlgebraicNumber[θ,{c0,c1,…,cn}]

で与えられる体における代数的数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

AlgebraicNumber

AlgebraicNumber[θ,{c0,c1,…,cn}]

で与えられる体における代数的数を表す．

詳細

  • 同じ体の中のAlgebraicNumberオブジェクトは，算術演算で自動的に結合される．
  • 生成元 θ は，根基すなわちRootオブジェクトによって表された任意の代数的数でよい．係数 ciは整数または有理数でなければならない．
  • AlgebraicNumberは，θ が代数的整数で ciのリストの長さが θ の最小多項式の次数と等しくなるように自動的に簡約される．
  • AlgebraicNumberオブジェクトは常に数量として扱われる．
  • NによってAlgebraicNumberオブジェクトの近似数値が求められる．
  • AlgebraicNumberオブジェクトに，Abs，Re，Round，Lessのような操作を使うことができる．
  • RootReduceを使ってAlgebraicNumberオブジェクトをRootオブジェクトに変換することができる．
  • 特定の代数的数を，AlgebraicNumberオブジェクトとして，多数の異なる方法で表すことができる．各表し方は，その体に指定された生成元 θ によって特徴付けられる．
  • 整数または有理数を表しているAlgebraicNumberオブジェクトは，自動的に明示的な整数または有理式に簡約される．

例題

すべて開く すべて閉じる

例  (1)

代数的数を表す：

Wolfram Language code: AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 2, 1}]

演算を行う：

Wolfram Language code: 1 + % ^ 2

数値近似を得る：

Wolfram Language code: N[%]

スコープ  (7)

AlgebraicNumberオブジェクトは任意の精度で評価できる：

Wolfram Language code: N[AlgebraicNumber[Sqrt[2] I, {1, -1}], 50]

整数または有理数を表すオブジェクトは自動的に簡約される：

Wolfram Language code: AlgebraicNumber[3, {1, 2}]
Wolfram Language code: AlgebraicNumber[5 / 2, {3, 2}]

AlgebraicNumber[θ,{c0,…,cn}]中の生成元 θ は代数的整数に自動的に簡約される：

Wolfram Language code: AlgebraicNumber[(1 + I) / 2, {1, 3}]

無理式：

Wolfram Language code: AlgebraicNumber[Sqrt[Sqrt[2] + 1], {1, 2, 1, 2}]

Rootオブジェクト：

Wolfram Language code: AlgebraicNumber[Root[5# ^ 5 + 11# + 1&, 1], {1, 1, 2}]

AlgebraicNumberオブジェクト：

Wolfram Language code: AlgebraicNumber[AlgebraicNumber[Root[-3 + #1^3&, 1], {1, 2, 1}], {1, 1, 2}]

AlgebraicNumberオブジェクトの係数は整数か有理数である：

Wolfram Language code: AlgebraicNumber[Sqrt[2] + Sqrt[5], {1, 1 / 2}]

係数の数は代数的数の次数にマッチするように調整される：

Wolfram Language code: AlgebraicNumber[3 ^ (1 / 5), {1, 2, 1}]
Wolfram Language code: AlgebraicNumber[3 ^ (1 / 5), {1, 2, 1, 3, 3, 1}]

数体における演算：

Wolfram Language code: AlgebraicNumber[Sqrt[2], {1, 1 / 2}] + AlgebraicNumber[Sqrt[2], {1, 2}]
Wolfram Language code: AlgebraicNumber[Sqrt[2], {1, 1 / 2}] * AlgebraicNumber[Sqrt[2], {1, 2}]
Wolfram Language code: 1 / AlgebraicNumber[Sqrt[2], {1, 1 / 2}]
Wolfram Language code: AlgebraicNumber[Sqrt[2], {1, 1 / 2}] ^ 3

AlgebraicNumberオブジェクトの操作：

Wolfram Language code: a = AlgebraicNumber[Root[-1 + #1 + #1^3&, 1], {0, -1, 4}]
Wolfram Language code: Re[a]
Wolfram Language code: Abs[a]
Wolfram Language code: Round[a]
Wolfram Language code: 1 < a

アプリケーション  (2)

同じ数体におけるAlgebraicNumberオブジェクトの計算は速い：

Wolfram Language code: {a, b, c} = {I, Sqrt[2], Root[#1^3 - 2 #1 + 3&, 1]};

これらを同じ数体の一部にする：

Wolfram Language code: {x, y, z} = ToNumberField[{a, b, c}];
Wolfram Language code: RootReduce[(-2 y z (7 + x - y + z^2) + (6 + x^2 + 2 y) (-11 + x y + z^2)/2 y z (-4 - x + 3 y z) - (6 + x^2 + 2 y) (2 - 2 x + z^3))]//Timing

この例では，RootReduceは自動的にAlgebraicNumberオブジェクト計算を使う：

Wolfram Language code: {x, y, z} = {a, b, c};
Wolfram Language code: RootReduce[(-2 y z (7 + x - y + z^2) + (6 + x^2 + 2 y) (-11 + x y + z^2)/2 y z (-4 - x + 3 y z) - (6 + x^2 + 2 y) (2 - 2 x + z^3))]//Timing

Rootオブジェクトを使った直接計算と比較する：

Wolfram Language code: RootReduce[(-2 y z (7 + x - y + z^2) + (6 + x^2 + 2 y) (-11 + x y + z^2)/2 y z (-4 - x + 3 y z) - (6 + x^2 + 2 y) (2 - 2 x + z^3)), Method -> "Recursive"]//Timing

ペル方程式 の2つの解：

Wolfram Language code: {x1, y1} = {9, 1};
Wolfram Language code: {x2, y2} = {163, 18};

他の解も容易に演繹できる：

Wolfram Language code: a = Last /@ (AlgebraicNumber[Sqrt[82], {x1, y1}] ^ Range[1, 5])
Wolfram Language code: b = Last /@ (AlgebraicNumber[Sqrt[82], {x2, y2}] ^ Range[1, 5])

検証する：

Wolfram Language code: Apply[#1 ^ 2 - 82#2 ^ 2 &, a, 1]
Wolfram Language code: Apply[#1 ^ 2 - 82#2 ^ 2 &, b, 1]

特性と関係  (5)

RootReduceを使って代数的数をRootオブジェクトに変換する：

Wolfram Language code: RootReduce[AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 2, 1}]]

ToNumberFieldを使って，AlgebraicNumberオブジェクトとしてのRootオブジェクトの表現を得る：

Wolfram Language code: ToNumberField[Root[1 + 2#1 + 2#1 ^ 2 + 2#1 ^ 3 + 2#1 ^ 4&, 1]]

生成多項式を得る：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 2, 1}];
Wolfram Language code: AlgebraicNumberPolynomial[a, x]

代数的数論の操作：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 1, 1}];
Wolfram Language code: AlgebraicNumberNorm[a]
Wolfram Language code: AlgebraicNumberTrace[a]

最小多項式：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 1, 1}];
Wolfram Language code: MinimalPolynomial[a, x]
Wolfram Language code: % /. x -> a

考えられる問題  (1)

Sqrt，Re，Im等の操作は自動的に簡約しない：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 2, 1}];
Wolfram Language code: Re[a]
Wolfram Language code: Sqrt[a]

RootReduceを使ってAlgebraicNumberに変換する：

Wolfram Language code: ToNumberField[RootReduce[Re[a]]]
Wolfram Language code: ToNumberField[RootReduce[Sqrt[a]]]
Wolfram Research (2007), AlgebraicNumber, Wolfram言語関数， https://reference.wolfram.com/language/ref/AlgebraicNumber.html.

テキスト

Wolfram Research (2007), AlgebraicNumber, Wolfram言語関数， https://reference.wolfram.com/language/ref/AlgebraicNumber.html.

CMS

Wolfram Language. 2007. "AlgebraicNumber." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AlgebraicNumber.html.

APA

Wolfram Language. (2007). AlgebraicNumber. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AlgebraicNumber.html

BibTeX

@misc{reference.wolfram_2026_algebraicnumber, author="Wolfram Research", title="{AlgebraicNumber}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/AlgebraicNumber.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_algebraicnumber, organization={Wolfram Research}, title={AlgebraicNumber}, year={2007}, url={https://reference.wolfram.com/language/ref/AlgebraicNumber.html}, note=[Accessed: 16-August-2026]}