WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Association[key1val1,key2val2,…]またはkey1val1,key2val2,…

キーと値の連想を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
構築と抽出  
パターンマッチング操作  
特性と関係  
考えられる問題  
関連項目
関連するガイド
関連するワークフロー
関連リンク
履歴
引用書式

Association

Association[key1val1,key2val2,…]またはkey1val1,key2val2,…

キーと値の連想を表す．

詳細

  • 連想 assoc 中の任意の key に関連付けられた値は assoc[key]を使って抽出することができる． »
  • 連想は記号指標の付いたリストのように振る舞う．任意の key に関連付けられている値は，部分指定Key[key]を使って抽出することができる．key が文字列の場合は，Keyを省略することができる． »
  • assoc 中に key がない場合，assoc[key]はMissing["KeyAbsent",key]を返す． »
  • assoc が連想中に値があるシンボルなら，assoc[key]=val を使って key と val の連想を関連付けたり再設定したりできる． »
  • Map，Select，Sort等のよく使われるリスト操作は，連想中の値に適用され，キーは変更されずに残る． »
  • Association[{key1val1,…}]は<|key1val1,…|>を与える． »
  • 同じキーを持つ複数の要素がある場合，これらの要素の最後のものを除くすべてが削除される．Mergeは，代りに繰り返されるキーの値のリストを与える．
  • 連想は，\[LeftAssociation]および\[RightAssociation]の記号を使って入力することができる．この記号は，順に <| および |>を使って入力できる．
  • NormalはAssociationオブジェクトを規則のリストに変換する． »
  • KeyValuePatternを使って特定の要素を含む連想のためのパターンを表すことができる． »

例題

すべて開く すべて閉じる

例  (4)

キーaが値xに，キーbが値yに，という具合に関連付けられている連想：

Wolfram Language code: <|a -> x, b -> y, c -> z|>

キーbに関連付けられた値を抽出する：

Wolfram Language code: %[b]

規則のリストを連想に変換する：

Wolfram Language code: Association[{a -> x, b -> y, c -> z}]

値をリセットすることで連想が変更できる：

Wolfram Language code: assoc = <|a -> x, b -> y, c -> z|>
Wolfram Language code: assoc[b] = w

キーbの値がyではなくwになった：

Wolfram Language code: assoc

遅延規則を使うことで，連想の構築中の値の評価を防ぐことができる：

Wolfram Language code: <|a -> 1 + 1, b -> 2 + 2, c :> 3 + 3, d :> 4 + 4|>

値は抽出時に評価される：

Wolfram Language code: %[c]

スコープ  (17)

構築と抽出  (9)

連想は，キーとして連想を含む任意の式を持つことができる：

Wolfram Language code: Keys[<|{2, 3} -> x, RGBColor[0.95, 0.43, 0.96] -> y, <|a -> 1, b -> 2|> -> z|>]

連想を追加する：

Wolfram Language code: Append[<|a -> x, b -> y, c -> z|>, d -> w]

連想は任意数の要素に使うことができる：

Wolfram Language code: assoc = Association[Table[i -> i ^ 2, {i, 10000}]];

連想から値を抽出することは，非常に効率がよい：

Wolfram Language code: assoc[10000]//EchoTiming
2.`*^-6

不在の要素はMissingで表される：

Wolfram Language code: <|a -> x, b -> y, c -> z|>[d]

Lookupでは，デフォルト値を与えることができる：

Wolfram Language code: Lookup[<|a -> x, b -> y, c -> z|>, d, q]

Partを使って連想から値を抽出する：

Wolfram Language code: assoc = <|a -> x, b -> {y, z}|>; assoc[[Key[b]]]

値の一部を抽出する：

Wolfram Language code: assoc[[Key[b], 1]]

Key[k]という部分指定は，値が連想である任意のレベルで使うことができる：

Wolfram Language code: {5, 7, assoc}[[3, Key[b], 2]]

連想の3番目の値を抽出する：

Wolfram Language code: assoc = <|3 -> a, 1 -> b, 2 -> c|>; assoc[[3]]

キー3に関連付けられた値を抽出する：

Wolfram Language code: assoc[[Key[3]]]

連想の2番目と3番目の部分からなる部分連想を入手する：

Wolfram Language code: assoc = <|3 -> a, 1 -> b, 2 -> c|>; assoc[[{2, 3}]]

代りにキー2とキー3を使う：

Wolfram Language code: assoc[[{Key[2], Key[3]}]]

キー{2,3}に関連付けられた値を抽出する：

Wolfram Language code: assoc[[Key[{2, 3}]]]

Extractを使って値を抽出する：

Wolfram Language code: assoc = <|a -> 1 + 1, b -> 2 + 2, c :> 3 + 3, d :> 4 + 4|>; Extract[assoc, Key[c]]

評価しないで値を入手する：

Wolfram Language code: assoc = <|a -> 1 + 1, b -> 2 + 2, c :> 3 + 3, d :> 4 + 4|>; Extract[assoc, Key[c], Hold]

連想をキーのリストと値のリストに分離する：

Wolfram Language code: Comap[{Keys, Values}, <|a -> 1, b -> 2, c -> 3|>]

これを順序対のリストに変換する：

Wolfram Language code: Transpose[%]

パターンマッチング操作  (8)

連想はパターンマッチングに使うことができる：

Wolfram Language code: MatchQ[<|a -> 1|>, <|_ -> _|>]
Wolfram Language code: Replace[<|a -> 1|>, <|a -> x_|> -> x]

連想からキーと値を抽出する：

Wolfram Language code: <|1 -> 2|> /. <|a_ -> b_|> :> {a, b}

関数の引数を置換する：

Wolfram Language code: f[<|1 -> 2, 3 -> 4|>] /. f[<|a_ -> b_, ___|>] :> f[a, b]

特定のキーで規則を取り出す：

Wolfram Language code: <|1 -> 2, 2 -> 3, 3 -> 4, 5 -> 6|> /. <|___, 3 -> b_, ___|> :> f[b]

長さが2の連想だけをフィルターする：

Wolfram Language code: Cases[{<|1 -> x|>, <|1 -> x, 2 -> y|>, <|1 -> x, 2 -> y, 3 -> z|>}, <|_, _|>]

連想を引数として関数を定義する：

Wolfram Language code: g[<|k_ -> v_|>] := v
Wolfram Language code: g[<|1 -> 2|>]

ネストした連想を関数の引数として使う：

Wolfram Language code: h[<|k_ -> <|k2_ -> v2_|>|>] := {k, k2, v2}
Wolfram Language code: h[<|1 -> <|2 -> 3|>|>]

KeyValuePatternは，連想中の任意の要素のマッチングに使える：

Wolfram Language code: MatchQ[<|a -> 1, b -> 2, c -> 3|>, KeyValuePattern[b -> 2]]

KeyValuePatternは連想中の任意の位置に出現する要素をマッチする：

Wolfram Language code: Replace[<|a -> 1, b -> 2, c -> 3|>, KeyValuePattern[{a -> x_, c -> y_}] :> {x, y}]

特性と関係  (9)

キーは，典型的なリスト操作では「透過的」である：

Wolfram Language code: Map[f, <|a -> 4, b -> 2, c -> 1, d -> 5|>]
Wolfram Language code: Sort[<|a -> 4, b -> 2, c -> 1, d -> 5|>]
Wolfram Language code: Select[<|a -> 4, b -> 2, c -> 1, d -> 5|>, # > 3&]
Wolfram Language code: Total[<|a -> 4, b -> 2, c -> 1, d -> 5|>]

Valuesは，連想から値を抽出する：

Wolfram Language code: Values[<|a -> x, b -> y, c -> z|>]

Keysは，連想からキーを抽出する：

Wolfram Language code: Keys[<|a -> x, b -> y, c -> z|>]

Normalは，連想を規則のリストに変える：

Wolfram Language code: Normal[<|a -> x, b -> y, c -> z|>]

Positionは連想中のキーを与える：

Wolfram Language code: Position[<|a -> 4, b -> 2, c -> 1, d -> 5|>, 2]

連想中の値は部分のように抽出できる：

Wolfram Language code: <|a -> x, b -> y, c -> z|>[[Key[b]]]

連想中のキーが文字列なら，これを部分として抽出するのに明示的なKeyは不要である：

Wolfram Language code: <|"a" -> x, "b" -> y, "c" -> z|>[["b"]]

数値による部分指定は，連想に対して構造的に働く：

Wolfram Language code: <|a -> x, b -> y, c -> z|>[[2]]

連想は，繰り返されるキーの最後のものしか保存しない：

Wolfram Language code: <|a -> x, a -> xp, b -> y, c -> z, c -> zp|>
Wolfram Language code: Join[<|a -> x, b -> y, c -> z|>, <|a -> xp, c -> zp|>]

連想が変更されたときは，新たなコピーが作られる：

Wolfram Language code: v = w = <|a -> 1, b -> 2|>
Wolfram Language code: v[a] = 3

vは変更されているが，wは変わっていない：

Wolfram Language code: {v, w}

連想の長さは0でもよい：

Wolfram Language code: <||>
Wolfram Language code: Length[%]

考えられる問題  (2)

Associationは，構造的な関数では，2レベルではなく，1レベルとして数えられる：

Wolfram Language code: Level[<|a -> x, b -> y|>, {1}]
Wolfram Language code: Depth[<|a -> x, b -> y|>]

規則のリストは2レベルである：

Wolfram Language code: Level[{a -> x, b -> y}, {1}]
Wolfram Language code: Depth[{a -> x, b -> y}]

連想の頭部を置換するとキーが失われる：

Wolfram Language code: ReplacePart[<|"x" -> 1, "y" -> 2|>, {0} -> List]

連想から規則を抽出する：

Wolfram Language code: Normal[<|"x" -> 1, "y" -> 2|>]
Wolfram Research (2014), Association, Wolfram言語関数， https://reference.wolfram.com/language/ref/Association.html （2016年に更新）.

テキスト

Wolfram Research (2014), Association, Wolfram言語関数， https://reference.wolfram.com/language/ref/Association.html （2016年に更新）.

CMS

Wolfram Language. 2014. "Association." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2016. https://reference.wolfram.com/language/ref/Association.html.

APA

Wolfram Language. (2014). Association. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Association.html

BibTeX

@misc{reference.wolfram_2026_association, author="Wolfram Research", title="{Association}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/Association.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_association, organization={Wolfram Research}, title={Association}, year={2016}, url={https://reference.wolfram.com/language/ref/Association.html}, note=[Accessed: 08-September-2026]}