WOLFRAM

Wolfram 语言与系统参考资料中心

BesselK[n,z]

给出第二类修正贝塞尔函数 TemplateBox[{n, z}, BesselK].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
积分变换  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

BesselK

BesselK[n,z]

给出第二类修正贝塞尔函数 TemplateBox[{n, z}, BesselK].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值化计算：

Wolfram Language code: BesselK[0, 0.53]

在实数的子集上绘制 ：

Wolfram Language code: Plot[BesselK[0, x], {x, 0.5, 3}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[BesselK[1 / 2, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[BesselK[0, x], {x, 0, 3}]

在 Infinity 的级数展开：

Wolfram Language code: Series[BesselK[0, x], {x, ∞, 4}]//Normal

范围  (45)

数值运算  (6)

进行数值运算：

Wolfram Language code: BesselK[0, 4.0]

高精度求值：

Wolfram Language code: N[BesselK[0, 4], 50]

输出精度与输入精度一致：

Wolfram Language code: BesselK[1, 4.000000000000000000000000000000000000]

对复变量和参量求值：

Wolfram Language code: BesselK[1 + I, 3.0 - 2I]

在高精度条件下高效计算 BesselK：

Wolfram Language code: BesselK[0, 4`500]//Timing
Wolfram Language code: BesselK[0, 4`5000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证区间：

Wolfram Language code: BesselK[1 / 2, Interval[{2.15, 2.16}]]
Wolfram Language code: BesselK[1 / 2, CenteredInterval[2, 1 / 100]]

或使用 Around 计算平均情况下的统计区间：

Wolfram Language code: BesselK[2, Around[2, 0.01]]

计算数组的逐元素数值：

Wolfram Language code: BesselK[0.5, {{1, 2}, {3, 4}}]

或使用 MatrixFunction 计算矩阵 BesselK 函数：

Wolfram Language code: MatrixFunction[BesselK[0.5, #]&, {{1, 2}, {3, 4}}]

特殊值  (4)

整数 () 阶数的 BesselK 函数在 处的值：

Wolfram Language code: {BesselK[0, 0], BesselK[1, 0]}

对于半整数指数，BesselK 求解为初等函数：

Wolfram Language code: Table[BesselK[(2n - 1/2), x], {n, 1, 3}]

无穷处的极限值：

Wolfram Language code: Limit[BesselK[n, x], x -> Infinity]

求满足方程 TemplateBox[{0, x}, BesselK]=2 的 TemplateBox[{0, x}, BesselK] 的值：

Wolfram Language code: sol = Solve[BesselK[0, x] == 2, x]//Quiet

可视化结果：

Wolfram Language code: xzero = x /. First[sol]; Plot[BesselK[0, x], {x, 0, 1}, Epilog -> Style[Point[{xzero, BesselK[0, xzero]}], Red, PointSize[Large]]]

可视化  (3)

绘制整数 () 阶数的 BesselK 函数：

Wolfram Language code: Plot[{BesselK[0, x], BesselK[1, x]}, {x, 0, 5}]

绘制整数阶 () 的 BesselK 函数的实部和虚部：

Wolfram Language code: ReImPlot[{BesselK[0, x], BesselK[1, x]}, {x, -3, 3}]

绘制 TemplateBox[{0, z}, BesselK] 的实部：

Wolfram Language code: ComplexContourPlot[Re[BesselK[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{0, z}, BesselK] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[BesselK[0, z]], {z, -4 - 4I, 4 + 4I}, IconizedObject[«PlotOptions»]]

函数属性  (11)

是针对所有大于 0 的实数定义的：

Wolfram Language code: FunctionDomain[BesselK[n, x], x]

复定义域：

Wolfram Language code: FunctionDomain[BesselK[n, z], z, Complexes]

对于实数 ，TemplateBox[{n, x}, BesselK] 的值域为所有正实数：

Wolfram Language code: FunctionRange[BesselK[π, x], x, y]

相对于第一个参数而言，BesselK 是一个偶函数：

Wolfram Language code: BesselK[-n, z]//FullSimplify

TemplateBox[{n, z}, BesselK] 不是解析函数：

Wolfram Language code: Table[FunctionAnalytic[BesselK[n, z], z], {n, -2, 2}]

BesselK 既不是非递增，也不是非递减:

Wolfram Language code: Table[FunctionMonotonicity[BesselK[n, z], z], {n, 5}]
Wolfram Language code: Table[FunctionMonotonicity[BesselK[1 / n, z], z], {n, 5}]

为实数时，TemplateBox[{n, z}, BesselK] 是单射函数：

Wolfram Language code: FunctionInjective[BesselK[n, z], z, Assumptions -> n∈Reals]
Wolfram Language code: Plot[{BesselK[1, z], BesselK[2, z], BesselK[1 / 3, z], .5}, {z, 0, 5}]

为实数时，TemplateBox[{n, z}, BesselK] 不是满射函数：

Wolfram Language code: FunctionSurjective[BesselK[n, z], z, Assumptions -> n∈Reals]
Wolfram Language code: Plot[{BesselK[1, z], BesselK[2, z], BesselK[1 / 3, z], -1}, {z, 0, 5}]

BesselK 既不是非负，也不是非正：

Wolfram Language code: Table[FunctionSign[BesselK[n, z], z], {n, 4}]

对于 z≤0，BesselK 有奇点和断点：

Wolfram Language code: FunctionSingularities[BesselK[n, z], z]
Wolfram Language code: FunctionDiscontinuities[BesselK[n, z], z]

在实定义域上，TemplateBox[{n, z}, BesselK] 是凸函数：

Wolfram Language code: FunctionConvexity[{BesselK[n, z], z > 0}, z, Assumptions -> n∈Reals]

TraditionalForm 格式：

Wolfram Language code: BesselK[n, r]//TraditionalForm

微分  (3)

一阶导数：

Wolfram Language code: D[BesselK[n, x], x]

高阶导数：

Wolfram Language code: derivs = Table[D[BesselK[n, x], {x, k}], {k, 1, 4}]

绘制阶数 时的高阶导数：

Wolfram Language code: Plot[Evaluate[derivs /. n -> 0], {x, 0, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[BesselK[n, x], {x, j}]

积分  (3)

BesselK 函数的不定积分：

Wolfram Language code: Integrate[BesselK[n, x], x]

Integrate 含有 BesselK 的表达式：

Wolfram Language code: Integrate[x^n BesselK[0, x], {x, 0, Infinity}, Assumptions -> n ≥ 0]
Wolfram Language code: Integrate[BesselJ[n, x] BesselK[n, x], x]

BesselK 在实数域上的定积分：

Wolfram Language code: Integrate[BesselK[n, x], {x, 0, Infinity}]

级数展开式  (5)

在 处的展开式：

Wolfram Language code: Series[BesselK[0, x], {x, 0, 5}]

绘制 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[BesselK[0, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{BesselK[0, x], terms}, {x, 0, 3}]

BesselK 的级数展开式的通项：

Wolfram Language code: SeriesCoefficient[BesselK[0, x], {x, 1, n}]

BesselK 的渐近展开式：

Wolfram Language code: Series[BesselK[n, x], {x, Infinity, 2}]//Normal

常点处的泰勒展开式：

Wolfram Language code: Series[BesselK[n, x], {x, x0, 2}]// FullSimplify

BesselK 可被应用于幂级数：

Wolfram Language code: BesselK[0, Log[1 + x] + O[x] ^ 2]

积分变换  (3)

LaplaceTransform:

Wolfram Language code: LaplaceTransform[BesselK[n, t], t, s]

HankelTransform:

Wolfram Language code: HankelTransform[BesselK[n, r], r, s ]

用 MellinTransform 计算 Mellin 变换：

Wolfram Language code: MellinTransform[BesselK[n, x], x, s ]

函数恒等式和化简  (3)

用 FullSimplify 化简贝塞尔函数：

Wolfram Language code: FullSimplify[x BesselK[2, x] - x BesselK[0, x]]

验证恒等式 TemplateBox[{nu, z}, BesselI] TemplateBox[{{nu, +, 1}, z}, BesselK]+TemplateBox[{{nu, +, 1}, z}, BesselI] TemplateBox[{nu, z}, BesselK]=1/z：

Wolfram Language code: BesselI[ν, z] BesselK[ν + 1, z] + BesselI[ν + 1, z] BesselK[ν, z] == (1/z)//FullSimplify

递推关系式 z (TemplateBox[{{n, +, 1}, z}, BesselK]-TemplateBox[{{n, -, 1}, z}, BesselK])=2 n TemplateBox[{n, z}, BesselK]：

Wolfram Language code: FullSimplify[z(BesselK[n + 1, z] - BesselK[n - 1, z]) == 2n BesselK[n, z]]

函数表示  (4)

BesselK 的积分表示：

Wolfram Language code: (Sqrt[π]z^n/2^nGamma[n + (1/2)])Integrate[Exp[-z t](t^2 - 1)^n - (1/2), {t, 1, Infinity}]

用 BesselI 和 Sin 表示：

Wolfram Language code: FullSimplify[(Pi/2)(BesselI[-n, x] - BesselI[n, x]/Sin[n Pi])]

可用 MeijerG 表示BesselK：

Wolfram Language code: MeijerGReduce[BesselK[n, x], x]
Wolfram Language code: Activate[%]

可用 DifferenceRoot 表示BesselK：

Wolfram Language code: DifferenceRootReduce[BesselK[k, z], k]

应用  (3)

单个粒子的相对论理想气体比热：

Wolfram Language code: cv[β_] := 3 + β(β - (BesselK[1, β]/BesselK[2, β])(3 + β (BesselK[1, β]/BesselK[2, β])))

求超相对论极限：

Wolfram Language code: Series[cv[β], {β, 0, 4}, Assumptions -> β > 0]

两个独立指数随机变量几何平均数的 PDF：

Wolfram Language code: PDF[TransformedDistribution[GeometricMean[{x, y}], {xExponentialDistribution[λ], yExponentialDistribution[μ]}], z]
Wolfram Language code: FullSimplify[%]

电解质溶液的表面张力与浓度 y 的函数关系：

Wolfram Language code: 2 BesselK[0, 2Sqrt[y]]HypergeometricPFQ[{1}, {2 / 3, 5 / 3}, y] + 3Sqrt[y]BesselK[1, 2Sqrt[y]]HypergeometricPFQ[{1}, {5 / 3, 5 / 3}, y];

小浓度的 Onsager 定律：

Wolfram Language code: Normal[Series[%, {y, 0, 0}, Assumptions -> y > 0]]

属性和关系  (2)

用 FullSimplify 简化贝塞尔函数：

Wolfram Language code: FullSimplify[x BesselK[2, x] - x BesselK[0, x]]

BesselK 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[BesselK[n, k], n, x]

可能存在的问题  (1)

对于数值自变量，半整数贝塞尔函数不能自动求值：

Wolfram Language code: BesselK[11 / 2, 1]

若自变量为符号，则为：

Wolfram Language code: BesselK[11 / 2, x]

这将致使机器精度求值中存在大误差：

Wolfram Language code: {BesselK[55 / 2, -20.], BesselK[55 / 2, x] /. x -> -20.}

巧妙范例  (1)

绘制 TemplateBox[{0, z}, BesselK] 的黎曼曲面：

Wolfram Language code: With[{n = 0, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[(-1)^n kBesselK[n, r Exp[I φ]] + (-1)^n(k - 1) - 1π I k BesselI[n, r Exp[I φ]]]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.46], Opacity[0.6]]]]

绘制 TemplateBox[{{1, /, 3}, z}, BesselK] 的黎曼曲面：

Wolfram Language code: With[{ν = 1 / 3, ε = 1*^-12}, ParametricPlot3D[Table[{r Cos[φ], r Sin[φ], Im[Exp[-k ν π I] BesselK[ν, r Exp[I φ]] - π I ChebyshevU[k - 1, Cos[ν π]] BesselI[ν, r Exp[I φ]]]}, {k, -2, 2}], {r, ε, 3}, {φ, -π + ε, π - ε}, BoxRatios -> {1, 1, 2.5}, Mesh -> None, PlotStyle -> Directive[Hue[0.23], Opacity[0.6]]]]
Wolfram Research (1988)，BesselK，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BesselK.html （更新于 2022 年）.

文本

Wolfram Research (1988)，BesselK，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BesselK.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "BesselK." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/BesselK.html.

APA

Wolfram 语言. (1988). BesselK. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BesselK.html 年

BibTeX

@misc{reference.wolfram_2026_besselk, author="Wolfram Research", title="{BesselK}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/BesselK.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_besselk, organization={Wolfram Research}, title={BesselK}, year={2022}, url={https://reference.wolfram.com/language/ref/BesselK.html}, note=[Accessed: 16-September-2026]}