BesselK

BesselK[n,z]

第2種変形ベッセル関数を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
は，微分方程式を満足させる．
BesselK[n,z]は，複素 z 平面上，〜の範囲で不連続な分枝切断線を持つ．
FullSimplifyとFunctionExpandはBesselKの変換規則を含む．
特別な引数の場合，BesselKは，自動的に厳密値を計算する．
BesselKは任意の数値精度で評価できる．
BesselKは自動的にリストに縫い込まれる．
BesselKはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: BesselK[0, 0.53]

実数の部分集合上でをプロットする：

Wolfram Language code: Plot[BesselK[0, x], {x, 0.5, 3}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[BesselK[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[BesselK[0, x], {x, 0, 3}]

Infinityにおける級数展開：

Wolfram Language code: Series[BesselK[0, x], {x, ∞, 4}]//Normal

スコープ (45)

数値評価 (6)

数値的に評価する：

Wolfram Language code: BesselK[0, 4.0]

高精度で評価する：

Wolfram Language code: N[BesselK[0, 4], 50]

出力精度は入力精度に従う：

Wolfram Language code: BesselK[1, 4.000000000000000000000000000000000000]

複素引数とパラメータについて評価する：

Wolfram Language code: BesselK[1 + I, 3.0 - 2I]

BesselKを高精度で効率よく評価する：

Wolfram Language code: BesselK[0, 4`500]//Timing

Wolfram Language code: BesselK[0, 4`5000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: BesselK[1 / 2, Interval[{2.15, 2.16}]]

Wolfram Language code: BesselK[1 / 2, CenteredInterval[2, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: BesselK[2, Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: BesselK[0.5, {{1, 2}, {3, 4}}]

MatrixFunctionを使って行列のBesselK関数を計算することもできる：

Wolfram Language code: MatrixFunction[BesselK[0.5, #]&, {{1, 2}, {3, 4}}]

特定の値 (4)

における整数次数() についてのBesselKの値：

Wolfram Language code: {BesselK[0, 0], BesselK[1, 0]}

半整数の指標について，BesselKを評価すると初等関数になる：

Wolfram Language code: Table[BesselK[(2n - 1/2), x], {n, 1, 3}]

無限大における極限値：

Wolfram Language code: Limit[BesselK[n, x], x -> Infinity]

方程式を満足するの値を求める：

Wolfram Language code: sol = Solve[BesselK[0, x] == 2, x]//Quiet

結果を可視化する：

Wolfram Language code:

xzero = x /. First[sol];
Plot[BesselK[0, x], {x, 0, 1}, Epilog -> Style[Point[{xzero, BesselK[0, xzero]}], Red, PointSize[Large]]]

可視化 (3)

整数次数()でBesselK関数をプロットする：

Wolfram Language code: Plot[{BesselK[0, x], BesselK[1, x]}, {x, 0, 5}]

BesselK関数の実部と虚部を整数次数()についてプロットする：

Wolfram Language code: ReImPlot[{BesselK[0, x], BesselK[1, x]}, {x, -3, 3}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[BesselK[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[BesselK[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

関数の特性 (11)

は0より大きいすべての実数値について定義される：

Wolfram Language code: FunctionDomain[BesselK[n, x], x]

複素領域：

Wolfram Language code: FunctionDomain[BesselK[n, z], z, Complexes]

は実数についてすべての正の実数値に達する：

Wolfram Language code: FunctionRange[BesselK[π, x], x, y]

BesselKは，第1パラメータについて偶関数である：

Wolfram Language code: BesselK[-n, z]//FullSimplify

は解析関数ではない：

Wolfram Language code: Table[FunctionAnalytic[BesselK[n, z], z], {n, -2, 2}]

BesselKは非減少でも非増加でもない：

Wolfram Language code: Table[FunctionMonotonicity[BesselK[n, z], z], {n, 5}]

Wolfram Language code: Table[FunctionMonotonicity[BesselK[1 / n, z], z], {n, 5}]

はすべての実数について単射である：

Wolfram Language code: FunctionInjective[BesselK[n, z], z, Assumptions -> n∈Reals]

Wolfram Language code: Plot[{BesselK[1, z], BesselK[2, z], BesselK[1 / 3, z], .5}, {z, 0, 5}]

は任意の実数について全射ではない：

Wolfram Language code: FunctionSurjective[BesselK[n, z], z, Assumptions -> n∈Reals]

Wolfram Language code: Plot[{BesselK[1, z], BesselK[2, z], BesselK[1 / 3, z], -1}, {z, 0, 5}]

BesselKは非負でも非正でもない：

Wolfram Language code: Table[FunctionSign[BesselK[n, z], z], {n, 4}]

BesselKは z≤0のとき特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[BesselK[n, z], z]

Wolfram Language code: FunctionDiscontinuities[BesselK[n, z], z]

は実数領域で凸である：

Wolfram Language code: FunctionConvexity[{BesselK[n, z], z > 0}, z, Assumptions -> n∈Reals]

TraditionalFormによる表示：

Wolfram Language code: BesselK[n, r]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[BesselK[n, x], x]

高次導関数：

Wolfram Language code: derivs = Table[D[BesselK[n, x], {x, k}], {k, 1, 4}]

次数について高次導関数をプロットする：

Wolfram Language code:

Plot[Evaluate[derivs /. n -> 0], {x, 0, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[BesselK[n, x], {x, j}]

積分 (3)

BesselKの不定積分：

Wolfram Language code: Integrate[BesselK[n, x], x]

BesselKを含むIntegrate式：

Wolfram Language code: Integrate[x^n BesselK[0, x], {x, 0, Infinity}, Assumptions -> n ≥ 0]

Wolfram Language code: Integrate[BesselJ[n, x] BesselK[n, x], x]

実領域上でのBesselKの定積分：

Wolfram Language code: Integrate[BesselK[n, x], {x, 0, Infinity}]

級数展開 (5)

の周りのの級数展開：

Wolfram Language code: Series[BesselK[0, x], {x, 0, 5}]

の周りのの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[BesselK[0, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{BesselK[0, x], terms}, {x, 0, 3}]

BesselKの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[BesselK[0, x], {x, 1, n}]

BesselKについての漸近展開：

Wolfram Language code: Series[BesselK[n, x], {x, Infinity, 2}]//Normal

生成点におけるテイラー(Taylor)展開：

Wolfram Language code: Series[BesselK[n, x], {x, x0, 2}]// FullSimplify

BesselKはベキ級数に適用できる：

Wolfram Language code: BesselK[0, Log[1 + x] + O[x] ^ 2]

積分変換 (3)

LaplaceTransform：

Wolfram Language code: LaplaceTransform[BesselK[n, t], t, s]

HankelTransform：

Wolfram Language code: HankelTransform[BesselK[n, r], r, s ]

MellinTransformを使ってメリン(Mellin)変換を計算する：

Wolfram Language code: MellinTransform[BesselK[n, x], x, s ]

関数の恒等式と簡約 (3)

FullSimplifyを使ってベッセル関数を簡約する：

Wolfram Language code: FullSimplify[x BesselK[2, x] - x BesselK[0, x]]

恒等式を確かめる：

Wolfram Language code: BesselI[ν, z] BesselK[ν + 1, z] + BesselI[ν + 1, z] BesselK[ν, z] == (1/z)//FullSimplify

漸化式：

Wolfram Language code: FullSimplify[z(BesselK[n + 1, z] - BesselK[n - 1, z]) == 2n BesselK[n, z]]

関数表現 (4)

BesselKの積分表現：

Wolfram Language code: (Sqrt[π]z^n/2^nGamma[n + (1/2)])Integrate[Exp[-z t](t^2 - 1)^n - (1/2), {t, 1, Infinity}]

BesselIとSinを使って表す：

Wolfram Language code: FullSimplify[(Pi/2)(BesselI[-n, x] - BesselI[n, x]/Sin[n Pi])]

BesselKはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[BesselK[n, x], x]

Wolfram Language code: Activate[%]

BesselKはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[BesselK[k, z], k]

アプリケーション (3)

1粒子あたりの相対論的な理想気体の比熱：

Wolfram Language code: cv[β_] := 3 + β(β - (BesselK[1, β]/BesselK[2, β])(3 + β (BesselK[1, β]/BesselK[2, β])))

超相対論的な極限を求める：

Wolfram Language code: Series[cv[β], {β, 0, 4}, Assumptions -> β > 0]

2つのランダムな独立指数変数の幾何平均のPDF：

Wolfram Language code:

PDF[TransformedDistribution[GeometricMean[{x, y}], {xExponentialDistribution[λ], yExponentialDistribution[μ]}], z]

Wolfram Language code: FullSimplify[%]

濃度 y の関数としての電解質溶液の表面張力：

Wolfram Language code:

2 BesselK[0, 2Sqrt[y]]HypergeometricPFQ[{1}, {2 / 3, 5 / 3}, y] + 3Sqrt[y]BesselK[1, 2Sqrt[y]]HypergeometricPFQ[{1}, {5 / 3, 5 / 3}, y];

低濃度についてのオンサーガー(Onsager)の法則：

Wolfram Language code: Normal[Series[%, {y, 0, 0}, Assumptions -> y > 0]]

特性と関係 (2)

FullSimplifyを使ってベッセル関数を簡約する：

Wolfram Language code: FullSimplify[x BesselK[2, x] - x BesselK[0, x]]

BesselKの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[BesselK[n, k], n, x]

考えられる問題 (1)

数値引数の場合，半整数のベッセル関数は自動的には評価されない：

Wolfram Language code: BesselK[11 / 2, 1]

記号引数の場合には評価される：

Wolfram Language code: BesselK[11 / 2, x]

次は，機械精度の評価では不正確になることがある：

Wolfram Language code: {BesselK[55 / 2, -20.], BesselK[55 / 2, x] /. x -> -20.}

おもしろい例題 (1)

のリーマン(Riemann)面をプロットする：

Wolfram Language code:

With[{n = 0, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[(-1)^n kBesselK[n, r Exp[I φ]] + (-1)^n(k - 1) - 1π I k BesselI[n, r Exp[I φ]]]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.46], Opacity[0.6]]]]

のリーマン面をプロットする：

Wolfram Language code:

With[{ν = 1 / 3, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[-k ν π I] BesselK[ν, r Exp[I φ]] - π I ChebyshevU[k - 1, Cos[ν π]] BesselI[ν, r Exp[I φ]]]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.23], Opacity[0.6]]]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

BesselK

詳細

例題

例 (5)

スコープ (45)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (11)

微分 (3)

積分 (3)

級数展開 (5)

積分変換 (3)

関数の恒等式と簡約 (3)

関数表現 (4)

アプリケーション (3)

特性と関係 (2)

考えられる問題 (1)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

BesselK

詳細

例題

例 (5)

スコープ (45)

数値評価 (6)

特定の値 (4)

可視化 (3)

関数の特性 (11)

微分 (3)

積分 (3)

級数展開 (5)

積分変換 (3)

関数の恒等式と簡約 (3)

関数表現 (4)

アプリケーション (3)

特性と関係 (2)

考えられる問題 (1)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX