WOLFRAM

Wolfram 语言与系统参考资料中心

BarLegend[cf]

生成图例，用于识别来自色彩函数 cf 的颜色，值的范围自动给定.

BarLegend[{cf,{min,max}}]

生成图例，用于识别来自色彩函数 cf 的颜色，值的范围在 min 和 max 之间.

BarLegend[cf,contours]

生成图例，用于识别来自色彩函数 cf 的颜色，值的范围基于等值线 contours 的集合.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
色彩函数  
等值线  
图形图例  
选项  
LabelStyle  
LegendFunction  
LegendLayout  
LegendLabel  
LegendMargins  
LegendMarkerSize  
参见
相关指南
历史
按以下格式引用：

BarLegend

BarLegend[cf]

生成图例，用于识别来自色彩函数 cf 的颜色，值的范围自动给定.

BarLegend[{cf,{min,max}}]

生成图例，用于识别来自色彩函数 cf 的颜色，值的范围在 min 和 max 之间.

BarLegend[cf,contours]

生成图例，用于识别来自色彩函数 cf 的颜色，值的范围基于等值线 contours 的集合.

更多信息和选项

  • BarLegend 使用与色彩函数 cf 相关联的颜色列表来识别可视化图形或其他图例项中位于 min 和 max 之间的 contours.
  • 在诸如 ContourPlot 和 ListContourPlot 等函数中，BarLegend 自动被启用.
  • 在可视化函数中，BarLegend[Automatic,…] 中的 Automatic 自动由实际色彩函数、数据范围和等值线规范（用于确定等值线的值和等值线之间的颜色）取代.
  • 在 BarLegend 中，contours 可以取以下形式：
  • nn 个等间距层的等值线
    Automatic自动选择等值线
    All全部等值线
    None无等值线
    {Automatic,n}至多 n 个自动选择的等值线
    {f1,f2,…}在层 fi 的等值线
    {{f1,gr1},…}由图形指令 gri 绘制的等值线
    func应用于 zmin, zmax 从而得到等值线列表的函数
  • BarLegend[cf,contours] 可以使用颜色列表或取决于等值线数值的密度的连续色谱.
  • Legended[expr,BarLegend[…]] 可用于将图例应用于任意表达式 expr.
  • 可以给出以下选项：
  • LabelStyle Automatic标签所用的样式
    LegendFunction Identity用于全局图例的封装
    LegendLabel None图例的全局标签
    LegendLayout Automatic图例布局
    LegendMargins Automatic图例内容和边界之间的空间
    LegendMarkersNone用于表示每个元素的标记
    LegendMarkerSize Automatic形状的尺寸
  • BarLegend 在 StandardForm 中显示为图形对象. 在 InputForm 中，它显示为色彩函数、数据范围的等值线数值的显式列表.
  • 在 BarLegend 中，LegendLayout 可取以下形式：
  • Automatic自动确定布局
    "Row"在水平行中显示图例
    "Column"在垂直列中显示图例
  • 在 LineLegend 中，LegendLayout 可取以下形式：
  • Automatic自动确定布局
    "Row"在水平行中显示图例
    "Column"在垂直列中显示图例
    "ReversedRow"在水平行中显示逆向图例
    "ReversedColumn"在垂直列中显示逆向图例
  • LegendFunction 被应用于图例，包括所有全局标签和边幅.

范例

打开所有单元 关闭所有单元

基本范例  (7)

连续梯度条：

Wolfram Language code: BarLegend["Rainbow"]

指定数据范围：

Wolfram Language code: BarLegend[{"DeepSeaColors", {-2, 2}}]

选取5个等间距的等值线：

Wolfram Language code: BarLegend[{"SolarColors", {0, 1}}, 5]

使用色彩方案：

Wolfram Language code: BarLegend[{"Rainbow", {0, 1}}]

使用 Hue：

Wolfram Language code: BarLegend[{Hue, {0, 1}}]

使用 GrayLevel：

Wolfram Language code: BarLegend[{GrayLevel, {0, 1}}]

为图形生成自动图例：

Wolfram Language code: ContourPlot[Sin[x y], {x, 0, π}, {y, 0, π}, Contours -> 5, PlotLegends -> Automatic]

范围  (22)

色彩函数  (4)

使用已命名色彩方案：

Wolfram Language code: BarLegend["AvocadoColors"]

指定色彩函数的范围：

Wolfram Language code: BarLegend[{"AvocadoColors", {0, 100}}]

使用色彩列表和数目匹配的等值线：

Wolfram Language code: BarLegend[{{Red, Orange, Yellow, White, Green, Blue}, {-1, 1}}, {-1, -(2/3), -(1/3), 0, (1/3), (2/3), 1}]

混合色彩列表以匹配等值线：

Wolfram Language code: BarLegend[{{Red, Orange, Yellow, White, Green, Blue}, {-1, 1}}, 8]

使用函数：

Wolfram Language code: BarLegend[{Hue[#]&, {0, 1}}]

等值线  (10)

自动选择等值线：

Wolfram Language code: BarLegend["LakeColors", Automatic]

选取5个等间距的等值线：

Wolfram Language code: BarLegend["LakeColors", 5]

显式指定等值线集合：

Wolfram Language code: BarLegend["LakeColors", {0.2, 0.4, 0.6, 0.8}]

自动选取至多10个等值线：

Wolfram Language code: BarLegend["LakeColors", {Automatic, 10}]

当等值线密集时，BarLegend 使用连续梯度：

Wolfram Language code: BarLegend["LakeColors", 20]

指定数据范围：

Wolfram Language code: BarLegend[{"LakeColors", {0.2, 0.78}}, Automatic]

使用函数确定等值线：

Wolfram Language code: fivecontours = Function[{min, max}, Range[min, max, (max - min) / 5]];
Wolfram Language code: BarLegend[{"Rainbow", {-2, 2}}, fivecontours]

BarLegend 有选择地标记等值线：

Wolfram Language code: ContourPlot[Sin[x]Cos[y], {x, 0, 2Pi}, {y, 0, 2Pi}, PlotLegends -> Automatic, Contours -> {Automatic, 10}]

使用 All 标记全部等值线：

Wolfram Language code: ContourPlot[Sin[x]Cos[y], {x, 0, 2Pi}, {y, 0, 2Pi}, PlotLegends -> BarLegend[Automatic, All], Contours -> {Automatic, 10}]

使用 None 绘制连续梯度：

Wolfram Language code: ContourPlot[Sin[x]Cos[y], {x, 0, 2Pi}, {y, 0, 2Pi}, Contours -> {Automatic, 10}, PlotLegends -> BarLegend[Automatic, None]]

图形图例  (8)

密度和等值线图使用 BarLegend：

Wolfram Language code: {DensityPlot[Cos[x y], {x, 0, π}, {y, 0, π}, PlotLegends -> Automatic], ContourPlot[Cos[x y], {x, 0, π}, {y, 0, π}, PlotLegends -> Automatic]}

用 Placed 改变图例位置：

Wolfram Language code: ContourPlot[Cos[x y], {x, 0, π}, {y, 0, π}, PlotLegends -> Placed[Automatic, Below]]

BarLegend 根据长宽比自动改变位置和大小：

Wolfram Language code: ContourPlot[Cos[x y], {x, 0, π}, {y, 0, π}, AspectRatio -> 1 / 2, ImageSize -> 200, PlotLegends -> Automatic]
Wolfram Language code: ContourPlot[Cos[x Sin[y]], {x, 0, π}, {y, 0, π}, AspectRatio -> 2, ImageSize -> {Automatic, 200}, PlotLegends -> Automatic]

BarLegend 自动选取 ColorFunction 和 ColorFunctionScaling 的值：

Wolfram Language code: ContourPlot[Cos[x y], {x, 0, π}, {y, 0, π}, ColorFunction -> "Rainbow", ColorFunctionScaling -> False, PlotLegends -> Automatic]

BarLegend 自动选取等值线的值：

Wolfram Language code: ContourPlot[Cos[x y], {x, 0, π}, {y, 0, π}, Contours -> {0., 0.2, 0.4, 0.6, 0.8, 1.}, PlotLegends -> Automatic]

BarLegend 包括指定的等值线样式：

Wolfram Language code: ContourPlot[Cos[x y], {x, 0, π}, {y, 0, π}, Contours -> {0., {0.2, Red}, 0.4, {0.6, Blue}, 0.8, 1}, PlotLegends -> Automatic]

BarLegend 匹配等值线之间的阴影样式：

Wolfram Language code: ContourPlot[Sin[x]Sin[y], {x, -3, 3}, {y, -3, 3}, Contours -> 3, ContourShading -> {Red, Green, Yellow, Blue}, PlotLegends -> All]

使用 BarLegend 给自动计算的图例指定标签和边框：

Wolfram Language code: ContourPlot[Sin[x]Sin[y], {x, -3, 3}, {y, -3, 3}, PlotLegends -> Placed[BarLegend[Automatic, LegendMarkerSize -> 150, LegendFunction -> (Framed[#, RoundingRadius -> 5]&), LegendLabel -> "z-value"], {After, Top}]]

选项  (19)

LabelStyle  (3)

所有标签具有相同的默认样式：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendLabel -> "legend"]

指定标签样式：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LabelStyle -> Red]

LabelStyle 应用于 LegendLabel：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LabelStyle -> Directive[Gray, FontSize -> 18, Bold], LegendLabel -> "legend"]

LegendFunction  (5)

使用边框：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> "Frame"]

使用面板：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> "Panel"]

使用任意函数：

Wolfram Language code: container[legend_] := Tooltip[legend, "legend"]
Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> container]

使用样式化的边：

Wolfram Language code: frame[legend_] := Framed[legend, FrameStyle -> Red, RoundingRadius -> 10, FrameMargins -> 10, Background -> StandardGray]
Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> frame]

使用阴影框：

Wolfram Language code: shadowbox[legend_] := Graphics[{{Gray, Rectangle[Scaled[{0.05, -0.05}], Scaled[{1.1, 0.95}]]}, {StandardBrown, EdgeForm[Gray], Rectangle[Scaled[{0, 0}], Scaled[{1, 1}]]}, Inset[legend, Scaled[{0.5, 0.5}], Center, Scaled[{1, 0.9}]]}, ImageSize -> {60, 200}, AspectRatio -> Full]
Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, 5, LegendFunction -> shadowbox]

LegendLayout  (1)

以行或列的形式绘制图例：

Wolfram Language code: Table[BarLegend[{"LakeColors", {0, 1}}, LegendLayout -> ly, LegendLabel -> ly], {ly, {"Row", "Column"}}]

LegendLabel  (5)

给出图例标签：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendLabel -> "legend"]

图例标签位于图例箱之内：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> "Frame", LegendLabel -> "legend"]

使用 Placed 在边框内部放置图例标签：

Wolfram Language code: Table[BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> "Frame", LegendLabel -> Placed["legend", pos]], {pos, {Left, Top, Bottom, Right}}]

使用 Placed 在边框外部放置图例标签：

Wolfram Language code: Table[BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> "Frame", LegendLabel -> Placed["legend", pos]], {pos, {Before, Above, Below, After}}]

在 Placed 中使用第三个参数旋转图例标签：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> "Frame", LegendLabel -> Placed["legend", Left, Rotate[#, 90Degree]&]]

LegendMargins  (3)

内容与边界之间无边幅：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> "Frame", LegendMargins -> 0]

指定到全部边界的相同边幅：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendFunction -> "Frame", LegendMargins -> 10]

指定到边界的不同边幅：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, LegendMargins -> {{10, 0}, {20, 10}}, LegendFunction -> Framed]

LegendMarkerSize  (2)

自动尺寸：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}]

指定分区的数量：

Wolfram Language code: BarLegend[{"LakeColors", {0, 1}}, 3]

指定 LegendMarkerSize：

Wolfram Language code: Table[BarLegend[{"LakeColors", {0, 1}}, LegendMarkerSize -> size], {size, {100, 200, 300}}]//Row
Wolfram Research (2012)，BarLegend，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BarLegend.html.

文本

Wolfram Research (2012)，BarLegend，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BarLegend.html.

CMS

Wolfram 语言. 2012. "BarLegend." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BarLegend.html.

APA

Wolfram 语言. (2012). BarLegend. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BarLegend.html 年

BibTeX

@misc{reference.wolfram_2026_barlegend, author="Wolfram Research", title="{BarLegend}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BarLegend.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_barlegend, organization={Wolfram Research}, title={BarLegend}, year={2012}, url={https://reference.wolfram.com/language/ref/BarLegend.html}, note=[Accessed: 10-August-2026]}