WOLFRAM

Wolfram 语言与系统参考资料中心

AudioStream[source]

创建一个起自 source 的新的 AudioStream 对象.

AudioStream[id]

是表示惟一音频流的对象.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
Basic Uses  
Playback Streams  
Generator Streams  
Input Streams  
选项  
AudioChannelAssignment  
AudioOutputDevice  
Looping  
SampleRate  
SoundVolume  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

AudioStream

AudioStream[source]

创建一个起自 source 的新的 AudioStream 对象.

AudioStream[id]

是表示惟一音频流的对象.

更多信息和选项

  • AudioStream 是 Audio 对象或设备的句柄，编程式控制音频信号的回放或录音.
  • source 可为一下任意：
  • audio播放单个音频信号的音频流
    {audio1,audio2,…}播放音频信号列表的音频流
    func从函数生成的流 func
    dev从音频输入设备录制的音频流 dev
  • 函数 func 在时间值的缓冲区上运行，并且每次应返回标量或数值向量
  • 用 AudioPlay 开始播放音频流.
  • 用 AudioRecord 开始记录音频流.
  • 用 AudioPause 或 AudioStop 暂停或停止播放录音.
  • dev 可以是任何来自于 $AudioInputDevices 的可用输入音频设备.
  • 用 Audio[astream] 根据录制的流创建 Audio 对象.
  • 可以指定下列选项：
  • AudioChannelAssignment Inherited如何把音频通道分配给输出
    AudioOutputDevice Inherited用于播放的音频输出设备
    Looping False是否循环播放
    SampleRate Automatic采样率
    SoundVolume Automatic音量
  • 可用 astream["prop"] 获取音频流 astream 的属性.
  • 可以用 astream["prop"]=val 设置属性的值.
  • 播放音频流的一些属性包括：
  • "AudioChannelAssignment"如何把音频通道分配给输出
    "AudioOutputDevice"用于播放的音频输出设备
    "BufferSize"每个缓存内的样本数
    "CurrentAudio"当前音频信号中的片段
    "ID"流 ID
    "Looping"是否循环回放
    "Position"以时间 Quantity 形式给出的播放位置
    "SampleRate"每秒样本数
    "SoundVolume"音量
    "Status"流状态
  • "Status" 的可能设置包括 "Playing" 、"Recording"、"Paused" 或 "Stopped".
  • AudioStream[{audio1,audio2,…}] 的其他属性：
  • "CurrentTrack"播放曲目的索引
    "Ordering"用于播放曲目的订购
    "Duration"当前曲目的持续时间
    "Durations"所有曲目的持续时间
    "TrackCount"轨道数
  • AudioStream[func] 的附加属性：
  • "Function"生成器函数
  • AudioStream[dev] 的其他属性：
  • "AudioInputDevice"用于录音的音频输入设备
    "GeneratedAssetLocation"到将要存储录制的音频的文件的路径
    "RecordedAudio"包含录音的 Audio 对象
  • 例如 Join、Append、AppendTo 和 Drop 的函数可用于更改 AudioStream 对象.

范例

打开所有单元 关闭所有单元

基本范例  (3)

从音频对象创建 AudioStream 对象：

Wolfram Language code: a = Audio["ExampleData/rule30.wav"]; s = AudioStream[a]

播放音频流：

Wolfram Language code: AudioPlay[s]

从输入设备创建 AudioStream 对象：

Wolfram Language code: AudioStream[$DefaultAudioInputDevice]

记录音频流：

Wolfram Language code: AudioRecord[%]

停止录音：

Wolfram Language code: AudioStop[%]

从一个函数创建 AudioStream 对象：

Wolfram Language code: s = AudioStream[Function[t, TriangleWave[200t]]]

播放 AudioStream：

Wolfram Language code: AudioPlay[s]

停止播放：

Wolfram Language code: AudioStop[s]

范围  (17)

Basic Uses  (5)

创建一个音频对象的两个分离的音频流：

Wolfram Language code: a = Audio["ExampleData/rule30.wav"]; stream1 = AudioStream[a] stream2 = AudioStream[a]

两个流是互相独立的. 在一个开始 0.5 秒后播放另一个：

Wolfram Language code: AudioPlay[stream1];Pause[.5];AudioPlay[stream2];

检查可用的音频流属性：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}]; stream = AudioStream[a]; stream["Properties"]

获取音频流的属性值：

Wolfram Language code: AssociationMap[stream, stream["Properties"]]

设定 "Position" 属性：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}]; stream = AudioStream[a]
Wolfram Language code: stream["Position"] = 3

从所选节点播放：

Wolfram Language code: AudioPlay[stream]

在播放音频流时修改属性：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}]; stream = AudioStream[a]
Wolfram Language code: AudioPlay[stream]; Pause[1]; stream["SoundVolume"] = .1; Pause[1]; stream["SoundVolume"] = 1;

缓冲区大小从系统选项中继承：

Wolfram Language code: SystemOptions["AudioProcessingOptions" -> "StreamBufferSize"]

Playback Streams  (7)

检查从 Audio 对象创建的 AudioStream 的属性：

Wolfram Language code: a = Audio["ExampleData/rule30.wav"]; astream = AudioStream[a]
Wolfram Language code: props = astream["Properties"]
Wolfram Language code: Table[prop -> astream[prop], {prop, props}]//Column

从 Audio 对象列表创建 AudioStream：

Wolfram Language code: audios = SpeechSynthesize /@ {1, 2, 3}; astream = AudioStream[audios]

播放音频流：

Wolfram Language code: AudioPlay[astream]

检查从 Audio 对象列表创建的 AudioStream 的属性：

Wolfram Language code: audios = SpeechSynthesize /@ {1, 2, 3}; astream = AudioStream[audios]

获取可用属性的列表：

Wolfram Language code: props = astream["Properties"]

获取所有可用属性的值：

Wolfram Language code: Table[prop -> astream[prop], {prop, props}]//Column

从 Audio 对象列表创建 AudioStream 并指定顺序：

Wolfram Language code: audios = SpeechSynthesize /@ {1, 2, 3}; astream = AudioStream[audios]

更改顺序：

Wolfram Language code: astream["Ordering"] = OrderingBy[audios, Duration]

以指定的顺序播放流：

Wolfram Language code: AudioPlay[astream]

从 Audio 对象列表创建一个 AudioStream 并设置一些属性：

Wolfram Language code: audios = SpeechSynthesize /@ {1, 2, 3}; astream = AudioStream[audios]

更改 "CurrentTrack" 属性并播放 AudioStream:

Wolfram Language code: astream["CurrentTrack"] = 2
Wolfram Language code: AudioPlay[astream]

可以使用 Append 扩展音频流。生成两个音频信号的音频流：

Wolfram Language code: stream = AudioStream[SpeechSynthesize /@ {"Hello.", "How are you?"}]

创建另一个音频信号：

Wolfram Language code: a = SpeechSynthesize["Goodbye!"];

将新的音频信号追加到流中：

Wolfram Language code: res = Append[stream, a]
Wolfram Language code: res["TrackCount"]

播放结果音频流：

Wolfram Language code: AudioPlay[res];

音频流可以合并，生成两个音频流：

Wolfram Language code: stream1 = AudioStream[SpeechSynthesize /@ {"Hello.", "How are you?"}]
Wolfram Language code: stream2 = AudioStream[SpeechSynthesize[#, "Karen"]& /@ {"I'm fine.", "Thank you!"}]

加入两个音频流：

Wolfram Language code: res = Join[stream1, stream2]
Wolfram Language code: res["TrackCount"]

播放结果音频流：

Wolfram Language code: AudioPlay[res];

Generator Streams  (4)

检查从函数创建的 AudioStream 的属性：

Wolfram Language code: astream = AudioStream[Function[t, TriangleWave[200t]]]
Wolfram Language code: props = astream["Properties"]
Wolfram Language code: Table[prop -> astream[prop], {prop, props}]//Column

用 AudioStream 从函数并记录生成的信号：

Wolfram Language code: s = AudioStream[Function[t, TriangleWave[200t]]]; AudioRecord[s]

停止录制：

Wolfram Language code: AudioStop[s]

检索记录的信号：

Wolfram Language code: Audio[s]//Normal

使用返回深度为2的数组的函数，第一个维度将解释为通道数：

Wolfram Language code: s = AudioStream[Function[t, {TriangleWave[200t], TriangleWave[250t]}]]; AudioPlay[s]
Wolfram Language code: AudioStop[s]

通过函数创建 AudioStream：

Wolfram Language code: s = AudioStream[Function[t, TriangleWave[200t]]]; AudioPlay[s]

在播放期间更改功能：

Wolfram Language code: s["Function"] = Function[t, .5Tanh[100Sin[300 * 2.Pit]]]
Wolfram Language code: AudioStop[s]

Input Streams  (1)

检查从输入设备创建的 AudioStream 的属性：

Wolfram Language code: astream = AudioStream[$DefaultAudioInputDevice]
Wolfram Language code: props = astream["Properties"]
Wolfram Language code: Table[prop -> astream[prop], {prop, props}]//Column

选项  (6)

AudioChannelAssignment  (1)

默认情况下，AudioChannelAssignment 继承自相应的 Audio 对象：

Wolfram Language code: a = Audio["ExampleData/rule30.wav", AudioChannelAssignment -> {1, 2}]; astream = AudioStream[a];
Wolfram Language code: AudioChannelAssignment /. Options[a]
Wolfram Language code: astream["AudioChannelAssignment"]

有可能把 AudioStream 设置成不同的通道分配：

Wolfram Language code: astream = AudioStream[a, AudioChannelAssignment -> {2}];
Wolfram Language code: astream["AudioChannelAssignment"]

注意原始音频对象的通道分配是一样的：

Wolfram Language code: AudioChannelAssignment /. Options[a]

AudioOutputDevice  (1)

缺省情况下，AudioOutputDevice 承继自相应的 Audio 对象：

Wolfram Language code: a = Audio["ExampleData/rule30.wav", AudioOutputDevice -> $DefaultAudioOutputDevice]; astream = AudioStream[a];
Wolfram Language code: AudioOutputDevice /. Options[a]
Wolfram Language code: astream["AudioOutputDevice"]

可以用 AudioOutputDevice 选项把 AudioStream 分配到不同的设备：

Wolfram Language code: astream = AudioStream[a, AudioOutputDevice -> $AudioOutputDevices[[2]]];
Wolfram Language code: AudioOutputDevice /. Options[a]
Wolfram Language code: astream["AudioOutputDevice"]

Looping  (1)

默认情况下，AudioLooping 为 1：

Wolfram Language code: a = Audio["ExampleData/rule30.wav"]; astream = AudioStream[a]; AudioPlay[astream]

播放音频流两次：

Wolfram Language code: astream = AudioStream[a, Looping -> 2]; AudioPlay[astream]

Looping 选项的值不必为整数：

Wolfram Language code: astream = AudioStream[a, Looping -> 1.5]; AudioPlay[astream]

SampleRate  (2)

用 SampleRate 选项控制生成器 AudioStream 输入采样率：

Wolfram Language code: astream = AudioStream[SawtoothWave[250 * #]&, SampleRate -> 8000]; AudioPlay[astream]
Wolfram Language code: AudioStop[astream]

用 SampleRate 选项控制 AudioStream 输入采样率：

Wolfram Language code: astream = AudioStream[$DefaultAudioInputDevice, SampleRate -> 8000]; AudioRecord[astream]
Wolfram Language code: AudioStop[astream] AudioSampleRate[Audio[astream]]

SoundVolume  (1)

缺省情况下，SoundVolume 承继自相应的 Audio 对象：

Wolfram Language code: a = Audio["ExampleData/rule30.wav", SoundVolume -> .5]; astream = AudioStream[a];
Wolfram Language code: astream["SoundVolume"]
Wolfram Language code: astream["SoundVolume"]

可以用 SoundVolume 选项把 AudioStream 的音量设置为不同的值：

Wolfram Language code: astream = AudioStream[a, SoundVolume -> .1];
Wolfram Language code: SoundVolume /. Options[a]
Wolfram Language code: astream["SoundVolume"]

应用  (4)

构建一个基本的 GUI：

Wolfram Language code: With[{a = ExampleData[{"Audio", "Drums"}]}, astream = AudioStream[a]; Column@{Button[ Dynamic[astream["Status"]], Switch[astream["Status"], "Playing", astream["Status"] = "Paused", "Paused" | "Stopped", astream["Status"] = "Playing" ] ], ProgressIndicator[Dynamic[astream["Position"] / Duration[a]] ] }]

在播放时显示一个表明信号的 RMS 幅值的仪表：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}]; astream = AudioStream[a];

定义一个函数，将响度绘制为水平仪表上的位置：

Wolfram Language code: gauge[audio_] := HorizontalGauge[AudioMeasurements[audio, "LoudnessEBU"], {-60, 10}, GaugeMarkers -> Placed[Automatic, "DivisionCenter"], GaugeStyle -> Blue, GaugeLabels -> {"dbRMS", "Value"}, ScaleDivisions -> {5, 2}]

在仪表上动态显示响度：

Wolfram Language code: Dynamic[gauge[astream["CurrentAudio"]]] AudioPlay[astream];

停止播放音频流：

Wolfram Language code: AudioStop[astream]

播放时显示信号的功率谱：

Wolfram Language code: a = ExampleData[{"Audio", "Drums"}]; astream = AudioStream[a];

定义显示功率谱的函数：

Wolfram Language code: spectrum[audio_] := Periodogram[audio, 2000, PlotRange -> {{40, 20000}, {-80, 10}}, ScalingFunctions -> {"Log", "dB"}, Frame -> True, Axes -> False]

动态显示功率谱：

Wolfram Language code: Dynamic[spectrum[astream["CurrentAudio"]]] AudioPlay[astream];

停止播放音频流：

Wolfram Language code: AudioStop[astream]

从仅使用二进制操作的函数创建 AudioStream：

Wolfram Language code: par1 = 12;par2 = 8;par3 = 4;sampleRate = 8000; s = AudioStream[Function[time, With[{t = Round[time * sampleRate]}, Clip[t * BitAnd[BitOr[BitShiftRight[t, par1], BitShiftRight[t, par2]], BitAnd[63, BitShiftRight[t, par3]]], {0, 255}] / 255. - .5 ]], SampleRate -> sampleRate]; AudioPlay[s]

使用滑块动态控制部分参数：

Wolfram Language code: Column[{Slider[Dynamic[par1], {4, 20, 1}], Slider[Dynamic[par2], {4, 20, 1}], Slider[Dynamic[par3], {1, 6, 1}]}]
Wolfram Language code: AudioStop[]

属性和关系  (2)

用 AudioPlay 创建并开始播放一个音频流：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; AudioPlay[a]

用 AudioRecord 创建并开始对一个音频流进行录音：

Wolfram Language code: AudioRecord[$DefaultAudioInputDevice]
Wolfram Language code: AudioStop[%]

可能存在的问题  (2)

如果音频不连贯，请尝试增加缓冲区的大小：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];
Wolfram Language code: astream = AudioStream[a];
Wolfram Language code: astream["BufferSize"]
Wolfram Language code: AudioPlay[astream]
Wolfram Language code: astream["BufferSize"] = 10000
Wolfram Language code: AudioPlay[astream]

无法设置输入流的 "Position" 属性：

Wolfram Language code: astream = AudioStream[$DefaultAudioInputDevice];
Wolfram Language code: astream["Position"] = 3
Wolfram Research (2017)，AudioStream，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioStream.html （更新于 2021 年）.

文本

Wolfram Research (2017)，AudioStream，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioStream.html （更新于 2021 年）.

CMS

Wolfram 语言. 2017. "AudioStream." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/AudioStream.html.

APA

Wolfram 语言. (2017). AudioStream. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AudioStream.html 年

BibTeX

@misc{reference.wolfram_2026_audiostream, author="Wolfram Research", title="{AudioStream}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/AudioStream.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_audiostream, organization={Wolfram Research}, title={AudioStream}, year={2021}, url={https://reference.wolfram.com/language/ref/AudioStream.html}, note=[Accessed: 14-September-2026]}