WOLFRAM

Wolfram 语言与系统参考资料中心

AlgebraicNumber[θ,{c0,c1,…,cn}]

表示由 给出的域 中的代数数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
历史
按以下格式引用：

AlgebraicNumber

AlgebraicNumber[θ,{c0,c1,…,cn}]

表示由 给出的域 中的代数数.

更多信息

  • 在相同域中的 AlgebraicNumber 对象由算术运算自动组合.
  • 生成元 θ 可以是任意代数数，以根或 Root 对象表示. 系数 ci 必须是整数或有理数.
  • AlgebraicNumber 自动简化使 θ 成为代数整数，并且 ci 的列表长度与 θ 的极小多项式次数相等.
  • AlgebraicNumber 对象总是作为数值量处理.
  • N 求出一个 AlgebraicNumber 对象的近似数值.
  • Abs、 Re、 Round 和 Less 一类的运算可用于 AlgebraicNumber 对象.
  • RootReduce 可用于 AlgebraicNumber 对象到 Root 对象的变换.
  • 作为 AlgebraicNumber 对象的一个特定代数数可以有多种不同表示. 每种表示都由为该域指定的生成元 θ 表征.
  • 表示整数或有理数的 AlgebraicNumber 对象自动简化为明确的整数或有理形式.

范例

打开所有单元 关闭所有单元

基本范例  (1)

表示一个代数数：

Wolfram Language code: AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 2, 1}]

进行算术运算：

Wolfram Language code: 1 + % ^ 2

得到一个数值近似：

Wolfram Language code: N[%]

范围  (7)

AlgebraicNumber 对象可以计算至任意精度：

Wolfram Language code: N[AlgebraicNumber[Sqrt[2] I, {1, -1}], 50]

表示整数或有理数的对象自动简化：

Wolfram Language code: AlgebraicNumber[3, {1, 2}]
Wolfram Language code: AlgebraicNumber[5 / 2, {3, 2}]

AlgebraicNumber[θ,{c0,…,cn}] 中的生成元 θ 将自动化简为代数整数：

Wolfram Language code: AlgebraicNumber[(1 + I) / 2, {1, 3}]

根表达式：

Wolfram Language code: AlgebraicNumber[Sqrt[Sqrt[2] + 1], {1, 2, 1, 2}]

Root 对象：

Wolfram Language code: AlgebraicNumber[Root[5# ^ 5 + 11# + 1&, 1], {1, 1, 2}]

AlgebraicNumber 对象：

Wolfram Language code: AlgebraicNumber[AlgebraicNumber[Root[-3 + #1^3&, 1], {1, 2, 1}], {1, 1, 2}]

AlgebraicNumber 对象的系数为整数或有理数：

Wolfram Language code: AlgebraicNumber[Sqrt[2] + Sqrt[5], {1, 1 / 2}]

对系数的值进行调整以便与代数数的次数相匹配：

Wolfram Language code: AlgebraicNumber[3 ^ (1 / 5), {1, 2, 1}]
Wolfram Language code: AlgebraicNumber[3 ^ (1 / 5), {1, 2, 1, 3, 3, 1}]

在数域中进行算术运算：

Wolfram Language code: AlgebraicNumber[Sqrt[2], {1, 1 / 2}] + AlgebraicNumber[Sqrt[2], {1, 2}]
Wolfram Language code: AlgebraicNumber[Sqrt[2], {1, 1 / 2}] * AlgebraicNumber[Sqrt[2], {1, 2}]
Wolfram Language code: 1 / AlgebraicNumber[Sqrt[2], {1, 1 / 2}]
Wolfram Language code: AlgebraicNumber[Sqrt[2], {1, 1 / 2}] ^ 3

AlgebraicNumber 对象运算：

Wolfram Language code: a = AlgebraicNumber[Root[-1 + #1 + #1^3&, 1], {0, -1, 4}]
Wolfram Language code: Re[a]
Wolfram Language code: Abs[a]
Wolfram Language code: Round[a]
Wolfram Language code: 1 < a

应用  (2)

在相同数域中利用 AlgebraicNumber 对象进行计算速度较快：

Wolfram Language code: {a, b, c} = {I, Sqrt[2], Root[#1^3 - 2 #1 + 3&, 1]};

使它们成为同一数域的一部分：

Wolfram Language code: {x, y, z} = ToNumberField[{a, b, c}];
Wolfram Language code: RootReduce[(-2 y z (7 + x - y + z^2) + (6 + x^2 + 2 y) (-11 + x y + z^2)/2 y z (-4 - x + 3 y z) - (6 + x^2 + 2 y) (2 - 2 x + z^3))]//Timing

在这个例子中，RootReduce 自动采用 AlgebraicNumber 对象计算：

Wolfram Language code: {x, y, z} = {a, b, c};
Wolfram Language code: RootReduce[(-2 y z (7 + x - y + z^2) + (6 + x^2 + 2 y) (-11 + x y + z^2)/2 y z (-4 - x + 3 y z) - (6 + x^2 + 2 y) (2 - 2 x + z^3))]//Timing

与 Root 对象直接计算进行比较：

Wolfram Language code: RootReduce[(-2 y z (7 + x - y + z^2) + (6 + x^2 + 2 y) (-11 + x y + z^2)/2 y z (-4 - x + 3 y z) - (6 + x^2 + 2 y) (2 - 2 x + z^3)), Method -> "Recursive"]//Timing

Pell 方程 的两种解法：

Wolfram Language code: {x1, y1} = {9, 1};
Wolfram Language code: {x2, y2} = {163, 18};

很容易推算出更多解：

Wolfram Language code: a = Last /@ (AlgebraicNumber[Sqrt[82], {x1, y1}] ^ Range[1, 5])
Wolfram Language code: b = Last /@ (AlgebraicNumber[Sqrt[82], {x2, y2}] ^ Range[1, 5])

检验：

Wolfram Language code: Apply[#1 ^ 2 - 82#2 ^ 2 &, a, 1]
Wolfram Language code: Apply[#1 ^ 2 - 82#2 ^ 2 &, b, 1]

属性和关系  (5)

利用 RootReduce 把一个代数数变换成一个 Root 对象：

Wolfram Language code: RootReduce[AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 2, 1}]]

利用 ToNumberField 像 AlgebraicNumber 对象那样表示 Root 对象：

Wolfram Language code: ToNumberField[Root[1 + 2#1 + 2#1 ^ 2 + 2#1 ^ 3 + 2#1 ^ 4&, 1]]

得到生成元多项式：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 2, 1}];
Wolfram Language code: AlgebraicNumberPolynomial[a, x]

代数数理论运算：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 1, 1}];
Wolfram Language code: AlgebraicNumberNorm[a]
Wolfram Language code: AlgebraicNumberTrace[a]

极小多项式：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 1, 1}];
Wolfram Language code: MinimalPolynomial[a, x]
Wolfram Language code: % /. x -> a

可能存在的问题  (1)

Sqrt、Re 和 Im 等运算不会自动化简：

Wolfram Language code: a = AlgebraicNumber[Root[# ^ 3 + # + 1&, 3], {1, 2, 1}];
Wolfram Language code: Re[a]
Wolfram Language code: Sqrt[a]

利用 RootReduce 转换为 AlgebraicNumber：

Wolfram Language code: ToNumberField[RootReduce[Re[a]]]
Wolfram Language code: ToNumberField[RootReduce[Sqrt[a]]]
Wolfram Research (2007)，AlgebraicNumber，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AlgebraicNumber.html.

文本

Wolfram Research (2007)，AlgebraicNumber，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AlgebraicNumber.html.

CMS

Wolfram 语言. 2007. "AlgebraicNumber." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AlgebraicNumber.html.

APA

Wolfram 语言. (2007). AlgebraicNumber. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AlgebraicNumber.html 年

BibTeX

@misc{reference.wolfram_2026_algebraicnumber, author="Wolfram Research", title="{AlgebraicNumber}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/AlgebraicNumber.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_algebraicnumber, organization={Wolfram Research}, title={AlgebraicNumber}, year={2007}, url={https://reference.wolfram.com/language/ref/AlgebraicNumber.html}, note=[Accessed: 17-August-2026]}