WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AttachCell[expr]

expr を現在評価中のセルに貼付する．

AttachCell[obj,expr]

expr を，ノートブック，セル，あるいはボックスオブジェクト obj に貼付する．

AttachCell[obj,expr,pos]

貼付セルが obj と相対的な位置 pos になるように指定する．

AttachCell[obj,expr,pos,dist]

貼付セルが pos から dist の距離になるように指定する．

AttachCell[obj,expr,pos,dist,opos]

expr の位置 opos が場所 pos から距離 dist になるように貼付セルを置く．

AttachCell[cellobj,expr,"Inline"]

貼付セルが cellobj の下部と下部余白の間に置かれるように指定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
オプション  
RemovalConditions  
特性と関係  
インタラクティブな例題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AttachCell

AttachCell[expr]

expr を現在評価中のセルに貼付する．

AttachCell[obj,expr]

expr を，ノートブック，セル，あるいはボックスオブジェクト obj に貼付する．

AttachCell[obj,expr,pos]

貼付セルが obj と相対的な位置 pos になるように指定する．

AttachCell[obj,expr,pos,dist]

貼付セルが pos から dist の距離になるように指定する．

AttachCell[obj,expr,pos,dist,opos]

expr の位置 opos が場所 pos から距離 dist になるように貼付セルを置く．

AttachCell[cellobj,expr,"Inline"]

貼付セルが cellobj の下部と下部余白の間に置かれるように指定する．

詳細とオプション

  • 貼付セルは，現在表示されているノートブックのバージョンにしか表示されず，ノートブックと一緒に保存はされない．
  • AttachCell[obj,…]は obj が存在する間しか効果がない．
  • 貼付セルは効率的に配備され，コントロールのみがアクティブになる．
  • AttachCellは，成功した場合は貼付セルのCellObjectを，それ以外の場合は$Failedを返す．結果の貼付セルオブジェクトは，そのCellObjectに対してNotebookDeleteを呼び出すことで破棄できる．
  • expr は，生のCell式，TextCell，ExpressionCellのときは，適切なタイプのセルとして解釈される．その他の式はExpressionCell[expr]と同様に扱われる．
  • obj は，以下のいずれかの型の式でよい．
  • BoxObject[…]指定されたボックスオブジェクトで占められた矩形領域に追加する．追加されたセルは親ボックスとともにスクロールする
    CellObject[…]指定されたセルオブジェクトで締められた矩形領域に追加する．追加されたんセルは親のセルとともにスクロールする
    NotebookObject[…]ノートブックウィンドウそれ自体の矩形領域に追加する．追加されたセルはスクロール位置にかかわらずウィンドウ内に固定される
    NotebookSelection[NotebookObject[…]]ノートブックの原稿選択の矩形領域に追加される．追加されたセルは後に選択項目が変わっても，ドキュメントの相対的な位置に残る
  • 貼付セルあるいは貼付セルに含まれる obj を指定して貼付セルをネストさせることができる．
  • obj に複数のセルを貼付する場合はAttachCellを複数回呼び出す．
  • 貼付セルは，通常は，親ノートブックの他のコンテンツに重ねて表示され，親ノートブックウィンドウの外まで拡張されることはない．貼付点がノートブック内でスクロールされると，貼付セルも一緒にスクロールされる．
  • 次は，位置引数の pos と opos の使用可能な値である．
  • Center中央
    Left左中央
    Right右中央
    Top上中央
    Bottom下中央
    {hor,ver}hor で指定される水平位置と ver で指定される垂直位置
  • pos については次の値も指定できる．
  • "CellBracket"単独で，または最上位のセルのセルブラケットに接続する pos の水平成分として指定可
    "Inline"その下のセルを押し出して，トップレベルのセルの下に貼付
  • 距離 dist は以下で指定できる．
  • Automatic外周に置く
    None中央に置く
    d外周から d 単位の位置に置く
    Scaled[d]外周からスケールされた距離に置く
    Absolute[d]外周から絶対距離に置く
    Offset[{dx,dy},d]d からのオフセットで置く
  • AttachCell[obj,expr]はAttachCell[obj,expr,{Center,Bottom},Automatic,Automatic]に等しい．
  • 貼付セルはインラインセルと同じように obj から形式を継承する．
  • AttachCell[…,RemovalConditions->{cond1,cond2,…}]は，条件 condiが出現した場合は自動的に貼付セルを削除する．以下は可能な条件である．
  • "EvaluatorQuit"セルのデフォルトカーネルが終了する
    "MouseExit"マウスがエリアを離れる
    "MouseClickOutside"クリックがエリア外で登録された
    "ParentChanged"親オブジェクトが何らかの方法で編集された
    "SelectionExit"選択範囲がエリアを離れた
  • 削除条件の中には，その外側でアクションを実行すると貼付セルが削除される領域が定義されるものがある．そのようなエリアには，obj および expr が占めているスクリーン上の空間が含まれる．obj が同様に貼付セルなら，obj のエリアが含まれる．expr が貼付先のセルなら，エリアはすべてのネストされた貼付物に拡張される．
  • obj がトップレベルのセルなら，エリアにはセルブラケットが含まれる．そのセルのすぐ下に選択されたセル挿入点はエリア内を選択したものと解釈される．

例題

すべて開く すべて閉じる

例  (4)

指定のテキストを含むセルを入力セルに貼付する：

Wolfram Language code: AttachCell["Hello world"];

貼付セルを削除する：

Wolfram Language code: NotebookDelete[%]

"Inline"の置き方では，貼付セルは他のノートブックコンテンツを押し出す：

Wolfram Language code: AttachCell[EvaluationCell[], "Hello world", "Inline"];
Wolfram Language code: NotebookDelete[%]

貼付セルを貼付先セルの右端に表示する：

Wolfram Language code: AttachCell[EvaluationCell[], "Hello world", Right];
Wolfram Language code: NotebookDelete[%]

貼付セルの右上コーナーをセルブラケットの上と揃える：

Wolfram Language code: AttachCell[EvaluationCell[], "Hello world", {"CellBracket", Top}, 0, {Right, Top}];
Wolfram Language code: NotebookDelete[%]

スコープ  (3)

EvaluationBoxを使ってボタンにセルを貼付する：

Wolfram Language code: Button["click", obj = AttachCell[EvaluationBox[], Slider[], Right, 20, Left]]
Wolfram Language code: NotebookDelete[obj]

AttachCellはセルを貼付セルに貼付することができる：

Wolfram Language code: c = EvaluationCell[];
Wolfram Language code: obj1 = AttachCell[c, "Hello world", "Inline"];
Wolfram Language code: obj2 = AttachCell[obj1, "Hello again", "Inline"];

貼付セルを削除するとそれに貼付されたセルも削除される：

Wolfram Language code: NotebookDelete[obj1]

ノートブックにセルを貼付する：

Wolfram Language code: AttachCell[EvaluationNotebook[], Button["click to delete", NotebookDelete[EvaluationCell[]]], Bottom, 0, Bottom];

一般化と拡張  (2)

セルが表示されたときに自動的に貼付セルを作る：

Wolfram Language code: CellPrint[ExpressionCell[4, "Output", Initialization :> AttachCell["attached content"]]]

InheritScopeを使って貼付セルのDynamicModuleをその貼付されたDynamicModuleに接続する：

Wolfram Language code: DynamicModule[{x = 0}, Row[{"x=", Dynamic[x]}], Initialization :> (AttachCell[EvaluationBox[], DynamicModule[{}, Button["x++", x++], InheritScope -> True], Bottom, 0, Top])]

オプション  (2)

RemovalConditions  (2)

デフォルトで，貼付セルは貼付先のセルが存在する間は存在する：

Wolfram Language code: AttachCell["Hello world"];

セルはNotebookDeleteのような操作によってしか削除できない：

Wolfram Language code: NotebookDelete[%]

貼付物の外側をクリックされると閉じる貼付セルを作る：

Wolfram Language code: AttachCell["Hello world", RemovalConditions -> {"MouseClickOutside"}];

貼付先のセルが編集されると閉じる貼付セルを作る：

Wolfram Language code: AttachCell[EvaluationCell[], Framed["Edit this cell", Background -> Pink], "CellBracket", RemovalConditions -> {"ParentChanged"}];

特性と関係  (1)

貼付されたセルはAttachedCellTrueとしてCellsで見付けることができる：

Wolfram Language code: AttachCell[EvaluationCell[], "fish"]; NotebookRead[Cells[EvaluationCell[], AttachedCell -> True]]

インタラクティブな例題  (1)

コントロールとインタラクトしているときに動的コンテンツを貼付する：

Wolfram Language code: {Slider[Dynamic[a, {(a = #;obj = AttachCell[EvaluationBox[], Dynamic[a]])&, (a = #)&, (a = #;NotebookDelete[obj])&}], {1, 5}], Dynamic[Plot[Sin[a x], {x, 0, 10}]]}

おもしろい例題  (2)

カスタムの評価進捗器をセルブラケットの近くに表示する：

Wolfram Language code: obj = AttachCell[EvaluationCell[], Animator[Appearance -> "Necklace"], {"CellBracket", Top}, 0, {Right, Top}]; Pause[3]; NotebookDelete[obj]

評価の進捗状況をセルブラケットの近くに表示する：

Wolfram Language code: obj = AttachCell[EvaluationCell[], Panel[Dynamic[i]], {"CellBracket", Bottom}, 0, {Right, Bottom}]; Do[PrimeQ[i], {i, 10 ^ 7}]; NotebookDelete[obj]
Wolfram Research (2020), AttachCell, Wolfram言語関数， https://reference.wolfram.com/language/ref/AttachCell.html （2024年に更新）.

テキスト

Wolfram Research (2020), AttachCell, Wolfram言語関数， https://reference.wolfram.com/language/ref/AttachCell.html （2024年に更新）.

CMS

Wolfram Language. 2020. "AttachCell." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/AttachCell.html.

APA

Wolfram Language. (2020). AttachCell. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AttachCell.html

BibTeX

@misc{reference.wolfram_2026_attachcell, author="Wolfram Research", title="{AttachCell}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/AttachCell.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_attachcell, organization={Wolfram Research}, title={AttachCell}, year={2024}, url={https://reference.wolfram.com/language/ref/AttachCell.html}, note=[Accessed: 10-August-2026]}