Wolfram 语言与系统参考资料中心

AsymptoticDSolveValue

AsymptoticDSolveValue[eqn,f,xx₀]

计算微分方程 eqn 的渐近逼近，f[x] 以 x₀ 为中心.

AsymptoticDSolveValue[{eqn₁,eqn₂,…},{f₁,f₂,…},xx₀]

计算微分方程组的渐近逼近.

AsymptoticDSolveValue[eqn,f,x,ϵϵ₀]

计算 f[x,ϵ] 的渐近逼近，参数 ϵ 以 ϵ₀ 为中心.

AsymptoticDSolveValue[eqn,f,…,{ξ,ξ₀,n}]

计算 n 阶渐近逼近.

AsymptoticDSolveValue

AsymptoticDSolveValue[eqn,f,xx₀]

计算微分方程 eqn 的渐近逼近，f[x] 以 x₀ 为中心.

AsymptoticDSolveValue[{eqn₁,eqn₂,…},{f₁,f₂,…},xx₀]

计算微分方程组的渐近逼近.

AsymptoticDSolveValue[eqn,f,x,ϵϵ₀]

计算 f[x,ϵ] 的渐近逼近，参数 ϵ 以 ϵ₀ 为中心.

AsymptoticDSolveValue[eqn,f,…,{ξ,ξ₀,n}]

计算 n 阶渐近逼近.

范例

打开所有单元关闭所有单元

基本范例 (3)

计算一个微分方程的渐近近似：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] - y[x] == 0, y[0] == 0, y'[0] == 1}, y[x], x -> 0]

求微分方程的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + y[x] == 0, y[0] == 1, y'[0] == 0}, y[x], {x, 0, 10}]

绘制解：

Wolfram Language code: Plot[%, {x, 0, 3π / 2}]

求摄动问题的渐近展开式：

Wolfram Language code: AsymptoticDSolveValue[{ϵ y''[x] + y'[x] + x y[x] == 0, y[0] == 0, y[1] == 1 / 2}, y[x], x, {ϵ, 0, 1}]

绘制解：

Wolfram Language code: Plot[Evaluate[Table[%, {ϵ, {1 / 30, 1 / 10, 1 / 5}}]], {x, 0, 1}]

范围 (50)

基本用法 (8)

计算常微分方程在 x=0 附近的阶数为 10 的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + x y[x] == 0, y[0] == 0, y'[0] == 1}, y[x], {x, 0, 10}]

绘制渐近解的连续逼近：

Wolfram Language code: sol = AsymptoticDSolveValue[{y'[x] - y[x] == 0, y[0] == 1}, y[x], {x, 0, 4}]

用 Accumulate 来构建逼近解的列表：

Wolfram Language code: accum = Accumulate[List@@sol]

获取所要求的绘图：

Wolfram Language code: Plot[Evaluate[accum], {x, 0, 5}, PlotLegends -> "Expressions"]

在 x=3 附近计算级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + 2 y[x] == 0, y[3] == 1, y'[3] == 0}, y[x], {x, 3, 10}]

获取通解的级数近似：

Wolfram Language code: AsymptoticDSolveValue[y''[x] + y[x] == 0, y[x], {x, 0, 8}]

获取不同项数的级数近似：

Wolfram Language code: AsymptoticDSolveValue[{ y'[x] + 3y[x] == 1, y[0] == 2}, y[x], {x, 0, 3}]

Wolfram Language code: AsymptoticDSolveValue[{ y'[x] + 3y[x] == 1, y[0] == 2}, y[x], {x, 0, 5}]

计算常微分方程组的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y'[x] == z[x] + 3, z'[x] == -y[x], y[0] == 1, z[0] == 5}, {y[x], z[x]}, {x, 0, 5}]

计算摄动问题的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y'[x] + ϵ y[x] == Cos[x], y[0] == 0}, y[x], x, {ϵ, 0, 1}]

改变项数：

Wolfram Language code: AsymptoticDSolveValue[{y'[x] + ϵ y[x] == Cos[x], y[0] == 0}, y[x], x, {ϵ, 0, 2}]

Wolfram Language code: AsymptoticDSolveValue[{y'[x] + ϵ y[x] == Cos[x], y[0] == 0}, y[x], x, {ϵ, 0, 3}]

求摄动问题的渐近解：

Wolfram Language code: AsymptoticDSolveValue[{ y''[x] + ϵ y'[x] + y[x] == 0, y[0] == 1, y'[0] == 0}, y[x], x, {ϵ, 0, 2}]//Simplify

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[Accumulate[CoefficientList[%, ϵ] /. {ϵ -> 1 / 100}]], {x, 0, π / 2}]

常点 (7)

求线性一阶常微分方程在常点 x=0 处的泰勒级数解：

Wolfram Language code: AsymptoticDSolveValue[{ y'[x] - x y[x] == 0, y[0] == 1}, y[x], {x, 0, 10}]

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[Accumulate[List@@%]], {x, 0, 3}, PlotLegends -> "Expressions"]

线性二阶常微分方程在常点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + x y'[x] - y[x] == 0, y[0] == 1, y'[0] == 0}, y[x], {x, 0, 10}]

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[Accumulate[List@@%]], {x, 0, 3}, PlotLegends -> "Expressions"]

线性非齐次常微分方程在常点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y'[x] + 7y[x] == E ^ x, y[0] == 1}, y[x], {x, 0, 5}]

具有无理系数的线性常微分方程在常点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + E ^ x y'[x] + 7 Sin[x] ^ 2 y[x] == Cos[2x], y[0] == 1, y'[0] == 5}, y[x], {x, 0, 5}]

线性高阶常微分方程在常点 x=0 处的级数解：

Wolfram Language code:

AsymptoticDSolveValue[{y''''[x] + 26 y''[x] + 25 y[x] == 0, y[0] == 1, Derivative[1][y][0] == 0, Derivative[2][y][0] == -1, Derivative[3][y][0] == 5}, y[x], {x, 0, 8}]

线性常微分方程在常点 x=1 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + 5y[x] == Cos[2x], y[1] == 1, y'[1] == 5}, y[x], {x, 1, 3}]

线性常微分方程在常点处的通解的级数近似：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + 5y[x] == 0}, y[x], {x, 1, 3}]

正则奇点 (5)

求线性一阶常微分方程在正则奇点 x=0 处的 Frobenius 级数解：

Wolfram Language code: AsymptoticDSolveValue[Sin[x] y'[x] + y[x] == 0, y[x], {x, 0, 7}]

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[Accumulate[List@@(Expand[% /. {C[1] -> 1}])]], {x, 0, 3}, PlotLegends -> "Expressions"]

线性二阶常微分方程在正则奇点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[2 x ^ 2 y''[x] + 3x y'[x] - (x ^ 2 + 1)y[x] == 0, y[x], {x, 0, 5}]

求线性高阶常微分方程在正则奇点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[x ^ 4 y''''[x] + y[x] == 0, y[x], {x, 0, 4}]//FullSimplify

此例中级数解就是精确解：

Wolfram Language code: (x ^ 4 y''''[x] + y[x] == 0 /. {y -> Function[{x}, Evaluate[%]]})//Simplify

线性常微分方程在正则奇点 x=1 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[(x - 1)y''[x] + y[x] == 0, y[x], {x, 1, 2}]

具有无理系数的线性常微分方程在正则奇点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[Sin[x] ^ 2 * y''[x] + x y[x] == 0, y[x], {x, 0, 2}]

非正则奇点 (3)

求线性一阶常微分方程在非正则奇点 x=0 处的渐近解：

Wolfram Language code: AsymptoticDSolveValue[x ^ 2 y'[x] + (x ^ 2 + 1)y[x] == 0, y[x], {x, 0, 4}]

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[Accumulate[List@@(Expand[% /. {C[1] -> 1}])]], {x, 0, 3}, PlotLegends -> "Expressions"]

线性二阶常微分方程在非正则奇点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[x ^ 3 y''[x] + y[x] == 0, y[x], {x, 0, 2}]

线性高阶常微分方程在非正则奇点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[x ^ 4 y'''[x] - 2 y'[x] + y[x] == 0, y[x], {x, 0, 2}]

非线性常微分方程 (7)

求非线性一阶常微分方程在 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{ y'[x] - x y[x] ^ 3 == 0, y[0] == 1}, y[x], {x, 0, 8}]

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[Accumulate[List@@%]], {x, 0, 1}, PlotLegends -> "Expressions"]

非线性二阶常微分方程在 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + 2y'[x] - y[x] ^ 2 == 0, y[0] == 1, y'[0] == 0}, y, {x, 0, 6}]

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[Accumulate[List@@%]], {x, 0, 3}, PlotLegends -> "Expressions"]

非线性非齐次常微分方程在常点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y'[x] + y[x] ^ 2 == E ^ (2x), y[0] == 1}, y[x], {x, 0, 5}]

具有无理系数的非线性常微分方程在 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + y'[x] ^ 2 + 7 Sin[x] ^ 2 y[x] == Cos[2x], y[0] == 1, y'[0] == 5}, y[x], {x, 0, 5}]

非线性高阶常微分方程在 x=0 处的级数解：

Wolfram Language code:

AsymptoticDSolveValue[{y''''[x] + y''[x] ^ 2 + 3y[x] == 0, y[0] == 1, Derivative[1][y][0] == 0, Derivative[2][y][0] == -1, Derivative[3][y][0] == 5}, y[x], {x, 0, 8}]

非线性常微分方程在 x=1 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + 7y[x] ^ 2 == Cos[2x], y[1] == 1, y'[1] == 5}, y[x], {x, 1, 3}]

非线性常微分方程的通解的级数近似：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + 3y[x] ^ 3 == 0}, y[x], {x, 0, 3}]

无穷大处的解 (4)

求线性常微分方程在常点 x=∞ 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[x ^ 2 y'[x] + y[x] == 0, y[x], {x, ∞, 4}]

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[Rest@Accumulate[List@@(% /. {C[1] -> 1})]], {x, 0, 60}, PlotLegends -> "Expressions"]

求线性常微分方程在正则奇点 x=∞ 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[x ^ 3 y''[x] + x * y'[x] + y[x] == 0, y[x], {x, ∞, 3}]

求线性常微分方程在非正则奇点 x=∞ 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[y''[x] - x ^ 2 y[x] == 0, y[x], {x, ∞, 2}]

求非线性常微分方程在 x=∞ 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{x ^ 2 y'[x] - 5y[x] ^ 2 == 0, y[∞] == 1}, y[x], {x, ∞, 4}]

常微分方程组 (8)

求线性一阶常微分方程组在常点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{u'[x] == x v[x] + 3, v'[x] == -x u[x], u[0] == 1, v[0] == 3}, {u[x], v[x]}, {x, 0, 5}]

绘制解的逼近：

Wolfram Language code: ParametricPlot[Evaluate[%], {x, 0, 2}]

线性高阶常微分方程组在常点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] == z[x], z'[x] == -y[x], y[0] == 1, z[0] == 3, y'[0] == 4}, {y[x], z[x]}, {x, 0, 3}]

非齐次线性常微分方程组在常点 x=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y'[x] + z[x] == E ^ x, z'[x] == 5y[x] + 1, y[0] == 1, z[0] == 3}, {y[x], z[x]}, {x, 0, 5}]

线性常微分方程组在常点 x=1 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y'[x] == x z[x] + 2, z'[x] == -x y[x], y[1] == 1, z[1] == 3}, {y[x], z[x]}, {x, 1, 3}]

线性常微分方程组在常点的通解的级数近似：

Wolfram Language code: AsymptoticDSolveValue[{y'[x] == 3 z[x], z'[x] == y[x]}, {y[x], z[x]}, {x, 1, 3}]

使用向量变量在寻常点 x=0 处的 ODE 线性方程组的级数解：

Wolfram Language code: m = {{0, 1}, {-1, 0}};

Wolfram Language code: AsymptoticDSolveValue[{y'[x] == m.y[x], y[0] == {1, 1}}, Element[y[x], Vectors[2]], {x, 0, 3}]

或者将定义为 VectorSymbol：

Wolfram Language code: y = VectorSymbol["y", 2]

Wolfram Language code: AsymptoticDSolveValue[{y'[x] == m.y[x], y[0] == {1, 1}}, y[x], {x, 0, 3}]

使用矩阵变量在寻常点 x=0 处的 ODE 线性方程组的级数解：

Wolfram Language code:

m = {{0, 1}, {-1, 0}};
x0 = {{1, 2}, {3, 4}};

Wolfram Language code: AsymptoticDSolveValue[{y'[x] == m.y[x], y[0] == x0}, Element[y[x], Matrices[{2, 2}]], {x, 0, 3}]//MatrixForm

或者将定义为 MatrixSymbol：

Wolfram Language code: y = MatrixSymbol["y", {2, 2}]

Wolfram Language code: AsymptoticDSolveValue[{y'[x] == m.y[x], y[0] == x0}, y[x], {x, 0, 3}]//MatrixForm

求解 ϵ=0: 处的扰动 Fuchsian 线性常微分方程组：

Wolfram Language code:

AsymptoticDSolveValue[{Derivative[1][y1][x] == ϵ ((3 y1[x]/-6 + x) + ((1/-8 + x) + (2/-6 + x)) y2[x] + ((2/-8 + x) + (3/-6 + x)) y3[x]), Derivative[1][y2][x] == ϵ (-(4 y1[x]/-8 + x) + ((3/-8 + x) + (2/-6 + x)) y3[x]), Derivative[1][y3][x] == 0, y1[0] == 1, y2[0] == 2, y3[0] == 3}, {y1[x], y2[x], y3[x]}, x, {ϵ, 0, 2}]

正则摄动 (2)

求正则线性摄动问题在 ϵ=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] - y'[x] - ϵ x y[x] == 0, y[0] == 0, y'[0] == 1}, y[x], x, {ϵ, 0, 3}]//Simplify

绘制解的连续逼近：

Wolfram Language code: Plot[Evaluate[CoefficientList[%, ϵ] /. {ϵ -> 1 / 10}], {x, 0, 3}, PlotLegends -> "Expressions"]

求正则非线性摄动问题在 ϵ=0 处的级数解：

Wolfram Language code: AsymptoticDSolveValue[{u''[x] + u[x] + ϵ u[x] ^ 2 == 0, u[0] == 1, u'[0] == 2}, u[x], x, {ϵ, 0, 2}]//Simplify

绘制解的逼近：

Wolfram Language code: Plot[Evaluate[% /. {ϵ -> 1 / 100}], {x, 0, 10}]

奇异摄动 (3)

求奇异边界值问题的一阶近似：

Wolfram Language code: AsymptoticDSolveValue[{ϵ y''[x] + (x + 1) y[x] == 0, y[0] == 1, y[1] == 0}, y[x], x, {ϵ, 0, 1}]

绘制不同参数值的近似：

Wolfram Language code: Plot[% /. {ϵ -> 1 / 500}, {x, 0, 1}]

与数值解比较：

Wolfram Language code: NDSolveValue[{(1 / 500) y''[x] + (x + 1) y[x] == 0, y[0] == 1, y[1] == 0}, y[x], {x, 0, 1}];

Wolfram Language code: Plot[%, {x, 0, 1}]

求奇异边界值问题的二阶近似：

Wolfram Language code: AsymptoticDSolveValue[{ϵ y''[x] - (2x + 1) y[x] == 0, y[0] == 1 / 3, y[1] == 0}, y[x], x, {ϵ, 0, 2}]

绘制不同参数值的近似：

Wolfram Language code: Plot[Table[%, {ϵ, {1 / 10, 1 / 30, 1 / 50}}]//Evaluate, {x, 0, 1}]

求 λ=∞ 处的二阶摄动近似：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + λ (x + 1) ^ 2y[x] == 0, y[0] == 1, y[1] == 0}, y[x], x, {λ, ∞, 2}]

绘制较大参数值的近似：

Wolfram Language code: Plot[% /. {λ -> 160}, {x, 0, 1}, WorkingPrecision -> 20]

Wolfram Language code: NDSolveValue[{y''[x] + 160(x + 1) ^ 2y[x] == 0, y[0] == 1, y[1] == 0}, y[x], {x, 0, 1}]

Wolfram Language code: Plot[%, {x, 0, 1}]

分数阶常微分方程 (ODE) (3)

求阶数为 0.7 的线性分数 ODE 的级数解：

Wolfram Language code: AsymptoticDSolveValue[{CaputoD[y[x], {x, 0.7}] + 3 y[x] == 0, y[0] == 1}, y[x], {x, 0, 5}]

使用 DSolveValue 求解同一个 ODE：

Wolfram Language code: dsol = DSolveValue[{CaputoD[y[x], {x, 0.7}] + 3 y[x] == 0, y[0] == 1}, y[x], x]

对不同的阶逼近值的精确解和渐近解进行比较：

Wolfram Language code: asol[n_] := AsymptoticDSolveValue[{CaputoD[y[x], {x, 0.7}] + 3 y[x] == 0, y[0] == 1}, y[x], {x, 0, n}];

Wolfram Language code:

Plot[Evaluate[{dsol, asol[5], asol[10], asol[15], asol[20]}], {x, 0, 2}, PlotLegends -> {"Exact", "n=5", "n=10", "n=15", "n=20"}]

求解具有非常数系数的线性分数阶 ODE 的级数解：

Wolfram Language code: sol = AsymptoticDSolveValue[{CaputoD[y[x], {x, 1 / 2}] - x y[x] == 0, y[0] == 1}, y[x], {x, 0, 15}]

求解两个线性分数阶 ODE 方程组的级数解：

Wolfram Language code:

eqns = {CaputoD[x1[t], {t, 0.95}] == 2x1[t] - x2[t], CaputoD[x2[t], {t, 0.95}] == 4x1[t] - 3x2[t], x1[0] == 1.2, x2[0] == 4.2};

Wolfram Language code: asol = AsymptoticDSolveValue[eqns, {x1, x2}, {t, 0, 15}]

绘制解：

Wolfram Language code: Plot[asol, {t, 0, 2}, PlotRange -> All]

选项 (1)

GeneratedParameters (1)

使用命名不同的常量：

Wolfram Language code: AsymptoticDSolveValue[y''[x] == y[x], y[x], {x, 0, 3}, GeneratedParameters -> d]

使用有下标的常量：

Wolfram Language code: AsymptoticDSolveValue[y''[x] == y[x], y[x], {x, 0, 3}, GeneratedParameters -> (Subscript[c, #]&)]

应用 (7)

计算 Cos 的泰勒多项式近似：

Wolfram Language code: sol1 = AsymptoticDSolveValue[{y''[x] + y[x] == 0, y[0] == 1, y'[0] == 0}, y[x], {x, 0, 8}]

Wolfram Language code: Plot[{sol1, Cos[x]}, {x, 0, 3Pi}, PlotRange -> {-2, 5}]

通过指定更高阶数扩大近似范围：

Wolfram Language code: sol2 = AsymptoticDSolveValue[{y''[x] + y[x] == 0, y[0] == 1, y'[0] == 0}, y[x], {x, 0, 16}]

Wolfram Language code: Plot[{sol2, Cos[x]}, {x, 0, 3Pi}, PlotRange -> {-2, 5}]

研究范围随近似阶数变化的情况：

Wolfram Language code: sol[n_] := AsymptoticDSolveValue[{y''[x] + y[x] == 0, y[0] == 1, y'[0] == 0}, y[x], {x, 0, n}]

Wolfram Language code: Plot[{sol[4], sol[8], sol[12], sol[16], sol[24], Cos[x]}//Evaluate, {x, 0, 3Pi}, PlotRange -> {-2, 5}]

在正则奇点 x=0 处求解阶贝塞尔方程：

Wolfram Language code: sol = AsymptoticDSolveValue[x ^ 2 y''[x] + x y'[x] + (x ^ 2 - 1 / 4)y[x] == 0, y[x], {x, 0, 24}]

绘制通解的两个分量：

Wolfram Language code: Plot[{(sol /. {C[1] -> 1, C[2] -> 0}), (sol /. {C[1] -> 0, C[2] -> 1})}, {x, 0, 3π}, PlotRange -> {-2, 2}]

Airy 方程在 x=∞ 处有一个非正则奇点：

Wolfram Language code: airyode = y''[x] - x y[x] == 0;

计算非正则奇点处的渐近展开式：

Wolfram Language code: sol = AsymptoticDSolveValue[airyode, y[x], {x, ∞, 3}]

与 Infinity 处的 Airy 函数展开式相比较：

Wolfram Language code: s1 = Series[AiryAi[x], {x, ∞, 4}]//Normal

Wolfram Language code: s2 = Series[AiryBi[x], {x, ∞, 4}]//Normal

绘制 Airy 函数和近似：

Wolfram Language code:

Plot[Evaluate[{AiryAi[x], AiryBi[x], (sol  /. {C[1] -> 1 / (2 Sqrt[Pi]), C[2] -> 0}), (sol  /. {C[1] -> 0, C[2] -> 1 / Sqrt[Pi]}) }], {x, -3, 3}, PlotLegends -> {AiryAi[x], AiryBi[x], "sol1", "sol2"}, 
	 PlotStyle -> Thickness[0.008]]

计算非线性一阶常微分方程的精确多项式解：

Wolfram Language code: ode = 3y'[x] ^ 2 + 4x y'[x] - y[x] + x ^ 2 == 0;

Wolfram Language code: sol = AsymptoticDSolveValue[ode, y[x], {x, 0, 4}]//Quiet

验证这是常微分方程的解：

Wolfram Language code: ode /. y -> Function[{x}, Evaluate[sol]]//Simplify

计算一阶常微分方程组系统的均衡解：

Wolfram Language code: odes = {u'[t] == u[t] ^ 2 / v[t] - u[t], v'[t] == u[t] ^ 2 - v[t]};

可视化方程组定义的向量场：

Wolfram Language code: StreamPlot[{u ^ 2 / v - u, u ^ 2 - v}, {u, -2, 2}, {v, -2, 2}]

在广义初始条件下求解方程组：

Wolfram Language code: sol = AsymptoticDSolveValue[{odes, u[0] == a, v[0] == b}, {u[t], v[t]}, {t, 0, 5}];

求均衡解：

Wolfram Language code: sol /. {a -> 1, b -> 1}

求 Duffing 方程的一阶摄动展开式：

Wolfram Language code: eqn = {u''[x] + u[x] + ϵ u[x] ^ 3 == 0, u[0] == 3, u'[0] == 0};

Wolfram Language code: psol = AsymptoticDSolveValue[eqn, u[x], x, {ϵ, 0, 1}]

绘制近似解：

Wolfram Language code: Plot[psol /. {ϵ -> 1 / 800}, {x, 0, 20}, PlotPoints -> 100, WorkingPrecision -> 20]

与精确解相比较：

Wolfram Language code: dsol = DSolveValue[eqn /. {ϵ -> (1/800)}, u[x], x]

Wolfram Language code: Plot[dsol // Evaluate, {x, 0, 20}, PlotPoints -> 100]

求对应于的 Sturm–Liouville 问题的近似特征函数，其中取较大值. 用较小参数重写问题：

Wolfram Language code: eqns = {ϵ y''[x] + (x + 1) ^ 2y[x] == 0, y[0] == A, y[1] == B};

获取一阶渐近逼近：

Wolfram Language code: sol = FullSimplify[AsymptoticDSolveValue[eqns, y[x], x, {ϵ, 0, 1}], 0 < x < 1]

忽略 Csc 常量因子，使用构建特征函数：

Wolfram Language code:

eigfuns = Simplify[(Sqrt[2] B Sin[(x (2 + x)/2 Sqrt[ϵ])] - A Sin[((-1 + x) (3 + x)/2 Sqrt[ϵ])]/Sqrt[1 + x]) /.  {B -> 1, A -> 0, ϵ -> (9/4 n^2 π^2)}, n∈ℤ && n > 0]

绘制近似特征函数：

Wolfram Language code: Plot[Table[eigfuns, {n, 1, 4}]//Evaluate, {x, 0, 1}]

属性和关系 (3)

给定阶数的解可以满足微分方程：

Wolfram Language code: sol = AsymptoticDSolveValue[{y'[x] + y[x] == 0, y[0] == 1}, y[x], {x, 0, 8}]

Wolfram Language code: {y'[x] + y[x], y[0] == 1} /. y -> Function[{x}, Evaluate[sol]]

用 DSolveValue 求精确解：

Wolfram Language code: asol = AsymptoticDSolveValue[{y'[x] - 2y[x] == 0, y[0] == 1}, y[x], {x, 0, 4}]

Wolfram Language code: dsol = DSolveValue[{y'[x] - 2y[x] == 0, y[0] == 1}, y[x], x]

Wolfram Language code: Series[%, {x, 0, 4}]//Normal

用 NDSolveValue 求数值解：

Wolfram Language code: asol = AsymptoticDSolveValue[{y'[x] + 2y[x] == 0, y[0] == 1}, y[x], {x, 0, 10}]

Wolfram Language code: Table[%, {x, 0, 1, 0.2}]

Wolfram Language code: dsol = NDSolveValue[{y'[x] + 2y[x] == 0, y[0] == 1}, y[x], {x, 0, 1}]

Wolfram Language code: Table[%, {x, 0, 1, 0.2}]

可能存在的问题 (1)

此例中返回的展开式少于四项：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + y[x] == 0, y[0] == 0, y'[0] == 1}, y[x], {x, 0, 4}]

对于更普通的问题，展开式中出现缺失的项：

Wolfram Language code: AsymptoticDSolveValue[{y''[x] + a y'[x] + y[x] == 0, y[0] == b, y'[0] == 1}, y[x], {x, 0, 4}]

Wolfram Language code: % /. {a -> 0, b -> 0}

Top

		Taylor 尺度，当 xx₀ 时
		Laurent 尺度，当 xx₀ 时
		Laurent 尺度，当 x±∞ 时
		Puiseux 尺度，当 xx₀ 时

AccuracyGoal	Automatic	寻求的绝对准确度
Assumptions	$Assumptions	对参数的设定
GenerateConditions	Automatic	是否给出与参数的条件有关的答案
GeneratedParameters	None	怎样命名生成的参数
Method	Automatic	所用的方法
PerformanceGoal	$PerformanceGoal	优化目标
PrecisionGoal	Automatic	寻求的精度
SeriesTermGoal	Automatic	近似式的项数
WorkingPrecision	Automatic	内部计算中使用的精度

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

AsymptoticDSolveValue

更多信息和选项

范例

基本范例 (3)

范围 (50)

基本用法 (8)

常点 (7)

正则奇点 (5)

非正则奇点 (3)

非线性常微分方程 (7)

无穷大处的解 (4)

常微分方程组 (8)

正则摄动 (2)

奇异摄动 (3)

分数阶常微分方程 (ODE) (3)

选项 (1)

GeneratedParameters (1)

应用 (7)

属性和关系 (3)

可能存在的问题 (1)

文本

CMS

APA

BibTeX

BibLaTeX

AsymptoticDSolveValue

更多信息和选项

范例

基本范例 (3)

范围 (50)

基本用法 (8)

常点 (7)

正则奇点 (5)

非正则奇点 (3)

非线性常微分方程 (7)

无穷大处的解 (4)

常微分方程组 (8)

正则摄动 (2)

奇异摄动 (3)

分数阶常微分方程 (ODE) (3)

选项 (1)

GeneratedParameters (1)

应用 (7)

属性和关系 (3)

可能存在的问题 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX