WOLFRAM

Wolfram 语言与系统参考资料中心

BandpassFilter[data,{ω1,ω2}]

对一组数据阵列应用带通滤波器，其中截止频率为 ω1 和 ω2.

BandpassFilter[data,{{ω,q}}]

使用中心频率 ω 和质量因子 q.

BandpassFilter[data,spec,n]

使用长度为 n 的滤波器内核.

BandpassFilter[data,spec,n,wfun]

将平滑窗 wfun 应用于滤波器内核.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
数据  
参数  
选项  
Padding  
SampleRate  
应用  
属性和关系  
可能存在的问题  
互动范例  
参见
相关指南
历史
按以下格式引用：

BandpassFilter

BandpassFilter[data,{ω1,ω2}]

对一组数据阵列应用带通滤波器，其中截止频率为 ω1 和 ω2.

BandpassFilter[data,{{ω,q}}]

使用中心频率 ω 和质量因子 q.

BandpassFilter[data,spec,n]

使用长度为 n 的滤波器内核.

BandpassFilter[data,spec,n,wfun]

将平滑窗 wfun 应用于滤波器内核.

更多信息和选项

  • 带通滤波通常用于音频均衡器和音频接收器，以衰减信号中的低频和高频，同时保持中频不变.
  • BandpassFilter 用窗口法创建的有限脉冲响应（FIR）核卷积数字信号.
  • 内核越长，鉴频能力越强.
  • data 可以是以下任何形式：
  • list任意秩数值数组
    tseries诸如 TimeSeries 和 TemporalData 等时间数据
    image任意 Image 或 Image3D 对象
    audioAudio 或 Sound 对象
    videoVideo 对象
  • 衰减的频率范围取决于截止频率值 ω1 和 ω2，其中 ω2>ω1.
  • 当应用到图像和多维阵列时，滤波从第 1 层开始，先后应用于每个维度. BandpassFilter[data,{{ω11,ω21},…}] 对于第 i 维使用频率 {ω1i,ω2i}.
  • BandpassFilter[data,{ω1,ω2}] 所用的滤波器内核长度和平滑窗口是与截止频率{ω1,ω2} 和输入 data 相适应的.
  • 典型的平滑窗 wfun 包括：
  • BlackmanWindow使用 Blackman 窗平滑
    DirichletWindow不进行平滑处理
    HammingWindow使用 Hamming 窗平滑
    {v1,v2,…}使用值为 vi 的窗
    f通过在范围 和 上对 f 采样创建窗
  • 可以给出下列选项：
  • Padding "Fixed"使用的填充值
    SampleRate Automatic对输入假定的采样率
  • 默认情况下，对于图像和数据，假定 SampleRate->1. 对于音频信号和时间序列，从输入数据中提取或计算采样率.
  • 在 SampleRate->sr 时，截止频率 ωc 应该在 0 和 sr 之间.

范例

打开所有单元 关闭所有单元

基本范例  (3)

余弦和信号的带通滤波：

Wolfram Language code: data = Table[Cos[x] + Cos[10x] + Cos[20x], {x, 0, 2Pi, 0.04}]; filtered = BandpassFilter[data, {.2, .6}, 31]; ListLinePlot[{data, filtered}, PlotLegends -> {"original", "filtered"}]

音频的带通滤波：

Wolfram Language code: BandpassFilter[\!\(\*AudioBox["![Embedded Audio Player](audio://content-1323j)"]\), {Quantity[500, "Hertz"], Quantity[2500, "Hertz"]}]

对图像进行带通滤波处理：

Wolfram Language code: BandpassFilter[[image], {0.5, .8}, 25]//ImageAdjust

范围  (14)

数据  (8)

对一维脉冲序列滤波：

Wolfram Language code: data = BoxMatrix[5, {41}]; ListLinePlot[{data, BandpassFilter[data, {.5, 1.5}, 15]}, PlotRange -> All]

对二维脉冲序列滤波：

Wolfram Language code: data = Table[UnitBox[(n/7), (m/7)], {n, -7, 7}, {m, -7, 7}]; ListPlot3D[data]
Wolfram Language code: BandpassFilter[data, {0.5, 1.5}]//ListPlot3D

对 TimeSeries 进行滤波：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1]; filtered = BandpassFilter[ts, {Quantity[5, "Hertz"], Quantity[10, "Hertz"]}];
Wolfram Language code: ListLinePlot[{ts, filtered}, PlotRange -> All, PlotLegends -> {"original data", "filtered"}]

三音信号 Sound 对象的带通滤波：

Wolfram Language code: snd = Sound[SampledSoundList[Table[Sin[2 π 697 t] + Sin[2 π 1209 t] + Sin[2π 1633 t], {t, 0., 0.3, 1 / 8000.}], 8000]]

使用长度为101的 Blackman 窗口的带通滤波器消除外因：

Wolfram Language code: BandpassFilter[snd, {Quantity[1000, "Hertz"], Quantity[1400, "Hertz"]}, 101, BlackmanWindow]

半音图像的带通滤波：

Wolfram Language code: BandpassFilter[[image], {0.5, 1.5}]//ImageAdjust

对视频帧进行滤波：

Wolfram Language code: BandpassFilter[Video["ExampleData/fish.mp4"], {.2, 1.5}]

三维图像的带通滤波：

Wolfram Language code: BandpassFilter[[image], {0.25, 1.25}]

通过准确精度滤波：

Wolfram Language code: BandpassFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, {Pi / 2, Pi}, 3]

参数  (6)

通过采样率为 s 的音频信号，数值频率将被解释为 rad/s 量值：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-1323j)"]\);
Wolfram Language code: BandpassFilter[a, {{Quantity[1000, "Hertz"], 1.}}] === BandpassFilter[a, {{Quantity[1000*2*Pi, "Radians"/"Seconds"], 1.}}] === BandpassFilter[a, {{1000 2 Pi, 1.}}]

使用截止频率为 8000 Hz 和 12000 Hz 的带通滤波器滤波白噪声信号：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; Periodogram[noise]
Wolfram Language code: Periodogram[BandpassFilter[noise, {Quantity[8000, "Hertz"], Quantity[12000, "Hertz"]}]]

使用 9798 Hz 的中心频率和量值因子 q 为 2：

Wolfram Language code: Periodogram[BandpassFilter[noise, {{Quantity[9798, "Hertz"], 2}}]]

通过增大品质因数来使通带变窄：

Wolfram Language code: Periodogram[BandpassFilter[noise, {{Quantity[9798, "Hertz"], 5}}]]

使用长度为 33 的滤波器：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; Periodogram[BandpassFilter[noise, {Quantity[8000, "Hertz"], Quantity[12000, "Hertz"]}, 33]]

通过使用更长的内核来增加频率辨别：

Wolfram Language code: Periodogram[BandpassFilter[noise, {Quantity[8000, "Hertz"], Quantity[12000, "Hertz"]}, 55]]

通过使用不同的窗函数来改变衰减量：

Wolfram Language code: a = AudioGenerator[Sin[11025 2 π #^2]&]; Periodogram[BandpassFilter[a, {Quantity[5000, "Hertz"], Quantity[15000, "Hertz"]}, 33, #]& /@ {DirichletWindow, HammingWindow, BlackmanWindow}, PlotLegends -> {"Dirichlet", "Hamming", "Hann"}]

使用可调凯塞窗改变衰减量：

Wolfram Language code: Periodogram[Table[BandpassFilter[a, {Quantity[5000, "Hertz"], Quantity[15000, "Hertz"]}, 33, KaiserWindow[#, b]&], {b, {3, 5, 7}}], PlotLegends -> {3, 5, 7}]

以数值列表形式指定窗函数：

Wolfram Language code: Periodogram[BandpassFilter[a, {Quantity[5000, "Hertz"], Quantity[15000, "Hertz"]}, 33, ConstantArray[1, {33}]]]

使用不同中心频率的带通滤波：

Wolfram Language code: a = AudioGenerator[Sin[11025 2 π #^2]&]; Periodogram[BandpassFilter[a, {{#, QuantityMagnitude[(#/Quantity[5000, "Hertz"])]}}, 33]& /@ {Quantity[5000, "Hertz"], Quantity[10000, "Hertz"], Quantity[15000, "Hertz"]}, PlotLegends -> {Quantity[5000, "Hertz"], Quantity[10000, "Hertz"], Quantity[15000, "Hertz"]}]

使用相同的中心频率和不同的质量因子：

Wolfram Language code: Periodogram[BandpassFilter[a, {{Quantity[10000, "Hertz"], #}}, 33]& /@ {2, 4}, PlotLegends -> {2, 4}]

在各维度上使用不同的中心频率：

Wolfram Language code: BandpassFilter[[image], {{0.2, 0.45}, {0.45, 1}}]//ImageAdjust

选项  (3)

Padding  (1)

不同的填充方法导致不同的边效应：

Wolfram Language code: ramp = Range[21] / 21. + RandomReal[.1, 21]; GraphicsRow@(ListLinePlot[{ramp, BandpassFilter[ramp, {0.5, 1.5}, Padding -> #]}, ...]& /@ {"Fixed", "Periodic", 0})

SampleRate  (2)

假定样本率为 sr=1 ，使用以频率 π/2 为中心的滤波器：

Wolfram Language code: BandpassFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, {{π / 2., 1}}, 5]

假定样本率为 sr=3：

Wolfram Language code: BandpassFilter[{0, 0, 0, 1, 1, 1, 0, 0, 0}, {{3π / 2., 1}}, 5, SampleRate -> 3]

对采样率为 44100 Hz 的音频信号应用以半带频率为中心的带通滤波器：

Wolfram Language code: noise = AudioGenerator["White", 0.2]; sr = QuantityMagnitude@AudioSampleRate[noise]
Wolfram Language code: BandpassFilter[noise, {{sr π / 2., 1}}]//Periodogram

应用  (1)

在现代 88 键钢琴上，键 55（音符 C5）的基频约为 523 Hz. 使用 BandpassFilter 可有效去除此键的所有谐波，同时保留以下音频剪辑中的基波：

Wolfram Language code: key55 = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sglcp)"]\);

使用以基频 (523 Hz) 为中心、长度为 63 的窄滤波器 (Q=3)：

Wolfram Language code: f = 523; res = BandpassFilter[key55, {{2 π f, 3}}, 63]

比较两个音频片段的频谱：

Wolfram Language code: Periodogram[{key55, res}, PlotRange -> All, GridLines -> All, PlotLegends -> {"original", "filtered"}, Epilog -> {Red, InfiniteLine[{{f, 0}, {f, 1}}]}]

属性和关系  (6)

使用截止频率 0 和 π 返回原始序列：

Wolfram Language code: BandpassFilter[{0., 0., 0., 0., 1., 1., 1., 1.}, {0, Pi}]

使用 LeastSquaresFilterKernel 和 Hamming 窗创建带通滤波器：

Wolfram Language code: n = 5; ω = {1, 1.5}; win = Array[HammingWindow, n, {-1 / 2, 1 / 2}]; ker = win LeastSquaresFilterKernel[{"Bandpass", ω}, n]
Wolfram Language code: ListConvolve[ker, {0, 0, 0, 0, 1, 1, 1, 1}, Ceiling[n / 2], 0]

与 BandpassFilter 的结果比较：

Wolfram Language code: BandpassFilter[{0, 0, 0, 0, 1, 1, 1, 1}, ω, n, win, Padding -> 0]

长度为 21 的带通滤波器的冲激响应：

Wolfram Language code: h = BandpassFilter[ArrayPad[{1}, 10], {0.75, 1.5}, 21]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

滤波器的幅度谱：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

长度为 21 的、没有平滑窗口的带通滤波器的冲激响应：

Wolfram Language code: h = BandpassFilter[ArrayPad[{1}, 10], {1., 1.5}, 21, None]
Wolfram Language code: ListPlot[h, PlotRange -> All, Filling -> 0]

滤波器的幅度谱：

Wolfram Language code: Plot[Abs[ListFourierSequenceTransform[h, ω]], {ω, 0, π}]

带通滤波器的频率分辨力随着滤波器长度的增加而提高：

Wolfram Language code: Manipulate[ ListLinePlot[Abs[Fourier[BandpassFilter[ArrayPad[{1.}, 128], {Pi / 4., 3 Pi / 4.}, n, None], FourierParameters -> {1, -1}]][[ ;; 129]], ...], {{n, 21}, 3, 63, 1}]

冲激响应的长度随着滤波器品质因数的增大而增大：

Wolfram Language code: Manipulate[ListPlot[x = DeleteCases[BandpassFilter[ArrayPad[{1.}, 65], {{Pi / 2, q}}, Padding -> 0], 0.], ...], {{q, 5., "𝒬"}, 1., 13.}]

可能存在的问题  (1)

如果设置 PaddingNone，返回的输出将比输入短：

Wolfram Language code: BandpassFilter[{0, 0, 0, 1, 1, 1}, {0.5, 1.5}, Padding -> None]

互动范例  (1)

使用不同的中心频率和质量因子对一个图像进行带通滤波：

Wolfram Language code: Manipulate[BandpassFilter[[image], {{ω, q}}, 25]//ImageAdjust, {{ω, 0.5}, 0, 1.5}, {{q, 2., 𝒬}, .5, 5}]
Wolfram Research (2012)，BandpassFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BandpassFilter.html （更新于 2025 年）.

文本

Wolfram Research (2012)，BandpassFilter，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BandpassFilter.html （更新于 2025 年）.

CMS

Wolfram 语言. 2012. "BandpassFilter." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/BandpassFilter.html.

APA

Wolfram 语言. (2012). BandpassFilter. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BandpassFilter.html 年

BibTeX

@misc{reference.wolfram_2026_bandpassfilter, author="Wolfram Research", title="{BandpassFilter}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/BandpassFilter.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bandpassfilter, organization={Wolfram Research}, title={BandpassFilter}, year={2025}, url={https://reference.wolfram.com/language/ref/BandpassFilter.html}, note=[Accessed: 13-August-2026]}