Wolfram言語＆システムドキュメントセンター

AsymptoticIntegrate

AsymptoticIntegrate[f,x,xx₀]

x₀を中心とする x についての不定積分の漸近近似を計算する．

AsymptoticIntegrate[f,{x,a,b},αα₀]

α₀を中心とする α についての定積分の漸近近似を計算する．

AsymptoticIntegrate[f,…,{ξ,ξ₀,n}]

漸近近似を次数 n まで計算する．

詳細とオプション

積分の漸近近似は漸近展開または摂動展開としても知られるものである．これらは，ラプラス(Laplace)法，停留値法，最降下法等の特定のメソッドで漸近近似のいくつかを計算する方法としても知られている．
漸近近似は，厳密解が求まらない問題を解くため，あるいは，計算，比較，解釈のためにより簡単な答を得るために，使われることが多い．
AsymptoticIntegrate[f,…,xx₀]は，f の積分についての漸近展開における最高次数の項を計算する．より多くの項が指定したければSeriesTermGoalを使うとよい．
厳密な結果が g[x]で x₀における次数 n の漸近近似が g_n[x]の場合は，xx₀のとき，AsymptoticLess[g[x]-g_n[x],g_n[x]-g_n-1[x],xx₀]または g[x]-g_n[x]∈o[g_n[x]-g_n-1[x]]である．

漸近近似 g_n[x]は，しばしば総和 g_n[x]α_kϕ_k[x]として与えられる．ただし，{ϕ₁[x],…,ϕ_n[x]}は xx₀のときの漸近尺度 ϕ₁[x]≻ϕ₂[x]≻⋯>ϕ_n[x]である．結果は，xx₀のとき，AsymptoticLess[g[x]-g_n[x],ϕ_n[x],xx₀]または g[x]-g_n[x]∈o[ϕ_n[x]]である．
次は，よく使われる漸近尺度である．

		xx₀のとき，テイラー(Taylor)スケール
		xx₀のとき，ローラン(Laurent)スケール
		x±∞のとき，ローランスケール
		xx₀のとき，ピュイゾー(Puiseux)スケール

漸近近似を表すために使われる尺度は，問題から自動的に推測される．より珍しい尺度が使われることも多い．
中心 x₀は，任意の，有限あるいは無限の実数あるいは複素数でよい．
次数 n は正の整数で，漸近解の近似次数を指定しなければならない．これは，多項式次数とは無関係である．
次は，使用可能なオプションである．

AccuracyGoal	Automatic	目標とする絶対確度の桁数
Assumptions	$Assumptions	パラメータについての仮定
GenerateConditions	Automatic	パラメータについての条件を含む答を生成するかどうか
GeneratedParameters	None	生成されたパラメータの名付け方
Method	Automatic	使用するメソッド
PerformanceGoal	$PerformanceGoal	パフォーマンスのどの局面について最適化するか
PrecisionGoal	Automatic	目標精度の桁数
SeriesTermGoal	Automatic	近似における項数
WorkingPrecision	Automatic	内部計算の精度

PerformanceGoalの可能な設定には，$PerformanceGoal，"Quality"，"Speed"がある．"Quality"設定のとき，AsymptoticIntegrateはより多くの問題を解いたりより簡単な結果を与えたりすることが多いが，より多くの時間とメモリが必要になる可能性がある．

例題

すべて開くすべて閉じる

例 (3)

積分について最高次の漸近近似を計算する：

Wolfram Language code: AsymptoticIntegrate[Sin[t x], {t, 0, 1}, x -> 0]

積分についての漸近展開を計算する：

Wolfram Language code: AsymptoticIntegrate[E ^ (t x), {t, 0, 1}, {x, 0, 7}]

厳密な結果の展開と比較する：

Wolfram Language code: Integrate[E ^ (x t), {t, 0, 1}]

Wolfram Language code: Series[%, {x, 0, 7}]//Normal

ガウス積分についての展開の主項を得る：

Wolfram Language code: f[x_] := E^-ω (x^2 - 2 x)

Wolfram Language code: Plot[f[x] /. {ω -> 3}, {x, 0, 7}, PlotRange -> All, Filling -> Axis]

必要な項を計算する：

Wolfram Language code: AsymptoticIntegrate[f[x], {x, 0, ∞}, {ω, ∞, 1}]

数値近似の結果と比較する：

Wolfram Language code: {% /. {ω -> 300.}, NIntegrate[Exp[-300 (x^2 - 2 x)], {x, 0, ∞}]}

スコープ (21)

不定積分 (3)

x=0についての三角積分の漸近展開を計算する：

Wolfram Language code: AsymptoticIntegrate[Sin[x], x, {x, 0, 8}]

Integrateが与える結果と比較する：

Wolfram Language code: Integrate[Sin[x], x]

Wolfram Language code: Series[%, {x, 0, 8}]//Normal

x=0についての指数塔の積分の漸近展開：

Wolfram Language code: AsymptoticIntegrate[x^x^x, x, {x, 0, 4}]

ある点における値を推定する：

Wolfram Language code: % /. {x -> 0.0005}

NIntegrateが与える値と比較する：

Wolfram Language code: NIntegrate[x ^ x ^ x, {x, 0, 0.0005}]

不定積分についての漸近展開をパラメータについて計算する：

Wolfram Language code: AsymptoticIntegrate[E ^ (-m Sin[x]), x, {m, 0, 3}]

指数積分 (6)

ラプラス変換積分の漸近展開を計算する：

Wolfram Language code: AsymptoticIntegrate[Exp[ -x t] / (1 + t), {t, 0, Infinity}, {x, Infinity, 7}]

LaplaceTransformが与える結果と比較する：

Wolfram Language code: LaplaceTransform[1 / (1 + t), t, x]

Wolfram Language code: Series[%, {x, Infinity, 7}]//Normal//Simplify//Expand

t=-1で最大となるガウスカーネルで関数を定義する：

Wolfram Language code: f[t_] := E^-x (t^2 + t) (1 + t)^5 / 2

Wolfram Language code: Plot[f[t] /. {x -> 3.}, {t, -3, 2}, PlotRange -> All, Filling -> Axis]

{0,2}上での積分について，漸近近似における主項を計算する：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 0, 2}, {x, Infinity, 1}]

数値近似を使った結果と比較する：

Wolfram Language code: % /. {x -> 3000.}

Wolfram Language code: NIntegrate[Exp[-3000(t ^ 2 + t )] (1 + t) ^ (5 / 2), {t, 0, 2}]

t=0で最大となるガウスカーネルで関数を定義する：

Wolfram Language code: f[t_] := Exp[-x t ^ 2] / (t + 2)

Wolfram Language code: Plot[f[t] /. {x -> 30.}, {t, -2, 2}, PlotRange -> All, Filling -> Axis]

{0,2}上の積分について漸近近似を計算する：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 0, 2}, {x, Infinity, 7}]

数値近似を使った結果と比較する：

Wolfram Language code: % /. {x -> 300.}

Wolfram Language code: NIntegrate[Exp[ -300 t ^ 2] / (t + 2), {t, 0, 2}]

t=1で最大となる指数カーネルで関数を定義する：

Wolfram Language code: f[t_] := Exp[-x(t + (1 / t))] / (t + 1)

Wolfram Language code: Plot[f[t] /. {x -> 3.}, {t, 1, 2}, Filling -> Axis]

{1,2}上での積分について，漸近近似における主項を計算する：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 1, 2}, {x, Infinity, 1}]

数値近似を使った結果と比較する：

Wolfram Language code: % /. {x -> 3.}

Wolfram Language code: NIntegrate[Exp[-3(t + (1 / t))] / (t + 1), {t, 1, 2}]

t=1で最大となる指数カーネルで関数を定義する：

Wolfram Language code: f[t_] := Exp[-x (t ^ 2 - 2t)] / (t + 1)

Wolfram Language code: Plot[f[t] /. {x -> 3.}, {t, 0, 3}, Filling -> Axis]

{0,3}上の積分について漸近近似における主項を計算する：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 0, 3}, {x, Infinity, 1}]

数値近似を使った結果と比較する：

Wolfram Language code: % /. {x -> 3000.}

Wolfram Language code: NIntegrate[Exp[-3000(t ^ 2 - 2t)] / (t ^ 2 + 1), {t, 0, 3}]

t=π/2で最大となる指数カーネルで関数を定義する：

Wolfram Language code: f[t_] := Exp[x Sin[t]]

Wolfram Language code: Plot[f[t] /. {x -> 3.}, {t, 0, Pi}, Filling -> Axis]

{0,3}上の積分について漸近近似における主項を計算する：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 0, Pi}, {x, Infinity, 1}]

数値近似を使った結果と比較する：

Wolfram Language code: % /. {x -> 3000.}

Wolfram Language code: NIntegrate[Exp[3000Sin[t]], {t, 0, Pi}]

振動積分 (4)

上のフーリエ型の積分について漸近展開を計算する：

Wolfram Language code: AsymptoticIntegrate[Exp[ I x t] / (1 + t ^ 2), {t, 0, Infinity}, {x, Infinity, 7}]

上での複雑な振動積分について主項近似を求める：

Wolfram Language code: f[x_] := E ^ (I ω Sin[t])

Wolfram Language code: Plot[Re[f[x] /. {ω -> 50}], {t, 0, π}, Filling -> Axis]

必要な近似を計算する：

Wolfram Language code: int = AsymptoticIntegrate[f[t], {t, 0, π}, {ω, ∞, 1}]

数値近似と比較する：

Wolfram Language code: NIntegrate[E ^ (I 500 Sin[t]), {t, 0, π}]//Quiet

Wolfram Language code: int /. {ω -> 500.}

Sinを含む実数振動積分について主項近似を求める：

Wolfram Language code: f[t_] := Sin[ x t ^ 3] / Sqrt[t + 1]

Wolfram Language code: Plot[f[t] /. {x -> 30.}, {t, 0, π / 2}, Filling -> Axis, PlotRange -> All]

主項を計算する：

Wolfram Language code: int = AsymptoticIntegrate[f[t], {t, 0, π / 2}, {x, ∞, 1}]

数値近似と比較する：

Wolfram Language code: NIntegrate[Sin[ 300 t ^ 3] / Sqrt[t + 1], {t, 0, π / 2}]

Wolfram Language code: int /. {x -> 300.}

Cosを含む実数振動積分についての漸近展開を計算する：

Wolfram Language code: f[t_] := Cos[ x t] / (1 + E ^ (t ^ 2))

Wolfram Language code: Plot[f[t] /. {x -> 30.}, {t, 1, 2}, Filling -> Axis, PlotRange -> All]

2つの項がある展開を計算する：

Wolfram Language code: int = AsymptoticIntegrate[f[t], {t, 1, 2}, {x, ∞, 2}]//Simplify

数値近似と比較する：

Wolfram Language code: NIntegrate[Cos[ 300 t] / (1 + E ^ t ^ 2), {t, 1, 2}]

Wolfram Language code: int /. {x -> 300.}

一般的な定積分 (4)

x=0における有理関数の積分についての漸近展開を計算する：

Wolfram Language code: AsymptoticIntegrate[1 / (t ^ 2 + x ^ 2), {t, 1, 3}, {x, 0, 4}]

Integrateが与える結果と比較する：

Wolfram Language code: Integrate[1 / (t ^ 2 + x ^ 2), {t, 1, 3}, Assumptions -> x > 0]

Wolfram Language code: Series[%, {x, 0, 4}]//Normal

x=π/2における三角積分についての漸近展開：

Wolfram Language code: AsymptoticIntegrate[Sin[t + x] ^ 5, {t, 0, π}, {x, π / 2, 3}]

Integrateが与える結果と比較する：

Wolfram Language code: Integrate[Sin[t + x] ^ 5, {t, 0, π}]

Wolfram Language code: Collect[Series[%, {x, π / 2, 3}]//Normal, x]

x=0における完全楕円積分についての漸近展開：

Wolfram Language code: AsymptoticIntegrate[1 / Sqrt[1 - m * Sin[θ] ^ 2], {θ, 0, Pi / 2}, {m, 0, 5}]

Integrateが与える結果と比較する：

Wolfram Language code: Integrate[1 / Sqrt[1 - m * Sin[θ] ^ 2], {θ, 0, Pi / 2}, Assumptions -> 0 < m < 1]

Wolfram Language code: Series[%, {m, 0, 4}]//Normal

x=-Infinityにおける積分についての漸近展開：

Wolfram Language code: AsymptoticIntegrate[E ^ (x t) / (1 + t ^ 2), {t, 0, Infinity}, {x, -Infinity, 6}]

数値近似と比較する：

Wolfram Language code: % /. {x -> -30.}

Wolfram Language code: NIntegrate[E ^ (-30 t) / (1 + t ^ 2), {t, 0, Infinity}]

積分変換 (4)

関数のラプラス変換についての漸近展開：

Wolfram Language code: f[t_] := 1 / (1 + t)

Wolfram Language code: Plot[f[t], {t, 0, 4}, Filling -> Axis]

Wolfram Language code: AsymptoticIntegrate[f[t] E ^ (-s t), {t, 0, Infinity}, {s, Infinity, 5}]

LaplaceTransformを使った厳密な結果の級数展開と比較する：

Wolfram Language code: LaplaceTransform[f[t], t, s]

Wolfram Language code: Series[%, {s, Infinity, 5}]//Normal

関数のメリン(Mellin)変換についての漸近展開：

Wolfram Language code: f[t_] := t / (t ^ 3 + 1)

Wolfram Language code: Plot[f[t], {t, 0, 4}, Exclusions -> None, Filling -> Axis]

Wolfram Language code: AsymptoticIntegrate[f[t] t ^ (s - 1), {t, 0, Infinity}, {s, 0, 2}]

MellinTransformを使った厳密な結果の級数展開と比較する：

Wolfram Language code: MellinTransform[f[t], t, s]

Wolfram Language code: Series[%, {s, 0, 2}]//Normal

関数のフーリエ余弦変換の漸近展開：

Wolfram Language code: f[t_] := E ^ (-t ^ 2)

Wolfram Language code: Sqrt[2 / Pi] AsymptoticIntegrate[f[t] Cos[s t], {t, 0, Infinity}, {s, 0, 2}]//Expand

FourierCosTransformを使った厳密な結果の級数展開と比較する：

Wolfram Language code: FourierCosTransform[f[t], t, s]

Wolfram Language code: Series[%, {s, 0, 2}]//Normal

関数のフーリエ正弦変換の漸近展開：

Wolfram Language code: f[t_] := E ^ (-t ^ 2 + t)

Wolfram Language code: afs = Sqrt[2 / Pi] AsymptoticIntegrate[f[t] Sin[s t], {t, 0, Infinity}, {s, 0, 2}]//FullSimplify

FourierSinTransformを使った厳密な結果の級数展開と比較する：

Wolfram Language code: FourierSinTransform[f[t], t, s]

Wolfram Language code: Series[%, {s, 0, 2}, Assumptions -> s > 0]//Normal//FullSimplify

Wolfram Language code: % - afs//FullSimplify

オプション (1)

GeneratedParameters (1)

不定積分の任意定数を生成する：

Wolfram Language code: AsymptoticIntegrate[Cos[x], x, {x, 0, 3}, GeneratedParameters -> C]

任意定数のデフォルト値は0である：

Wolfram Language code: % /. {C[1] -> 0}

Wolfram Language code: AsymptoticIntegrate[Cos[x], x, {x, 0, 3}]

アプリケーション (7)

定積分についての漸近展開を求める：

Wolfram Language code: int = AsymptoticIntegrate[1 / Sqrt[1 - ϵ t ^ 14], {t, 0, 1}, {ϵ, 0, 2}]

数値近似と比較する：

Wolfram Language code: int /. {ϵ -> 0.3}

Wolfram Language code: NIntegrate[1 / Sqrt[1 - 0.3 t ^ 14], {t, 0, 1}]

項数を増やすことで漸近展開を向上させる：

Wolfram Language code: AsymptoticIntegrate[1 / Sqrt[1 - ϵ t ^ 14], {t, 0, 1}, {ϵ, 0, 5}]

Wolfram Language code: % /. {ϵ -> 0.3}

曲線のからまでの下の面積を求める：

Wolfram Language code: Plot[Sin[a x] ^ 2 Cos[x] ^ 4 /. {a -> 1.05}, {x, -π, π}, Filling -> Axis]

Wolfram Language code: AsymptoticIntegrate[Sin[a x] ^ 2 Cos[x] ^ 4, {x, -π, π}, {a, 1, 4}]

の特定の値についての面積を求める：

Wolfram Language code: % /. {a -> 1.05}

がで軸について回転されたときの体積を求める：

Wolfram Language code: AsymptoticIntegrate[π(Sin[a x] ^ 2) ^ 2, {x, 0, π}, {a, 3, 4}]

の特定の値についての体積を求める：

Wolfram Language code: % /. {a -> 3.1}

立体を可視化する：

Wolfram Language code: RevolutionPlot3D[Sin[3.1 x] ^ 2, {x, 0, π}, RevolutionAxis -> "X"]

LaplaceTransformの漸近バージョンを定義する：

Wolfram Language code: asymLaplaceTransform[f_, t_, s_, n_] := AsymptoticIntegrate[f E ^ (-s t), {t, 0, ∞}, {s, ∞, n}]

これを使って周期関数の漸近ラプラス変換を計算する：

Wolfram Language code: f[t_] := 1 / (3 + Sin[t] ^ 3)

Wolfram Language code: Plot[f[t], {t, 0, 20}, PlotRange -> All, Filling -> Axis]

Wolfram Language code: lap = asymLaplaceTransform[f[t], t, s, 8]

結果をプロットする：

Wolfram Language code: Plot[lap, {s, 100, 1000}]

数値近似と比較する：

Wolfram Language code: Table[NIntegrate[f[t] E ^ (-s t), {t, 0, ∞}], {s, 100, 1000, 200}]

Wolfram Language code: Table[lap, {s, 100, 1000, 200}]//N

ProbabilityDistributionについての漸近平均を，定義域で計算する：

Wolfram Language code: dist = ProbabilityDistribution[1 / (1 + ϵ (x - 2 / 3) ^ 2), {x, 0, 1}, Assumptions -> ϵ > 0];

PDF（確率密度関数）を正規化する：

Wolfram Language code: norm = Integrate[1 / (1 + ϵ (x - 1 / 3) ^ 2), {x, 0, 1}, Assumptions -> ϵ > 0]

確率密度関数をプロットする：

Wolfram Language code: Plot[PDF[dist, x] / norm /. {ϵ -> 1 / 20}, {x, 0, 1}, Filling -> Axis]

漸近平均を定義する：

Wolfram Language code: asympMean[dist_, ϵ_, n_] := AsymptoticIntegrate[x Refine[PDF[dist, x], 0 < x < 1], {x, 0, 1}, {ϵ, 0, n}]

与えられた分布の漸近平均を計算する：

Wolfram Language code: asympMean[dist, ϵ, 3]

厳密な結果の展開と比較する：

Wolfram Language code: Mean[dist]

Wolfram Language code: Series[%, {ϵ, 0, 3}, Assumptions -> ϵ > 0]//Normal

BesselJの積分表現についての漸近展開を得る：

Wolfram Language code:

besselint = ((2 ^ (1 - ν) * z ^ ν) / (Sqrt[Pi] * Gamma[ν + 1 / 2]))AsymptoticIntegrate[(1 - t ^ 2) ^ (ν - 1 / 2) * Cos[z * t], {t, 0, 1}, {z, 0, 2}, Assumptions -> ν > 0]

ベッセル(Bessel)関数の数値と比較する：

Wolfram Language code: Table[besselint /. {ν -> 2}, {z, 0.1, 0.5, 0.1}]

Wolfram Language code: Table[BesselJ[2, z], {z, 0.1, 0.5, 0.1}]

振動積分について漸近近似を計算する：

Wolfram Language code: f[t_] := Sin[t] E ^ (I x (t ^ 3 + 3 t))

Wolfram Language code: ReImPlot[f[t] /. {x -> 30}, {t, -2, 2}, PlotLegends -> "ReIm"]

Wolfram Language code: AsymptoticIntegrate[f[t], {t, -2, 2}, {x, ∞, 4}]

結果を数値近似と比較する：

Wolfram Language code: % /. {x -> 30.}

Wolfram Language code: NIntegrate[Sin[t] E ^ (I 30 (t ^ 3 + 3 t)), {t, -2, 2}]

特性と関係 (4)

AsymptoticIntegrateは，指定された次数まで積分を計算する：

Wolfram Language code: AsymptoticIntegrate[Sin[x], x, {x, 0, 6}]

Wolfram Language code: Series[-Cos[x] - %, {x, 0, 6}]

Integrateを使って閉形式で積分を計算する：

Wolfram Language code: AsymptoticIntegrate[Sin[x t] ^ 2, {t, 0, 1}, {x, 0, 8}]

Wolfram Language code: Integrate[Sin[x t] ^ 2, {t, 0, 1}]

Wolfram Language code: Series[%, {x, 0, 8}]//Normal

NIntegrateを使って数値近似を計算する：

Wolfram Language code: AsymptoticIntegrate[E ^ (-ω t ^ 2)(t + 5) ^ (1 / 2), {t, 0, 5}, {ω, ∞, 3}]

Wolfram Language code: % /. {ω -> 300.}

Wolfram Language code: NIntegrate[E ^ (-300 t ^ 2)(t + 5) ^ (1 / 2), {t, 0, 5}]

AsymptoticExpectationを使って漸近期待値を計算する：

Wolfram Language code: dist = UniformDistribution[{-1, 2}];

Wolfram Language code: AsymptoticExpectation[E ^ (a x), xdist, {a, 0, 3}]

AsymptoticIntegrateを使って同じ結果を得る：

Wolfram Language code: AsymptoticIntegrate[E ^ (a x) PDF[dist, x], {x, -∞, ∞}, {a, 0, 3}]

考えられる問題 (1)

例について返される展開は4項未満である：

Wolfram Language code: AsymptoticIntegrate[Cos[x], x, {x, 0, 4}]

欠落した項は，より一般的な積分の展開には存在する：

Wolfram Language code: AsymptoticIntegrate[Cos[x + a], x, {x, 0, 4}]

Wolfram Language code: % /. {a -> 0}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

AsymptoticIntegrate

詳細とオプション

例題

例 (3)

スコープ (21)

不定積分 (3)

指数積分 (6)

振動積分 (4)

一般的な定積分 (4)

積分変換 (4)

オプション (1)

GeneratedParameters (1)

アプリケーション (7)

特性と関係 (4)

考えられる問題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

AsymptoticIntegrate

詳細とオプション

例題

例 (3)

スコープ (21)

不定積分 (3)

指数積分 (6)

振動積分 (4)

一般的な定積分 (4)

積分変換 (4)

オプション (1)

GeneratedParameters (1)

アプリケーション (7)

特性と関係 (4)

考えられる問題 (1)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX