WOLFRAM

Wolfram 语言与系统参考资料中心

BezierCurve[{pt1,pt2,…}]

图形基元，表示控制点为 pti 的贝塞尔曲线.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
指定  
图形  
区域  
选项  
SplineDegree  
SplineClosed  
应用  
字体  
向量图形  
属性和关系  
互动范例  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BezierCurve

BezierCurve[{pt1,pt2,…}]

图形基元，表示控制点为 pti 的贝塞尔曲线.

更多信息和选项

  • BezierCurve 也被称为贝塞尔样条曲线或伯恩斯坦多项式曲线.
  • BezierCurve 通常用于表示字体和矢量图形中的曲线路径.
  • 控制点 pi 是诸如 {x,y} 或 {x,y,z} 这样的普通坐标.
  • BezierCurve[{p1,p2,p3,p4}] 表示一条简单的三次贝塞尔曲线.
  • 具有超过四个控制点的 BezierCurve 表示一条复合三次贝塞尔曲线.
  • 通过使用多个贝塞尔线段，复合曲线可表示更多样化的形状.
  • BezierCurve 既可用作几何区域，也可用作图形基元.
  • 在图形中，点 pi 可以是 Scaled、Offset、ImageScaled 和 Dynamic 表达式.
  • 图形渲染受诸如 Thickness、Dashing、JoinForm、CapForm 以及颜色等指令的影响.
  • 可给出下列选项：
  • SplineDegree Automatic多项式基的次数
    SplineClosed False是否使曲线闭合
  • 选项 SplineDegree->d 指定底层多项式基的最大次数为 d.
  • SplineDegree->d 时，有 d+1 个控制点的 BezierCurve 产生一个简单的 d 次 Bézier 曲线. 控制点较少时，产生一个较低次数的曲线. 控制点较多时，则产生一个复合 Bézier 曲线.
  • 具有 n 个控制点的 d 次 BezierCurve 表示区域 {}，其中，B_(k,d) 是第 k 个 d 次 Bernstein 基函数.

范例

打开所有单元 关闭所有单元

基本范例  (3)

二维图形中的一个 Bézier 曲线和它的控制点：

Wolfram Language code: pts = {{0, 0}, {1, 1}, {2, -1}, {3, 0}};
Wolfram Language code: Graphics[{BezierCurve[pts], Dashed, Gray, Line[pts], Red, Point[pts]}]

三维图形中的一个 Bézier 曲线和它的控制点：

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, 1}, {2, -1, 1}, {3, 0, 2}}
Wolfram Language code: Graphics3D[{BezierCurve[pts], Dashed, Gray, Line[pts], Red, Point[pts]}]

弧长和界限：

Wolfram Language code: reg = BezierCurve[{{0, 0}, {1, 1}, {2, -1}}];
Wolfram Language code: ArcLength[reg]
Wolfram Language code: RegionBounds[reg]

用 Bézier 曲线构建的字母 "S"：

Wolfram Language code: Graphics[{LinearGradientFilling[{StandardRed, StandardYellow}], EdgeForm[Thick], FilledCurve[BezierCurve[IconizedObject[«[image]»]]]}]

范围  (26)

基本用法  (4)

模拟线性曲线：

Wolfram Language code: Graphics[BezierCurve[{{0, 0}, {2, 1}}]]

非线性曲线：

Wolfram Language code: Graphics[BezierCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]]

模拟开放曲线：

Wolfram Language code: Graphics[BezierCurve[{{-1, 3}, {-2, 0}, {2, 0}, {1, 3}}]]

闭合曲线：

Wolfram Language code: Graphics[BezierCurve[{{0, 1}, {-1, 0}, {1, 0}}, SplineClosed -> True]]

模拟填充曲线：

Wolfram Language code: Graphics[{FilledCurve[BezierCurve[IconizedObject[«[image]»]]]}]

未填充曲线：

Wolfram Language code: Graphics[BezierCurve[IconizedObject[«[image]»]]]

摘要框：

Wolfram Language code: BezierCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]

指定  (4)

二次贝塞尔曲线需要三个控制点：

Wolfram Language code: Graphics[BezierCurve[{{-1, 0}, {0, 2}, {1, 0}}]]
Wolfram Language code: Graphics3D[BezierCurve[{{-1, 0, 0}, {0, 2, 1}, {1, 0, 0}}]]

三次贝塞尔曲线需要四个控制点：

Wolfram Language code: Graphics[BezierCurve[{{-3, 0}, {6, 5}, {-6, -5}, {3, 0}}]]
Wolfram Language code: Graphics3D[BezierCurve[{{-3, -1, 0}, {6, 5, 5}, {-6, -5, -5}, {3, 1, 0}}]]

通常，一条简单的次数为 d 的贝塞尔样条曲线需要 (d+1) 个控制点：

Wolfram Language code: pts = {{0, 0}, {(1/3), (Sqrt[3]/2)}, {(2/3), (Sqrt[3]/2)}, {1, 0}, {(4/3), (Sqrt[3]/2)}, {(5/3), (Sqrt[3]/2)}, {2, 0}};
Wolfram Language code: deg = Length[pts] - 1;
Wolfram Language code: BezierCurve[pts, SplineDegree -> deg]
Wolfram Language code: Graphics[%]

控制点越少，生成的曲线次数越低：

Wolfram Language code: BezierCurve[Take[pts, 4], SplineDegree -> deg]
Wolfram Language code: Graphics[%]

通过更多的控制点，可以生成一条复合贝塞尔曲线：

Wolfram Language code: BezierCurve[pts, SplineDegree -> 3]
Wolfram Language code: Graphics[%]

开放的贝塞尔曲线：

Wolfram Language code: Graphics[{BezierCurve[{{-2, 0}, {-1, 2}, {1, 2}, {2, 0}}]}]

闭合的：

Wolfram Language code: Graphics[{BezierCurve[{{-2, 0}, {-1, 2}, {1, 2}, {2, 0}}, SplineClosed -> True]}]

图形  (12)

彩色的曲线：

Wolfram Language code: Table[Graphics[{c, BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]}], {c, {RGBColor[0.93, 0.27, 0.27], RGBColor[0.14, 0.8, 0.14], RGBColor[0.4, 0.6, 1]}}]

不同粗细的贝塞尔曲线：

Wolfram Language code: Table[Graphics[{Thickness[i], BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{t, BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]}], {t, {Thin, Thick}}]

相对于 PlotRange 缩放的粗细：

Wolfram Language code: Table[Graphics[{Thickness[i], BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]}], {i, {.005, .05, .1}}]

以打印阵点表示的粗细：

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]}], {i, {1, 5, 10}}]

虚线：

Wolfram Language code: Table[Graphics[{Dashing[i], BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{d, BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]}], {d, {Dotted, Dashed, DotDashed}}]

Opacity 指定曲线的透明度：

Wolfram Language code: Table[Graphics[{Opacity[o], BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]}], {o, {0.1, 0.5, 0.9}}]

在用作 FilledCurve 的边界时，可通过 EdgeForm 指定曲线的样式：

Wolfram Language code: Graphics[{EdgeForm[{StandardBlue, Thick}], Opacity[0.1], FilledCurve[BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]]}]

BezierCurve 可用作二维图形中 Arrow 的曲线：

Wolfram Language code: Graphics[{Arrowheads[Large], Arrow[BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}]]}]

3D：

Wolfram Language code: Graphics3D[{Arrowheads[Large], Arrow[BezierCurve[{{0, 0, 0}, {1, 2, 2}, {3, 2, 02}, {4, 0, 0}}]]}]

在三维空间中，BezierCurve 可用作 Tube 的曲线：

Wolfram Language code: Graphics3D[{Tube[BezierCurve[{{0, 0, 0}, {1, 2, 2}, {3, 2, 02}, {4, 0, 0}}], 0.1]}]

带有 Arrow 的 Tube：

Wolfram Language code: Graphics3D[{Arrowheads[0.2], Arrow[Tube[BezierCurve[{{0, 0, 0}, {1, 2, 2}, {3, 2, 02}, {4, 0, 0}}], 0.1]]}]

BezierCurve 可用在 GraphicsComplex 中：

Wolfram Language code: Graphics[{GraphicsComplex[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}, BezierCurve[{1, 2, 3, 4}]]}]

默认情况下，控制点被假定为在世界坐标系中：

Wolfram Language code: pts = {{0, 0}, {(1/4), 1}, {(3/4), 1}, {1, 0}};
Wolfram Language code: Table[Graphics[{BezierCurve[pts]}, Frame -> True, PlotRange -> {{0, pr}, {0, pr}}], {pr, {1, 2, 4}}]

用 Scaled 来指定相对于 PlotRange 的控制点：

Wolfram Language code: Table[Graphics[{BezierCurve[Map[Scaled, pts]]}, Frame -> True, PlotRange -> {{0, pr}, {0, pr}}], {pr, {4, 8, 16}}]

用 ImageScaled 来指定相对于整个二维图像区域的控制点：

Wolfram Language code: Table[Graphics[{BezierCurve[Map[ImageScaled, pts]]}, Frame -> True, PlotRange -> {{0, pr}, {0, pr}}], {pr, {4, 8, 16}}]

用 Offset 设置二维控制点的绝对偏移量：

Wolfram Language code: pts = {{0, 0}, {(1/4), 1}, {(3/4), 1}, {1, 0}};
Wolfram Language code: offsets = {{-80, 0}, {0, 0}, {80, 0}};
Wolfram Language code: Graphics[{Table[BezierCurve[Map[Offset[offset, #]&, pts]], {offset, offsets}]}, PlotRange -> {{-1.4, 2.4}, {-0.1, 1}}, ImageSize -> 250]

控制点可以是 Dynamic：

Wolfram Language code: DynamicModule[{z = 0, pts}, pts = {{Dynamic[{0, z}], {1, 2}, {3, 2}, {4, 0}}}; {Slider[Dynamic[z], {0, 4}], Graphics[{BezierCurve[pts]}]}]

区域  (6)

嵌入维度：

Wolfram Language code: reg = BezierCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}];
Wolfram Language code: RegionEmbeddingDimension[reg]

几何维度：

Wolfram Language code: RegionDimension[reg]

点成员测试：

Wolfram Language code: reg = BezierCurve[{{0, 0}, {1, 2}, {3, 2}, {4, 0}}];
Wolfram Language code: {RegionMember[reg, {0, 0}], RegionMember[reg, {0, 1}]}

弧长：

Wolfram Language code: reg = BezierCurve[{{0, 0}, {1, 2}, {2, 0}}];
Wolfram Language code: {ArcLength[reg], RegionMeasure[reg]}

形心：

Wolfram Language code: c = RegionCentroid[reg]
Wolfram Language code: Show[Region[reg], Graphics[{LightDarkSwitched[Black, White], Point[c]}]]

与点的距离：

Wolfram Language code: reg = BezierCurve[{{-1, -1}, {0, 1}, {1, -1}}];
Wolfram Language code: {RegionDistance[reg, {-1, -1}], RegionDistance[reg, {2, 2}]}

可视化等距线：

Wolfram Language code: Show[Region[reg], ContourPlot[Evaluate@RegionDistance[reg, {x, y}], {x, -4, 4}, {y, -4, 3}, Contours -> {1, 2, 3}, ...], Frame -> True]

到点的有符号距离：

Wolfram Language code: reg = BezierCurve[{{-1, -1}, {0, 1}, {1, -1}}];
Wolfram Language code: {SignedRegionDistance[reg, {-1, -1}], SignedRegionDistance[reg, {2, 2}]}

贝塞尔曲线是有边界的：

Wolfram Language code: reg = BezierCurve[{{-1, -1}, {0, 1}, {1, -1}}];
Wolfram Language code: BoundedRegionQ[reg]

获取其范围：

Wolfram Language code: bb = CoordinateBoundingBox[reg]
Wolfram Language code: Show[Region[reg], Graphics[{Opacity[0.1], EdgeForm[Dashed], Cuboid@@bb}]]

选项  (3)

SplineDegree  (2)

默认情况下，一个具有 4 个或更多控制点的 BezierCurve 将使用 3 次曲线：

Wolfram Language code: pts = Table[{i, (-1) ^ i}, {i, 10}];
Wolfram Language code: {BezierCurve[Take[pts, 4]], BezierCurve[Take[pts, 10]]}

控制点较少时，会使用较低的次数：

Wolfram Language code: {BezierCurve[Take[pts, 2]], BezierCurve[Take[pts, 3]]}

用 SplineDegree 指定应使用较低的次数：

Wolfram Language code: BezierCurve[pts, SplineDegree -> 1]

更高的次数：

Wolfram Language code: BezierCurve[pts, SplineDegree -> 9]

对于有 n 个控制点的 BezierCurve，当指定次数 d 满足 d < n-1 时，将生成一条复合贝塞尔曲线：

Wolfram Language code: pts = Table[{i, 2(-1) ^ i}, {i, 7}];
Wolfram Language code: Region[BezierCurve[pts, SplineDegree -> #]]& /@ {2, 3, 4}

SplineClosed  (1)

默认情况下，曲线是开放的：

Wolfram Language code: pts = {{0, -(1/2)}, {(Sqrt[3]/2), -(1/2)}, {(Sqrt[3]/2), (1/2)}, {0, (1/2)}, {-(Sqrt[3]/2), (1/2)}, {-(Sqrt[3]/2), -(1/2)}};
Wolfram Language code: Graphics[{BezierCurve[pts]}]

用 SplineClosed 使曲线闭合：

Wolfram Language code: Graphics[{BezierCurve[pts, SplineClosed -> True]}]

这相当于将第一个控制点附加到数组的末尾：

Wolfram Language code: Graphics[{BezierCurve[Append[pts, First[pts]]]}]

应用  (6)

字体  (4)

字体通常使用贝塞尔曲线来定义字形轮廓：

Wolfram Language code: Graphics[BezierCurve[#]]& /@ {IconizedObject[«[image]»], IconizedObject[«[image]»], IconizedObject[«[image]»]}

指定不同样式的边：

Wolfram Language code: glyph = FilledCurve[BezierCurve[IconizedObject[«[image]»]]];
Wolfram Language code: Graphics[{EdgeForm[#], FaceForm[], glyph}]& /@ {Thick, Dashed, StandardRed}

不同的填充样式：

Wolfram Language code: Graphics[{#, glyph}]& /@ {StandardBlue, LinearGradientFilling[{StandardRed, StandardYellow}], HatchFilling[0, 1, 3]}

视觉效果：

Wolfram Language code: Graphics[{#, glyph}, PlotRangePadding -> Scaled[0.05]]& /@ {DropShadowing[], Haloing[StandardYellow, 0, 5], Blurring[]}

用 RegionDilation 来模拟不同的字体粗细：

Wolfram Language code: glyph = FilledCurve[Map[List, BezierCurve /@ {IconizedObject[«[image]»], IconizedObject[«[image]»], IconizedObject[«[image]»]}]];
Wolfram Language code: Table[Graphics[RegionDilation[glyph, t]], {t, {0, 2}}]

Haloing：

Wolfram Language code: Table[Graphics[{Haloing[ThemeColor["Foreground"], t], glyph}, PlotRangePadding -> Scaled[.1]], {t, {0, 5}}]

用 ShearingTransform 模拟不同的字体倾斜效果：

Wolfram Language code: glyph = FilledCurve[Map[List, BezierCurve /@ {IconizedObject[«[image]»], IconizedObject[«[image]»], IconizedObject[«[image]»]}]];
Wolfram Language code: Table[Graphics[GeometricTransformation[glyph, ShearingTransform[θ , {1, 0}, {0, 1}]]], {θ, {0, 20Degree}}]

向量图形  (2)

用 BezierCurve 来绘制由自由曲线路径组成的形状：

Wolfram Language code: Graphics[{BezierCurve[IconizedObject[«[image]»]]}]

用 FilledCurve 来设置形状内部的样式：

Wolfram Language code: Graphics[{LinearGradientFilling[{Hue[0.333, 0.8250000000000001, 0.639], Hue[0.169, 1, 0.9530000000000001]}, Top], EdgeForm[Thick], FilledCurve[BezierCurve[IconizedObject[«[image]»]]]}]

用多条贝塞尔曲线绘制更复杂的形状：

Wolfram Language code: curves = BezierCurve /@ {IconizedObject[«[image]»], IconizedObject[«[image]»], IconizedObject[«[image]»], IconizedObject[«[image]»], IconizedObject[«[image]»]};
Wolfram Language code: Graphics[curves]

设置内部的样式：

Wolfram Language code: Graphics[{FilledCurve[List /@ curves], RGBColor[0.9058724017188509, 0.13725482819401516, 0., 1.], FilledCurve[curves[[1]]]}]

属性和关系  (14)

次数为 1 的 BezierCurve 等价于 Line：

Wolfram Language code: pts = {{0, -1}, {2, 1}, {4, -1}, {6, 1}};
Wolfram Language code: Graphics /@ {BezierCurve[pts, SplineDegree -> 1], Line[pts]}

BezierCurve 是 BSplineCurve 的特例：

Wolfram Language code: pts = {{-3, 0}, {6, 5}, {-6, -5}, {3, 0}};
Wolfram Language code: Graphics /@ {BezierCurve[pts], BSplineCurve[pts]}

用 RegionConvert 获取等价的 BSplineCurve：

Wolfram Language code: RegionConvert[BezierCurve[pts], "Spline"]

BezierSurface 是 BezierCurve 的高维形式，它接受一个控制点矩形数组：

Wolfram Language code: pts = (⁠| | | | | | ---------- | ----------- | ----------- | ----------- | | {0, 0, 7} | {0, 3, 10} | {0, 7, 10} | {0, 10, 7} | | {3, 0, 10} | {3, 3, 14} | {3, 7, 14} | {3, 10, 10} | | {7, 0, 10} | {7, 3, 14} | {7, 7, 14} | {7, 10, 10} | | {10, 0, 7} | {10, 3, 10} | {10, 7, 10} | {10, 10, 7} |⁠);
Wolfram Language code: Graphics3D[BezierSurface[pts]]

下面的 BezierSurface 的边界由四条贝塞尔曲线构成：

Wolfram Language code: bc = Map[BezierCurve, {pts[[1]], pts[[-1]], pts[[All, 1]], pts[[All, -1]]}];
Wolfram Language code: Graphics3D[{BezierSurface[pts], Thick, StandardRed, bc}]

BezierSurface 上的所有等参曲线都是有效的贝塞尔曲线：

Wolfram Language code: uc = Table[BezierCurve[Map[#[u]&, Map[BezierFunction, pts]]], {u, 0, 1, 1 / 5}]; vc = Table[BezierCurve[Map[#[v]&, Map[BezierFunction, Transpose[pts]]]], {v, 0, 1, 1 / 5}];
Wolfram Language code: Graphics3D[{BezierSurface[pts], Thick, RGBColor[0.14, 0.8, 0.14], uc, RGBColor[0.4, 0.6, 1], vc}]

可用一条复合的 BezierCurve 很好地近似一个 Circle：

Wolfram Language code: Region /@ {BezierCurve[IconizedObject[«[image]»]], Circle[]}

近似误差很小：

Wolfram Language code: RegionHausdorffDistance@@%

BezierCurve 总是对第一个和最后一个控制点进行插值：

Wolfram Language code: pts = {{0, -1}, {1, 2}, {2, -2}, {3, 1}};
Wolfram Language code: Graphics[{BezierCurve[pts], Red, Point[{First[pts], Last[pts]}]}]

Bézier 曲线位于其控制点的凸包内：

Wolfram Language code: pts = {{0, -1}, {2, 1}, {4, -1}, {6, 1}, {4, 2}};
Wolfram Language code: hull = ConvexHullMesh[pts, MeshCellStyle -> {0 -> Red, 2 -> Opacity[1 / 4]}];
Wolfram Language code: Show[hull, Region[BezierCurve[pts, SplineDegree -> 4]]]

在三维空间中，具有共面控制点的贝塞尔曲线与其控制点位于同一平面内：

Wolfram Language code: pts = {{-3, -1, 0}, {6, 10, 0}, {-6, -10, 0}, {3, 1, 0}};
Wolfram Language code: pts//CoplanarPoints
Wolfram Language code: Graphics3D[{InfinitePlane[Take[pts, 3]], BezierCurve[pts]}, Lighting -> "Accent", ViewPoint -> #]& /@ {2{1, -1, 1}, Front, Top}

BezierFunction 给出 BezierCurve 上对应于特定参数值的位置：

Wolfram Language code: pts = {{-3, 0}, {6, 5}, {-6, -5}, {3, 0}};
Wolfram Language code: bfunc = BezierFunction[pts]
Wolfram Language code: positions = Table[bfunc[u], {u, 0, 1, 1 / 10}];
Wolfram Language code: Graphics[{BezierCurve[pts], StandardRed, PointSize[0.02], Point[positions]}]

Bézier 曲线可以通过使用 Bernstein 多项式对其控制点进行加权求和来构建：

Wolfram Language code: pts = {{0, -1}, {1, 1}, {2, -1}, {3, 1}};
Wolfram Language code: bezier[t_] := Sum[BernsteinBasis[3, i, t] * pts[[i + 1]], {i, 0, 3}]
Wolfram Language code: GraphicsRow[{ParametricPlot[bezier[t], {t, 0, 1}, Frame -> True, Axes -> False], Graphics[BezierCurve[pts], Frame -> True]}, ImageSize -> 400]

用 BernsteinBasis 来可视化曲线上每个控制点的权重：

Wolfram Language code: weights = Table[BernsteinBasis[3, i, t], {i, 0, 3}];
Wolfram Language code: Plot[weights, {t, 0, 1}, PlotLegends -> {"SubscriptBox[p, 1]", "SubscriptBox[p, 2]", "SubscriptBox[p, 3]", "SubscriptBox[p, 4]"}]

贝塞尔曲线具有仿射不变性：

Wolfram Language code: pts = {{0, -1}, {2, 2}, {4, -2}, {6, 1}};
Wolfram Language code: A = AffineTransform[{{{1, 1}, {0, 2}}, {1, 2}}];
Wolfram Language code: {Graphics[GeometricTransformation[BezierCurve[pts], A], Frame -> True], Graphics[BezierCurve[A[pts]], Frame -> True]}

对两条贝塞尔曲线的控制点进行平均，等同于对曲线本身进行平均：

Wolfram Language code: pts1 = {{0, -1}, {2, 1}, {4, 2}, {6, 2}}; pts2 = {{2, -1}, {3, 1}, {4, -1}, {6, 0}};
Wolfram Language code: Graphics[{Thick, RGBColor[0.4, 0.6, 1], BezierCurve[pts1], RGBColor[0.98, 0.56, 0.17], BezierCurve[pts2], RGBColor[0.93, 0.27, 0.27], BezierCurve[Mean[{pts1, pts2}]]}, Frame -> True]
Wolfram Language code: ParametricPlot[{BezierFunction[pts1][t], BezierFunction[pts2][t], Mean[{BezierFunction[pts1][t], BezierFunction[pts2][t]}]}, {t, 0, 1}, Frame -> True, Axes -> False, PlotStyle -> {RGBColor[0.4, 0.6, 1], RGBColor[0.98, 0.56, 0.17], RGBColor[0.93, 0.27, 0.27]}]

在两个线段的连接处，一个复合 Bézier 曲线可能不是平滑的：

Wolfram Language code: pts = {{0, 0}, {1, -1}, {3, -1}, {3, 0}, {4, 1}, {5, 1}, {6, 0}};
Wolfram Language code: Graphics[{BezierCurve[pts], Dashed, Gray, Line[pts], Red, Point[pts]}]

将边界附近的点设置为共线，以保证复合贝塞尔曲线的平滑性：

Wolfram Language code: pts[[5, 1]] = 3;
Wolfram Language code: Graphics[{BezierCurve[pts], Dashed, Gray, Line[pts], Red, Point[pts]}]

Bézier 曲线可被改为任意更高次数的等效曲线：

Wolfram Language code: pts = {{0, 0}, {2, 3}, {4, 0}};
Wolfram Language code: elevate[pts_] := With[...]
Wolfram Language code: epts = Table[Nest[elevate, pts, d], {d, 0, 3}];
Wolfram Language code: Graphics /@ Table[{BezierCurve[epts[[i]], SplineDegree -> i + 2], Dashed, Gray, Line[epts[[i]]], Red, Point[epts[[i]]]}, {i, Length[epts]}]

SubdivisionRegion 根据控制网格而非控制点生成平滑曲面：

Wolfram Language code: Region /@ {SubdivisionRegion[[image]], BezierCurve[IconizedObject[«[image]»]]}

互动范例  (2)

单个 Bézier 曲线编辑器：

Wolfram Language code: Column[{Manipulate[DynamicModule[{}, $curve = BezierCurve[pts, SplineDegree -> d, SplineClosed -> c]; Graphics[{$curve, Dashed, Opacity[0.5], Line[pts]}, PlotRange -> 5, Frame -> True, ImageSize -> 250]], {{pts, {{-4, -4}, {-3, 4}, {3, -4}, {4, 4}}}, Locator, LocatorAutoCreate -> True}, {{d, 3, "degree"}, 2, 6, 1}, {{c, False, "closed"}, {False, True}}], Button["Copy Curve to Clipboard", CopyToClipboard[$curve]]}]

在两个简单的贝塞尔曲线之间平滑插值：

Wolfram Language code: interpolateCurves[pts1_, pts2_] := Manipulate[Graphics[{BezierCurve[pts1(1 - t) + pts2 t], Opacity[0.25], Dashed, BezierCurve[pts1], BezierCurve[pts2]}], {t, 0, 1}]
Wolfram Language code: interpolateCurves[{...}, {...}]

两条符合曲线：

Wolfram Language code: interpolateCurves@@{{...}, {...}}

巧妙范例  (1)

由复合贝塞尔曲线构成的花朵：

Wolfram Language code: Graphics[BezierCurve[Table[{Cos[2k Pi / 13], Sin[2 k Pi / 13]}, {k, 0, 156, 4}]]]
Wolfram Research (2008)，BezierCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BezierCurve.html.

文本

Wolfram Research (2008)，BezierCurve，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BezierCurve.html.

CMS

Wolfram 语言. 2008. "BezierCurve." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BezierCurve.html.

APA

Wolfram 语言. (2008). BezierCurve. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BezierCurve.html 年

BibTeX

@misc{reference.wolfram_2026_beziercurve, author="Wolfram Research", title="{BezierCurve}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BezierCurve.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_beziercurve, organization={Wolfram Research}, title={BezierCurve}, year={2008}, url={https://reference.wolfram.com/language/ref/BezierCurve.html}, note=[Accessed: 16-August-2026]}