WOLFRAM

Wolfram 语言与系统参考资料中心

AsymptoticIntegrate[f,x,xx0]

计算不定积分 的渐近逼近，x 以 x0 为中心.

AsymptoticIntegrate[f,{x,a,b},αα0]

计算不定积分 的渐近逼近，α 以 α0 为中心.

AsymptoticIntegrate[f,…,{ξ,ξ0,n}]

计算 n 阶渐近逼近.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
不定积分  
指数积分  
振荡积分  
普通定积分  
变换积分  
选项  
GeneratedParameters  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

AsymptoticIntegrate

AsymptoticIntegrate[f,x,xx0]

计算不定积分 的渐近逼近，x 以 x0 为中心.

AsymptoticIntegrate[f,{x,a,b},αα0]

计算不定积分 的渐近逼近，α 以 α0 为中心.

AsymptoticIntegrate[f,…,{ξ,ξ0,n}]

计算 n 阶渐近逼近.

更多信息和选项

  • 积分的渐近逼近亦被称为渐近展开式和摄动展开式. 其中有些展开式也可以用特定的方法来计算，如拉普拉斯方法、稳相法和最速下降法等.
  • 渐近逼近通常用于求解无法找到精确解的问题，或者为计算、比较和解释寻求更简单的答案.
  • AsymptoticIntegrate[f,…,xx0] 计算 f 的积分的渐近展开式中的首项. 使用 SeriesTermGoal 指定更多项.
  • 如果精确结果为 g[x]，在 x0 处的 n 阶渐近逼近为 gn[x]，那么当 xx0 时，结果为 AsymptoticLess[g[x]-gn[x],gn[x]-gn-1[x],xx0] 或 g[x]-gn[x]∈o[gn[x]-gn-1[x]].
  • 渐近逼近 gn[x] 常以和 gn[x]αkϕk[x] 的形式给出，其中 {ϕ1[x],…,ϕn[x]} 是当 xx0 时的渐近尺度 ϕ1[x]≻ϕ2[x]≻⋯>ϕn[x]. 当 xx0 时，结果为 AsymptoticLess[g[x]-gn[x],ϕn[x],xx0] 或 g[x]-gn[x]∈o[ϕn[x]].
  • 常见的渐近尺度包括：
  • Taylor 尺度，当 xx0 时
    Laurent 尺度，当 xx0 时
    Laurent 尺度，当 x±∞ 时
    Puiseux 尺度，当 xx0 时
  • 用于表示渐近逼近的尺度是从问题中自动推断出来的，通常可以包含更多的奇异尺度.
  • 中心点 x0 可以为任意有限或无限大实数及复数.
  • 阶数 n 必须为一个正整数，指定渐近解的近似阶数. 与多项式的次数无关.
  • 可以给出以下选项：
  • AccuracyGoalAutomatic所求绝对精度的位数
    Assumptions$Assumptions对参数的设定
    GenerateConditionsAutomatic是否给出与参数的条件有关的答案
    GeneratedParameters None怎样命名生成的参数
    MethodAutomatic所用的方法
    PerformanceGoal$PerformanceGoal优化的目标
    PrecisionGoalAutomatic所求精度的位数
    SeriesTermGoalAutomatic近似的项数
    WorkingPrecisionAutomatic内部计算使用的精度
  • PerformanceGoal 的可能设置包括 $PerformanceGoal、"Quality" 和 "Speed". 当设置为 "Quality" 时，AsymptoticIntegrate 通常可以解出更多的问题或者产生更简单的结果，但是可能会耗费更多的时间和内存.

范例

打开所有单元 关闭所有单元

基本范例  (3)

计算积分的渐近逼近:

Wolfram Language code: AsymptoticIntegrate[Sin[t x], {t, 0, 1}, x -> 0]

计算积分的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[E ^ (t x), {t, 0, 1}, {x, 0, 7}]

与精确结果的展开式相比较：

Wolfram Language code: Integrate[E ^ (x t), {t, 0, 1}]
Wolfram Language code: Series[%, {x, 0, 7}]//Normal

获取高斯积分的展开式的首项：

Wolfram Language code: f[x_] := E^-ω (x^2 - 2 x)
Wolfram Language code: Plot[f[x] /.  {ω -> 3}, {x, 0, 7}, PlotRange -> All, Filling -> Axis]

计算所要求的项：

Wolfram Language code: AsymptoticIntegrate[f[x], {x, 0, ∞}, {ω, ∞, 1}]

与数值近似的结果相比较：

Wolfram Language code: {% /.  {ω -> 300.}, NIntegrate[Exp[-300 (x^2 - 2 x)], {x, 0, ∞}]}

范围  (21)

不定积分  (3)

计算三角积分关于 x=0 的的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[Sin[x], x, {x, 0, 8}]

与 Integrate 给出的结果相比较：

Wolfram Language code: Integrate[Sin[x], x]
Wolfram Language code: Series[%, {x, 0, 8}]//Normal

叠加幂积分关于 x=0 的的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[x^x^x, x, {x, 0, 4}]

估计一个点的值：

Wolfram Language code: % /. {x -> 0.0005}

与 NIntegrate 给出的结果相比较：

Wolfram Language code: NIntegrate[x ^ x ^ x, {x, 0, 0.0005}]

计算不定积分关于一个参数的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[E ^ (-m Sin[x]), x, {m, 0, 3}]

指数积分  (6)

计算拉普拉斯变换积分的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[Exp[ -x t] / (1 + t), {t, 0, Infinity}, {x, Infinity, 7}]

与 LaplaceTransform 给出的结果相比较：

Wolfram Language code: LaplaceTransform[1 / (1 + t), t, x]
Wolfram Language code: Series[%, {x, Infinity, 7}]//Normal//Simplify//Expand

定义一个具有高斯内核的函数，在 t=-1 处取最大值：

Wolfram Language code: f[t_] := E^-x (t^2 + t) (1 + t)^5 / 2
Wolfram Language code: Plot[f[t] /. {x -> 3.}, {t, -3, 2}, PlotRange -> All, Filling -> Axis]

计算 {0,2} 上的积分的渐近逼近的首项：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 0, 2}, {x, Infinity, 1}]

将结果与数值近似相比较：

Wolfram Language code: % /. {x -> 3000.}
Wolfram Language code: NIntegrate[Exp[-3000(t ^ 2 + t )] (1 + t) ^ (5 / 2), {t, 0, 2}]

定义一个具有高斯内核的函数，在 t=0 处取最大值：

Wolfram Language code: f[t_] := Exp[-x t ^ 2] / (t + 2)
Wolfram Language code: Plot[f[t] /. {x -> 30.}, {t, -2, 2}, PlotRange -> All, Filling -> Axis]

计算 {0,2} 上的积分的渐近逼近：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 0, 2}, {x, Infinity, 7}]

将结果与数值近似相比较：

Wolfram Language code: % /. {x -> 300.}
Wolfram Language code: NIntegrate[Exp[ -300 t ^ 2] / (t + 2), {t, 0, 2}]

定义一个具有指数内核的函数，在 t=1 处取最大值：

Wolfram Language code: f[t_] := Exp[-x(t + (1 / t))] / (t + 1)
Wolfram Language code: Plot[f[t] /. {x -> 3.}, {t, 1, 2}, Filling -> Axis]

计算 {1,2} 上的积分的渐近逼近的首项：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 1, 2}, {x, Infinity, 1}]

将结果与数值近似相比较：

Wolfram Language code: % /. {x -> 3.}
Wolfram Language code: NIntegrate[Exp[-3(t + (1 / t))] / (t + 1), {t, 1, 2}]

定义一个具有指数内核的函数，在 t=1 处取最大值：

Wolfram Language code: f[t_] := Exp[-x (t ^ 2 - 2t)] / (t + 1)
Wolfram Language code: Plot[f[t] /. {x -> 3.}, {t, 0, 3}, Filling -> Axis]

计算 {0,3} 上的积分的渐近逼近的首项：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 0, 3}, {x, Infinity, 1}]

将结果与数值近似相比较：

Wolfram Language code: % /. {x -> 3000.}
Wolfram Language code: NIntegrate[Exp[-3000(t ^ 2 - 2t)] / (t ^ 2 + 1), {t, 0, 3}]

定义一个具有指数内核的函数，在 t=π/2 处取最大值：

Wolfram Language code: f[t_] := Exp[x Sin[t]]
Wolfram Language code: Plot[f[t] /. {x -> 3.}, {t, 0, Pi}, Filling -> Axis]

计算 {0,3} 上的积分的渐近逼近的首项：

Wolfram Language code: AsymptoticIntegrate[f[t], {t, 0, Pi}, {x, Infinity, 1}]

将结果与数值近似相比较：

Wolfram Language code: % /. {x -> 3000.}
Wolfram Language code: NIntegrate[Exp[3000Sin[t]], {t, 0, Pi}]

振荡积分  (4)

计算 上的傅立叶类型的积分的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[Exp[ I x t] / (1 + t ^ 2), {t, 0, Infinity}, {x, Infinity, 7}]

求 上的复振荡积分的首项近似：

Wolfram Language code: f[x_] := E ^ (I ω Sin[t])
Wolfram Language code: Plot[Re[f[x] /.  {ω -> 50}], {t, 0, π}, Filling -> Axis]

计算所要求的逼近：

Wolfram Language code: int = AsymptoticIntegrate[f[t], {t, 0, π}, {ω, ∞, 1}]

与数值近似相比较：

Wolfram Language code: NIntegrate[E ^ (I 500 Sin[t]), {t, 0, π}]//Quiet
Wolfram Language code: int /. {ω -> 500.}

求含有 Sin 的实振荡积分的首项近似：

Wolfram Language code: f[t_] := Sin[ x t ^ 3] / Sqrt[t + 1]
Wolfram Language code: Plot[f[t] /. {x -> 30.}, {t, 0, π / 2}, Filling -> Axis, PlotRange -> All]

计算首项：

Wolfram Language code: int = AsymptoticIntegrate[f[t], {t, 0, π / 2}, {x, ∞, 1}]

与数值近似相比较：

Wolfram Language code: NIntegrate[Sin[ 300 t ^ 3] / Sqrt[t + 1], {t, 0, π / 2}]
Wolfram Language code: int /. {x -> 300.}

求含有 Cos 的实振荡积分的近似展开式：

Wolfram Language code: f[t_] := Cos[ x t] / (1 + E ^ (t ^ 2))
Wolfram Language code: Plot[f[t] /. {x -> 30.}, {t, 1, 2}, Filling -> Axis, PlotRange -> All]

计算含有两项的展开式：

Wolfram Language code: int = AsymptoticIntegrate[f[t], {t, 1, 2}, {x, ∞, 2}]//Simplify

与数值近似相比较：

Wolfram Language code: NIntegrate[Cos[ 300 t] / (1 + E ^ t ^ 2), {t, 1, 2}]
Wolfram Language code: int /. {x -> 300.}

普通定积分  (4)

计算有理函数的积分在 x=0 处的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[1 / (t ^ 2 + x ^ 2), {t, 1, 3}, {x, 0, 4}]

与 Integrate 给出的结果相比较：

Wolfram Language code: Integrate[1 / (t ^ 2 + x ^ 2), {t, 1, 3}, Assumptions -> x > 0]
Wolfram Language code: Series[%, {x, 0, 4}]//Normal

三角积分在 x=π/2 处的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[Sin[t + x] ^ 5, {t, 0, π}, {x, π / 2, 3}]

与 Integrate 给出的结果相比较：

Wolfram Language code: Integrate[Sin[t + x] ^ 5, {t, 0, π}]
Wolfram Language code: Collect[Series[%, {x, π / 2, 3}]//Normal, x]

完整椭圆积分在 x=0 处的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[1 / Sqrt[1 - m * Sin[θ] ^ 2], {θ, 0, Pi / 2}, {m, 0, 5}]

与 Integrate 给出的结果相比较：

Wolfram Language code: Integrate[1 / Sqrt[1 - m * Sin[θ] ^ 2], {θ, 0, Pi / 2}, Assumptions -> 0 < m < 1]
Wolfram Language code: Series[%, {m, 0, 4}]//Normal

积分在 x=-Infinity 处的渐近展开式：

Wolfram Language code: AsymptoticIntegrate[E ^ (x t) / (1 + t ^ 2), {t, 0, Infinity}, {x, -Infinity, 6}]

与数值近似相比较：

Wolfram Language code: % /. {x -> -30.}
Wolfram Language code: NIntegrate[E ^ (-30 t) / (1 + t ^ 2), {t, 0, Infinity}]

变换积分  (4)

一个函数的拉普拉斯变换的渐近展开式：

Wolfram Language code: f[t_] := 1 / (1 + t)
Wolfram Language code: Plot[f[t], {t, 0, 4}, Filling -> Axis]
Wolfram Language code: AsymptoticIntegrate[f[t] E ^ (-s t), {t, 0, Infinity}, {s, Infinity, 5}]

与使用 LaplaceTransform 得到的精确结果的级数展开式相比较：

Wolfram Language code: LaplaceTransform[f[t], t, s]
Wolfram Language code: Series[%, {s, Infinity, 5}]//Normal

一个函数的 Mellin 变换的渐近展开式：

Wolfram Language code: f[t_] := t / (t ^ 3 + 1)
Wolfram Language code: Plot[f[t], {t, 0, 4}, Exclusions -> None, Filling -> Axis]
Wolfram Language code: AsymptoticIntegrate[f[t] t ^ (s - 1), {t, 0, Infinity}, {s, 0, 2}]

与使用 MellinTransform 得到的精确结果的级数展开式相比较：

Wolfram Language code: MellinTransform[f[t], t, s]
Wolfram Language code: Series[%, {s, 0, 2}]//Normal

一个函数的傅立叶余弦变换的渐近展开式：

Wolfram Language code: f[t_] := E ^ (-t ^ 2)
Wolfram Language code: Sqrt[2 / Pi] AsymptoticIntegrate[f[t] Cos[s t], {t, 0, Infinity}, {s, 0, 2}]//Expand

与使用 FourierCosTransform 得到的精确结果的级数展开式相比较：

Wolfram Language code: FourierCosTransform[f[t], t, s]
Wolfram Language code: Series[%, {s, 0, 2}]//Normal

一个函数的傅立叶正弦变换的渐近展开式：

Wolfram Language code: f[t_] := E ^ (-t ^ 2 + t)
Wolfram Language code: afs = Sqrt[2 / Pi] AsymptoticIntegrate[f[t] Sin[s t], {t, 0, Infinity}, {s, 0, 2}]//FullSimplify

与使用 FourierSinTransform 得到的精确结果的级数展开式相比较：

Wolfram Language code: FourierSinTransform[f[t], t, s]
Wolfram Language code: Series[%, {s, 0, 2}, Assumptions -> s > 0]//Normal//FullSimplify
Wolfram Language code: % - afs//FullSimplify

选项  (1)

GeneratedParameters  (1)

生成不定积分的任意常数：

Wolfram Language code: AsymptoticIntegrate[Cos[x], x, {x, 0, 3}, GeneratedParameters -> C]

任意常数的默认值为 0：

Wolfram Language code: % /. {C[1] -> 0}
Wolfram Language code: AsymptoticIntegrate[Cos[x], x, {x, 0, 3}]

应用  (7)

获取定积分的渐近展开式

Wolfram Language code: int = AsymptoticIntegrate[1 / Sqrt[1 - ϵ t ^ 14], {t, 0, 1}, {ϵ, 0, 2}]

与数值近似相比较：

Wolfram Language code: int /. {ϵ -> 0.3}
Wolfram Language code: NIntegrate[1 / Sqrt[1 - 0.3 t ^ 14], {t, 0, 1}]

通过增加项数改进渐近逼近：

Wolfram Language code: AsymptoticIntegrate[1 / Sqrt[1 - ϵ t ^ 14], {t, 0, 1}, {ϵ, 0, 5}]
Wolfram Language code: % /. {ϵ -> 0.3}

求从 到 曲线 下面的面积：

Wolfram Language code: Plot[Sin[a x] ^ 2 Cos[x] ^ 4 /. {a -> 1.05}, {x, -π, π}, Filling -> Axis]
Wolfram Language code: AsymptoticIntegrate[Sin[a x] ^ 2 Cos[x] ^ 4, {x, -π, π}, {a, 1, 4}]

求 取特定值时的面积：

Wolfram Language code: % /. {a -> 1.05}

计算 () 绕 轴旋转所围成的体积：

Wolfram Language code: AsymptoticIntegrate[π(Sin[a x] ^ 2) ^ 2, {x, 0, π}, {a, 3, 4}]

求 取特定值时的体积：

Wolfram Language code: % /. {a -> 3.1}

可视化该实体：

Wolfram Language code: RevolutionPlot3D[Sin[3.1 x] ^ 2, {x, 0, π}, RevolutionAxis -> "X"]

定义渐近版本的 LaplaceTransform：

Wolfram Language code: asymLaplaceTransform[f_, t_, s_, n_] := AsymptoticIntegrate[f E ^ (-s t), {t, 0, ∞}, {s, ∞, n}]

用它来计算一个周期函数的渐近拉普拉斯变换：

Wolfram Language code: f[t_] := 1 / (3 + Sin[t] ^ 3)
Wolfram Language code: Plot[f[t], {t, 0, 20}, PlotRange -> All, Filling -> Axis]
Wolfram Language code: lap = asymLaplaceTransform[f[t], t, s, 8]

绘制结果：

Wolfram Language code: Plot[lap, {s, 100, 1000}]

与数值近似相比较：

Wolfram Language code: Table[NIntegrate[f[t] E ^ (-s t), {t, 0, ∞}], {s, 100, 1000, 200}]
Wolfram Language code: Table[lap, {s, 100, 1000, 200}]//N

计算域为 的 ProbabilityDistribution 的渐近均值：

Wolfram Language code: dist = ProbabilityDistribution[1 / (1 + ϵ (x - 2 / 3) ^ 2), {x, 0, 1}, Assumptions -> ϵ > 0];

归一化 PDF：

Wolfram Language code: norm = Integrate[1 / (1 + ϵ (x - 1 / 3) ^ 2), {x, 0, 1}, Assumptions -> ϵ > 0]

绘制 PDF：

Wolfram Language code: Plot[PDF[dist, x] / norm /. {ϵ -> 1 / 20}, {x, 0, 1}, Filling -> Axis]

定义渐近均值：

Wolfram Language code: asympMean[dist_, ϵ_, n_] := AsymptoticIntegrate[x Refine[PDF[dist, x], 0 < x < 1], {x, 0, 1}, {ϵ, 0, n}]

计算给定分布的渐近均值：

Wolfram Language code: asympMean[dist, ϵ, 3]

与精确结果的展开式相比较：

Wolfram Language code: Mean[dist]
Wolfram Language code: Series[%, {ϵ, 0, 3}, Assumptions -> ϵ > 0]//Normal

获取 BesselJ 的积分表示的渐近展开式：

Wolfram Language code: besselint = ((2 ^ (1 - ν) * z ^ ν) / (Sqrt[Pi] * Gamma[ν + 1 / 2]))AsymptoticIntegrate[(1 - t ^ 2) ^ (ν - 1 / 2) * Cos[z * t], {t, 0, 1}, {z, 0, 2}, Assumptions -> ν > 0]

与贝塞尔函数的实际数值相比较：

Wolfram Language code: Table[besselint /. {ν -> 2}, {z, 0.1, 0.5, 0.1}]
Wolfram Language code: Table[BesselJ[2, z], {z, 0.1, 0.5, 0.1}]

计算一个振荡积分的渐近逼近：

Wolfram Language code: f[t_] := Sin[t] E ^ (I x (t ^ 3 + 3 t))
Wolfram Language code: ReImPlot[f[t] /. {x -> 30}, {t, -2, 2}, PlotLegends -> "ReIm"]
Wolfram Language code: AsymptoticIntegrate[f[t], {t, -2, 2}, {x, ∞, 4}]

与数值近似的结果相比较：

Wolfram Language code: % /. {x -> 30.}
Wolfram Language code: NIntegrate[Sin[t] E ^ (I 30 (t ^ 3 + 3 t)), {t, -2, 2}]

属性和关系  (4)

AsymptoticIntegrate 按给定阶数计算积分：

Wolfram Language code: AsymptoticIntegrate[Sin[x], x, {x, 0, 6}]
Wolfram Language code: Series[-Cos[x] - %, {x, 0, 6}]

用 Integrate 算出解析形式的积分：

Wolfram Language code: AsymptoticIntegrate[Sin[x t] ^ 2, {t, 0, 1}, {x, 0, 8}]
Wolfram Language code: Integrate[Sin[x t] ^ 2, {t, 0, 1}]
Wolfram Language code: Series[%, {x, 0, 8}]//Normal

用 NIntegrate 计算数值近似：

Wolfram Language code: AsymptoticIntegrate[E ^ (-ω t ^ 2)(t + 5) ^ (1 / 2), {t, 0, 5}, {ω, ∞, 3}]
Wolfram Language code: % /. {ω -> 300.}
Wolfram Language code: NIntegrate[E ^ (-300 t ^ 2)(t + 5) ^ (1 / 2), {t, 0, 5}]

用 AsymptoticExpectation 计算渐近期望：

Wolfram Language code: dist = UniformDistribution[{-1, 2}];
Wolfram Language code: AsymptoticExpectation[E ^ (a x), xdist, {a, 0, 3}]

用 AsymptoticIntegrate 获取同样的结果：

Wolfram Language code: AsymptoticIntegrate[E ^ (a x) PDF[dist, x], {x, -∞, ∞}, {a, 0, 3}]

可能存在的问题  (1)

此例中返回的展开式少于四项：

Wolfram Language code: AsymptoticIntegrate[Cos[x], x, {x, 0, 4}]

对于更普通的积分，展开式中出现缺失的项：

Wolfram Language code: AsymptoticIntegrate[Cos[x + a], x, {x, 0, 4}]
Wolfram Language code: % /. {a -> 0}
Wolfram Research (2018)，AsymptoticIntegrate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AsymptoticIntegrate.html （更新于 2020 年）.

文本

Wolfram Research (2018)，AsymptoticIntegrate，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AsymptoticIntegrate.html （更新于 2020 年）.

CMS

Wolfram 语言. 2018. "AsymptoticIntegrate." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/AsymptoticIntegrate.html.

APA

Wolfram 语言. (2018). AsymptoticIntegrate. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AsymptoticIntegrate.html 年

BibTeX

@misc{reference.wolfram_2026_asymptoticintegrate, author="Wolfram Research", title="{AsymptoticIntegrate}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/AsymptoticIntegrate.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_asymptoticintegrate, organization={Wolfram Research}, title={AsymptoticIntegrate}, year={2020}, url={https://reference.wolfram.com/language/ref/AsymptoticIntegrate.html}, note=[Accessed: 11-August-2026]}